pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 function fixedsub(s1,s2,t,      ind) {
   4 # substitutes fixed strings (not regexps)
   5         if (ind = index(t,s1)) {
   6                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
   7         }
   8         return t
   9 }
  10
  11 function compare_ver(v1,v2) {
  12 # compares version numbers
  13         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  14                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  15         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  16                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  17         sub("^0*","",v1)
  18         sub("^0*","",v2)
  19         if (DEBUG) print "v1 == " v1
  20         if (DEBUG) print "v2 == " v2
  21         count=split(v1,v1a,"\.")
  22         count2=split(v2,v2a,"\.")
  23
  24         if (count<count2) mincount=count
  25         else mincount=count2
  26
  27         for (i=1; i<=mincount; i++) {
  28                 if (v1a[i]=="") v1a[i]=0
  29                 if (v2a[i]=="") v2a[i]=0
  30                 if (DEBUG) print "i == " i
  31                 if (DEBUG) print "v1[i] == " v1a[i]
  32                 if (DEBUG) print "v2[i] == " v2a[i]
  33                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  34                         if (length(v2a[i])>length(v1a[i]))
  35                                 return 1
  36                         else if (v2a[i]>v1a[i])
  37                                 return 1
  38                         else if (length(v1a[i])>length(v2a[i]))
  39                                 return 0
  40                         else if (v1a[i]>v2a[i])
  41                                 return 0
  42                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  43                         if (v2a[i]>v1a[i])
  44                                 return 1
  45                         else if (v1a[i]>v2a[i])
  46                                 return 0
  47                 } else if ((v1a[i]~"pre")||(v1a[i]~"beta")||(v1a[i]~"alpha"))
  48                         return 1
  49                 else
  50                         return 0
  51         }
  52         if ((count2==mincount)&&(count!=count2)) {
  53                 for (i=count2+1; i<=count; i++)
  54                         if ((v1a[i]~"pre")||(v1a[i]~"beta")||(v1a[i]~"alpha"))
  55                                 return 1
  56                 return 0
  57         } else if (count!=count2) {
  58                 for (i=count+1; i<=count2; i++)
  59                         if ((v2a[i]~"pre")||(v2a[i]~"beta")||(v2a[i]~"alpha"))
  60                                 return 0
  61                 return 1
  62         }
  63         return 0
  64 }
  65
  66 function get_links(url, errno,link,oneline,retval,odp,tmpfile) {
  67 # get all <A HREF=..> tags from specified URL
  68         "mktemp /tmp/XXXXXX" | getline tmpfile
  69         close("mktemp /tmp/XXXXXX")
  70
  71         if (DEBUG) print "Retrieving: " url
  72         errno=system("wget --inet -O - \"" url "\" > " tmpfile " 2>/dev/null" )
  73
  74         if (errno==0) {
  75                 while (getline oneline < tmpfile)
  76                         odp=(odp " " oneline)
  77                 if ( DEBUG ) print "Odpowiedz: " odp
  78         }
  79
  80         close(tmpfile)
  81         system("rm -f " tmpfile)
  82         if ( errno==0) {
  83                 while ((tolower(odp) ~ /<frame[ \t]/)||(tolower(odp) ~ /href=/)) {
  84                         if (tolower(odp) ~ /<frame[ \t]/) {
  85                                 match(tolower(odp),/<frame[ \t][^>]*>/)
  86                                 ramka=substr(odp,RSTART,RLENGTH)
  87                                 odp=substr(odp,RSTART+RLENGTH)
  88                                 match(tolower(ramka),/src="[^"]+"/)
  89                                 newurl=substr(ramka,RSTART+5,RLENGTH-6)
  90                                 if (DEBUG) print "Ramka: " newurl
  91                                 retval=(retval " " get_links(newurl))
  92                         } else {
  93                                 match(tolower(odp),/href="[^"]+"/)
  94                                 link=substr(odp,RSTART,RLENGTH)
  95                                 odp=substr(odp,RSTART+RLENGTH)
  96                                 link=substr(link,7,length(link)-7)
  97                                 retval=(retval " " link)
  98                         }
  99                 }
 100         } else {
 101                 retval=("WGET ERROR: " errno)
 102         }
 103
 104
 105         if (DEBUG) print "Zwracane: " retval
 106         return retval
 107 }
 108
 109 function subst_defines(var,defs) {
 110 # substitute all possible RPM macros
 111         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 112                 oldvar=var
 113                 for (j in defs) {
 114                         gsub("%{" j "}", defs[j], var)
 115                         gsub("%" j , defs[j], var)
 116                 }
 117                 if (var==oldvar) {
 118                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 119                         return var
 120                 }
 121         }
 122         return var
 123 }
 124
 125 function process_source(number,lurl,name,version) {
 126 # fetches file list, and compares version numbers
 127         if ( DEBUG ) print "Przetwarzam " lurl
 128
 129         if ( index(lurl,version)==0 ) {
 130                 if (DEBUG) print "Nie ma numeru wersji."
 131                 return 0
 132         }
 133
 134         sub("://",":",lurl)
 135         sub("/",":/",lurl)
 136         gsub("[^/]*$",":&",lurl)
 137         split(lurl,url,":")
 138         acc=url[1]
 139         host=url[2]
 140         dir=url[3]
 141         filename=url[4]
 142
 143         if (index(dir,version)) {
 144                 dir=substr(dir,1,index(dir,version)-1)
 145                 sub("[^/]*$","",dir)
 146                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 147                 if ( DEBUG ) print "Sprawdze katalog: " dir
 148                 if ( DEBUG ) print "i plik: " filename
 149         }
 150
 151         filenameexp=filename
 152         gsub("\+","\\+",filenameexp)
 153         sub(version,"[A-Za-z0-9\\.]+",filenameexp)
 154         if ( DEBUG ) print "Wzorzec: " filenameexp
 155         match(filename,version)
 156         prever=substr(filename,1,RSTART-1)
 157         postver=substr(filename,RSTART+RLENGTH)
 158         if ( DEBUG ) print "Przed numerkiem: " prever
 159         if ( DEBUG ) print "i po: " postver
 160
 161         if ( DEBUG ) print "Zagl±dam na " acc "://" host dir
 162
 163         references=0
 164         finished=0
 165         oldversion=version
 166         odp=get_links(acc "://" host dir)
 167         if( odp ~ "ERROR: ") {
 168                 print name "(" number ") " odp
 169         } else {
 170                 c=split(odp,linki)
 171                 for (nr=1; nr<=c; nr++) {
 172                         addr=linki[nr]
 173                         if (DEBUG) print "Znaleziony link: " addr
 174                         if (addr ~ filenameexp) {
 175                                 match(addr,filenameexp)
 176                                 newfilename=substr(addr,RSTART,RLENGTH)
 177                                 if (DEBUG) print "Hipotetyczny nowy: " newfilename
 178                                 newfilename=fixedsub(prever,"",newfilename)
 179                                 newfilename=fixedsub(postver,"",newfilename)
 180                                 if (DEBUG) print "Wersja: " newfilename
 181                                 if ( compare_ver(version, newfilename)==1 ) {
 182                                         if (DEBUG) print "Tak, jest nowa"
 183                                         version=newfilename
 184                                         finished=1
 185                                 }
 186                         }
 187                 }
 188                 if (finished==0)
 189                         print name "(" number ") seems ok: " oldversion
 190                 else
 191                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 192         }
 193 }
 194
 195 function process_data(name,ver,rel,src) {
 196 # this function checks if substitutions were valid, and if true:
 197 # processes each URL and tries to get current file list
 198         for (i in src) {
 199                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 200                         if ( DEBUG ) print "Zrodlo: " src[i]
 201                         process_source(i,src[i],name,ver)
 202                 } else {
 203                         print FNAME ":" i ": niemozliwe podstawienie: " src[i]
 204                 }
 205         }
 206 }
 207
 208 BEGIN {
 209         # if U want to use DEBUG, run script with "-v DEBUG=1"
 210         # or uncomment the line below
 211         # DEBUG = 1
 212
 213         errno=system("wget --help > /dev/null 2>&1")
 214         if (errno) {
 215                 print "No wget installed!"
 216                 exit 1
 217         }
 218 }
 219
 220 FNR==1 {
 221         if ( ARGIND != 1 ) {
 222                 process_data(NAME,VER,REL,SRC)
 223                 NAME="" ; VER="" ; REL=""
 224                 for (i in DEFS) delete DEFS[i]
 225                 for (i in SRC) delete SRC[i]
 226         }
 227         FNAME=FILENAME
 228 }
 229
 230 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 231 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 232 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 233 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 234 /^[Ss]ource[0-9]*:/ { if (/(ftp|http):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 235 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 236
 237 END {
 238         process_data(NAME,VER,REL,SRC)
 239 }