pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2011 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17 # - support debian/watch http://wiki.debian.org/debian/watch/
  18
  19
  20 function d(s) {
  21         if (!DEBUG) {
  22                 return
  23         }
  24
  25 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  26         print s >> "/dev/stderr"
  27 }
  28
  29 function fixedsub(s1,s2,t,      ind) {
  30 # substitutes fixed strings (not regexps)
  31         if (ind = index(t,s1)) {
  32                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  33         }
  34         return t
  35 }
  36
  37 function ispre(s) {
  38         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  39                 d("pre-version")
  40                 return 1
  41         } else {
  42                 return 0
  43         }
  44 }
  45
  46 function compare_ver(v1,v2) {
  47 # compares version numbers
  48         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  49                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  50         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  51                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  52         sub("^0*","",v1)
  53         sub("^0*","",v2)
  54         gsub("\.0*",".",v1)
  55         gsub("\.0*",".",v2)
  56         d("v1 == " v1)
  57         d("v2 == " v2)
  58         count=split(v1,v1a,"\.")
  59         count2=split(v2,v2a,"\.")
  60
  61         if (count<count2) mincount=count
  62         else mincount=count2
  63
  64         for (i=1; i<=mincount; i++) {
  65                 if (v1a[i]=="") v1a[i]=0
  66                 if (v2a[i]=="") v2a[i]=0
  67                 d("i == " i)
  68                 d("v1[i] == " v1a[i])
  69                 d("v2[i] == " v2a[i])
  70                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  71                         if (length(v2a[i])>length(v1a[i]))
  72                                 return 1
  73                         else if (v2a[i]>v1a[i])
  74                                 return 1
  75                         else if (length(v1a[i])>length(v2a[i]))
  76                                 return 0
  77                         else if (v1a[i]>v2a[i])
  78                                 return 0
  79                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  80                         if (v2a[i]>v1a[i])
  81                                 return 1
  82                         else if (v1a[i]>v2a[i])
  83                                 return 0
  84                 } else if (ispre(v1a[i]) == 1)
  85                         return 1
  86                 else
  87                         return 0
  88         }
  89         if ((count2==mincount)&&(count!=count2)) {
  90                 for (i=count2+1; i<=count; i++)
  91                         if (ispre(v1a[i]) == 1)
  92                                 return 1
  93                 return 0
  94         } else if (count!=count2) {
  95                 for (i=count+1; i<=count2; i++)
  96                         if (ispre(v2a[i]) == 1)
  97                                 return 0
  98                 return 1
  99         }
 100         return 0
 101 }
 102
 103 function compare_ver_dec(v1,v2) {
 104 # compares version numbers as decimal floats
 105         while (match(v1,/[0-9][a-zA-Z]/))
 106                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 107         while (match(v2,/[0-9][a-zA-Z]/))
 108                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 109         sub("^0*","",v1)
 110         sub("^0*","",v2)
 111         d("v1 == " v1)
 112         d("v2 == " v2)
 113         count=split(v1,v1a,"\.")
 114         count2=split(v2,v2a,"\.")
 115
 116         if (count<count2) mincount=count
 117         else mincount=count2
 118
 119         for (i=1; i<=mincount; i++) {
 120                 if (v1a[i]=="") v1a[i]=0
 121                 if (v2a[i]=="") v2a[i]=0
 122                 d("i == " i)
 123                 d("v1[i] == " v1a[i])
 124                 d("v2[i] == " v2a[i])
 125                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 126                         if (i==2) {
 127                                 if (0+("." v2a[i])>0+("." v1a[i]))
 128                                         return 1
 129                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 130                                         return 0
 131                         } else {
 132                                 if (length(v2a[i])>length(v1a[i]))
 133                                         return 1
 134                                 else if (v2a[i]>v1a[i])
 135                                         return 1
 136                                 else if (length(v1a[i])>length(v2a[i]))
 137                                         return 0
 138                                 else if (v1a[i]>v2a[i])
 139                                         return 0
 140                         }
 141                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 142                         if (v2a[i]>v1a[i])
 143                                 return 1
 144                         else if (v1a[i]>v2a[i])
 145                                 return 0
 146                 } else if (ispre(v1a[i]) == 1)
 147                         return 1
 148                 else
 149                         return 0
 150         }
 151         if ((count2==mincount)&&(count!=count2)) {
 152                 for (i=count2+1; i<=count; i++)
 153                         if (ispre(v1a[i]) == 1)
 154                                 return 1
 155                 return 0
 156         } else if (count!=count2) {
 157                 for (i=count+1; i<=count2; i++)
 158                         if (ispre(v2a[i]) == 1)
 159                                 return 0
 160                 return 1
 161         }
 162         return 0
 163 }
 164
 165 function link_seen(link) {
 166         for (seenlink in frameseen) {
 167                 if (seenlink == link) {
 168                         d("Link: [" link "] seen already, skipping...")
 169                         return 1
 170                 }
 171         }
 172         frameseen[link]=1
 173         return 0
 174 }
 175
 176 function mktemp(   _cmd, _tmpfile) {
 177         _cmd = "mktemp /tmp/XXXXXX"
 178         _cmd | getline _tmpfile
 179         close(_cmd)
 180         return _tmpfile
 181 }
 182
 183 # fix link to artificial one that will be recognized rest of this script
 184 function postfix_link(url, link,   oldlink) {
 185         oldlink = link
 186         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 187                 gsub(".*\/tarball\/", "", link)
 188                 link = link ".tar.gz"
 189         }
 190         if (oldlink != link) {
 191                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 192         }
 193         return link
 194 }
 195
 196 # use perl HTML::TreeBuilder module to extract links from html
 197 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 198 function extract_links_cmd(tmpfile) {
 199         return "perl -MHTML::TreeBuilder -e ' \
 200         my $content = join q//, <>; \
 201         my $root = new HTML::TreeBuilder; \
 202         $root->parse($content); \
 203         \
 204         my %links = (); \
 205         for (@{$root->extract_links(qw(a iframe))}) { \
 206                 my($link, $element, $attr, $tag) = @$_; \
 207                 $links{$link} = $tag; \
 208         } \
 209         \
 210         while (my($link, $tag) = each %links) { \
 211                 print $tag, q/ /, $link, $/; \
 212         } \
 213         ' " tmpfile
 214 }
 215
 216 # get all <A HREF=..> tags from specified URL
 217 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 218
 219         wholeerr=""
 220
 221         tmpfile = mktemp()
 222         tmpfileerr = mktemp()
 223
 224         if (url ~ /^http:\/\/(download|dl)\.(sf|sourceforge)\.net\//) {
 225                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 226                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 227
 228                 gsub("/.*", "", url)
 229                 url = "http://sourceforge.net/projects/" url "/files/"
 230                 d("sf url, mungled url to: " url)
 231         }
 232
 233         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 234                 gsub("^http://", "", url)
 235                 gsub("\..*", "", url)
 236                 url = "http://code.google.com/p/" url "/downloads/list"
 237                 d("googlecode url, mungled url to: " url)
 238         }
 239
 240         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 241                 gsub("-.*", "", filename)
 242                 url = "http://pecl.php.net/package/" filename
 243                 d("pecl.php.net url, mungled url to: " url)
 244         }
 245
 246         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 247                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 248                  d("mysql 5.1 url, mungled url to: " url)
 249         }
 250
 251         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 252                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 253                 gsub("\/.*/", "", url)
 254                 url = "https://code.launchpad.net/" url "/+download"
 255                 d("main launchpad url, mungled url to: " url)
 256         }
 257
 258         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 259                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 260                 gsub("\/.*/", "", url)
 261                 url = "https://edge.launchpad.net/" url "/+download"
 262                 d("edge launchpad url, mungled url to: " url)
 263         }
 264
 265         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 266                 gsub("\/tarball\/.*", "/downloads", url)
 267                 d("github tarball url, mungled url to: " url)
 268         }
 269
 270         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 271                 gsub("\/snapshot\/.*", "/", url)
 272                 d("cgit snapshot tarball url, mungled url to: " url)
 273         }
 274
 275         if (url ~/^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 276                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 277                 d("aquamaniac.de tarball url, mungled url to: " url)
 278         }
 279
 280         d("Retrieving: " url)
 281         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 282         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 283         d("Execute: " cmd)
 284         errno = system(cmd)
 285         d("Execute done")
 286
 287         if (errno != 0) {
 288                 d("Reading failure response...")
 289                 wholeerr = ""
 290                 while (getline oneline < tmpfileerr)
 291                         wholeerr = (wholeerr " " oneline)
 292                 d("Error Response: " wholeerr)
 293
 294                 system("rm -f " tmpfile)
 295                 system("rm -f " tmpfileerr)
 296                 retval = ("WGET ERROR: " errno ": " wholeerr)
 297                 return retval
 298         }
 299         system("rm -f " tmpfileerr)
 300
 301         urldir = url;
 302         sub(/[^\/]+$/, "", urldir)
 303
 304 if (USE_PERL) {
 305         cmd = extract_links_cmd(tmpfile)
 306         while (cmd | getline) {
 307                 tag = $1
 308                 link = substr($0, length(tag) + 2)
 309
 310                 if (tag == "iframe") {
 311                         d("Frame: " link)
 312                         if (url !~ /\//) {
 313                                 link = (urldir link)
 314                                 d("Frame->: " link)
 315                         }
 316
 317                         if (link_seen(link)) {
 318                                 continue
 319                         }
 320                         retval = (retval " " get_links(link))
 321                 }
 322
 323                 if (link_seen(link)) {
 324                         continue
 325                 }
 326
 327                 retval = (retval " " link)
 328                 d("href(): " link)
 329         }
 330         close(cmd)
 331         system("rm -f " tmpfile)
 332
 333         d("Returning: [" retval "]")
 334         return retval
 335 }
 336
 337         wholeodp = ""
 338         d("Reading success response...")
 339         while (getline oneline < tmpfile) {
 340                 wholeodp = (wholeodp " " oneline)
 341 #               d("Response: " wholeodp)
 342         }
 343         d("Reponse read done...")
 344         system("rm -f " tmpfile)
 345
 346         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 347                 d("Processing links...")
 348                 odp = substr(wholeodp,RSTART,RLENGTH);
 349                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 350
 351                 lowerodp = tolower(odp);
 352                 if (lowerodp ~ /<frame[ \t]/) {
 353                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 354                         match(odp, /src="[^"]+"/)
 355                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 356                         d("Frame: " newurl)
 357                         if (newurl !~ /\//) {
 358                                 newurl=(urldir newurl)
 359                                 d("Frame->: " newurl)
 360                         }
 361
 362                         if (link_seen(newurl)) {
 363                                 newurl = ""
 364                                 continue
 365                         }
 366
 367                         retval = (retval " " get_links(newurl))
 368                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 369                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 370                         match(odp,/href="[^"]*"/)
 371                         link=substr(odp,RSTART,RLENGTH)
 372                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 373                         link=substr(link,7,length(link)-7)
 374                         link=postfix_link(url, link)
 375
 376                         if (link_seen(link)) {
 377                                 link=""
 378                                 continue
 379                         }
 380
 381                         # link ends with at least 2 digit version
 382                         mlink = ""
 383                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 384                                 mlink = get_links(link)
 385
 386                         retval = (retval " " link " " mlink)
 387                         d("href(\"\"): " link)
 388                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 389                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 390                         match(odp,/href='[^']*'/)
 391                         link=substr(odp,RSTART,RLENGTH)
 392                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 393                         link=substr(link,7,length(link)-7)
 394                         link=postfix_link(url, link)
 395
 396                         if (link_seen(link)) {
 397                                 link=""
 398                                 continue
 399                         }
 400
 401                         retval = (retval " " link)
 402                         d("href(''): " link)
 403                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 404                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 405                         match(odp,/href=[^ \t>]*/)
 406                         link=substr(odp,RSTART,RLENGTH)
 407                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 408                         link=substr(link,6,length(link)-5)
 409
 410                         if (link_seen(link)) {
 411                                 link=""
 412                                 continue
 413                         }
 414
 415                         retval = (retval " " link)
 416                         d("href(): " link)
 417                 } else {
 418                         # <a ...> but not href - skip
 419                         d("skipping <a > without href: " odp)
 420                 }
 421         }
 422
 423         d("Returning: [" retval "]")
 424         return retval
 425 }
 426
 427 function subst_defines(var,defs) {
 428 # substitute all possible RPM macros
 429         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 430                 oldvar=var
 431                 for (j in defs) {
 432                         gsub("%{" j "}", defs[j], var)
 433                         gsub("%" j , defs[j], var)
 434                 }
 435                 if (var==oldvar) {
 436                         if (DEBUG) {
 437                                 for (i in defs) {
 438                                         d(i " == " defs[i])
 439                                 }
 440                         }
 441                         return var
 442                 }
 443         }
 444         return var
 445 }
 446
 447 function find_mirror(url) {
 448
 449         while (succ = (getline line < "mirrors")) {
 450             if (succ==-1) { return url }
 451                 nf=split(line,fields,"|")
 452                 if (nf>1){
 453                         origin=fields[1]
 454                         mirror=fields[2]
 455                         mname=fields[3]
 456                         prefix=substr(url,1,length(origin))
 457                         if (prefix==origin){
 458                                 d("Mirror found at " mname)
 459                                 close("mirrors")
 460                                 return mirror substr(url,length(origin)+1)
 461                         }
 462                 }
 463         }
 464
 465         return url
 466 }
 467
 468 function process_source(number, lurl, name, version) {
 469 # fetches file list, and compares version numbers
 470         d("Processing " lurl)
 471
 472         if (index(lurl, version) == 0) {
 473                 d("There is no version number ["version"] in ["lurl"]")
 474                 return 0
 475         }
 476
 477         sub("://",":",lurl)
 478         sub("/",":/",lurl)
 479         gsub("[^/]*$",":&",lurl)
 480         split(lurl,url,":")
 481         acc=url[1]
 482         host=url[2]
 483         dir=url[3]
 484         filename=url[4]
 485
 486         if (index(dir,version)) {
 487                 # directory name as version maching mode:
 488                 # if /something/version/name-version.tarball then check
 489                 # in /something/ looking for newer directory
 490                 dir=substr(dir,1,index(dir,version)-1)
 491                 sub("[^/]*$","",dir)
 492                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 493         }
 494
 495         d("Will check a directory: " dir)
 496         d("and a file: " filename)
 497
 498         filenameexp=filename
 499         gsub("[+]","\\+",filenameexp)
 500         sub(version,"[A-Za-z0-9.]+",filenameexp)
 501         gsub("[.]","\\.",filenameexp)
 502         d("Expression: " filenameexp)
 503         match(filename,version)
 504         prever=substr(filename,1,RSTART-1)
 505         postver=substr(filename,RSTART+RLENGTH)
 506         d("Before number: " prever)
 507         d("and after: " postver)
 508         newurl=find_mirror(acc "://" host dir)
 509         #print acc "://" host dir
 510         #newurl=url[1]"://"url[2]url[3]url[4]
 511         #newurl=acc "://" host dir filename
 512         d("Looking at " newurl)
 513
 514         references=0
 515         finished=0
 516         oldversion=version
 517         odp = get_links(newurl, filename)
 518         if( odp ~ "ERROR: ") {
 519                 print name "(" number ") " odp
 520         } else {
 521                 d("WebPage downloaded")
 522                 c=split(odp,linki)
 523                 for (nr=1; nr<=c; nr++) {
 524                         addr=linki[nr]
 525
 526                         d("Found link: " addr)
 527
 528                         # github has very different tarball links that clash with this safe check
 529                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 530                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 531                                         continue
 532                                 }
 533                         }
 534
 535                         if (addr ~ filenameexp) {
 536                                 match(addr,filenameexp)
 537                                 newfilename=substr(addr,RSTART,RLENGTH)
 538                                 d("Hypothetical new: " newfilename)
 539                                 newfilename=fixedsub(prever,"",newfilename)
 540                                 newfilename=fixedsub(postver,"",newfilename)
 541                                 d("Version: " newfilename)
 542                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 543                                 # strip ending (happens when in directiory name as version matching mode)
 544                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 545                                 if (NUMERIC) {
 546                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 547                                                 d("Yes, there is new one")
 548                                                 version=newfilename
 549                                                 finished=1
 550                                         }
 551                                 } else if ( compare_ver(version, newfilename)==1 ) {
 552                                         d("Yes, there is new one")
 553                                         version=newfilename
 554                                         finished=1
 555                                 }
 556                         }
 557                 }
 558                 if (finished == 0)
 559                         print name "(" number ") seems ok: " oldversion
 560                 else
 561                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 562         }
 563 }
 564
 565 function rss_upgrade(name, ver, url, regex, cmd, nver) {
 566         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 567         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 568
 569         d("rss_upgrade_cmd: " cmd)
 570         cmd | getline nver
 571         close(cmd)
 572
 573         if (compare_ver(ver, nver)) {
 574                 print name " [OLD] " ver " [NEW] " nver
 575         } else {
 576                 print name " seems ok: " ver
 577         }
 578 }
 579
 580 # check for ZF upgrade from rss
 581 function zf_upgrade(name, ver) {
 582         rss_upgrade(name, ver, \
 583                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 584                 "Zend Framework ([^\\s]+) Released" \
 585         );
 586 }
 587
 588 function hudson_upgrade(name, ver) {
 589         rss_upgrade(name, ver, \
 590                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 591                 "Hudson ([0-9.]+) released" \
 592         );
 593 }
 594
 595 # upgrade check for pear package using PEAR CLI
 596 function pear_upgrade(name, ver,    pname, pearcmd, nver) {
 597         pname = name;
 598         sub(/^php-pear-/, "", pname);
 599
 600         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 601         d("pearcmd: " pearcmd)
 602         pearcmd | getline nver
 603         close(pearcmd)
 604
 605         if (compare_ver(ver, nver)) {
 606                 print name " [OLD] " ver " [NEW] " nver
 607         } else {
 608                 print name " seems ok: " ver
 609         }
 610
 611         return
 612 }
 613
 614 function vim_upgrade(name, ver,     mver, nver, vimcmd) {
 615         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 616         mver = substr(ver, 0, 4)
 617         vimcmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/"mver"/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 618         d("vimcmd: " vimcmd)
 619         vimcmd | getline nver
 620         close(vimcmd)
 621
 622         if (compare_ver(ver, nver)) {
 623                 print name " [OLD] " ver " [NEW] " nver
 624         } else {
 625                 print name " seems ok: " ver
 626         }
 627 }
 628
 629 function process_data(name, ver, rel, src) {
 630         if (name ~ /^php-pear-/) {
 631                 return pear_upgrade(name, ver);
 632         }
 633         if (name == "ZendFramework") {
 634                 return zf_upgrade(name, ver);
 635         }
 636         if (name == "hudson") {
 637                 return hudson_upgrade(name, ver);
 638         }
 639         if (name == "vim") {
 640                 return vim_upgrade(name, ver);
 641         }
 642         if (name == "xulrunner") {
 643                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 644                 d("package xulrunner, change version to firefox ["ver"]")
 645         }
 646
 647 # this function checks if substitutions were valid, and if true:
 648 # processes each URL and tries to get current file list
 649         for (i in src) {
 650                 if (src[i] ~ /%{nil}/) {
 651                         gsub(/\%\{nil\}/, "", src[i])
 652                 }
 653                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 654                         d("Source: " src[i])
 655                         process_source(i, src[i], name, ver)
 656                 } else {
 657                         print FNAME ":" i ": impossible substitution: " src[i]
 658                 }
 659         }
 660 }
 661
 662 BEGIN {
 663         # if U want to use DEBUG, run script with "-v DEBUG=1"
 664         # or uncomment the line below
 665         # DEBUG = 1
 666
 667         errno=system("wget --help > /dev/null 2>&1")
 668         if (errno && errno != 3) {
 669                 print "No wget installed!"
 670                 exit 1
 671         }
 672         if (ARGC>=3 && ARGV[2]=="-n") {
 673                 NUMERIC=1
 674                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 675                 ARGC=ARGC-1
 676         }
 677 }
 678
 679 FNR==1 {
 680         if ( ARGIND != 1 ) {
 681                 # clean frameseen for each ARG
 682                 for (i in frameseen) {
 683                         delete frameseen[i]
 684                 }
 685                 frameseen[0] = 1
 686
 687                 process_data(NAME,VER,REL,SRC)
 688                 NAME="" ; VER="" ; REL=""
 689                 for (i in DEFS) delete DEFS[i]
 690                 for (i in SRC) delete SRC[i]
 691         }
 692         FNAME=FILENAME
 693         DEFS["_alt_kernel"]=""
 694         DEFS["20"]="\\ "
 695         DEFS["nil"]=""
 696 }
 697
 698 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 699 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 700 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 701 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 702 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 703 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 704
 705 END {
 706         process_data(NAME,VER,REL,SRC)
 707 }