pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 function fixedsub(s1,s2,t,      ind) {
   4 # substitutes fixed strings (not regexps)
   5         if (ind = index(t,s1)) {
   6                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
   7         }
   8         return t
   9 }
  10
  11 function compare_ver(v1,v2) {
  12 # compares version numbers
  13         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  14                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  15         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  16                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  17         sub("^0*","",v1)
  18         sub("^0*","",v2)
  19         if (DEBUG) print "v1 == " v1
  20         if (DEBUG) print "v2 == " v2
  21         count=split(v1,v1a,"\.")
  22         count2=split(v2,v2a,"\.")
  23
  24         if (count<count2) mincount=count
  25         else mincount=count2
  26
  27         for (i=1; i<=mincount; i++) {
  28                 if (v1a[i]=="") v1a[i]=0
  29                 if (v2a[i]=="") v2a[i]=0
  30                 if (DEBUG) print "i == " i
  31                 if (DEBUG) print "v1[i] == " v1a[i]
  32                 if (DEBUG) print "v2[i] == " v2a[i]
  33                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  34                         if (length(v2a[i])>length(v1a[i]))
  35                                 return 1
  36                         else if (v2a[i]>v1a[i])
  37                                 return 1
  38                         else if (length(v1a[i])>length(v2a[i]))
  39                                 return 0
  40                         else if (v1a[i]>v2a[i])
  41                                 return 0
  42                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  43                         if (v2a[i]>v1a[i])
  44                                 return 1
  45                         else if (v1a[i]>v2a[i])
  46                                 return 0
  47                 } else if ((v1a[i]~"pre")||(v1a[i]~"beta")||(v1a[i]~"alpha"))
  48                         return 1
  49                 else
  50                         return 0
  51         }
  52         if ((count2==mincount)&&(count!=count2)) {
  53                 for (i=count2+1; i<=count; i++)
  54                         if ((v1a[i]~"pre")||(v1a[i]~"beta")||(v1a[i]~"alpha"))
  55                                 return 1
  56                 return 0
  57         } else if (count!=count2) {
  58                 for (i=count+1; i<=count2; i++)
  59                         if ((v2a[i]~"pre")||(v2a[i]~"beta")||(v2a[i]~"alpha"))
  60                                 return 0
  61                 return 1
  62         }
  63         return 0
  64 }
  65
  66 function get_links(url, errno,link,oneline,retval,odp,tmpfile) {
  67 # get all <A HREF=..> tags from specified URL
  68         "mktemp /tmp/XXXXXX" | getline tmpfile
  69         close("mktemp /tmp/XXXXXX")
  70
  71         if (DEBUG) print "Retrieving: " url
  72         errno=system("wget -O - \"" url "\" -t 1 -T 300 --passive-ftp > " tmpfile " 2>/dev/null" )
  73
  74         if (errno==0) {
  75                 while (getline oneline < tmpfile)
  76                         odp=(odp " " oneline)
  77                 if ( DEBUG ) print "Odpowiedz: " odp
  78         }
  79
  80         close(tmpfile)
  81         system("rm -f " tmpfile)
  82         if ( errno==0) {
  83                 while ((tolower(odp) ~ /<frame[ \t]/)||(tolower(odp) ~ /href=/)) {
  84                         if (tolower(odp) ~ /<frame[ \t]/) {
  85                                 match(tolower(odp),/<frame[ \t][^>]*>/)
  86                                 ramka=substr(odp,RSTART,RLENGTH)
  87                                 odp=substr(odp,RSTART+RLENGTH)
  88                                 sub(/[sS][rR][cC]=[ \t]+/,"src=",ramka);
  89                                 match(tolower(ramka),/src="[^"]+"/)
  90                                 newurl=substr(ramka,RSTART+5,RLENGTH-6)
  91                                 if (DEBUG) print "Ramka: " newurl
  92                                 retval=(retval " " get_links(newurl))
  93                         } else if (tolower(odp) ~ /href=[ \t]*"[^"]+"/) {
  94                                 sub(/[hH][rR][eE][fF]=[ \t]+/,"href=",odp)
  95                                 match(tolower(odp),/href="[^"]+"/)
  96                                 link=substr(odp,RSTART,RLENGTH)
  97                                 odp=substr(odp,RSTART+RLENGTH)
  98                                 link=substr(link,7,length(link)-7)
  99                                 retval=(retval " " link)
 100                         } else if (tolower(odp) ~ /href=[ \t]*[^ \t>]+/) {
 101                                 sub(/[hH][rR][eE][fF]=[ \t]+/,"href=",odp)
 102                                 match(tolower(odp),/href=[^ \t>]+/)
 103                                 link=substr(odp,RSTART,RLENGTH)
 104                                 odp=substr(odp,RSTART+RLENGTH)
 105                                 link=substr(link,6,length(link)-5)
 106                                 retval=(retval " " link)
 107                         } else {
 108                                 retval=(retval " INTERNAL_ERROR")
 109                                 break
 110                         }
 111                 }
 112         } else {
 113                 retval=("WGET ERROR: " errno)
 114         }
 115
 116
 117         if (DEBUG) print "Zwracane: " retval
 118         return retval
 119 }
 120
 121 function subst_defines(var,defs) {
 122 # substitute all possible RPM macros
 123         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 124                 oldvar=var
 125                 for (j in defs) {
 126                         gsub("%{" j "}", defs[j], var)
 127                         gsub("%" j , defs[j], var)
 128                 }
 129                 if (var==oldvar) {
 130                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 131                         return var
 132                 }
 133         }
 134         return var
 135 }
 136
 137 function find_mirror(url) {
 138
 139         while (succ = (getline line < "mirrors")) {
 140             if (succ==-1) { return url }
 141                 nf=split(line,fields,"|")
 142                 if (nf>1){
 143                         origin=fields[1]
 144                         mirror=fields[2]
 145                         mname=fields[3]
 146                         prefix=substr(url,1,length(origin))
 147                         if (prefix==origin){
 148                                 if ( DEBUG ) print "Mirror znaleziony na " mname
 149                                 close("mirrors")
 150                                 return mirror substr(url,length(origin))
 151                         }
 152                 }
 153         }
 154
 155         return url
 156 }
 157
 158 function process_source(number,lurl,name,version) {
 159 # fetches file list, and compares version numbers
 160         if ( DEBUG ) print "Przetwarzam " lurl
 161
 162         if ( index(lurl,version)==0 ) {
 163                 if (DEBUG) print "Nie ma numeru wersji."
 164                 return 0
 165         }
 166
 167         sub("://",":",lurl)
 168         sub("/",":/",lurl)
 169         gsub("[^/]*$",":&",lurl)
 170         split(lurl,url,":")
 171         acc=url[1]
 172         host=url[2]
 173         dir=url[3]
 174         filename=url[4]
 175
 176         if (index(dir,version)) {
 177                 dir=substr(dir,1,index(dir,version)-1)
 178                 sub("[^/]*$","",dir)
 179                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 180                 if ( DEBUG ) print "Sprawdze katalog: " dir
 181                 if ( DEBUG ) print "i plik: " filename
 182         }
 183
 184         filenameexp=filename
 185         gsub("\+","\\+",filenameexp)
 186         sub(version,"[A-Za-z0-9\\.]+",filenameexp)
 187         if ( DEBUG ) print "Wzorzec: " filenameexp
 188         match(filename,version)
 189         prever=substr(filename,1,RSTART-1)
 190         postver=substr(filename,RSTART+RLENGTH)
 191         if ( DEBUG ) print "Przed numerkiem: " prever
 192         if ( DEBUG ) print "i po: " postver
 193         newurl=find_mirror(acc "://" host dir)
 194         #print acc "://" host dir
 195         #newurl=url[1]"://"url[2]url[3]url[4]
 196         #newurl=acc "://" host dir filename
 197         if ( DEBUG ) print "Zagl±dam na " newurl
 198
 199         references=0
 200         finished=0
 201         oldversion=version
 202         odp=get_links(newurl)
 203         if( odp ~ "ERROR: ") {
 204                 print name "(" number ") " odp
 205         } else {
 206                 if (DEBUG) print "Sciagnieta strona"
 207                 c=split(odp,linki)
 208                 for (nr=1; nr<=c; nr++) {
 209                         addr=linki[nr]
 210                         if (DEBUG) print "Znaleziony link: " addr
 211                         if (addr ~ filenameexp) {
 212                                 match(addr,filenameexp)
 213                                 newfilename=substr(addr,RSTART,RLENGTH)
 214                                 if (DEBUG) print "Hipotetyczny nowy: " newfilename
 215                                 newfilename=fixedsub(prever,"",newfilename)
 216                                 newfilename=fixedsub(postver,"",newfilename)
 217                                 if (DEBUG) print "Wersja: " newfilename
 218                                 if ( compare_ver(version, newfilename)==1 ) {
 219                                         if (DEBUG) print "Tak, jest nowa"
 220                                         version=newfilename
 221                                         finished=1
 222                                 }
 223                         }
 224                 }
 225                 if (finished==0)
 226                         print name "(" number ") seems ok: " oldversion
 227                 else
 228                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 229         }
 230 }
 231
 232 function process_data(name,ver,rel,src) {
 233 # this function checks if substitutions were valid, and if true:
 234 # processes each URL and tries to get current file list
 235         for (i in src) {
 236                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 237                         if ( DEBUG ) print "Zrodlo: " src[i]
 238                         process_source(i,src[i],name,ver)
 239                 } else {
 240                         print FNAME ":" i ": niemozliwe podstawienie: " src[i]
 241                 }
 242         }
 243 }
 244
 245 BEGIN {
 246         # if U want to use DEBUG, run script with "-v DEBUG=1"
 247         # or uncomment the line below
 248         # DEBUG = 1
 249
 250         errno=system("wget --help > /dev/null 2>&1")
 251         if (errno) {
 252                 print "No wget installed!"
 253                 exit 1
 254         }
 255 }
 256
 257 FNR==1 {
 258         if ( ARGIND != 1 ) {
 259                 process_data(NAME,VER,REL,SRC)
 260                 NAME="" ; VER="" ; REL=""
 261                 for (i in DEFS) delete DEFS[i]
 262                 for (i in SRC) delete SRC[i]
 263         }
 264         FNAME=FILENAME
 265 }
 266
 267 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 268 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 269 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 270 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 271 /^[Ss]ource[0-9]*:/ { if (/(ftp|http):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 272 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 273
 274 END {
 275         process_data(NAME,VER,REL,SRC)
 276 }