pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2008 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17
  18 function fixedsub(s1,s2,t,      ind) {
  19 # substitutes fixed strings (not regexps)
  20         if (ind = index(t,s1)) {
  21                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  22         }
  23         return t
  24 }
  25
  26 function ispre(s) {
  27         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  28                 if (DEBUG) print "pre-version"
  29                 return 1
  30         } else {
  31                 return 0
  32         }
  33 }
  34
  35 function compare_ver(v1,v2) {
  36 # compares version numbers
  37         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  38                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  39         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  40                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  41         sub("^0*","",v1)
  42         sub("^0*","",v2)
  43         gsub("\.0*",".",v1)
  44         gsub("\.0*",".",v2)
  45         if (DEBUG) print "v1 == " v1
  46         if (DEBUG) print "v2 == " v2
  47         count=split(v1,v1a,"\.")
  48         count2=split(v2,v2a,"\.")
  49
  50         if (count<count2) mincount=count
  51         else mincount=count2
  52
  53         for (i=1; i<=mincount; i++) {
  54                 if (v1a[i]=="") v1a[i]=0
  55                 if (v2a[i]=="") v2a[i]=0
  56                 if (DEBUG) print "i == " i
  57                 if (DEBUG) print "v1[i] == " v1a[i]
  58                 if (DEBUG) print "v2[i] == " v2a[i]
  59                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  60                         if (length(v2a[i])>length(v1a[i]))
  61                                 return 1
  62                         else if (v2a[i]>v1a[i])
  63                                 return 1
  64                         else if (length(v1a[i])>length(v2a[i]))
  65                                 return 0
  66                         else if (v1a[i]>v2a[i])
  67                                 return 0
  68                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  69                         if (v2a[i]>v1a[i])
  70                                 return 1
  71                         else if (v1a[i]>v2a[i])
  72                                 return 0
  73                 } else if (ispre(v1a[i]) == 1)
  74                         return 1
  75                 else
  76                         return 0
  77         }
  78         if ((count2==mincount)&&(count!=count2)) {
  79                 for (i=count2+1; i<=count; i++)
  80                         if (ispre(v1a[i]) == 1)
  81                                 return 1
  82                 return 0
  83         } else if (count!=count2) {
  84                 for (i=count+1; i<=count2; i++)
  85                         if (ispre(v2a[i]) == 1)
  86                                 return 0
  87                 return 1
  88         }
  89         return 0
  90 }
  91
  92 function compare_ver_dec(v1,v2) {
  93 # compares version numbers as decimal floats
  94         while (match(v1,/[0-9][a-zA-Z]/))
  95                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  96         while (match(v2,/[0-9][a-zA-Z]/))
  97                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  98         sub("^0*","",v1)
  99         sub("^0*","",v2)
 100         if (DEBUG) print "v1 == " v1
 101         if (DEBUG) print "v2 == " v2
 102         count=split(v1,v1a,"\.")
 103         count2=split(v2,v2a,"\.")
 104
 105         if (count<count2) mincount=count
 106         else mincount=count2
 107
 108         for (i=1; i<=mincount; i++) {
 109                 if (v1a[i]=="") v1a[i]=0
 110                 if (v2a[i]=="") v2a[i]=0
 111                 if (DEBUG) print "i == " i
 112                 if (DEBUG) print "v1[i] == " v1a[i]
 113                 if (DEBUG) print "v2[i] == " v2a[i]
 114                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 115                         if (i==2) {
 116                                 if (0+("." v2a[i])>0+("." v1a[i]))
 117                                         return 1
 118                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 119                                         return 0
 120                         } else {
 121                                 if (length(v2a[i])>length(v1a[i]))
 122                                         return 1
 123                                 else if (v2a[i]>v1a[i])
 124                                         return 1
 125                                 else if (length(v1a[i])>length(v2a[i]))
 126                                         return 0
 127                                 else if (v1a[i]>v2a[i])
 128                                         return 0
 129                         }
 130                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 131                         if (v2a[i]>v1a[i])
 132                                 return 1
 133                         else if (v1a[i]>v2a[i])
 134                                 return 0
 135                 } else if (ispre(v1a[i]) == 1)
 136                         return 1
 137                 else
 138                         return 0
 139         }
 140         if ((count2==mincount)&&(count!=count2)) {
 141                 for (i=count2+1; i<=count; i++)
 142                         if (ispre(v1a[i]) == 1)
 143                                 return 1
 144                 return 0
 145         } else if (count!=count2) {
 146                 for (i=count+1; i<=count2; i++)
 147                         if (ispre(v2a[i]) == 1)
 148                                 return 0
 149                 return 1
 150         }
 151         return 0
 152 }
 153
 154 function link_seen(link) {
 155         for (seenlink in frameseen) {
 156                 if (seenlink == link) {
 157                         if (DEBUG) print "Link: [" link "] seen already, skipping..."
 158                         return 1
 159                 }
 160         }
 161         frameseen[link]=1
 162         return 0
 163 }
 164
 165 function get_links(url,filename,errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile) {
 166 # get all <A HREF=..> tags from specified URL
 167         "mktemp /tmp/XXXXXX" | getline tmpfile
 168         close(tmpfile)
 169
 170         if (url ~ /^http:\/\/(download|dl).(sf|sourceforge).net\//) {
 171                 gsub("^http://(download|dl).(sf|sourceforge).net/", "", url)
 172                 url = "http://prdownloads.sourceforge.net/" substr(url, 1, 1) "/" substr(url, 1, 2) "/" url
 173                 if (DEBUG) print "sf url, mungled url to: " url
 174         }
 175
 176         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 177                 gsub("^http://", "", url)
 178                 gsub("\..*", "", url)
 179                 url = "http://code.google.com/p/" url "/downloads/list"
 180                 if (DEBUG) print "googlecode url, mungled url to: " url
 181         }
 182
 183         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 184                 gsub("-.*", "", filename)
 185                 url = "http://pecl.php.net/package/" filename
 186                 if (DEBUG) print "pecl.php.net url, mungled url to: " url
 187         }
 188
 189         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 190                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 191                  if (DEBUG) print "mysql 5.1 url, mungled url to: " url
 192         }
 193
 194
 195         if (DEBUG) print "Retrieving: " url
 196         errno=system("wget -O - \"" url "\" -t 2 -T 45 --passive-ftp > " tmpfile " 2>/dev/null" )
 197
 198         if (errno==0) {
 199                 while (getline oneline < tmpfile)
 200                         wholeodp=(wholeodp " " oneline)
 201                 if ( DEBUG ) print "Response: " wholeodp
 202         }
 203
 204         close(tmpfile)
 205         system("rm -f " tmpfile)
 206         urldir=url;
 207         sub(/[^\/]+$/,"",urldir)
 208
 209         if ( errno==0) {
 210                 while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 211                         odp=substr(wholeodp,RSTART,RLENGTH);
 212                         wholeodp=substr(wholeodp,RSTART+RLENGTH);
 213
 214                         lowerodp=tolower(odp);
 215                         if (lowerodp ~ /<frame[ \t]/) {
 216                                 sub(/[sS][rR][cC]=[ \t]*/,"src=",odp);
 217                                 match(odp,/src="[^"]+"/)
 218                                 newurl=substr(odp,RSTART+5,RLENGTH-6)
 219                                 if (DEBUG) print "Frame: " newurl
 220                                 if (newurl !~ /\//) {
 221                                         newurl=(urldir newurl)
 222                                         if (DEBUG) print "Frame->: " newurl
 223                                 }
 224
 225                                 if (link_seen(newurl)) {
 226                                         newurl=""
 227                                         continue
 228                                 }
 229
 230                                 retval=(retval " " get_links(newurl))
 231                         } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 232                                 sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 233                                 match(odp,/href="[^"]*"/)
 234                                 link=substr(odp,RSTART,RLENGTH)
 235                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 236                                 link=substr(link,7,length(link)-7)
 237
 238                                 if (link_seen(link)) {
 239                                         link=""
 240                                         continue
 241                                 }
 242
 243                                 retval=(retval " " link)
 244                                 if (DEBUG) print "href(\"\"): " link
 245                         } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 246                                 sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 247                                 match(odp,/href='[^']*'/)
 248                                 link=substr(odp,RSTART,RLENGTH)
 249                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 250                                 link=substr(link,7,length(link)-7)
 251
 252                                 if (link_seen(link)) {
 253                                         link=""
 254                                         continue
 255                                 }
 256
 257                                 retval=(retval " " link)
 258                                 if (DEBUG) print "href(''): " link
 259                         } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 260                                 sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 261                                 match(odp,/href=[^ \t>]*/)
 262                                 link=substr(odp,RSTART,RLENGTH)
 263                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 264                                 link=substr(link,6,length(link)-5)
 265
 266                                 if (link_seen(link)) {
 267                                         link=""
 268                                         continue
 269                                 }
 270
 271                                 retval=(retval " " link)
 272                                 if (DEBUG) print "href(): " link
 273                         } else {
 274                                 # <a ...> but not href - skip
 275                                 if (DEBUG) print "skipping <a > without href: " odp
 276                         }
 277                 }
 278         } else {
 279                 retval=("WGET ERROR: " errno)
 280         }
 281
 282
 283         if (DEBUG) print "Returning: " retval
 284         return retval
 285 }
 286
 287 function subst_defines(var,defs) {
 288 # substitute all possible RPM macros
 289         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 290                 oldvar=var
 291                 for (j in defs) {
 292                         gsub("%{" j "}", defs[j], var)
 293                         gsub("%" j , defs[j], var)
 294                 }
 295                 if (var==oldvar) {
 296                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 297                         return var
 298                 }
 299         }
 300         return var
 301 }
 302
 303 function find_mirror(url) {
 304
 305         while (succ = (getline line < "mirrors")) {
 306             if (succ==-1) { return url }
 307                 nf=split(line,fields,"|")
 308                 if (nf>1){
 309                         origin=fields[1]
 310                         mirror=fields[2]
 311                         mname=fields[3]
 312                         prefix=substr(url,1,length(origin))
 313                         if (prefix==origin){
 314                                 if ( DEBUG ) print "Mirror fount at " mname
 315                                 close("mirrors")
 316                                 return mirror substr(url,length(origin)+1)
 317                         }
 318                 }
 319         }
 320
 321         return url
 322 }
 323
 324 function process_source(number,lurl,name,version) {
 325 # fetches file list, and compares version numbers
 326         if ( DEBUG ) print "Processing " lurl
 327
 328         if ( index(lurl,version)==0 ) {
 329                 if (DEBUG) print "There is no version number."
 330                 return 0
 331         }
 332
 333         sub("://",":",lurl)
 334         sub("/",":/",lurl)
 335         gsub("[^/]*$",":&",lurl)
 336         split(lurl,url,":")
 337         acc=url[1]
 338         host=url[2]
 339         dir=url[3]
 340         filename=url[4]
 341
 342         if (index(dir,version)) {
 343                 dir=substr(dir,1,index(dir,version)-1)
 344                 sub("[^/]*$","",dir)
 345                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 346                 if ( DEBUG ) print "Will check a directory: " dir
 347                 if ( DEBUG ) print "and a file: " filename
 348         }
 349
 350         filenameexp=filename
 351         gsub("\+","\\+",filenameexp)
 352         sub(version,"[A-Za-z0-9.]+",filenameexp)
 353         gsub("\.","\\.",filenameexp)
 354         if ( DEBUG ) print "Expression: " filenameexp
 355         match(filename,version)
 356         prever=substr(filename,1,RSTART-1)
 357         postver=substr(filename,RSTART+RLENGTH)
 358         if ( DEBUG ) print "Before number: " prever
 359         if ( DEBUG ) print "and after: " postver
 360         newurl=find_mirror(acc "://" host dir)
 361         #print acc "://" host dir
 362         #newurl=url[1]"://"url[2]url[3]url[4]
 363         #newurl=acc "://" host dir filename
 364         if ( DEBUG ) print "Looking at " newurl
 365
 366         references=0
 367         finished=0
 368         oldversion=version
 369         odp=get_links(newurl,filename)
 370         if( odp ~ "ERROR: ") {
 371                 print name "(" number ") " odp
 372         } else {
 373                 if (DEBUG) print "WebPage downloaded"
 374                 c=split(odp,linki)
 375                 for (nr=1; nr<=c; nr++) {
 376                         addr=linki[nr]
 377                         if (DEBUG) print "Found link: " addr
 378                         if ((addr ~ filenameexp) && !(addr ~ "[-_.0-9A-Za-z~]" filenameexp)) {
 379                                 match(addr,filenameexp)
 380                                 newfilename=substr(addr,RSTART,RLENGTH)
 381                                 if (DEBUG) print "Hypothetical new: " newfilename
 382                                 newfilename=fixedsub(prever,"",newfilename)
 383                                 newfilename=fixedsub(postver,"",newfilename)
 384                                 if (DEBUG) print "Version: " newfilename
 385                                 if (newfilename ~ /\.(pkg|bin|binary|built)$/) continue
 386                                 if (NUMERIC) {
 387                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 388                                                 if (DEBUG) print "Yes, there is new one"
 389                                                 version=newfilename
 390                                                 finished=1
 391                                         }
 392                                 } else if ( compare_ver(version, newfilename)==1 ) {
 393                                         if (DEBUG) print "Yes, there is new one"
 394                                         version=newfilename
 395                                         finished=1
 396                                 }
 397                         }
 398                 }
 399                 if (finished==0)
 400                         print name "(" number ") seems ok: " oldversion
 401                 else
 402                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 403         }
 404 }
 405
 406 # upgrade check for pear package using PEAR CLI
 407 function pear_upgrade(name, ver) {
 408         pname = name;
 409         sub(/^php-pear-/, "", pname);
 410
 411         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 412         if (DEBUG) {
 413                 print "pearcmd: " pearcmd
 414         }
 415         pearcmd | getline nver
 416         close(pearcmd)
 417
 418         if (compare_ver(ver, nver)) {
 419                 print name " [OLD] " ver " [NEW] " nver
 420         } else {
 421                 print name " seems ok: " ver
 422         }
 423
 424         return
 425 }
 426
 427 function process_data(name,ver,rel,src) {
 428         if (name ~ /^php-pear-/) {
 429                 return pear_upgrade(name, ver);
 430         }
 431
 432 # this function checks if substitutions were valid, and if true:
 433 # processes each URL and tries to get current file list
 434         for (i in src) {
 435                 if ( src[i] ~ /%{nil}/ ) {
 436                         gsub(/\%\{nil\}/, "", src[i])
 437                 }
 438                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 439                         if ( DEBUG ) print "Source: " src[i]
 440                         process_source(i,src[i],name,ver)
 441                 } else {
 442                         print FNAME ":" i ": impossible substitution: " src[i]
 443                 }
 444         }
 445 }
 446
 447 BEGIN {
 448         # if U want to use DEBUG, run script with "-v DEBUG=1"
 449         # or uncomment the line below
 450         # DEBUG = 1
 451
 452         errno=system("wget --help > /dev/null 2>&1")
 453         if (errno) {
 454                 print "No wget installed!"
 455                 exit 1
 456         }
 457         if (ARGC>=3 && ARGV[2]=="-n") {
 458                 NUMERIC=1
 459                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 460                 ARGC=ARGC-1
 461         }
 462         frameseen[0] = 1
 463 }
 464
 465 FNR==1 {
 466         if ( ARGIND != 1 ) {
 467                 process_data(NAME,VER,REL,SRC)
 468                 NAME="" ; VER="" ; REL=""
 469                 for (i in DEFS) delete DEFS[i]
 470                 for (i in SRC) delete SRC[i]
 471         }
 472         FNAME=FILENAME
 473         DEFS["_alt_kernel"]=""
 474         DEFS["20"]="\\ "
 475 }
 476
 477 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 478 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 479 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 480 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 481 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 482 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 483
 484 END {
 485         process_data(NAME,VER,REL,SRC)
 486 }