spec.vim

   1 " Filename:    spec.vim
   2 " Purpose:     Vim syntax file
   3 " Language:    SPEC: Build/install scripts for Linux RPM packages
   4 " Maintainer:  Donovan Rebbechi elflord@pegasus.rutgers.edu
   5 " URL:         http://pegasus.rutgers.edu/~elflord/vim/syntax/spec.vim
   6 " Last Change: Tue Oct  3 17:35:15 BRST 2000 <aurelio@conectiva.com.br>
   7
   8 " For version 5.x: Clear all syntax items
   9 " For version 6.x: Quit when a syntax file was already loaded
  10 if version < 600
  11   syntax clear
  12 elseif exists("b:current_syntax")
  13   finish
  14 endif
  15
  16 syn sync minlines=1000
  17
  18 syn match specSpecialChar contained '[][!$()\\|>^;:]'
  19 syn match specColon       contained ':'
  20 syn match specPercent     contained '%'
  21 syn match specSubstChar   contained '[#%]'
  22
  23 syn match specVariables   contained '\$\h\w*' contains=specSpecialVariablesNames,specSpecialChar
  24 syn match specVariables   contained '\${\w*}' contains=specSpecialVariablesNames,specSpecialChar
  25 syn match specVariables   contained '\${\w*[#%][^}]*}' contains=specSubstChar
  26
  27 syn match specMacroIdentifier contained '%\h\w*' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  28 "syn match specMacroIdentifier contained '%{\w*}' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  29 syn region specMacroIdentifier oneline matchgroup=Special start='%{' skip='\\}' end='}' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  30 syn match specBcond contained '%{with\(out\)\?\s\+[a-zA-Z0-9_-]\+}'
  31
  32 syn match specSpecialVariables contained '\$[0-9]\|\${[0-9]}'
  33 syn match specCommandOpts      contained '\s\(-\w\+\|--\w[a-zA-Z0-9_-]\+\)'ms=s+1
  34 syn match specComment '^\s*#.*$'
  35
  36
  37 syn case match
  38
  39
  40 " matches with no highlight
  41 syn match specNoNumberHilite 'X11\|X11R6\|[a-zA-Z]*\.\d\|[a-zA-Z][-/]\d'
  42 syn match specManpageFile '[a-zA-Z]\.1'
  43
  44 " Day, Month and most used license acronyms
  45 syn keyword specLicense contained GPL LGPL BSD MIT GNU Apache PHP
  46 syn keyword specLicenseWarning contained unknown
  47 syn match specLicenseWarning contained /same as perl/
  48 syn match specLicenseWarning contained "(enter GPL/LGPL/BSD/BSD-like/Artistic/other license name here)"
  49 syn keyword specWeekday contained Mon Tue Wed Thu Fri Sat Sun
  50 syn keyword specMonth   contained Jan Feb Mar Apr Jun Jul Aug Sep Oct Nov Dec
  51 syn keyword specMonth   contained January February March April May June July August September October November December
  52
  53 " #, @, www
  54 syn match specNumber '\(^-\=\|[ \t]-\=\|-\)[0-9.-]*[0-9]'
  55 syn match specEmail contained "<\=\<[A-Za-z0-9_.-]\+@\([A-Za-z0-9_-]\+\.\)\+[A-Za-z]\+\>>\="
  56 syn match specURL      contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#?=-]\+\>'
  57 syn match specURLMacro contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#%{}-]\+\>' contains=specMacroIdentifier
  58
  59 " TODO take specSpecialVariables out of the cluster for the sh* contains (ALLBUT)
  60 " Special system directories
  61 syn match specListedFilesPrefix contained '/\(usr\|local\|opt\|X11R6\|X11\)/'me=e-1
  62 syn match specListedFilesBin    contained '/s\=bin/'me=e-1
  63 syn match specListedFilesLib    contained '/\(lib\|include\)/'me=e-1
  64 syn match specListedFilesDoc    contained '/\(man\d*\|doc\|info\)\>'
  65 syn match specListedFilesEtc    contained '/etc/'me=e-1
  66 syn match specListedFilesShare  contained '/share/'me=e-1
  67 syn cluster specListedFiles contains=specListedFilesBin,specListedFilesLib,specListedFilesDoc,specListedFilesEtc,specListedFilesShare,specListedFilesPrefix,specSpecialChar
  68
  69 " specComands
  70 syn match   specConfigure  contained '\./configure'
  71 syn match   specTarCommand contained '\<tar\s\+[cxvpzjf]\{,5}\s*'
  72
  73 " XXX don't forget to update specScriptArea when updating specMacro
  74 syn match   specMacro contained '%\(group\|user\)\(add\|remove\)'
  75 syn match   specMacro contained '%\(depmod\|banner\|service\|addusertogroup\|env_update\)'
  76 syn match   specMacro contained '%\(\(nsplugin\|apache_config\)_\(un\)\?install\)'
  77 syn match   specMacro contained '%\(\(openldap_schema\|webapp\)_\(un\)\?register\)'
  78 syn match   specMacro contained '%\(pear_package_\(setup\|install\)\)'
  79 syn match   specMacro contained '%\(py_o\?comp\|py_postclean\)'
  80 syn match   specMacro contained '%\(build\|install\)_kernel_modules'
  81 syn match   specMacro contained '%ant'
  82 syn match   specMacro contained '%\(php\|php4\)_webserver_restart'
  83 syn match   specMacro contained '%update_browser_plugins\|%browser_plugins_add_browser'
  84
  85 syn keyword specCommandSpecial contained root
  86 syn keyword specCommand         contained make xmkmf mkdir chmod find sed rm strip moc echo grep ls rm mv mkdir chown install cp pwd cat tail then else elif cd gzip rmdir ln eval export touch unzip bzip2
  87 syn cluster specCommands contains=specCommand,specTarCommand,specConfigure,specCommandSpecial,specMacro
  88
  89 " frequently used rpm env vars
  90 syn keyword specSpecialVariablesNames contained RPM_BUILD_ROOT RPM_BUILD_DIR RPM_SOURCE_DIR RPM_OPT_FLAGS LDFLAGS CC CC_FLAGS CPPNAME CFLAGS CXX CXXFLAGS CPPFLAGS
  91
  92 " valid macro names from /usr/lib/rpm/macros
  93 syn keyword specMacroNameOther contained buildroot buildsubdir distribution disturl ix86 name nil optflags perl_sitearch release requires_eq vendor version
  94 syn keyword specMacroNameOther contained __kernel_ver date debugcflags debuginfocflags epoch kgcc kgcc_package packager
  95 syn keyword specMacroNameOther contained pear_package_install pear_package_setup perl_archlib perl_privlib perl_sitelib
  96 syn keyword specMacroNameOther contained perl_vendorarch perl_vendorlib php_pear_dir py_sitedir py_scriptdir py_sitescriptdir
  97 syn keyword specMacroNameOther contained requires_php_extension requires_php_pdo_module
  98 syn keyword specMacroNameOther contained requires_zend_extension ruby_mod_ver_requires_eq ruby_ver_requires_eq rpmcflags rpmcxxflags rpmldflags tmpdir x8664
  99 syn keyword specMacroNameOther contained ruby_archdir ruby_rubylibdir ruby_vendorarchdir ruby_vendorlibdir ruby_ridir ruby_sitearchdir ruby_sitelibdir ruby_version
 100 syn keyword specMacroNameOther contained apache_modules_api php_sysconfdir php_includedir php_extensiondir _browserpluginsdir _browserpluginsconfdir
 101 syn keyword specMacroNameOther contained releq_kernel releq_kernel_up releq_kernel_smp requires_releq_kernel requires_releq_kernel_up requires_releq_kernel_smp
 102
 103 syn match   specMacroNameOther contained '\<\(PATCH\|SOURCE\)\d*\>'
 104
 105 " valid _macro names from /usr/lib/rpm/macros
 106 syn keyword specMacroNameLocal contained _aclocaldir _applnkdir _arch _binary_payload _bindir _build _build_arch _build_alias
 107 syn keyword specMacroNameLocal contained _build_cpu _builddir _build_os _buildshell _buildsubdir _build_vendor _bzip2bin _datadir
 108 syn keyword specMacroNameLocal contained _dbpath _dbpath_rebuild _defaultdocdir _desktopdir _docdir _examplesdir _excludedocs _kdedocdir
 109 syn keyword specMacroNameLocal contained _exec_prefix _fixgroup _fixowner _fixperms _fontsdir _ftpport _ftpproxy _gnu _gpg_name
 110 syn keyword specMacroNameLocal contained _gpg_path _gtkdocdir _gzipbin _host _host_alias _host_cpu _host_os _host_vendor
 111 syn keyword specMacroNameLocal contained _httpport _httpproxy _iconsdir _includedir _infodir _initrddir _install_langs
 112 syn keyword specMacroNameLocal contained _install_script_path _instchangelog _javaclasspath _javadir _javadocdir _kernelsrcdir
 113 syn keyword specMacroNameLocal contained _kernel_ver _kernel_ver_str _langpatt _lib _libdir _libexecdir _localstatedir _mandir
 114 syn keyword specMacroNameLocal contained _netsharedpath _oldincludedir _omf_dest_dir _os _package_version _pgpbin _pgp_name
 115 syn keyword specMacroNameLocal contained _pgp_path _pixmapsdir _pkgconfigdir _prefix _preScriptEnvironment _provides _rpmdir
 116 syn keyword specMacroNameLocal contained _rpmfilename _sbindir _sharedstatedir _signature _smp_mflags _sourcedir _source_payload
 117 syn keyword specMacroNameLocal contained _specdir _srcrpmdir _sysconfdir _target _target_alias _target_cpu _target_os _target_platform
 118 syn keyword specMacroNameLocal contained _target_vendor _target_base_arch _timecheck _tmppath _topdir _usr _usrsrc _var _vendor
 119 syn keyword specMacroNameLocal contained __cxx __cc __libtoolize __autopoint __aclocal __autoconf __automake __autoheader
 120 syn keyword specMacroNameLocal contained __gettextize __glib_gettextize __intltoolize
 121 syn keyword specMacroNameLocal contained __bzip2 __cat __chgrp __chmod __chown __cp   __cpio __file __gpg __grep __gzip
 122 syn keyword specMacroNameLocal contained __id  __install __ld   __make   __mkdir __mkdir_p __mv __nm  __objcopy __objdump
 123 syn keyword specMacroNameLocal contained __patch __perl __pgp __python __rm __rsh  __sed __ssh __strip  __tar __unzip
 124
 125
 126
 127 " ------------------------------------------------------------------------------
 128 " here's is all the spec sections definitions: PreAmble, Description, Package,
 129 "   Scripts, Files and Changelog
 130
 131 " One line macros - valid in all ScriptAreas
 132 " tip: remember do include new items on specScriptArea's skip section
 133 syn region specSectionMacroArea oneline matchgroup=specSectionMacro start='^%\(\(un\)\?define\|dump\|trace\|patch\d*\|setup\|configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|scons\|waf\|bcond_with\(out\)\?\|include\)\>' end='$' contains=specCommandOpts,specMacroIdentifier,specSectionMacroBcondArea
 134 syn region specSectionMacroBracketArea oneline matchgroup=specSectionMacro start='^%{\(configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|scons\|waf\)}' end='$' contains=specCommandOpts,specMacroIdentifier
 135 syn region specSectionMacroBcondArea oneline matchgroup=specBlock start='%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):' skip='\\}' end='}' contains=ALLBUT,shCase
 136
 137 " %% Files Section %%
 138 " TODO %config valid parameters: missingok\|noreplace
 139 " TODO %verify valid parameters: \(not\)\= \(md5\|atime\|...\)
 140 syn region specFilesArea matchgroup=specSection start='^%[Ff][Ii][Ll][Ee][Ss]\>'
 141         \ skip='%\(attrib\|defattr\|attr\|dir\|config\|docdir\|doc\|lang\|verify\|ghost\|exclude\|dev\|if\|else\|endif\)\>'
 142         \ end='^%[a-zA-Z]'me=e-2
 143         \ contains=specFilesOpts,specFilesDirective,@specListedFiles,specComment,specCommandSpecial,specMacroIdentifier,specSectionMacroBcondArea,specIf
 144
 145 " tip: remember to include new items in specFilesArea above
 146 syn match  specFilesDirective contained '%\(attrib\|defattr\|attr\|dir\|config\|docdir\|doc\|lang\|verify\|ghost\|exclude\|dev\)\>'
 147
 148 " valid options for certain section headers
 149 syn match specDescriptionOpts contained '\s-[ln]\s*\a'ms=s+1,me=e-1
 150 syn match specPackageOpts     contained    '\s-n\s*\w'ms=s+1,me=e-1
 151 syn match specFilesOpts       contained    '\s-f\s*\w'ms=s+1,me=e-1
 152
 153
 154 syn case ignore
 155
 156
 157 " %% PreAmble Section %%
 158 " Copyright and Serial were deprecated by License and Epoch
 159 " PreReq and BuildPreReq deprecated by Requires ans BuildRequires
 160 syn region specPreAmbleDeprecated oneline matchgroup=specError start='^\(Copyright\|Serial\|PreReq\|BuildPreReq\(uires\)\?\)' end='$' contains=specEmail,specURL,specURLMacro,specLicense,specColon,specVariables,specSpecialChar,specMacroIdentifier
 161 syn region specPreAmble oneline matchgroup=specCommand
 162         \ start='\(^\|\(^%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):\)\@<=\)\(Summary\|Name\|Version\|Packager\|Requires\|Suggests\|Icon\|URL\|Source\d*\|Patch\d*\|Prefix\|Packager\|Group\|License\|Release\|BuildRoot\|Distribution\|Vendor\|Provides\|ExclusiveArch\|ExcludeArch\|ExclusiveOS\|Obsoletes\|BuildArch\|BuildArchitectures\|BuildRequires\|BuildConflicts\|Conflicts\|AutoRequires\|AutoReqProv\|AutoReq\|AutoProv\|Epoch\|NoSource\)'
 163         \ end='$\|}\@='
 164         \ contains=specEmail,specURL,specURLMacro,specLicense,specLicenseWarning,specColon,specVariables,specSpecialChar,specMacroIdentifier,specSectionMacroBcondArea
 165
 166 " %% Description Section %%
 167 syn region specDescriptionArea matchgroup=specSection start='^%description' end='^%'me=e-1
 168         \ contains=specDescriptionOpts,specEmail,specURL,specNumber,specMacroIdentifier,specComment
 169
 170 " %% Package Section %%
 171 syn region specPackageArea matchgroup=specSection start='^%package' end='^%'me=e-1
 172         \ contains=specPackageOpts,specPreAmble,specComment,specMacroNameOther
 173
 174 " %% Scripts Section %%
 175 syn region specScriptArea matchgroup=specSection
 176         \ start='^%\(prep\|build\|install\|clean\|pre\|postun\|preun\|post\|triggerin\|triggerun\|triggerpostun\|pretrans\|posttrans\|verifyscript\|check\)\>'
 177         \ skip='^%{\|^%\(define\|patch\d*\|configure2_13\|configure\|ant\|GNUconfigure\|setup\|find_lang\|makeinstall\|cmake\|scons\|waf\|useradd\|groupadd\|addusertogroup\|banner\|service\|env_update\|py_o\?comp\|py_postclean\|\(openldap_schema\|webapp\)_\(un\)\?register\|depmod\|pear_package_\(setup\|install\)\|\(build\|install\)_kernel_modules\|php_webserver_restart\|php4_webserver_restart\|update_browser_plugins\)\>'
 178         \ end='^%'me=e-1
 179         \ contains=specSpecialVariables,specVariables,@specCommands,specVariables,shDo,shFor,shCaseEsac,specNoNumberHilite,specCommandOpts,shComment,shIf,specSpecialChar,specMacroIdentifier,specSectionMacroArea,specSectionMacroBracketArea,shOperator,shQuote1,shQuote2,specSectionMacroBcondArea
 180 " XXX don't forget to update specMacro when updating specScriptArea skip definition
 181
 182 " %% Changelog Section %%
 183 syn region specChangelogArea matchgroup=specSection start='^%changelog' end='^%'me=e-1
 184         \ contains=specEmail,specURL,specWeekday,specMonth,specNumber,specComment,specLicense,specRevision,specLogMessage,specLogError
 185
 186 syn match specRevision contained "^Revision [.0-9]\+  [-/0-9]\+ [:0-9]\+  [a-zA-Z0-9]\+$"
 187 syn region specLogMessage contained start="^[- ] " end="$" contains=specLogError,specURL,specEmail
 188 syn match specLogError contained "%%"
 189
 190 " ------------------------------------------------------------------------------
 191 " here's the shell syntax for all the Script Sections
 192
 193
 194 syn case match
 195
 196
 197 " sh-like comment style, only valid in script part
 198 syn match shComment contained '#.*$'
 199
 200 syn region shQuote1 contained matchgroup=shQuoteDelim start=+'+ skip=+\\'+ end=+'+ contains=specMacroIdentifier
 201 syn region shQuote2 contained matchgroup=shQuoteDelim start=+"+ skip=+\\"+ end=+"+ contains=specVariables,specMacroIdentifier,specSectionMacroBcondArea
 202
 203 syn match shOperator contained '[><|!&;]\|[!=]='
 204 syn region shDo transparent matchgroup=specBlock start="\(^\|\s\)do\(\s\|$\)" end="\(^\|\s\)done\(\s\|$\)" contains=ALLBUT,shDoError,shCase,specPreAmble,@specListedFiles
 205
 206 syn region specIf  matchgroup=specBlock start="%ifosf\|%ifos\|%ifnos\|%ifarch\|%ifnarch\|ifdef\|ifndef\|%if\|%else"  end='%endif'  contains=ALLBUT, specIfError, shCase, shComment
 207
 208 syn region shIf transparent matchgroup=specBlock start="\(^\|\s\)if\(\s\|$\)" end="\(^\|\s\)fi\(\s\|$\)" contains=ALLBUT,shIfError,shCase,@specListedFiles
 209
 210 syn region shFor  matchgroup=specBlock start="\(^\|\s\)for\(\s\|$\)" end="\(^\|\s\)in\(\s\|$\)" contains=ALLBUT,shInError,shCase,@specListedFiles
 211
 212 syn region shCaseEsac transparent matchgroup=specBlock start="\(^\|\s\)case\(\s\|$\)" matchgroup=NONE end="\(^\|\s\)in\(\s\|$\)"me=s-1 contains=ALLBUT,@specListedFiles nextgroup=shCaseEsac
 213 syn region shCaseEsac matchgroup=specBlock start="\(^\|\s\)in\(\s\|$\)" end="\(^\|\s\)esac\(\s\|$\)" contains=ALLBUT,@specListedFilesBin
 214 syn region shCase matchgroup=specBlock contained start=")"  end=";;" contains=ALLBUT,shCase,@specListedFiles
 215
 216 syn sync match shDoSync       grouphere  shDo       "\<do\>"
 217 syn sync match shDoSync       groupthere shDo       "\<done\>"
 218 syn sync match shIfSync       grouphere  shIf       "\<if\>"
 219 syn sync match shIfSync       groupthere shIf       "\<fi\>"
 220 syn sync match specIfSync     grouphere  specIf     "%ifarch\|%ifos\|%ifnos"
 221 syn sync match specIfSync     groupthere specIf     "%endIf"
 222 syn sync match shForSync      grouphere  shFor      "\<for\>"
 223 syn sync match shForSync      groupthere shFor      "\<in\>"
 224 syn sync match shCaseEsacSync grouphere  shCaseEsac "\<case\>"
 225 syn sync match shCaseEsacSync groupthere shCaseEsac "\<esac\>"
 226
 227 " Define the default highlighting.
 228 " For version 5.7 and earlier: only when not done already
 229 " For version 5.8 and later: only when an item doesn't have highlighting yet
 230 if version >= 508 || !exists("did_spec_syntax_inits")
 231   if version < 508
 232     let did_spec_syntax_inits = 1
 233     command -nargs=+ HiLink hi link <args>
 234   else
 235     command -nargs=+ HiLink hi def link <args>
 236   endif
 237
 238   "main types color definitions
 239   HiLink specSection                    Structure
 240   HiLink specSectionMacro               Macro
 241   HiLink specWWWlink                    PreProc
 242   HiLink specOpts                       Operator
 243
 244   "yes, it's ugly, but white is sooo cool
 245   if &background == "dark"
 246     hi def specGlobalMacro              ctermfg=white
 247   else
 248     HiLink specGlobalMacro              Identifier
 249   endif
 250
 251   "sh colors
 252   HiLink shComment                      Comment
 253   HiLink shIf                           Statement
 254   HiLink shOperator                     Special
 255   HiLink shQuote1                       String
 256   HiLink shQuote2                       String
 257   HiLink shQuoteDelim                   Statement
 258
 259   " spec colors
 260   HiLink specBlock                      Function
 261   HiLink specBcond                      Function
 262   HiLink specColon                      Special
 263   HiLink specCommand                    Statement
 264   HiLink specCommandOpts                specOpts
 265   HiLink specCommandSpecial             Special
 266   HiLink specComment                    Comment
 267   HiLink specConfigure                  specCommand
 268   HiLink specDate                       String
 269   HiLink specDescriptionOpts            specOpts
 270   HiLink specEmail                      specWWWlink
 271   HiLink specError                      Error
 272   HiLink specFilesDirective             specSectionMacro
 273   HiLink specFilesOpts                  specOpts
 274   HiLink specLicense                    String
 275   HiLink specLicenseWarning             specError
 276   HiLink specMacroNameLocal             specGlobalMacro
 277   HiLink specMacroNameOther             specGlobalMacro
 278   HiLink specManpageFile                NONE
 279   HiLink specMonth                      specDate
 280   HiLink specNoNumberHilite             NONE
 281   HiLink specNumber                     Number
 282   HiLink specPackageOpts                specOpts
 283   HiLink specPercent                    Special
 284   HiLink specSpecialChar                Special
 285   HiLink specSubstChar                  Special
 286   HiLink specSpecialVariables           specGlobalMacro
 287   HiLink specSpecialVariablesNames      specGlobalMacro
 288   HiLink specTarCommand                 specCommand
 289   HiLink specMacro                      Macro
 290   HiLink specURL                        specWWWlink
 291   HiLink specURLMacro                   specWWWlink
 292   HiLink specVariables                  Identifier
 293   HiLink specWeekday                    specDate
 294   HiLink specListedFilesBin             Statement
 295   HiLink specListedFilesDoc             Statement
 296   HiLink specListedFilesEtc             Statement
 297   HiLink specListedFilesLib             Statement
 298   HiLink specListedFilesPrefix          Statement
 299   HiLink specListedFilesShare           Statement
 300
 301   HiLink specRevision                   Number
 302   HiLink specLogMessage                 Identifier
 303   HiLink specLogError                   Error
 304
 305   delcommand HiLink
 306 endif
 307
 308 let b:current_syntax = "spec"
 309
 310 " vim: ts=8