pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2008 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17
  18 function fixedsub(s1,s2,t,      ind) {
  19 # substitutes fixed strings (not regexps)
  20         if (ind = index(t,s1)) {
  21                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  22         }
  23         return t
  24 }
  25
  26 function ispre(s) {
  27         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  28                 if (DEBUG) print "pre-version"
  29                 return 1
  30         } else {
  31                 return 0
  32         }
  33 }
  34
  35 function compare_ver(v1,v2) {
  36 # compares version numbers
  37         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  38                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  39         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  40                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  41         sub("^0*","",v1)
  42         sub("^0*","",v2)
  43         gsub("\.0*",".",v1)
  44         gsub("\.0*",".",v2)
  45         if (DEBUG) print "v1 == " v1
  46         if (DEBUG) print "v2 == " v2
  47         count=split(v1,v1a,"\.")
  48         count2=split(v2,v2a,"\.")
  49
  50         if (count<count2) mincount=count
  51         else mincount=count2
  52
  53         for (i=1; i<=mincount; i++) {
  54                 if (v1a[i]=="") v1a[i]=0
  55                 if (v2a[i]=="") v2a[i]=0
  56                 if (DEBUG) print "i == " i
  57                 if (DEBUG) print "v1[i] == " v1a[i]
  58                 if (DEBUG) print "v2[i] == " v2a[i]
  59                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  60                         if (length(v2a[i])>length(v1a[i]))
  61                                 return 1
  62                         else if (v2a[i]>v1a[i])
  63                                 return 1
  64                         else if (length(v1a[i])>length(v2a[i]))
  65                                 return 0
  66                         else if (v1a[i]>v2a[i])
  67                                 return 0
  68                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  69                         if (v2a[i]>v1a[i])
  70                                 return 1
  71                         else if (v1a[i]>v2a[i])
  72                                 return 0
  73                 } else if (ispre(v1a[i]) == 1)
  74                         return 1
  75                 else
  76                         return 0
  77         }
  78         if ((count2==mincount)&&(count!=count2)) {
  79                 for (i=count2+1; i<=count; i++)
  80                         if (ispre(v1a[i]) == 1)
  81                                 return 1
  82                 return 0
  83         } else if (count!=count2) {
  84                 for (i=count+1; i<=count2; i++)
  85                         if (ispre(v2a[i]) == 1)
  86                                 return 0
  87                 return 1
  88         }
  89         return 0
  90 }
  91
  92 function compare_ver_dec(v1,v2) {
  93 # compares version numbers as decimal floats
  94         while (match(v1,/[0-9][a-zA-Z]/))
  95                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  96         while (match(v2,/[0-9][a-zA-Z]/))
  97                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  98         sub("^0*","",v1)
  99         sub("^0*","",v2)
 100         if (DEBUG) print "v1 == " v1
 101         if (DEBUG) print "v2 == " v2
 102         count=split(v1,v1a,"\.")
 103         count2=split(v2,v2a,"\.")
 104
 105         if (count<count2) mincount=count
 106         else mincount=count2
 107
 108         for (i=1; i<=mincount; i++) {
 109                 if (v1a[i]=="") v1a[i]=0
 110                 if (v2a[i]=="") v2a[i]=0
 111                 if (DEBUG) print "i == " i
 112                 if (DEBUG) print "v1[i] == " v1a[i]
 113                 if (DEBUG) print "v2[i] == " v2a[i]
 114                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 115                         if (i==2) {
 116                                 if (0+("." v2a[i])>0+("." v1a[i]))
 117                                         return 1
 118                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 119                                         return 0
 120                         } else {
 121                                 if (length(v2a[i])>length(v1a[i]))
 122                                         return 1
 123                                 else if (v2a[i]>v1a[i])
 124                                         return 1
 125                                 else if (length(v1a[i])>length(v2a[i]))
 126                                         return 0
 127                                 else if (v1a[i]>v2a[i])
 128                                         return 0
 129                         }
 130                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 131                         if (v2a[i]>v1a[i])
 132                                 return 1
 133                         else if (v1a[i]>v2a[i])
 134                                 return 0
 135                 } else if (ispre(v1a[i]) == 1)
 136                         return 1
 137                 else
 138                         return 0
 139         }
 140         if ((count2==mincount)&&(count!=count2)) {
 141                 for (i=count2+1; i<=count; i++)
 142                         if (ispre(v1a[i]) == 1)
 143                                 return 1
 144                 return 0
 145         } else if (count!=count2) {
 146                 for (i=count+1; i<=count2; i++)
 147                         if (ispre(v2a[i]) == 1)
 148                                 return 0
 149                 return 1
 150         }
 151         return 0
 152 }
 153
 154 function get_links(url, errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile) {
 155 # get all <A HREF=..> tags from specified URL
 156         "mktemp /tmp/XXXXXX" | getline tmpfile
 157         close("mktemp /tmp/XXXXXX")
 158
 159         if (url ~ /^http:\/\/(download|dl).(sf|sourceforge).net\//) {
 160                 gsub("^http://(download|dl).(sf|sourceforge).net/", "", url)
 161                 url = "http://prdownloads.sourceforge.net/" substr(url, 1, 1) "/" substr(url, 1, 2) "/" url
 162                 if (DEBUG) print "sf url, mungled url to: " url
 163         }
 164
 165         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 166                 gsub("^http://", "", url)
 167                 gsub("\..*", "", url)
 168                 url = "http://code.google.com/p/" url "/"
 169                 if (DEBUG) print "googlecode url, mungled url to: " url
 170         }
 171
 172         if (DEBUG) print "Retrieving: " url
 173         errno=system("wget -O - \"" url "\" -t 3 -T 300 --passive-ftp > " tmpfile " 2>/dev/null" )
 174
 175         if (errno==0) {
 176                 while (getline oneline < tmpfile)
 177                         wholeodp=(wholeodp " " oneline)
 178                 if ( DEBUG ) print "Response: " wholeodp
 179         }
 180
 181         close(tmpfile)
 182         system("rm -f " tmpfile)
 183         urldir=url;
 184         sub(/[^\/]+$/,"",urldir)
 185
 186         if ( errno==0) {
 187                 while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 188                         odp=substr(wholeodp,RSTART,RLENGTH);
 189                         wholeodp=substr(wholeodp,RSTART+RLENGTH);
 190
 191                         lowerodp=tolower(odp);
 192                         if (lowerodp ~ /<frame[ \t]/) {
 193                                 sub(/[sS][rR][cC]=[ \t]*/,"src=",odp);
 194                                 match(odp,/src="[^"]+"/)
 195                                 newurl=substr(odp,RSTART+5,RLENGTH-6)
 196                                 if (DEBUG) print "Frame: " newurl
 197                                 if (newurl !~ /\//) {
 198                                         newurl=(urldir newurl)
 199                                         if (DEBUG) print "Frame->: " newurl
 200                                 }
 201                                 retval=(retval " " get_links(newurl))
 202                         } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 203                                 sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 204                                 match(odp,/href="[^"]*"/)
 205                                 link=substr(odp,RSTART,RLENGTH)
 206                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 207                                 link=substr(link,7,length(link)-7)
 208                                 retval=(retval " " link)
 209                                 if (DEBUG) print "href(\"\"): " link
 210                         } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 211                                 sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 212                                 match(odp,/href='[^']*'/)
 213                                 link=substr(odp,RSTART,RLENGTH)
 214                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 215                                 link=substr(link,7,length(link)-7)
 216                                 retval=(retval " " link)
 217                                 if (DEBUG) print "href(''): " link
 218                         } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 219                                 sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 220                                 match(odp,/href=[^ \t>]*/)
 221                                 link=substr(odp,RSTART,RLENGTH)
 222                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 223                                 link=substr(link,6,length(link)-5)
 224                                 retval=(retval " " link)
 225                                 if (DEBUG) print "href(): " link
 226                         } else {
 227                                 # <a ...> but not href - skip
 228                                 if (DEBUG) print "skipping <a > without href: " odp
 229                         }
 230                 }
 231         } else {
 232                 retval=("WGET ERROR: " errno)
 233         }
 234
 235
 236         if (DEBUG) print "Returning: " retval
 237         return retval
 238 }
 239
 240 function subst_defines(var,defs) {
 241 # substitute all possible RPM macros
 242         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 243                 oldvar=var
 244                 for (j in defs) {
 245                         gsub("%{" j "}", defs[j], var)
 246                         gsub("%" j , defs[j], var)
 247                 }
 248                 if (var==oldvar) {
 249                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 250                         return var
 251                 }
 252         }
 253         return var
 254 }
 255
 256 function find_mirror(url) {
 257
 258         while (succ = (getline line < "mirrors")) {
 259             if (succ==-1) { return url }
 260                 nf=split(line,fields,"|")
 261                 if (nf>1){
 262                         origin=fields[1]
 263                         mirror=fields[2]
 264                         mname=fields[3]
 265                         prefix=substr(url,1,length(origin))
 266                         if (prefix==origin){
 267                                 if ( DEBUG ) print "Mirror fount at " mname
 268                                 close("mirrors")
 269                                 return mirror substr(url,length(origin)+1)
 270                         }
 271                 }
 272         }
 273
 274         return url
 275 }
 276
 277 function process_source(number,lurl,name,version) {
 278 # fetches file list, and compares version numbers
 279         if ( DEBUG ) print "Processing " lurl
 280
 281         if ( index(lurl,version)==0 ) {
 282                 if (DEBUG) print "There is no version number."
 283                 return 0
 284         }
 285
 286         sub("://",":",lurl)
 287         sub("/",":/",lurl)
 288         gsub("[^/]*$",":&",lurl)
 289         split(lurl,url,":")
 290         acc=url[1]
 291         host=url[2]
 292         dir=url[3]
 293         filename=url[4]
 294
 295         if (index(dir,version)) {
 296                 dir=substr(dir,1,index(dir,version)-1)
 297                 sub("[^/]*$","",dir)
 298                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 299                 if ( DEBUG ) print "Will check a directory: " dir
 300                 if ( DEBUG ) print "and a file: " filename
 301         }
 302
 303         filenameexp=filename
 304         gsub("\+","\\+",filenameexp)
 305         sub(version,"[A-Za-z0-9.]+",filenameexp)
 306         gsub("\.","\\.",filenameexp)
 307         if ( DEBUG ) print "Expression: " filenameexp
 308         match(filename,version)
 309         prever=substr(filename,1,RSTART-1)
 310         postver=substr(filename,RSTART+RLENGTH)
 311         if ( DEBUG ) print "Before number: " prever
 312         if ( DEBUG ) print "and after: " postver
 313         newurl=find_mirror(acc "://" host dir)
 314         #print acc "://" host dir
 315         #newurl=url[1]"://"url[2]url[3]url[4]
 316         #newurl=acc "://" host dir filename
 317         if ( DEBUG ) print "Looking at " newurl
 318
 319         references=0
 320         finished=0
 321         oldversion=version
 322         odp=get_links(newurl)
 323         if( odp ~ "ERROR: ") {
 324                 print name "(" number ") " odp
 325         } else {
 326                 if (DEBUG) print "WebPage downloaded"
 327                 c=split(odp,linki)
 328                 for (nr=1; nr<=c; nr++) {
 329                         addr=linki[nr]
 330                         if (DEBUG) print "Found link: " addr
 331                         if ((addr ~ filenameexp) && !(addr ~ "[-_.0-9A-Za-z~]" filenameexp)) {
 332                                 match(addr,filenameexp)
 333                                 newfilename=substr(addr,RSTART,RLENGTH)
 334                                 if (DEBUG) print "Hypothetical new: " newfilename
 335                                 newfilename=fixedsub(prever,"",newfilename)
 336                                 newfilename=fixedsub(postver,"",newfilename)
 337                                 if (DEBUG) print "Version: " newfilename
 338                                 if (newfilename ~ /\.(pkg|bin|binary|built)$/) continue
 339                                 if (NUMERIC) {
 340                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 341                                                 if (DEBUG) print "Yes, there is new one"
 342                                                 version=newfilename
 343                                                 finished=1
 344                                         }
 345                                 } else if ( compare_ver(version, newfilename)==1 ) {
 346                                         if (DEBUG) print "Yes, there is new one"
 347                                         version=newfilename
 348                                         finished=1
 349                                 }
 350                         }
 351                 }
 352                 if (finished==0)
 353                         print name "(" number ") seems ok: " oldversion
 354                 else
 355                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 356         }
 357 }
 358
 359 # upgrade check for pear package using PEAR CLI
 360 function pear_upgrade(name, ver) {
 361         pname = name;
 362         sub(/^php-pear-/, "", pname);
 363
 364         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 365         if (DEBUG) {
 366                 print "pearcmd: " pearcmd
 367         }
 368         pearcmd | getline nver
 369         close(pearcmd)
 370
 371         if (compare_ver(ver, nver)) {
 372                 print name " [OLD] " ver " [NEW] " nver
 373         } else {
 374                 print name " seems ok: " ver
 375         }
 376
 377         return
 378 }
 379
 380 function process_data(name,ver,rel,src) {
 381         if (name ~ /^php-pear-/) {
 382                 return pear_upgrade(name, ver);
 383         }
 384
 385 # this function checks if substitutions were valid, and if true:
 386 # processes each URL and tries to get current file list
 387         for (i in src) {
 388                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 389                         if ( DEBUG ) print "Source: " src[i]
 390                         process_source(i,src[i],name,ver)
 391                 } else {
 392                         print FNAME ":" i ": impossible substitution: " src[i]
 393                 }
 394         }
 395 }
 396
 397 BEGIN {
 398         # if U want to use DEBUG, run script with "-v DEBUG=1"
 399         # or uncomment the line below
 400         # DEBUG = 1
 401
 402         errno=system("wget --help > /dev/null 2>&1")
 403         if (errno) {
 404                 print "No wget installed!"
 405                 exit 1
 406         }
 407         if (ARGC>=3 && ARGV[2]=="-n") {
 408                 NUMERIC=1
 409                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 410                 ARGC=ARGC-1
 411         }
 412 }
 413
 414 FNR==1 {
 415         if ( ARGIND != 1 ) {
 416                 process_data(NAME,VER,REL,SRC)
 417                 NAME="" ; VER="" ; REL=""
 418                 for (i in DEFS) delete DEFS[i]
 419                 for (i in SRC) delete SRC[i]
 420         }
 421         FNAME=FILENAME
 422 }
 423
 424 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 425 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 426 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 427 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 428 /^[Ss]ource[0-9]*:/ { if (/(ftp|http):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 429 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 430
 431 END {
 432         process_data(NAME,VER,REL,SRC)
 433 }