pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|dl)\.(sf|sourceforge)\.net\//) {
 236                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 237                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 238
 239                 gsub("/.*", "", url)
 240                 url = "http://sourceforge.net/projects/" url "/files/"
 241                 d("sf url, mungled url to: " url)
 242
 243         } else if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 244                 gsub("^http://", "", url)
 245                 gsub("\..*", "", url)
 246                 url = "http://code.google.com/p/" url "/downloads/list"
 247                 d("googlecode url, mungled url to: " url)
 248         } else if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 249                 gsub("-.*", "", filename)
 250                 url = "http://pecl.php.net/package/" filename
 251                 d("pecl.php.net url, mungled url to: " url)
 252
 253         } else if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 254                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 255                 d("mysql 5.1 url, mungled url to: " url)
 256
 257         } else if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 258                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 259                 gsub("\/.*/", "", url)
 260                 url = "https://code.launchpad.net/" url "/+download"
 261                 d("main launchpad url, mungled url to: " url)
 262
 263         } else if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 264                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 265                 gsub("\/.*/", "", url)
 266                 url = "https://edge.launchpad.net/" url "/+download"
 267                 d("edge launchpad url, mungled url to: " url)
 268
 269         } else if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 270                 gsub("\/tarball\/.*", "/downloads", url)
 271                 d("github tarball url, mungled url to: " url)
 272
 273         } else if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 274                 gsub("\/archive\/.*", "/tags", url)
 275                 d("github archive url, mungled url to: " url)
 276
 277         } else if (url ~/^(http|https):\/\/bitbucket.org\/.*\/get\/.*/) {
 278                 # https://bitbucket.org/logilab/pylint/get/tip.tar.bz2 -> https://bitbucket.org/logilab/pylint/downloads
 279                 gsub("\/get\/.*", "/downloads", url)
 280                 d("github bitbucket url, mungled url to: " url)
 281
 282         } else if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 283                 gsub("\/snapshot\/.*", "/", url)
 284                 d("cgit snapshot tarball url, mungled url to: " url)
 285
 286         } else if (url ~/^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 287                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 288                 d("aquamaniac.de tarball url, mungled url to: " url)
 289
 290         } else if (url ~/^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 291                 url = "http://www.process-one.net/en/ejabberd/archive/"
 292                 d("ejabberd tarball url, mungled url to: " url)
 293
 294         } else if (url ~/^(http|https):\/\/llvm.org\/releases\//) {
 295                 url = "http://llvm.org/releases/download.html"
 296                 d("llvm tarball url, mungled url to: " url)
 297         }
 298
 299         if (url ~/^(http|https):\/\/download\.owncloud\.org\/community\//) {
 300                 url = "http://owncloud.org/changelog/"
 301                 d("owncloud tarball url, mungled url to: " url)
 302         }
 303
 304         if (url ~/^(http|https):\/\/hackage\.haskell\.org\/packages\/archive\//) {
 305                 gsub("\/packages\/archive","/package",url)
 306                 d("hackage haskell tarball url, mungled url to: " url)
 307         }
 308
 309         if (url ~/^http:\/\/www.taskwarrior.org\/download\//) {
 310                 url = "http://taskwarrior.org/projects/taskwarrior/wiki/Download"
 311                 d("taskwarrior tarball url, mungled url to: " url)
 312         }
 313
 314         d("Retrieving: " url)
 315         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 316         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 317         d("Execute: " cmd)
 318         errno = system(cmd)
 319         d("Execute done")
 320
 321         if (errno != 0) {
 322                 d("Reading failure response...")
 323                 wholeerr = ""
 324                 while (getline oneline < tmpfileerr)
 325                         wholeerr = (wholeerr " " oneline)
 326                 d("Error Response: " wholeerr)
 327
 328                 system("rm -f " tmpfile)
 329                 system("rm -f " tmpfileerr)
 330                 retval = ("WGET ERROR: " errno ": " wholeerr)
 331                 return retval
 332         }
 333         system("rm -f " tmpfileerr)
 334
 335         urldir = url;
 336         sub(/[^\/]+$/, "", urldir)
 337
 338 if (USE_PERL) {
 339         cmd = extract_links_cmd(tmpfile)
 340         while (cmd | getline) {
 341                 tag = $1
 342                 link = substr($0, length(tag) + 2)
 343
 344                 if (tag == "iframe") {
 345                         d("Frame: " link)
 346                         if (url !~ /\//) {
 347                                 link = (urldir link)
 348                                 d("Frame->: " link)
 349                         }
 350
 351                         if (link_seen(link)) {
 352                                 continue
 353                         }
 354                         retval = (retval " " get_links(link))
 355                 }
 356
 357                 if (link_seen(link)) {
 358                         continue
 359                 }
 360
 361                 retval = (retval " " link)
 362                 d("href(): " link)
 363         }
 364         close(cmd)
 365         system("rm -f " tmpfile)
 366
 367         d("Returning: [" retval "]")
 368         return retval
 369 }
 370
 371         wholeodp = ""
 372         d("Reading success response...")
 373         while (getline oneline < tmpfile) {
 374                 wholeodp = (wholeodp " " oneline)
 375 #               d("Response: " wholeodp)
 376         }
 377         d("Reponse read done...")
 378         system("rm -f " tmpfile)
 379
 380         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 381                 d("Processing links...")
 382                 odp = substr(wholeodp,RSTART,RLENGTH);
 383                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 384
 385                 lowerodp = tolower(odp);
 386                 if (lowerodp ~ /<frame[ \t]/) {
 387                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 388                         match(odp, /src="[^"]+"/)
 389                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 390                         d("Frame: " newurl)
 391                         if (newurl !~ /\//) {
 392                                 newurl=(urldir newurl)
 393                                 d("Frame->: " newurl)
 394                         }
 395
 396                         if (link_seen(newurl)) {
 397                                 newurl = ""
 398                                 continue
 399                         }
 400
 401                         retval = (retval " " get_links(newurl))
 402                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 403                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 404                         match(odp,/href="[^"]*"/)
 405                         link=substr(odp,RSTART,RLENGTH)
 406                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 407                         link=substr(link,7,length(link)-7)
 408                         link=postfix_link(url, link)
 409
 410                         if (link_seen(link)) {
 411                                 link=""
 412                                 continue
 413                         }
 414
 415                         # link ends with at least 2 digit version
 416                         mlink = ""
 417                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 418                                 mlink = get_links(link)
 419
 420                         retval = (retval " " link " " mlink)
 421                         d("href(\"\"): " link)
 422                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 423                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 424                         match(odp,/href='[^']*'/)
 425                         link=substr(odp,RSTART,RLENGTH)
 426                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 427                         link=substr(link,7,length(link)-7)
 428                         link=postfix_link(url, link)
 429
 430                         if (link_seen(link)) {
 431                                 link=""
 432                                 continue
 433                         }
 434
 435                         retval = (retval " " link)
 436                         d("href(''): " link)
 437                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 438                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 439                         match(odp,/href=[^ \t>]*/)
 440                         link=substr(odp,RSTART,RLENGTH)
 441                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 442                         link=substr(link,6,length(link)-5)
 443
 444                         if (link_seen(link)) {
 445                                 link=""
 446                                 continue
 447                         }
 448
 449                         retval = (retval " " link)
 450                         d("href(): " link)
 451                 } else {
 452                         # <a ...> but not href - skip
 453                         d("skipping <a > without href: " odp)
 454                 }
 455         }
 456
 457         d("Returning: [" retval "]")
 458         return retval
 459 }
 460
 461 function subst_defines(var,defs) {
 462 # substitute all possible RPM macros
 463         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 464                 oldvar=var
 465                 for (j in defs) {
 466                         gsub("%{" j "}", defs[j], var)
 467                         gsub("%" j , defs[j], var)
 468                 }
 469                 if (var==oldvar) {
 470                         if (DEBUG) {
 471                                 for (i in defs) {
 472                                         d(i " == " defs[i])
 473                                 }
 474                         }
 475                         return var
 476                 }
 477         }
 478         return var
 479 }
 480
 481 function find_mirror(url) {
 482
 483         while (succ = (getline line < "mirrors")) {
 484             if (succ==-1) { return url }
 485                 nf=split(line,fields,"|")
 486                 if (nf>1){
 487                         origin=fields[1]
 488                         mirror=fields[2]
 489                         mname=fields[3]
 490                         prefix=substr(url,1,length(origin))
 491                         if (prefix==origin){
 492                                 d("Mirror found at " mname)
 493                                 close("mirrors")
 494                                 return mirror substr(url,length(origin)+1)
 495                         }
 496                 }
 497         }
 498
 499         return url
 500 }
 501
 502 # fetches file list, and compares version numbers
 503 function process_source(number, lurl, name, version) {
 504         d("Processing " lurl)
 505
 506         if (index(lurl, version) == 0) {
 507                 d("There is no version number ["version"] in ["lurl"]")
 508                 return 0
 509         }
 510
 511         sub("://",":",lurl)
 512         sub("/",":/",lurl)
 513         gsub("[^/]*$",":&",lurl)
 514         split(lurl,url,":")
 515         acc=url[1]
 516         host=url[2]
 517         dir=url[3]
 518         filename=url[4]
 519
 520         if (index(dir,version)) {
 521                 # directory name as version maching mode:
 522                 # if /something/version/name-version.tarball then check
 523                 # in /something/ looking for newer directory
 524                 dir=substr(dir,1,index(dir,version)-1)
 525                 sub("[^/]*$","",dir)
 526                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 527         }
 528
 529         d("Will check a directory: " dir)
 530         d("and a file: " filename)
 531
 532         filenameexp=filename
 533         gsub("[+]","\\+",filenameexp)
 534         sub(version,"[A-Za-z0-9.]+",filenameexp)
 535         gsub("[.]","\\.",filenameexp)
 536         sub("\.(bz|bz2|gz|lzma|xz|zip)$",".(bz|bz2|gz|lzma|xz|zip)",filenameexp)
 537         d("Expression: " filenameexp)
 538         match(filename,version)
 539         prever=substr(filename,1,RSTART-1)
 540         postver=substr(filename,RSTART+RLENGTH)
 541         d("Before number: " prever)
 542         d("and after: " postver)
 543         newurl=find_mirror(acc "://" host dir)
 544         #print acc "://" host dir
 545         #newurl=url[1]"://"url[2]url[3]url[4]
 546         #newurl=acc "://" host dir filename
 547         d("Looking at " newurl)
 548
 549         references=0
 550         finished=0
 551         oldversion=version
 552         odp = get_links(newurl, filename)
 553         if( odp ~ "ERROR: ") {
 554                 print name "(" number ") " odp
 555         } else {
 556                 d("WebPage downloaded")
 557                 c=split(odp,linki)
 558                 for (nr=1; nr<=c; nr++) {
 559                         addr=linki[nr]
 560
 561                         d("Found link: " addr)
 562
 563                         # github has very different tarball links that clash with this safe check
 564                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 565                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 566                                         continue
 567                                 }
 568                         }
 569
 570                         if (addr ~ filenameexp) {
 571                                 match(addr,filenameexp)
 572                                 newfilename=substr(addr,RSTART,RLENGTH)
 573                                 d("Hypothetical new: " newfilename)
 574                                 newfilename=fixedsub(prever,"",newfilename)
 575                                 newfilename=fixedsub(postver,"",newfilename)
 576                                 d("Version: " newfilename)
 577                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 578                                 # strip ending (happens when in directiory name as version matching mode)
 579                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 580                                 if (NUMERIC) {
 581                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 582                                                 d("Yes, there is new one")
 583                                                 version=newfilename
 584                                                 finished=1
 585                                         }
 586                                 } else if ( compare_ver(version, newfilename)==1 ) {
 587                                         d("Yes, there is new one")
 588                                         version=newfilename
 589                                         finished=1
 590                                 }
 591                         }
 592                 }
 593                 if (finished == 0)
 594                         print name "(" number ") seems ok: " oldversion
 595                 else
 596                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 597         }
 598 }
 599
 600 function rss_upgrade(name, ver, url, regex, cmd) {
 601         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 602         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 603
 604         d("rss_upgrade_cmd: " cmd)
 605         cmd | getline ver
 606         close(cmd)
 607
 608         return ver
 609 }
 610
 611 # check for ZF upgrade from rss
 612 function zf_upgrade(name, ver) {
 613         return rss_upgrade(name, ver, \
 614                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 615                 "Zend Framework ([^\\s]+) Released" \
 616         );
 617 }
 618
 619 function hudson_upgrade(name, ver) {
 620         return rss_upgrade(name, ver, \
 621                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 622                 "Hudson ([0-9.]+) released" \
 623         );
 624 }
 625
 626 # upgrade check for pear package using PEAR CLI
 627 function pear_upgrade(name, ver,    cmd) {
 628         sub(/^php-pear-/, "", name);
 629
 630         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 631         d("PEAR: " cmd)
 632         cmd | getline ver
 633         close(cmd)
 634
 635         return ver
 636 }
 637
 638 function vim_upgrade(name, ver,     cmd) {
 639         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 640         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 641         d("VIM: " cmd)
 642         cmd | getline ver
 643         close(cmd)
 644         return ver
 645 }
 646
 647 function nodejs_upgrade(name, ver,   cmd) {
 648         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 649         if (DEFS["pkg"]) {
 650                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 651         } else {
 652                 cmd = "npm info " name " dist-tags.latest"
 653         }
 654         cmd | getline ver
 655         close(cmd)
 656
 657         return ver
 658 }
 659
 660 function rubygem_upgrade(name, ver,   cmd, pkg) {
 661         if (DEFS["gem_name"]) {
 662                 pkg = DEFS["gem_name"];
 663
 664         } else if (DEFS["gemname"]) {
 665                 pkg = DEFS["gemname"];
 666
 667         } else if (DEFS["pkgname"]) {
 668                 pkg = DEFS["pkgname"];
 669
 670         } else {
 671                 pkg = name;
 672                 gsub(/^ruby-/, "", pkg);
 673         }
 674
 675         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); print v}'"
 676         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 677         cmd | getline ver
 678
 679         close(cmd)
 680
 681         return ver
 682 }
 683
 684 function chrome_upgrade(name, ver,   cmd, sourceurl) {
 685         sourceurl = "http://dl.google.com/linux/chrome/rpm/stable/x86_64/repodata/primary.xml.gz"
 686         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>google-chrome-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 687         d("CHROME " cmd);
 688         cmd | getline ver
 689         close(cmd)
 690
 691         return ver
 692 }
 693
 694 function process_data(name, ver, rel, src,   nver) {
 695         if (name ~ /^php-pear-/) {
 696                 nver = pear_upgrade(name, ver);
 697         } else if (name == "ZendFramework") {
 698                 nver = zf_upgrade(name, ver);
 699         } else if (name == "hudson") {
 700                 nver = hudson_upgrade(name, ver);
 701         } else if (name == "vim") {
 702                 nver = vim_upgrade(name, ver);
 703         } else if (name == "google-chrome") {
 704                 nver = chrome_upgrade(name, ver);
 705         } else if (name ~ "^nodejs-") {
 706                 nver = nodejs_upgrade(name, ver);
 707         } else if (name ~ "^ruby-") {
 708                 nver = rubygem_upgrade(name, ver);
 709         }
 710
 711         if (nver) {
 712                 if (compare_ver(ver, nver)) {
 713                         print name " [OLD] " ver " [NEW] " nver
 714                 } else {
 715                         print name " seems ok: " ver
 716                 }
 717                 return;
 718         }
 719
 720         if (name == "xulrunner") {
 721                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 722                 d("package xulrunner, change version to firefox ["ver"]")
 723         }
 724
 725 # this function checks if substitutions were valid, and if true:
 726 # processes each URL and tries to get current file list
 727         for (i in src) {
 728                 if (src[i] ~ /%{nil}/) {
 729                         gsub(/\%\{nil\}/, "", src[i])
 730                 }
 731                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 732                         d("Source: " src[i])
 733                         process_source(i, src[i], name, ver)
 734                 } else {
 735                         print FNAME ":" i ": impossible substitution: " src[i]
 736                 }
 737         }
 738 }
 739
 740 BEGIN {
 741         # if you want to use DEBUG, run script with "-v DEBUG=1"
 742         # or uncomment the line below
 743         # DEBUG = 1
 744
 745         errno=system("wget --help > /dev/null 2>&1")
 746         if (errno && errno != 3) {
 747                 print "No wget installed!"
 748                 exit 1
 749         }
 750         if (ARGC>=3 && ARGV[2]=="-n") {
 751                 NUMERIC=1
 752                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 753                 ARGC=ARGC-1
 754         }
 755 }
 756
 757 FNR==1 {
 758         if ( ARGIND != 1 ) {
 759                 # clean frameseen for each ARG
 760                 for (i in frameseen) {
 761                         delete frameseen[i]
 762                 }
 763                 frameseen[0] = 1
 764
 765                 process_data(NAME,VER,REL,SRC)
 766                 NAME="" ; VER="" ; REL=""
 767                 for (i in DEFS) delete DEFS[i]
 768                 for (i in SRC) delete SRC[i]
 769         }
 770         FNAME=FILENAME
 771         DEFS["_alt_kernel"]=""
 772         DEFS["20"]="\\ "
 773         DEFS["nil"]=""
 774 }
 775
 776 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 777 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 778 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 779 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 780 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 781 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 782
 783 END {
 784         process_data(NAME,VER,REL,SRC)
 785 }