pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|downloads|dl)\.(sf|sourceforge)\.net\//) {
 236                 newurl = url
 237                 # http://dl.sourceforge.net/threestore/
 238                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 239                 gsub("^http://(download|downloads|dl)\.(sf|sourceforge)\.net/", "", newurl)
 240                 gsub("^project/", "", newurl)
 241                 gsub("/.*", "", newurl)
 242                 url = "http://sourceforge.net/projects/" newurl "/rss?path=/"
 243                 d("sf url, mangled url to: " url)
 244
 245         } else if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 246                 gsub("^http://", "", url)
 247                 gsub("\..*", "", url)
 248                 url = "http://code.google.com/p/" url "/downloads/list"
 249                 d("googlecode url, mangled url to: " url)
 250
 251         } else if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 252                 gsub("-.*", "", filename)
 253                 url = "http://pecl.php.net/package/" filename
 254                 d("pecl.php.net url, mangled url to: " url)
 255
 256         } else if (url ~/http:\/\/cdn.mysql.com\//) {
 257                 gsub("http:\/\/cdn.mysql.com\/", "", url)
 258                 url = "http://vesta.informatik.rwth-aachen.de/mysql/" url
 259                 d("mysql CDN, mangled url to: " url)
 260
 261         } else if (url ~ /^(http|https):\/\/launchpad\.net\/(.*)\//) {
 262                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 263                 gsub("\/.*/", "", url)
 264                 url = "https://code.launchpad.net/" url "/+download"
 265                 d("main launchpad url, mangled url to: " url)
 266
 267         } else if (url ~ /^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 268                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 269                 gsub("\/.*/", "", url)
 270                 url = "https://edge.launchpad.net/" url "/+download"
 271                 d("edge launchpad url, mangled url to: " url)
 272
 273         } else if (url ~ /^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 274                 gsub("\/tarball\/.*", "/downloads", url)
 275                 d("github tarball url, mangled url to: " url)
 276
 277         } else if (url ~ /^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 278                 gsub("\/archive\/.*", "/tags", url)
 279                 d("github archive url, mangled url to: " url)
 280
 281         } else if (url ~ /^(http|https):\/\/bitbucket.org\/.*\/get\/.*/) {
 282                 # https://bitbucket.org/logilab/pylint/get/tip.tar.bz2 -> https://bitbucket.org/logilab/pylint/downloads
 283                 gsub("\/get\/.*", "/downloads", url)
 284                 d("github bitbucket url, mangled url to: " url)
 285
 286         } else if (url ~ /^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 287                 gsub("\/snapshot\/.*", "/", url)
 288                 d("cgit snapshot tarball url, mangled url to: " url)
 289
 290         } else if (url ~ /^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 291                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 292                 d("aquamaniac.de tarball url, mangled url to: " url)
 293
 294         } else if (url ~ /^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 295                 url = "http://www.process-one.net/en/ejabberd/archive/"
 296                 d("ejabberd tarball url, mangled url to: " url)
 297
 298         } else if (url ~ /^(http|https):\/\/llvm.org\/releases\//) {
 299                 url = "http://llvm.org/releases/download.html"
 300                 d("llvm tarball url, mangled url to: " url)
 301
 302         } else if (url ~ /^(http|https):\/\/download\.owncloud\.org\/community\//) {
 303                 url = "http://owncloud.org/changelog/"
 304                 d("owncloud tarball url, mangled url to: " url)
 305
 306         } else if (url ~ /^(http|https):\/\/hackage\.haskell\.org\/packages\/archive\//) {
 307                 gsub("\/packages\/archive","/package",url)
 308                 d("hackage haskell tarball url, mangled url to: " url)
 309
 310         } else if (url ~ /^http:\/\/www.taskwarrior.org\/download\//) {
 311                 url = "http://taskwarrior.org/projects/taskwarrior/wiki/Download"
 312                 d("taskwarrior tarball url, mangled url to: " url)
 313         } else if (url ~/^http:\/\/www.rarlab.com\/rar\// && filename ~ /^unrarsrc/) {
 314                 url = "http://www.rarlab.com/rar_add.htm"
 315                 d("unrar tarball url, mangled url to: " url)
 316         } else if (url ~/^http:\/\/www.rarlab.com\/rar\//) {
 317                 url = "http://www.rarlab.com/download.htm"
 318                 d("rar tarball url, mangled url to: " url)
 319         } else if (url ~/^(http|https):\/\/pypi.python.org\/packages\/source\/.*/) {
 320                 gsub("/packages/source/[a-zA-Z0-9]/", "/pypi/", url)
 321                 d("pypi.python.org url, mangled url to: " url)
 322         }
 323
 324         d("Retrieving: " url)
 325         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 326         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 327         d("Execute: " cmd)
 328         errno = system(cmd)
 329         d("Execute done")
 330
 331         if (errno != 0) {
 332                 d("Reading failure response...")
 333                 wholeerr = ""
 334                 while (getline oneline < tmpfileerr)
 335                         wholeerr = (wholeerr " " oneline)
 336                 d("Error Response: " wholeerr)
 337
 338                 system("rm -f " tmpfile)
 339                 system("rm -f " tmpfileerr)
 340                 retval = ("WGET ERROR: " errno ": " wholeerr)
 341                 return retval
 342         }
 343         system("rm -f " tmpfileerr)
 344
 345         urldir = url;
 346         sub(/[^\/]+$/, "", urldir)
 347
 348 if (USE_PERL) {
 349         cmd = extract_links_cmd(tmpfile)
 350         while (cmd | getline) {
 351                 tag = $1
 352                 link = substr($0, length(tag) + 2)
 353
 354                 if (tag == "iframe") {
 355                         d("Frame: " link)
 356                         if (url !~ /\//) {
 357                                 link = (urldir link)
 358                                 d("Frame->: " link)
 359                         }
 360
 361                         if (link_seen(link)) {
 362                                 continue
 363                         }
 364                         retval = (retval " " get_links(link))
 365                 }
 366
 367                 if (link_seen(link)) {
 368                         continue
 369                 }
 370
 371                 retval = (retval " " link)
 372                 d("href(): " link)
 373         }
 374         close(cmd)
 375         system("rm -f " tmpfile)
 376
 377         d("Returning: [" retval "]")
 378         return retval
 379 }
 380
 381         wholeodp = ""
 382         d("Reading success response...")
 383         while (getline oneline < tmpfile) {
 384                 wholeodp = (wholeodp " " oneline)
 385 #               d("Response: " wholeodp)
 386         }
 387         d("Reponse read done...")
 388         system("rm -f " tmpfile)
 389
 390         # MATCH one of these:
 391         #while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 392         #while (match(wholeodp, /<link>[^<]*<\/link>/) > 0) {
 393
 394         while (match(wholeodp, /(<link>[^<]*<\/link>|<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>)/) > 0) {
 395                 d("Processing links...")
 396                 odp = substr(wholeodp,RSTART,RLENGTH);
 397                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 398
 399                 lowerodp = tolower(odp);
 400                 if (lowerodp ~ /<frame[ \t]/) {
 401                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 402                         match(odp, /src="[^"]+"/)
 403                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 404                         d("Frame: " newurl)
 405                         if (newurl !~ /\//) {
 406                                 newurl=(urldir newurl)
 407                                 d("Frame->: " newurl)
 408                         }
 409
 410                         if (link_seen(newurl)) {
 411                                 newurl = ""
 412                                 continue
 413                         }
 414
 415                         retval = (retval " " get_links(newurl))
 416                         d("href('condition1': " newurl)
 417                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 418                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 419                         match(odp,/href="[^"]*"/)
 420                         link=substr(odp,RSTART,RLENGTH)
 421                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 422                         link=substr(link,7,length(link)-7)
 423                         link=postfix_link(url, link)
 424
 425                         if (link_seen(link)) {
 426                                 link=""
 427                                 continue
 428                         }
 429
 430                         # link ends with at least 2 digit version
 431                         mlink = ""
 432                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 433                                 mlink = get_links(link)
 434
 435                         retval = (retval " " link " " mlink)
 436                         d("href('condition2'): " link)
 437                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 438                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 439                         match(odp,/href='[^']*'/)
 440                         link=substr(odp,RSTART,RLENGTH)
 441                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 442                         link=substr(link,7,length(link)-7)
 443                         link=postfix_link(url, link)
 444
 445                         if (link_seen(link)) {
 446                                 link=""
 447                                 continue
 448                         }
 449
 450                         retval = (retval " " link)
 451                         d("href('condition3'): " link)
 452                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 453                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 454                         match(odp,/href=[^ \t>]*/)
 455                         link=substr(odp,RSTART,RLENGTH)
 456                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 457                         link=substr(link,6,length(link)-5)
 458
 459                         if (link_seen(link)) {
 460                                 link=""
 461                                 continue
 462                         }
 463
 464                         retval = (retval " " link)
 465                         d("href('condition4'): " link)
 466                 } else if (lowerodp ~ /<link>/) {
 467                         link=lowerodp
 468                         sub("/<link>/", link)
 469                         sub("/\/download<\/link>/", link)
 470
 471                         if (link_seen(link)) {
 472                                 link=""
 473                                 continue
 474                         }
 475
 476                         retval = (retval " " link)
 477                         d("href('condition5'): " link)
 478                 } else {
 479                         # <a ...> but not href - skip
 480                         d("skipping <a > without href: " odp)
 481                 }
 482         }
 483
 484         d("Returning: [" retval "]")
 485         return retval
 486 }
 487
 488 function subst_defines(var,defs) {
 489 # substitute all possible RPM macros
 490         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 491                 oldvar=var
 492                 for (j in defs) {
 493                         gsub("%{" j "}", defs[j], var)
 494                         gsub("%" j , defs[j], var)
 495                         # conditional macros like %{?patchlevel:.5} - drop these for now
 496                         gsub("%{\?" j ":.*?}", "", var)
 497                 }
 498                 if (var==oldvar) {
 499                         if (DEBUG) {
 500                                 for (i in defs) {
 501                                         d(i " == " defs[i])
 502                                 }
 503                         }
 504                         return var
 505                 }
 506         }
 507         return var
 508 }
 509
 510 function find_mirror(url) {
 511
 512         while (succ = (getline line < "mirrors")) {
 513             if (succ==-1) { return url }
 514                 nf=split(line,fields,"|")
 515                 if (nf>1){
 516                         origin=fields[1]
 517                         mirror=fields[2]
 518                         mname=fields[3]
 519                         prefix=substr(url,1,length(origin))
 520                         if (prefix==origin){
 521                                 d("Mirror found at " mname)
 522                                 close("mirrors")
 523                                 return mirror substr(url,length(origin)+1)
 524                         }
 525                 }
 526         }
 527
 528         return url
 529 }
 530
 531 # fetches file list, and compares version numbers
 532 function process_source(number, lurl, name, version) {
 533         d("Processing " lurl)
 534
 535         if (index(lurl, version) == 0) {
 536                 d("There is no version number ["version"] in ["lurl"]")
 537                 return 0
 538         }
 539
 540         sub("://",":",lurl)
 541         sub("/",":/",lurl)
 542         gsub("[^/]*$",":&",lurl)
 543         split(lurl,url,":")
 544         acc=url[1]
 545         host=url[2]
 546         dir=url[3]
 547         filename=url[4]
 548
 549         if (index(dir,version)) {
 550                 # directory name as version maching mode:
 551                 # if /something/version/name-version.tarball then check
 552                 # in /something/ looking for newer directory
 553                 dir=substr(dir,1,index(dir,version)-1)
 554                 sub("[^/]*$","",dir)
 555                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 556         }
 557
 558         d("Will check a directory: " dir)
 559         d("and a file: " filename)
 560
 561         filenameexp=filename
 562         gsub("[+]","\\+",filenameexp)
 563         sub(version,"[A-Za-z0-9.]+",filenameexp)
 564         gsub("[.]","\\.",filenameexp)
 565         sub("\.(bz|bz2|gz|lzma|xz|zip)$",".(bz|bz2|gz|lzma|xz|zip)",filenameexp)
 566         d("Expression: " filenameexp)
 567         match(filename,version)
 568         prever=substr(filename,1,RSTART-1)
 569         postver=substr(filename,RSTART+RLENGTH)
 570         d("Before number: " prever)
 571         d("and after: " postver)
 572         newurl=find_mirror(acc "://" host dir)
 573         #print acc "://" host dir
 574         #newurl=url[1]"://"url[2]url[3]url[4]
 575         #newurl=acc "://" host dir filename
 576         d("Looking at " newurl)
 577
 578         references=0
 579         finished=0
 580         oldversion=version
 581         odp = get_links(newurl, filename)
 582         if( odp ~ "ERROR: ") {
 583                 print name "(" number ") " odp
 584         } else {
 585                 d("WebPage downloaded")
 586                 c=split(odp,linki)
 587                 for (nr=1; nr<=c; nr++) {
 588                         addr=linki[nr]
 589
 590                         d("Found link: " addr)
 591
 592                         # Try not to treat foobar or foo-bar as (possibly newer) version of bar
 593                         # (practical cases: KXL, lineakconfig, mhash...)
 594                         # but don't skip cases where name is like "/some/link/0.12.2.tar.gz"
 595                         if ((addr ~ "[-_.0-9A-Za-z~]" filenameexp) && addr !~ "[-_.0-9A-Za-z~]/" filenameexp)  {
 596                                 continue
 597                         }
 598
 599                         if (addr ~ filenameexp) {
 600                                 match(addr,filenameexp)
 601                                 newfilename=substr(addr,RSTART,RLENGTH)
 602                                 d("Hypothetical new: " newfilename)
 603                                 newfilename=fixedsub(prever,"",newfilename)
 604                                 newfilename=fixedsub(postver,"",newfilename)
 605                                 d("Version: " newfilename)
 606                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 607                                 # strip ending (happens when in directiory name as version matching mode)
 608                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 609                                 if (NUMERIC) {
 610                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 611                                                 d("Yes, there is new one")
 612                                                 version=newfilename
 613                                                 finished=1
 614                                         }
 615                                 } else if ( compare_ver(version, newfilename)==1 ) {
 616                                         d("Yes, there is new one")
 617                                         version=newfilename
 618                                         finished=1
 619                                 }
 620                         }
 621                 }
 622                 if (finished == 0)
 623                         print name "(" number ") seems ok: " oldversion
 624                 else
 625                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 626         }
 627 }
 628
 629 function rss_upgrade(name, ver, url, regex, cmd) {
 630         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 631         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 632
 633         d("rss_upgrade_cmd: " cmd)
 634         cmd | getline ver
 635         close(cmd)
 636
 637         return ver
 638 }
 639
 640 # check for ZF upgrade from rss
 641 function zf_upgrade(name, ver) {
 642         return rss_upgrade(name, ver, \
 643                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 644                 "Zend Framework ([^\\s]+) Released" \
 645         );
 646 }
 647
 648 function hudson_upgrade(name, ver) {
 649         return rss_upgrade(name, ver, \
 650                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 651                 "Hudson ([0-9.]+) released" \
 652         );
 653 }
 654
 655 # upgrade check for pear package using PEAR CLI
 656 function pear_upgrade(name, ver,    cmd) {
 657         sub(/^php-pear-/, "", name);
 658
 659         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 660         d("PEAR: " cmd)
 661         cmd | getline ver
 662         close(cmd)
 663
 664         return ver
 665 }
 666
 667 function vim_upgrade(name, ver,     cmd) {
 668         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 669         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 670         d("VIM: " cmd)
 671         cmd | getline ver
 672         close(cmd)
 673         return ver
 674 }
 675
 676 function nodejs_upgrade(name, ver,   cmd) {
 677         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 678         if (DEFS["pkg"]) {
 679                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 680         } else {
 681                 cmd = "npm info " name " dist-tags.latest"
 682         }
 683         cmd | getline ver
 684         close(cmd)
 685
 686         return ver
 687 }
 688
 689 function rubygem_upgrade(name, ver,   cmd, pkg) {
 690         if (DEFS["gem_name"]) {
 691                 pkg = DEFS["gem_name"];
 692
 693         } else if (DEFS["gemname"]) {
 694                 pkg = DEFS["gemname"];
 695
 696         } else if (DEFS["pkgname"]) {
 697                 pkg = DEFS["pkgname"];
 698
 699         } else {
 700                 pkg = name;
 701                 gsub(/^ruby-/, "", pkg);
 702         }
 703
 704         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); sub(/\)$/, \"\", v); print v}'"
 705         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 706         cmd | getline ver
 707
 708         close(cmd)
 709
 710         return ver
 711 }
 712
 713 function google_linux_repo(name, ver, reponame,   cmd, sourceurl) {
 714         sourceurl = "http://dl.google.com/linux/" reponame "/rpm/stable/x86_64/repodata/primary.xml.gz"
 715         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>" name "-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 716         d("google repo: " cmd);
 717         cmd | getline ver
 718         close(cmd)
 719
 720         return ver
 721 }
 722
 723 function jenkins_upgrade(name, ver, urls,  url, i, c, chunks, nver) {
 724         for (i in urls) {
 725                 url = urls[i]
 726                 # http://mirrors.jenkins-ci.org/war-stable/1.509.1/jenkins.war?/jenkins-1.509.1.war
 727                 gsub("/" ver "/jenkins.war\?/jenkins-" ver ".war", "/", url);
 728                 c = split(get_links(url), chunks, "/")
 729                 # new version is second one from the bottom
 730                 nver = chunks[c - 2]
 731                 gsub(/ /, "", nver)
 732                 return nver;
 733         }
 734 }
 735
 736 function process_data(name, ver, rel,     src, nver, i) {
 737         if (name ~ /^php-pear-/) {
 738                 nver = pear_upgrade(name, ver);
 739         } else if (name == "ZendFramework") {
 740                 nver = zf_upgrade(name, ver);
 741         } else if (name == "hudson") {
 742                 nver = hudson_upgrade(name, ver);
 743         } else if (name == "vim") {
 744                 nver = vim_upgrade(name, ver);
 745         } else if (name == "google-chrome") {
 746                 nver = google_linux_repo(name, ver, "chrome");
 747         } else if (name == "google-talkplugin") {
 748                 nver = google_linux_repo(name, ver, "talkplugin");
 749         } else if (name ~ "^nodejs-") {
 750                 nver = nodejs_upgrade(name, ver);
 751         } else if (name ~ "^ruby-" || name == "chef") {
 752                 nver = rubygem_upgrade(name, ver);
 753         } else if (name ~ "jenkins") {
 754                 nver = jenkins_upgrade(name, ver, src);
 755         }
 756
 757         if (nver) {
 758                 if (compare_ver(ver, nver)) {
 759                         print name " [OLD] " ver " [NEW] " nver
 760                 } else {
 761                         print name " seems ok: " ver
 762                 }
 763                 return;
 764         }
 765
 766         if (name == "xulrunner") {
 767                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 768                 d("package xulrunner, change version to firefox ["ver"]")
 769         }
 770
 771 # this function checks if substitutions were valid, and if true:
 772 # processes each URL and tries to get current file list
 773         for (i in src) {
 774                 if (src[i] ~ /%{nil}/) {
 775                         gsub(/\%\{nil\}/, "", src[i])
 776                 }
 777                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 778                         d("Source: " src[i])
 779                         process_source(i, src[i], name, ver)
 780                 } else {
 781                         print FNAME ":" i ": impossible substitution: " src[i]
 782                 }
 783         }
 784 }
 785
 786 BEGIN {
 787         # use perl links extraction by default
 788         USE_PERL = 1
 789
 790         # if you want to use DEBUG, run script with "-v DEBUG=1"
 791         # or uncomment the line below
 792         # DEBUG = 1
 793
 794         errno=system("wget --help > /dev/null 2>&1")
 795         if (errno && errno != 3) {
 796                 print "No wget installed!"
 797                 exit 1
 798         }
 799         if (ARGC>=3 && ARGV[2]=="-n") {
 800                 NUMERIC=1
 801                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 802                 ARGC=ARGC-1
 803         }
 804 }
 805
 806 FNR==1 {
 807         if ( ARGIND != 1 ) {
 808                 # clean frameseen for each ARG
 809                 for (i in frameseen) {
 810                         delete frameseen[i]
 811                 }
 812                 frameseen[0] = 1
 813
 814                 process_data(NAME,VER,REL,SRC)
 815                 NAME="" ; VER="" ; REL=""
 816                 for (i in DEFS) delete DEFS[i]
 817                 for (i in SRC) delete SRC[i]
 818         }
 819         FNAME=FILENAME
 820         DEFS["_alt_kernel"]=""
 821         DEFS["20"]="\\ "
 822         DEFS["nil"]=""
 823 }
 824
 825 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 826 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 827 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 828 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 829 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 830 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 831
 832 END {
 833         process_data(NAME,VER,REL,SRC)
 834 }