adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # Adapter adapts .spec files for PLD Linux.
   4 #
   5 # Copyright (C) 1999-2013 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Michał Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Jakub Bogusz <qboosh@pld-linux.org>
  13 #       Elan Ruusamäe <glen@pld-linux.org>
  14 #
  15 # See git log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - really long sourceX make preamble sorting totally fcked up (try snake.spec r1.1)
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27 # - it should change: /%source([0-9]+)/i to %{SOURCE\1}
  28 # - extra quote on LDFLAGS line: https://bugs.launchpad.net/pld-linux/+bug/385836
  29 # - %{with_foo:%attr()...} gets converted to %attr() %{with_foo:...} [vlc.spec]
  30 # - 'R: foo ' (with traliling space) gets coverted to "R: foo\nR: " [vlc.spec @ 1.199 ]
  31
  32 BEGIN {
  33         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  34         SECTIONS = "^%(" RPM_SECTIONS ")"
  35
  36         rev = "1.514"
  37         VERSION = "0.36/" rev
  38
  39         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests|Auto(Req|Prov))"
  40
  41         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  42
  43         preamble = 1    # Is it part of preamble? Default - yes
  44         bod = 0                 # Beginning of %description
  45         tw = 70                 # Descriptions width
  46
  47         b_idx = 0               # index of BR/R arrays
  48         BR_count = 0    # number of additional BuildRequires
  49
  50         # If variable removed, then 1 (for removing it from export)
  51         removed["LDFLAGS"] = 0
  52         removed["CFLAGS"] = 0
  53         removed["CXXFLAGS"] = 0
  54
  55         # If 1, we are inside of comment block (started with /^#%/)
  56         comment_block = 0
  57
  58         import_rpm_macros()
  59
  60         packages_dir = topdir
  61         groups_file = packages_dir "/../rpm-build-tools/rpm.groups"
  62
  63         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)")
  64 }
  65
  66 # If the latest line matched /%files/
  67 defattr == 1 {
  68         if (ENVIRON["SKIP_DEFATTR"] != 1) {
  69                 if ($0 !~ /defattr/) {  # If no %defattr
  70                         print "%defattr(644,root,root,755)"     # Add it
  71                 } else {
  72                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  73                 }
  74         }
  75         defattr = 0
  76 }
  77
  78 # call mktemp(1) and return the value
  79 function mktemp(template, tmp) {
  80    "mktemp " template | getline tmp
  81    return tmp
  82 }
  83
  84 function b_makekey(a, b,        s) {
  85         s = a "" b
  86         # kill bcond
  87         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s)
  88
  89         # kill commented out items
  90         gsub(/^#[ \t]*/, "", s)
  91
  92         # force order
  93         gsub(/^Summary\(/, "11Summary(", s)
  94         gsub(/^Summary/, "10Summary", s)
  95
  96         gsub(/^Name/, "2Name", s)
  97         gsub(/^Version/, "3Version", s)
  98         gsub(/^Release/, "4Release", s)
  99         gsub(/^Epoch/, "5Epoch", s)
 100         gsub(/^License/, "5License", s)
 101         gsub(/^Group/, "6Group", s)
 102         gsub(/^URL/, "7URL", s)
 103
 104         gsub(/^BuildRequires/, "B1BuildRequires", s)
 105         gsub(/^BuildConflicts/, "B2BuildConflicts", s)
 106
 107         gsub(/^Suggests/, "X1Suggests", s)
 108         gsub(/^Provides/, "X2Provides", s)
 109         gsub(/^Obsoletes/, "X3Obsoletes", s)
 110         gsub(/^Conflicts/, "X4Conflicts", s)
 111         gsub(/^BuildArch/, "X5BuildArch", s)
 112         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s)
 113         gsub(/^ExcludeArch/, "X7ExcludeArch", s)
 114         gsub(/^BuildRoot/, "X9BuildRoot", s)
 115
 116         gsub(/^AutoProv/, "Xx1AutoProv", s)
 117         gsub(/^AutoReq/, "Xx2AutoReq", s)
 118
 119 #       printf("%s -> %s\n", a""b, s)
 120         return s
 121 }
 122
 123 # Comments
 124 /^#/ && (description == 0) {
 125         if (/This file does not like to be adapterized!/) {
 126                 print                   # print this message
 127                 while (getline)         # print the rest of spec as it is
 128                         print
 129                 do_not_touch_anything = 1 # do not touch anything in END()
 130                 exit(rc = 0)
 131         }
 132
 133         # Generally, comments are printed without touching
 134         sub(/[ \t]+$/, "")
 135
 136         if (/#[ \t]*Source.*md5/) {
 137                 if (usedigest == 1) {
 138                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 139                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 140                 }
 141                 print $0
 142                 next
 143         }
 144 }
 145
 146 /^%define/ {
 147         # FIXME: this section will likely never match after cvs->git migration
 148         if ($2 == "date") {
 149                 if (did_files == 0) {
 150                         print "%files"
 151                         print ""
 152                         did_files = 1
 153                 }
 154         }
 155
 156         # Do not add %define of _prefix if it already is.
 157         if ($2 ~ /^_prefix/) {
 158                 sub("^"prefix, $3, bindir)
 159                 sub("^"prefix, $3, sbindir)
 160                 sub("^"prefix, $3, libdir)
 161                 sub("^"prefix, $3, datadir)
 162                 sub("^"prefix, $3, includedir)
 163                 prefix = $3
 164         }
 165
 166         if ($2 ~ /_bindir/ && !/_sbindir/)
 167                 bindir = $3
 168         if ($2 ~ /_sbindir/)
 169                 sbindir = $3
 170         if ($2 ~ /_libdir/) {
 171                 if ($3 ~ /^%\(/) {
 172                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 173                         libdir = "%%%%%%%%%%%%%%"
 174                 } else {
 175                         libdir = $3
 176                 }
 177         }
 178         if ($2 ~ /_sysconfdir/) {
 179                 if ($3 ~ /^%\(/) {
 180                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 181                         sysconfdir = "%%%%%%%%%%%%%%"
 182                 } else {
 183                         sysconfdir = $3
 184                 }
 185         }
 186         if ($2 ~ /_datadir/) {
 187                 if ($3 ~ /^%\(/) {
 188                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 189                         datadir = "%%%%%%%%%%%%%%"
 190                 } else {
 191                         datadir = $3
 192                 }
 193         }
 194         if ($2 ~ /_includedir/)
 195                 includedir = $3
 196         if ($2 ~ /_mandir/)
 197                 mandir = $3
 198         if ($2 ~ /_infodir/)
 199                 infodir = $3
 200         if ($2 ~ /_docdir/)
 201                 docdir = $3
 202
 203         # version related macros
 204         if ($2 ~ /^_beta$/)
 205                 _beta = $3
 206         if ($2 ~ /^_rc$/)
 207                 _rc = $3
 208         if ($2 ~ /^_pre$/)
 209                 _pre = $3
 210         if ($2 ~ /^_snap$/)
 211                 _snap = $3
 212         if ($2 ~ /^subver$/)
 213                 subver = $3
 214
 215         # these are used usually when adapterizing external spec
 216         if ($2 ~ /^name$/)
 217                 name = $3
 218         if ($2 ~ /^version$/)
 219                 version = $3
 220         if ($2 ~ /^release$/)
 221                 release = $3
 222
 223         if ($2 ~ /^mod_name$/)
 224                 mod_name = $3
 225         if ($2 ~ /^_?pearname$/)
 226                 pearname = $3
 227         if ($2 ~ /^_class$/)
 228                 pear_class = $3
 229         if ($2 ~ /^_subclass$/)
 230                 pear_subclass = $3
 231
 232         # kill the _class and _subclass pear macros
 233         if ($2 == "_pearname" || $2 == "pearname") {
 234                 if (pear_class) {
 235                         gsub("%{_class}", pear_class, $3)
 236                 }
 237                 if (pear_subclass) {
 238                         gsub("%{_subclass}", pear_subclass, $3)
 239                 }
 240         }
 241
 242         sub(/[ \t]+$/, "")
 243         # do nothing further, otherwise adapter thinks we're at preamble
 244         print
 245         next
 246 }
 247
 248 # Obsolete
 249 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 250         next
 251 }
 252
 253 # %package part
 254 /^%package/, (!/^%package/ && $0 ~ SECTIONS) {
 255         gsub(/\t/, " ")
 256 }
 257
 258 ################
 259 # %description #
 260 ################
 261 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 262         preamble = 0
 263
 264         if (/^%description/) {
 265                 bod++
 266                 format_line = ""
 267                 format_indent = -1
 268         }
 269
 270         # Format description
 271         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 272                 if (/^[ \t]*$/) {
 273                         format_flush(format_line, format_indent)
 274                         print ""
 275                         format_line = ""
 276                         format_indent = -1
 277                 } else if (/^[ \t]*[-\*][ \t]*/) {
 278                         format_flush(format_line, format_indent)
 279                         match($0, /^[ \t]*/)
 280                         format_indent = RLENGTH
 281                         match($0, /^[ \t]*[-\*][ \t]/)
 282                         format_line = substr($0, RLENGTH)
 283                 } else
 284                         format_line = format_line " " $0
 285                 next
 286         }
 287
 288         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 289                 if (NF > 3 && $2 == "-l") {
 290                         ll = $1
 291                         for (i = 4; i <= NF; i++)
 292                                 ll = ll " " $i
 293                         $0 = ll " -l " $3
 294                 }
 295                 format_flush(format_line, format_indent)
 296                 if (bod == 2) {
 297                         bod = 1
 298                         description = 1
 299                 } else {
 300                         bod = 0
 301                         description = 0
 302                 }
 303         } else
 304                 description = 1
 305 }
 306
 307 #########
 308 # %prep #
 309 #########
 310 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 311         preamble = 0
 312         did_prep = 1
 313
 314         use_macros()
 315
 316         # Add '-q' to %setup
 317         if (/^%setup/ && !/-q/) {
 318                 sub(/^%setup/, "%setup -q")
 319         }
 320
 321         if (/^%setup/ && name != "setup") {
 322                 $0 = fixedsub(name, "%{name}", $0)
 323                 $0 = fixedsub(version, "%{version}", $0)
 324                 if (_beta) {
 325                         $0 = fixedsub(_beta, "%{_beta}", $0)
 326                 }
 327                 if (_rc) {
 328                         $0 = fixedsub(_rc, "%{_rc}", $0)
 329                 }
 330                 if (_pre) {
 331                         $0 = fixedsub(_pre, "%{_pre}", $0)
 332                 }
 333                 if (_snap) {
 334                         $0 = fixedsub(_snap, "%{_snap}", $0)
 335                 }
 336                 if (subver) {
 337                         $0 = fixedsub(subver, "%{subver}", $0)
 338                 }
 339         }
 340
 341         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 342                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 343         }
 344         sub("^%patch ", "%patch0 ")
 345
 346         # fedora extras
 347         if (/^%apply/) {
 348                 sub("^%apply -n", "%patch")
 349         }
 350
 351         # invalid in %prep
 352         sub("^rm -rf \$RPM_BUILD_ROOT.*", "")
 353 }
 354
 355 ##########
 356 # %build #
 357 ##########
 358 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 359         preamble = 0
 360
 361         if (did_prep == 0) {
 362                 print "%prep"
 363                 print ""
 364                 did_prep = 1
 365         }
 366
 367         use_macros()
 368         use_tabs()
 369
 370         if (/^automake$/)
 371                 sub(/$/, " -a -c")
 372
 373         if (/LDFLAGS/) {
 374                 if (/LDFLAGS="-s"/) {
 375                         removed["LDFLAGS"] = 1
 376                         next
 377                 } else {
 378                         split($0, tmp, "LDFLAGS=")
 379                         count = split(tmp[2], flags, "\"")
 380                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 381                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 382                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 383                                 for (i = 2; i < count; i++)
 384                                         $0 = $0 flags[i] "\""
 385                         }
 386                 }
 387         }
 388
 389         if (/CFLAGS=/)
 390                 if (cflags("CFLAGS") == 0)
 391                         next
 392
 393         if (/CXXFLAGS=/)
 394                 if (cflags("CXXFLAGS") == 0)
 395                         next
 396
 397         if (/^export /) {
 398                 if (removed["LDFLAGS"])
 399                         sub(" LDFLAGS", "")
 400                 if (removed["CFLAGS"])
 401                         sub(" CFLAGS", "")
 402                 if (removed["CXXFLAGS"])
 403                         sub(" CXXFLAGS", "")
 404                 # Is there still something?
 405                 if (/^export[ ]*$/)
 406                         next
 407         }
 408
 409         # quote CC
 410         if (/CC=%{__cc} /) {
 411                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 412         }
 413
 414         # use PLD Linux macros
 415         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0)
 416         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0)
 417         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0)
 418         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0)
 419         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0)
 420         $0 = fixedsub("automake -a -c", "%{__automake}", $0)
 421         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0)
 422         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0)
 423
 424         sub(/^aclocal$/, "%{__aclocal}")
 425         sub(/^autoheader$/, "%{__autoheader}")
 426         sub(/^autoconf$/, "%{__autoconf}")
 427         sub(/^automake$/, "%{__automake}")
 428         sub(/^libtoolize$/, "%{__libtoolize}")
 429
 430         # atrpms
 431         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0)
 432         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0)
 433
 434         # alt linux
 435         $0 = fixedsub("%make_build", "%{__make}", $0)
 436 }
 437
 438 ##########
 439 # %clean #
 440 ##########
 441 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 442         did_clean = 1
 443
 444         use_macros()
 445 }
 446
 447 ############
 448 # %install #
 449 ############
 450 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 451
 452         preamble = 0
 453
 454         # foreign rpms
 455         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 456         sub("%buildroot", "$RPM_BUILD_ROOT")
 457         sub("%{buildroot}", "$RPM_BUILD_ROOT")
 458
 459         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 460                 did_rmroot=1
 461                 print "rm -rf $RPM_BUILD_ROOT"
 462                 next
 463         }
 464
 465         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 466                 print "rm -rf $RPM_BUILD_ROOT"
 467                 did_rmroot=1
 468         }
 469
 470         if (tmpdir) {
 471                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 472                 gsub(buildroot, "$RPM_BUILD_ROOT")
 473         }
 474
 475         if (!/%{_lib}/) {
 476                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 477         }
 478
 479         use_macros()
 480
 481         # 'install -d' instead 'mkdir -p'
 482         if (/mkdir -p/)
 483                 sub(/mkdir -p/, "install -d")
 484
 485         # cp -a already implies cp -r
 486         sub(/^cp -ar/, "cp -a")
 487
 488         # No '-u root' or '-g root' for 'install'
 489         if (/^install/ && /-[ug][ \t]*root/)
 490                 gsub(/-[ug][ \t]*root /, "")
 491
 492         if (/^install/ && /-m[ \t]*[0-9]+/)
 493                 gsub(/-m[ \t]*[0-9]+ /, "")
 494
 495         # install without options -> cp -p
 496         if (/^install [^-]/)
 497                 gsub(/^install/, "cp -p")
 498
 499         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 500         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 501                 next
 502
 503         # No lines contain 'chmod' if it sets the modes to '644'
 504         if ($1 ~ /chmod/ && $2 ~ /644/)
 505                 next
 506
 507         # atrpms
 508         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0)
 509
 510         # alt linux
 511         $0 = fixedsub("%make_install DESTDIR=$RPM_BUILD_ROOT install", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0)
 512 }
 513
 514 ##########
 515 # %files #
 516 ##########
 517 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 518         preamble = 0
 519         did_files = 1
 520
 521         if ($0 ~ /^%files/)
 522                 defattr = 1
 523
 524         if (!use_files_macros()) {
 525                 next
 526         }
 527 }
 528
 529 ###########
 530 # SCRIPTS #
 531 ###########
 532 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 533         preamble = 0
 534
 535         if (gsub("/usr/sbin/useradd", "%useradd")) {
 536                 sub(" 2> /dev/null \|\| :", "")
 537                 sub(" >/dev/null 2>&1 \|\|:", "")
 538         }
 539
 540         # fedora extras macros
 541         if (/%__fe_useradd/) {
 542                 sub("%__fe_useradd", "%useradd -u ")
 543                 sub(" 2> /dev/null \|\| :", "")
 544                 sub(" >/dev/null 2>&1 \|\|:", "")
 545                 sub(" &>/dev/null \\|\\| :", "")
 546         }
 547
 548         if (/%__fe_groupadd/) {
 549                 sub("%__fe_groupadd", "%groupadd -g ")
 550                 sub(" &>/dev/null \\|\\| :", "")
 551         }
 552
 553         # %useradd and %groupadd may not be wrapped
 554         if (/%(useradd|groupadd).*\\$/) {
 555                 a = $0; getline
 556                 sub(/^[\s\t]*/, "")
 557                 $0 = substr(a, 1, length(a) - 1) $0
 558         }
 559         use_script_macros()
 560 }
 561
 562 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 563         preamble = 0
 564
 565         # fedora extras macros
 566         sub("%__chkconfig", "/sbin/chkconfig")
 567
 568         sub("update-desktop-database &> /dev/null \\|\\| :", "%update_desktop_database")
 569         sub("touch --no-create %{_datadir}/icons/hicolor", "%update_icon_cache_post hicolor")
 570         sub("if \\[ -x %{_bindir}/gtk-update-icon-cache \\]; then\n\t%{_bindir}/gtk-update-icon-cache -q %{_datadir}/icons/hicolor \|\| :\nfi", "")
 571
 572         sub("export GCONF_CONFIG_SOURCE=`gconftool-2 --get-default-source`", "")
 573         if (/gconftool-2 --makefile-install-rule/) {
 574                 sub("gconftool-2 --makefile-install-rule %{_sysconfdir}/gconf/schemas/", "%gconf_schema_install ")
 575                 sub("> /dev/null", "")
 576         }
 577
 578         use_macros()
 579 }
 580 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 581         preamble = 0
 582         use_macros()
 583 }
 584 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 585         preamble = 0
 586
 587         # fedora extras macros
 588         if (/%__fe_userdel|%__fe_groupdel/) {
 589                 sub("%__fe_groupdel", "%groupremove")
 590                 sub("%__fe_userdel", "%userremove")
 591                 sub(" &>/dev/null \\|\\| :", "")
 592         }
 593
 594         use_script_macros()
 595 }
 596 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 597         preamble = 0
 598         use_script_macros()
 599 }
 600 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 601         preamble = 0
 602         use_script_macros()
 603 }
 604 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 605         preamble = 0
 606         use_script_macros()
 607 }
 608 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 609         preamble = 0
 610         use_script_macros()
 611 }
 612 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 613         preamble = 0
 614         use_script_macros()
 615 }
 616 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 617         preamble = 0
 618         use_script_macros()
 619 }
 620 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 621         preamble = 0
 622         use_script_macros()
 623 }
 624
 625 #############
 626 # PREAMBLES #
 627 #############
 628 preamble == 1 {
 629         # There should not be a space after the name of field
 630         # and before the colon.
 631         sub(/[ \t]*:/, ":")
 632
 633         if (/^%perl_module_wo_prefix/) {
 634                 name = $2
 635                 version = $3
 636                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 637         }
 638
 639         # deprecated. currently just resolves to name in $2
 640         if (/^%pyrequires_eq.+/) {
 641                 $1 = "Requires:"
 642         }
 643
 644         # F<16 had requires(hint)
 645         if (/^Requires\(hint\):/) {
 646                 $1 = "Suggests:"
 647         }
 648
 649         field = tolower($1)
 650         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 651                 sub(/\.$/, "", $0)
 652         }
 653         if (field ~ /group(\([^)]+\)):/) {
 654                 next
 655         }
 656
 657         if (field == "group:") {
 658                 format_preamble()
 659                 group = $0
 660                 sub(/^[^ \t]*[ \t]*/, "", group)
 661                 group = replace_groupnames(group)
 662                 $0 = "Group:\t\t" group
 663
 664                 byl_plik_z_groupmi = 0
 665                 byl_opis_grupy = 0
 666                 while ((getline linia_grup < groups_file) > 0) {
 667                         byl_plik_z_groupmi = 1
 668                         if (linia_grup == group) {
 669                                 byl_opis_grupy = 1
 670                                 break
 671                         }
 672                 }
 673
 674                 if (!byl_plik_z_groupmi)
 675                         print "######\t\t" groups_file ": no such file"
 676                 else if (!byl_opis_grupy)
 677                         print "######\t\t" "Unknown group!"
 678
 679                 close(groups_file)
 680                 did_groups = 1
 681         }
 682
 683         if (field == "prereq:") {
 684                 sub(/Pre[Rr]eq:/, "Requires:", $1)
 685         }
 686
 687         # split (build)requires, obsoletes on commas
 688         if (field ~ /(obsoletes|requires|provides|conflicts|suggests):/ && NF > 2) {
 689                 value = substr($0, index($0, $2))
 690                 $0 = format_requires($1, value)
 691         }
 692
 693         # BR: tar (and others) is to common (rpm-build requires it)
 694         if (field == "buildrequires:") {
 695                 l = substr($0, index($0, $2))
 696                 if (l == "awk" ||
 697                         l == "binutils" ||
 698                         l == "bzip2" ||
 699                         l == "cpio" ||
 700                         l == "diffutils" ||
 701                         l == "elfutils" ||
 702                         l == "fileutils" ||
 703                         l == "findutils" ||
 704                         l == "glibc-devel" ||
 705                         l == "grep" ||
 706                         l == "gzip" ||
 707                         l == "make" ||
 708                         l == "patch" ||
 709                         l == "sed" ||
 710                         l == "sh-utils" ||
 711                         l == "tar" ||
 712                         l == "textutils") {
 713                         next
 714                 }
 715
 716                 replace_requires(field)
 717         }
 718
 719         if (field == "requires:" || field ~ /^requires\(/ || field == "suggests:") {
 720                 replace_requires(field)
 721         }
 722
 723
 724         # obsolete/unwanted tags
 725         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 726                 next
 727         }
 728
 729         if (field ~ /buildroot:/) {
 730                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 731                 did_build_root = 1
 732         }
 733
 734         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 735         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 736                 $1 = "License:"
 737         }
 738
 739         # ease updating from debian .dsc
 740         if (field ~ /homepage:/) {
 741                 $1 = "URL:"
 742         }
 743
 744         # suse
 745         if (field ~ /recommends:/) {
 746                 $1 = "Suggests:"
 747         }
 748
 749         if ($3 == "==" && $1 !~ /%/) {
 750                 $3 = "="
 751         }
 752
 753         if (field ~ /license:/) {
 754                 l = substr($0, index($0, $2))
 755                 if (l == "Python Software Foundation License") {
 756                         l = "PSF"
 757                 }
 758                 if (l == "Apache License 2.0" || \
 759                            l == "Apache 2.0" || \
 760                            l == "Apache 2" || \
 761                            l == "Apache License (2.0)" ||
 762                            l == "Apache License Version 2.0" || \
 763                            l == "Apache License, Version 2.0" || \
 764                            l == "Apache Software License v2" || \
 765                            l == "ASL 2.0" \
 766                         ) {
 767                         l = "Apache v2.0"
 768                 }
 769                 if (l == "Apache Group License" || l == "Apache Software License" || l == "Apache License") {
 770                         l = "Apache"
 771                 }
 772                 if (l == "Apache-style License" || l == "Apache-style Software License") {
 773                         l = "Apache-like"
 774                 }
 775                 if (l == "Apache Software License 1.1" || l == "Apache 1.1") {
 776                         l = "Apache v1.1"
 777                 }
 778                 if (l == "GPLv2") {
 779                         l = "GPL v2"
 780                 }
 781                 if (l == "The BSD 3-Clause License") {
 782                         l = "BSD"
 783                 }
 784                 if (l == "GPLv2+") {
 785                         l = "GPL v2+"
 786                 }
 787                 if (l == "GPL v2 or later") {
 788                         l = "GPL v2+"
 789                 }
 790                 if (l == "LGPL v2.0 only") {
 791                         l = "LGPL v2"
 792                 }
 793                 if (l == "LGPLv2+") {
 794                         l = "LGPL v2+"
 795                 }
 796                 if (l == "GPLv3") {
 797                         l = "GPL v3"
 798                 }
 799                 if (l == "GPLv3+") {
 800                         l = "GPL v3+"
 801                 }
 802                 if (l == "MPLv1.1") {
 803                         l = "MPL v1.1"
 804                 }
 805                 $0 = "License:\t" l
 806         }
 807
 808
 809         if (field ~ /name:/) {
 810                 if ($2 == "%{name}" && name) {
 811                         $2 = name
 812                 }
 813                 name = $2
 814                 name_seen = 1
 815         }
 816
 817         if (field ~ /version:/) {
 818                 if ($2 == "%{version}" && version) {
 819                         $2 = version
 820                 }
 821                 version = $2
 822                 version_seen = 1
 823         }
 824
 825         if (field ~ /release:/) {
 826                 if ($2 == "%{release}" && release) {
 827                         $2 = release
 828                 }
 829                 sub(/%atrelease /, "0.", $0)
 830                 release = $2
 831                 release_seen = 1
 832         }
 833
 834
 835         if (field ~ /serial:/)
 836                 $1 = "Epoch:"
 837
 838         if (field ~ /home-page:/)
 839                 $1 = "URL:"
 840
 841         # proper caps
 842         if (field ~ /^url:$/)
 843                 $1 = "URL:"
 844
 845         if (field ~ /^patch/)
 846                 $1 = "Patch" substr(field, 6)
 847
 848         if (field ~ /^description:$/)
 849                 $1 = "\n%description\n"
 850
 851         # Use %{name} and %{version} in the filenames in "Source:"
 852         if (field ~ /^source/ || field ~ /patch/) {
 853                 n = split($2, url, /\//)
 854                 if (url[n] ~ /\.gz$/) {
 855                         url[n+1] = ".gz" url[n+1]
 856                         sub(/\.gz$/,"",url[n])
 857                 }
 858                 if (url[n] ~ /\.zip$/) {
 859                         url[n+1] = ".zip" url[n+1]
 860                         sub(/\.zip$/,"",url[n])
 861                 }
 862                 if (url[n] ~ /\.tar$/) {
 863                         url[n+1] = ".tar" url[n+1]
 864                         sub(/\.tar$/,"",url[n])
 865                 }
 866                 if (url[n] ~ /\.patch$/) {
 867                         url[n+1] = ".patch" url[n+1]
 868                         sub(/\.patch$/,"",url[n])
 869                 }
 870                 if (url[n] ~ /\.bz2$/) {
 871                         url[n+1] = ".bz2" url[n+1]
 872                         sub(/\.bz2$/,"",url[n])
 873                 }
 874                 if (url[n] ~ /\.logrotate$/) {
 875                         url[n+1] = ".logrotate" url[n+1]
 876                         sub(/\.logrotate$/,"",url[n])
 877                 }
 878                 if (url[n] ~ /\.pamd$/) {
 879                         url[n+1] = ".pamd" url[n+1]
 880                         sub(/\.pamd$/,"",url[n])
 881                 }
 882
 883                 # allow %{name} only in last url component
 884                 s = ""
 885                 for (i = 1; i <= n; i++) {
 886                         url[i] = fixedsub("%{name}", name, url[i])
 887                         if (s) {
 888                                 s = s "/" url[i]
 889                         } else {
 890                                 s = url[i]
 891                         }
 892                 }
 893                 $2 = s url[n+1]
 894
 895                 filename = url[n]
 896                 if (name) {
 897                         url[n] = fixedsub(name, "%{name}", url[n])
 898                 }
 899                 if (field ~ /source/) {
 900                         if (version) {
 901                                 url[n] = fixedsub(version, "%{version}", url[n])
 902                         }
 903                         if (_beta) {
 904                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 905                         }
 906                         if (_rc) {
 907                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 908                         }
 909                         if (_pre) {
 910                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 911                         }
 912                         if (_snap) {
 913                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 914                         }
 915                         if (subver) {
 916                                 url[n] = fixedsub(subver, "%{subver}", url[n])
 917                         }
 918                 }
 919                 # assigning to $2 kills preamble formatting
 920                 $2 = fixedsub(filename, url[n], $2)
 921
 922                 $2 = unify_url($2)
 923         }
 924
 925
 926         if (field ~ /^source:/)
 927                 $1 = "Source0:"
 928
 929         if (field ~ /^patch:/)
 930                 $1 = "Patch0:"
 931
 932         kill_preamble_macros()
 933         format_preamble()
 934
 935         if (field ~ /requires/) {
 936                 # atrpms
 937                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0)
 938         }
 939 }
 940
 941 /^%bcond_/ {
 942         # do nothing
 943         print
 944         next
 945 }
 946
 947 # sort BR/R!
 948 #
 949 # NOTES:
 950 # - mixing BR/R and anything else confuses this (all will be sorted together)
 951 #       so don't do that.
 952 # - comments leading the BR/R can not be associated,
 953 #       so don't adapterize when the BR/R are mixed with comments
 954 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS ":", $0 ~ PREAMBLE_TAGS ":"{
 955         if ($1 ~ /Pre[Rr]eq:/) {
 956                 sub(/Pre[Rr]eq:/, "Requires:", $1)
 957         }
 958         if ($1 == "BR:" ) {
 959                 $1 = "BuildRequires:"
 960         }
 961         if ($1 == "R:" ) {
 962                 $1 = "Requires:"
 963         }
 964         format_preamble()
 965 #       kill_preamble_macros(); # breaks tabbing
 966
 967         b_idx++
 968         l = substr($0, index($0, $2))
 969         b_ktmp = b_makekey($1, l)
 970         b_key[b_idx] = b_ktmp
 971         b_val[b_ktmp] = $0
 972
 973         next
 974 }
 975
 976 preamble == 1 {
 977         if (b_idx > 0) {
 978                 isort(b_key, b_idx)
 979                 for (i = 1; i <= b_idx; i++) {
 980                         v = b_val[b_key[i]]
 981                         sub(/[ \t]+$/, "", v)
 982                         print "" v
 983                 }
 984                 b_idx = 0
 985         }
 986 }
 987
 988 # main() ;-)
 989 {
 990         preamble = 1
 991
 992         sub(/[ \t]+$/, "")
 993         print
 994
 995         if (name_seen == 0 && name) {
 996                 print "Name:\t\t" name
 997                 name_seen = 1
 998         }
 999
1000         if (version_seen == 0 && version) {
1001                 print "Version:\t" version
1002                 version_seen = 1
1003         }
1004
1005         if (release_seen == 0 && release) {
1006                 print "Release:\t" release
1007                 release_seen = 1
1008         }
1009
1010         if (did_build_root == 0) {
1011 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
1012                 did_build_root = 1
1013         }
1014         if (did_groups == 0) {
1015 #               print "Group:\t\tunknown"
1016                 did_groups = 1
1017         }
1018 }
1019
1020
1021 END {
1022         if (do_not_touch_anything) {
1023                 exit(rc)
1024         }
1025
1026         # TODO: need to output these in proper place
1027         if (BR_count > 0) {
1028                 for (i = 0; i <= BR_count; i++) {
1029                         print BR[i]
1030                 }
1031         }
1032
1033         if (did_clean == 0) {
1034                 print ""
1035                 print "%clean"
1036                 print "rm -rf $RPM_BUILD_ROOT"
1037         }
1038 }
1039
1040 # substitutes fixed strings (not regexps)
1041 function fixedsub(s1,s2,t, ind) {
1042         if (ind = index(t,s1))
1043                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1044         return t
1045 }
1046
1047 # replace s with s2 if it equals to s1
1048 function replace(s, s1, s2) {
1049         if (s == s1) {
1050                 return s2
1051         } else {
1052                 return s
1053         }
1054 }
1055
1056 # There should be one or two tabs after the colon.
1057 function format_preamble()
1058 {
1059         if (/^#/ || /^%bcond_with/) {
1060                 return
1061         }
1062         sub(/:[ \t]*/, ":")
1063         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1064                 if (RLENGTH < 8) {
1065                         sub(/:/, ":\t\t")
1066                 } else {
1067                         sub(/:/, ":\t")
1068                 }
1069         }
1070 }
1071
1072 # Replace directly specified directories with macros
1073 function use_macros()
1074 {
1075         # -m, --skip-macros, --no-macros -- skip macros subst
1076         if (ENVIRON["SKIP_MACROS"]) {
1077                 return
1078         }
1079
1080         # leave inline sed lines alone
1081         if (/(%{__sed}|sed) -i -e/) {
1082                 return
1083         }
1084
1085         # leave alone with -DSOMETHING=/path/to/bin
1086         if (/-D.+=.+/) {
1087                 return
1088         }
1089
1090         sub("%{_defaultdocdir}", "%{_docdir}")
1091         sub("%{_datadir}/doc", "%{_docdir}")
1092         sub("%{_bindir}/perl", "%{__perl}")
1093         sub("%{_bindir}/python", "%{__python}")
1094
1095         gsub(infodir, "%{_infodir}")
1096
1097         gsub(perl_sitearch, "%{perl_sitearch}")
1098         gsub(perl_archlib, "%{perl_archlib}")
1099         gsub(perl_privlib, "%{perl_privlib}")
1100         gsub(perl_vendorlib, "%{perl_vendorlib}")
1101         gsub(perl_vendorarch, "%{perl_vendorarch}")
1102         gsub(perl_sitelib, "%{perl_sitelib}")
1103
1104         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1105         gsub(py_sitedir, "%{py_sitedir}")
1106         gsub(py_scriptdir, "%{py_scriptdir}")
1107
1108         gsub(py3_sitescriptdir, "%{py3_sitescriptdir}")
1109         gsub(py3_sitedir, "%{py3_sitedir}")
1110         gsub(py3_scriptdir, "%{py3_scriptdir}")
1111         gsub("%{python3_sitelib}", "%{py3_sitescriptdir}")
1112         gsub("%{python3_version}", "%{py3_ver}")
1113
1114         gsub(ruby_archdir, "%{ruby_archdir}")
1115         gsub(ruby_libdir, "%{ruby_libdir}")
1116
1117         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1118         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1119         gsub(ruby_sitedir, "%{ruby_sitedir}")
1120         gsub(ruby_vendorarchdir, "%{ruby_vendorarchdir}")
1121         gsub(ruby_vendorlibdir, "%{ruby_vendorlibdir}")
1122         gsub(ruby_vendordir, "%{ruby_vendordir}")
1123         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}") # deprecated
1124         gsub(ruby_rdocdir, "%{ruby_rdocdir}")
1125         gsub(ruby_ridir, "%{ruby_ridir}")
1126         gsub(ruby_specdir, "%{ruby_specdir}")
1127
1128         gsub("%{_unitdir}", "%{systemdunitdir}")
1129         gsub(systemdunitdir, "%{systemdunitdir}")
1130         gsub("%{_userunitdir}", "%{systemduserunitdir}")
1131         gsub(systemduserunitdir, "%{systemduserunitdir}")
1132         gsub(systemdtmpfilesdir, "%{systemdtmpfilesdir}")
1133         gsub("%{_tmpfilesdir}", "%{systemdtmpfilesdir}")
1134
1135         gsub("%{_datadir}/applications", "%{_desktopdir}")
1136         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1137         gsub("%{_datadir}/java", "%{_javadir}")
1138
1139         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}")
1140         gsub(pkgconfigdir, "%{_pkgconfigdir}")
1141
1142         gsub("%{_datadir}/pkgconfig", "%{_npkgconfigdir}")
1143         gsub(npkgconfigdir, "%{_npkgconfigdir}")
1144
1145         gsub("%{_datadir}/locale", "%{_localedir}")
1146         gsub(localedir, "%{_localedir}")
1147
1148         gsub(libdir, "%{_libdir}")
1149         gsub(javadir, "%{_javadir}")
1150
1151         gsub(bindir, "%{_bindir}")
1152         gsub("%{prefix}/bin", "%{_bindir}")
1153         if (prefix"/bin" == bindir)
1154                 gsub("%{_prefix}/bin", "%{_bindir}")
1155
1156         for (c = 1; c <= NF; c++) {
1157                 if ($c ~ sbindir "/fix-info-dir")
1158                         continue
1159                 if ($c ~ sbindir "/webapp")
1160                         continue
1161                 if ($c ~ sbindir "/ldconfig")
1162                         continue
1163                 if ($c ~ sbindir "/chsh")
1164                         continue
1165                 if ($c ~ sbindir "/usermod")
1166                         continue
1167                 if ($c ~ sbindir "/chkconfig")
1168                         continue
1169                 if ($c ~ sbindir "/installzope(product|3package)")
1170                         continue
1171                 gsub(sbindir, "%{_sbindir}", $c)
1172         }
1173
1174         gsub("%{prefix}/sbin", "%{_sbindir}")
1175         if (prefix"/sbin" == sbindir) {
1176                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1177         }
1178
1179         for (c = 1; c <= NF; c++) {
1180                 if ($c ~ sysconfdir "/{?cron.")
1181                         continue
1182                 if ($c ~ sysconfdir "/{?crontab.d")
1183                         continue
1184                 if ($c ~ sysconfdir "/{?env.d")
1185                         continue
1186                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1187                         continue
1188                 if ($c ~ sysconfdir "/{?udev")
1189                         continue
1190                 if ($c ~ sysconfdir "/{?hotplug")
1191                         continue
1192                 if ($c ~ sysconfdir "/{?logrotate.d")
1193                         continue
1194                 if ($c ~ sysconfdir "/{?pam.d")
1195                         continue
1196                 if ($c ~ sysconfdir "/{?apparmor.d")
1197                         continue
1198                 if ($c ~ sysconfdir "/{?profile.d")
1199                         continue
1200                 if ($c ~ sysconfdir "/{?rc.d")
1201                         continue
1202                 if ($c ~ sysconfdir "/{?security")
1203                         continue
1204                 if ($c ~ sysconfdir "/{?skel")
1205                         continue
1206                 if ($c ~ sysconfdir "/{?sysconfig")
1207                         continue
1208                 if ($c ~ sysconfdir "/{?shrc.d")
1209                         continue
1210                 if ($c ~ sysconfdir "/{?certs")
1211                         continue
1212                 if ($c ~ sysconfdir "/{?X11")
1213                         continue
1214                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1215                         continue
1216                 if ($c ~ sysconfdir "/{?rpm")
1217                         continue
1218                 if ($c ~ sysconfdir "/{?bash_completion.d")
1219                         continue
1220                 if ($c ~ sysconfdir "/{?samba")
1221                         continue
1222                 if ($c ~ sysconfdir "/{?xdg")
1223                         continue
1224                 if ($c ~ sysconfdir "/{?NetworkManager")
1225                         continue
1226                 if ($c ~ sysconfdir "/{?default")
1227                         continue
1228                 if ($c ~ sysconfdir "/{?pm")
1229                         continue
1230                 if ($c ~ sysconfdir "/shells")
1231                         continue
1232                 if ($c ~ sysconfdir "/inittab")
1233                         continue
1234                 if ($c ~ sysconfdir "/init")
1235                         continue
1236                 if ($c ~ sysconfdir "/ppp")
1237                         continue
1238                 if ($c ~ sysconfdir "/dbus-1")
1239                         continue
1240                 if ($c ~ sysconfdir "/tmpwatch")
1241                         continue
1242                 if ($c ~ sysconfdir "/acpi")
1243                         continue
1244                 if ($c ~ sysconfdir "/apm")
1245                         continue
1246                 if ($c ~ sysconfdir "/modules-load\.d")
1247                         continue
1248                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1249         }
1250
1251         gsub(docdir, "%{_docdir}")
1252
1253         gsub(kdedocdir, "%{_kdedocdir}")
1254
1255         gsub(gtkdocdir, "%{_gtkdocdir}")
1256         gsub("%{_docdir}/gtk-doc/html", "%{_gtkdocdir}")
1257
1258         gsub(php_pear_dir, "%{php_pear_dir}")
1259         gsub(php_data_dir, "%{php_data_dir}")
1260
1261         # change to %{_datadir}, with some exceptions
1262         for (c = 1; c <= NF; c++) {
1263                 if ($c ~ datadir "/automake")
1264                         continue
1265                 if ($c ~ datadir "/unsermake")
1266                         continue
1267                 if ($c ~ datadir "/file/magic.mime")
1268                         continue
1269                 gsub(datadir, "%{_datadir}", $c)
1270         }
1271
1272         # bash completions dir, after datadir change
1273         gsub("%{_datadir}/bash-completion/completions", "%{bash_compdir}")
1274
1275         gsub("%{prefix}/share", "%{_datadir}")
1276         if (prefix"/share" == datadir)
1277                 gsub("%{_prefix}/share", "%{_datadir}")
1278
1279         # CFLAGS="-I/usr/include/ncurses is usually correct.
1280         if (!/-I\/usr\/include/) {
1281                 gsub(includedir, "%{_includedir}")
1282         }
1283
1284         gsub("%{prefix}/include", "%{_includedir}")
1285         if (prefix"/include" == includedir) {
1286                 gsub("%{_prefix}/include", "%{_includedir}")
1287         }
1288
1289         gsub(mandir, "%{_mandir}")
1290         if ($0 !~ "%{_datadir}/manual") {
1291                 gsub("%{_datadir}/man", "%{_mandir}")
1292         }
1293         gsub("%{_prefix}/share/man", "%{_mandir}")
1294         gsub("%{prefix}/share/man", "%{_mandir}")
1295         gsub("%{prefix}/man", "%{_mandir}")
1296         gsub("%{_prefix}/man", "%{_mandir}")
1297
1298         gsub(infodir, "%{_infodir}")
1299         gsub("%{prefix}/info", "%{_infodir}")
1300         gsub("%{_prefix}/info", "%{_infodir}")
1301
1302         if (prefix !~ "/X11R6") {
1303                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1304         }
1305
1306         gsub(examplesdir, "%{_examplesdir}")
1307
1308         if (prefix != "/") {
1309                 # leave --with-foo=/usr alone
1310                 if ($0 !~ "--with.*=.*" prefix) {
1311                         for (c = 1; c <= NF; c++) {
1312                                 if ($c ~ prefix "/sbin/fix-info-dir")
1313                                         continue
1314                                 if ($c ~ prefix "/sbin/webapp")
1315                                         continue
1316                                 if ($c ~ prefix "/sbin/chsh")
1317                                         continue
1318                                 if ($c ~ prefix "/sbin/usermod")
1319                                         continue
1320                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1321                                         continue
1322                                 if ($c ~ prefix "/share/automake")
1323                                         continue
1324                                 if ($c ~ prefix "/share/unsermake")
1325                                         continue
1326                                 if ($c ~ prefix "/lib/sendmail")
1327                                         continue
1328                                 if ($c ~ prefix "/lib/pkgconfig")
1329                                         continue
1330
1331                                 # CFLAGS="-I/usr..." is usually correct.
1332                                 if (/-I\/usr/)
1333                                         continue
1334                                 # same for LDFLAGS="-L/usr..."
1335                                 if (/-L\/usr/)
1336                                         continue
1337
1338                                 gsub(prefix, "%{_prefix}", $c)
1339                         }
1340                 }
1341                 gsub("%{prefix}", "%{_prefix}")
1342         }
1343
1344         # replace back
1345         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1346         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1347
1348         gsub("%{PACKAGE_VERSION}", "%{version}")
1349         gsub("%{PACKAGE_NAME}", "%{name}")
1350
1351         gsub("^make$", "%{__make}")
1352         gsub("^make ", "%{__make} ")
1353         gsub("^gcc ", "%{__cc} ")
1354         gsub("^rm --interactive=never ", "%{__rm} ")
1355
1356         # fedora
1357         gsub("%{ruby_sitearch}", "%{ruby_sitearchdir}")
1358         gsub("%{python_sitearch}", "%{py_sitedir}")
1359         gsub("%{python_sitelib}", "%{py_sitescriptdir}")
1360
1361         # alt linux
1362         gsub("%_man1dir", "%{_mandir}/man1")
1363
1364         # mandrake specs
1365         gsub("^%make$", "%{__make}")
1366         gsub("^%make ", "%{__make} ")
1367         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1368         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1369         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1370         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1371         gsub("^%{__install}", "install")
1372         gsub("%optflags", "%{rpmcflags}")
1373         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1374
1375         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1376         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1377         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1378         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1379         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0)
1380         $0 = fixedsub("%__install", "install", $0)
1381
1382         # split configure line to multiple lines
1383         if (/%configure +$/) {
1384                 sub( / +$/, "" )
1385         } else if (/%configure / && !/\\$/) {
1386                 $0 = format_configure($0)
1387         }
1388
1389         gsub("%_bindir", "%{_bindir}")
1390         gsub("%_datadir", "%{_datadir}")
1391         gsub("%_iconsdir", "%{_iconsdir}")
1392         gsub("%_sbindir", "%{_sbindir}")
1393         gsub("%_mandir", "%{_mandir}")
1394         gsub("%name", "%{name}")
1395         gsub(/%__rm/, "rm")
1396         gsub(/%__mkdir_p/, "install -d")
1397         gsub(/%__cp/, "cp")
1398         gsub(/%__ln_s/, "ln -s")
1399         gsub(/%__sed/, "%{__sed}")
1400         gsub(/%__cat/, "cat")
1401         gsub(/%__chmod/, "chmod")
1402
1403         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1404         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1405
1406         if (/^ant / || /^%{ant}/) {
1407                 sub(/^ant/, "%ant")
1408                 sub(/^%{ant}/, "%ant")
1409                 add_br("BuildRequires:  jpackage-utils")
1410                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300")
1411         }
1412
1413         $0 = fixedsub("%(%{__cc} -dumpversion)", "%{cc_version}", $0)
1414         $0 = fixedsub("%(%{__cxx} -dumpversion)", "%{cxx_version}", $0)
1415
1416         # kill the _class and _subclass pear macros
1417         if (pear_class) {
1418                 gsub("%{_class}", pear_class)
1419         }
1420         if (pear_subclass) {
1421                 gsub("%{_subclass}", pear_subclass)
1422         }
1423 }
1424
1425 function format_configure(line,         n, a, s) {
1426         n = split(line, a, / /)
1427         s = a[1] " \\\n"
1428         for (i = 2; i <= n; i++) {
1429                 s = s "\t" a[i] " \\\n"
1430         }
1431         return s
1432 }
1433
1434
1435 # insertion sort of A[1..n]
1436 # copied from mawk manual
1437 function isort(A,n,             i,j,hold) {
1438         for (i = 2; i <= n; i++) {
1439                 hold = A[j = i]
1440                 while (A[j-1] > hold) {
1441                         j-- ; A[j+1] = A[j]
1442                 }
1443                 A[j] = hold
1444         }
1445         # sentinel A[0] = "" will be created if needed
1446 }
1447
1448
1449 function use_files_macros(      i, n, t, a, l)
1450 {
1451         use_macros()
1452
1453         # skip comments
1454         if (/^#/) {
1455                 return 1
1456         }
1457
1458         sub("^%doc %{_mandir}", "%{_mandir}")
1459
1460         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1461         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1462
1463         # uid/gid nobody is not valid in %files
1464         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1465                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1466         }
1467
1468         # s[gu]id programs with globs are evil
1469         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1470                 $0 = $0 " # FIXME no globs for suid/sgid files"
1471         }
1472
1473         # replace back
1474         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1475         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1476         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1477         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1478         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1479         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1480         gsub("%{_sysconfdir}/security", "/etc/security")
1481         gsub("%{_sysconfdir}/skel", "/etc/skel")
1482         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1483         gsub("%{_sysconfdir}/certs", "/etc/certs")
1484         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1485         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1486         gsub("%{_sysconfdir}/pki", "/etc/pki")
1487         gsub("%{_sysconfdir}/tmpwatch", "/etc/tmpwatch")
1488
1489         # /etc/init.d -> /etc/rc.d/init.d
1490         if (!/^\/etc\/init\.d$/) {
1491                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1492         }
1493
1494         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1495                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1496                         $0 = "%attr(754,root,root) " $0
1497                 }
1498                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1499                         gsub("^%attr\\(... *,", "%attr(754,")
1500                 }
1501         }
1502
1503         if (/lib.+\.so\b/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1504                 $0 = "%attr(755,root,root) " $0
1505         }
1506
1507         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1508                 $0 = "%attr(755,root,root) " $0
1509         }
1510
1511         # remove attrs from man pages
1512         if (/%{_mandir}/ && /^%attr/) {
1513                 sub("^%attr\\(.*\\) *", "")
1514         }
1515
1516         # /etc/sysconfig files
1517         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1518         # attr not required, allow default 644 attr
1519         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1520                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1521                         gsub("%config", "%config(noreplace)")
1522                 }
1523
1524                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1525                         $NF = "%config(noreplace) " $NF
1526                 }
1527
1528                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1529                         gsub("^%attr\\(... *,", "%attr(640,")
1530                 }
1531
1532                 if (/\/etc\/sysconfig\// && !/%verify/) {
1533                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig")
1534                 }
1535         }
1536
1537         # kill leading zeros
1538         if (/%attr\(0[1-9]/) {
1539                 gsub("%attr\\(0", "%attr(")
1540         }
1541
1542         # kill leading whitespace
1543         gsub(/^ +/, "")
1544
1545         # kill default attrs
1546         gsub(/%dir %attr\(755,root,root\)/, "%dir")
1547         gsub(/%attr\(755,root,root\) %dir/, "%dir")
1548         if (!/%dir/) {
1549                 gsub(/%attr\(644,root,root\) /, "")
1550         }
1551
1552         # sort %verify attrs
1553         if (match($0, /%verify\(not([^)]+)\)/)) {
1554                 t = substr($0, RSTART, RLENGTH)
1555                 # kill commas: %verify(not,md5,size,mtime)
1556                 gsub(/,/, " ", t)
1557
1558                 gsub(/^%verify\(not |\)$/, "", t)
1559                 n = split(t, a, / /)
1560                 isort(a, n)
1561
1562                 s = "%verify(not"
1563                 for (i = 1 ; i <= n; i++) {
1564                         s = s " " a[i]
1565                 }
1566                 s = s ")"
1567
1568                 gsub(/%verify\(not[^)]+\)/, s)
1569         }
1570
1571         if (/%{_mandir}/) {
1572                 gsub("\.gz$", "*")
1573                 gsub("%ext_man$", "*")
1574         }
1575
1576         # locale dir and no %lang -> bad
1577         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1578                 $(NF + 1) = "# FIXME consider using %find_lang"
1579         }
1580
1581         # python egg-infos
1582         if (match($0, "^%{py_site(script)?dir}/.+-py"py_ver".egg-info$")) {
1583                 # tests:
1584                 #%{py_sitedir}/*-py2.4.egg-info
1585                 #%{py_sitescriptdir}/GnuPGInterface-%{version}-py2.4.egg-info
1586                 #%{py_sitescriptdir}/python_mpd-%{version}-py2.4.egg-info
1587                 #%{py_sitescriptdir}/mechanize-0.1.6b-py2.4.egg-info
1588
1589                 l = index($0, "/")
1590                 t = substr($0, 0, l)
1591                 s = substr($0, l + 1, RLENGTH - l - length("-py"py_ver".egg-info"))
1592                 if (match(s, "[^-]+$")) {
1593                         if (RSTART > 1) {
1594                                 s = substr(s, 0, RSTART - 1)
1595                         }
1596                         print "%if \"%{py_ver}\" > \"2.4\""
1597                         gsub(t "/.+.egg-info", t "/" s "-*.egg-info")
1598                         print
1599                         print "%endif"
1600                         return 0
1601                 }
1602         }
1603
1604         # atrpms
1605         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0)
1606         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0)
1607         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0)
1608
1609         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}")
1610         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}")
1611         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}")
1612
1613         gsub("%{_datadir}/applications", "%{_desktopdir}")
1614         gsub("%{_datadir}/icons", "%{_iconsdir}")
1615         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1616         gsub("%{_datadir}/pear", "%{php_pear_dir}")
1617         gsub("%{_datadir}/php", "%{php_data_dir}")
1618
1619         return 1
1620 }
1621
1622 function use_script_macros()
1623 {
1624         if (gsub("/sbin/service", "%service")) {
1625                 sub(" >/dev/null 2>&1 \|\|:", "")
1626                 sub(" 2> /dev/null \|\| :", "")
1627         }
1628 }
1629
1630 function fill(ch, n, i) {
1631         for (i = 0; i < n; i++)
1632                 printf("%c", ch)
1633 }
1634
1635 function format_flush(line, indent, newline, word, first_word) {
1636         first_word = 1
1637         if (format_indent == -1)
1638                 newline = ""
1639         else
1640                 newline = fill(" ", format_indent) "- "
1641
1642         while (match(line, /[^\t ]+/)) {
1643                 word = substr(line, RSTART, RLENGTH)
1644                 if (length(newline) + length(word) + 1 > tw) {
1645                         print newline
1646
1647                         if (format_indent == -1)
1648                                 newline = ""
1649                         else
1650                                 newline = fill(" ", format_indent + 2)
1651                         first_word = 1
1652                 }
1653
1654                 if (first_word) {
1655                         newline = newline word
1656                         first_word = 0
1657                 } else
1658                         newline = newline " " word
1659
1660                 line = substr(line, RSTART + RLENGTH)
1661         }
1662         if (newline ~ /[^\t ]/) {
1663                 print newline
1664         }
1665 }
1666
1667 function cflags(var)
1668 {
1669         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1670                 removed[var] = 1
1671                 return 0
1672         }
1673
1674         if (!/!\?debug/)
1675                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1676         return 1
1677 }
1678
1679 # return whole matched pattern
1680 function matchstr(str, pat)
1681 {
1682         match(str, "[^/]+$")
1683         return substr(str, RSTART, RLENGTH)
1684 }
1685
1686 function unify_url(url)
1687 {
1688
1689         # sourceforge urls
1690         # Docs about sourceforge mirror system: http://sourceforge.net/apps/trac/sourceforge/wiki/Mirrors
1691
1692         # 1. unify domains
1693         sub("^http://prdownloads\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1694         sub("^http://download\.sf\.net/", "http://downloads.sourceforge.net/", url)
1695         sub("^http://download\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1696         sub("^http://dl\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1697         sub("^http://.*\.dl\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1698         sub("^http://dl\.sf\.net/", "http://downloads.sourceforge.net/", url)
1699         sub("^http://downloads\.sourceforge\.net/sourceforge/", "http://downloads.sourceforge.net/", url)
1700
1701         # 3. unify urls
1702         if (url ~ /sourceforge.net/) {
1703                 sub("[?&]big_mirror=.*$", "", url)
1704                 sub("[?&]modtime=.*$", "", url)
1705                 sub("[?]use_mirror=.*$", "", url)
1706                 sub("[?]download$", "", url)
1707                 sub("/download$", "", url)
1708         }
1709
1710         # SF: new style urls, strip "files/" between and prepend dl.
1711         if (match(url, "^http://sourceforge.net/projects/[^/]+/files/")) {
1712                 url = substr(url, 1, RLENGTH - length("files/")) substr(url, RSTART + RLENGTH)
1713                 sub("^http://sourceforge.net/projects/", "http://downloads.sourceforge.net/project/", url)
1714         }
1715
1716         # SF unify: http://downloads.sourceforge.net/PROJECT/TARBALL
1717         # http://downloads.sourceforge.net/project/PROJECT/FILE/VERSION/%{name}-%{version}.zip
1718         if (match(url, "^http://downloads.sourceforge.net/project/[^/]+")) {
1719                 url = sprintf("http://downloads.sourceforge.net/%s/%s", substr(url, 42, RLENGTH - 41), matchstr(url, "[^/]+$"))
1720         }
1721
1722         sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", url)
1723         sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", url)
1724
1725         # apache urls
1726         sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", url)
1727
1728         # gnu.org
1729         sub("^ftp://ftp\.gnu\.org/", "http://ftp.gnu.org/", url)
1730         sub("^http://ftp\.gnu\.org/pub/gnu/", "http://ftp.gnu.org/gnu/", url)
1731
1732         # debian.org
1733         sub("^ftp://ftp\.[^.]+\.debian\.org/", "ftp://ftp.debian.org/", url)
1734         sub("^http://ftp\.[^.]+\.debian\.org/", "ftp://ftp.debian.org/", url)
1735         sub("^ftp://ftp\.debian\.org/pub/debian/", "ftp://ftp.debian.org/debian/", url)
1736
1737         return url
1738 }
1739
1740 function demacroize(str)
1741 {
1742         if (mod_name) {
1743                 sub("%{mod_name}", mod_name, str)
1744         }
1745         if (pearname) {
1746                 sub("%{_pearname}", pearname, str)
1747         }
1748         if (pearname) {
1749                 sub("%{pearname}", pearname, str)
1750         }
1751         if (name) {
1752                 sub("%{name}", name, str)
1753         }
1754         if (version) {
1755                 sub("%{version}", version, str)
1756         }
1757         if (_beta) {
1758                 sub("%{_beta}", _beta, str)
1759         }
1760         if (_rc) {
1761                 sub("%{_rc}", _rc, str)
1762         }
1763         if (_pre) {
1764                 sub("%{_pre}", _pre, str)
1765         }
1766         if (_snap) {
1767                 sub("%{_snap}", _snap, str)
1768         }
1769         if (subver) {
1770                 sub("%{subver}", subver, str)
1771         }
1772         return str
1773 }
1774
1775 function kill_preamble_macros()
1776 {
1777         if ($1 ~ /^Obsoletes:/) {
1778                 # NB! assigning $2 a value breaks tabbing
1779                 $2 = demacroize($2)
1780         }
1781         if ($1 ~ /^URL:/) {
1782                 # NB! assigning $2 a value breaks tabbing
1783                 $2 = demacroize($2)
1784                 $2 = unify_url($2)
1785         }
1786
1787         # fedora extras
1788         if (/%{\?FE_USERADD_REQ}/) {
1789                 $0 = ""
1790                 print "BuildRequires:   rpmbuild(macros) >= 1.202"
1791                 print "Provides:        user(xxx)"
1792                 print "Requires(postun):        /usr/sbin/userdel"
1793                 print "Requires(pre):  /bin/id"
1794                 print "Requires(pre):  /usr/sbin/useradd"
1795         }
1796 }
1797
1798 function get_epoch(pkg, ver,    epoch)
1799 {
1800         return
1801 # should parse the BR lines more adequately:
1802 #       freetype = 2.0.0 -> correct
1803 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1804
1805         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'"
1806         shell | getline epoch
1807         return epoch
1808 }
1809
1810 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1811         # skip any formatting for commented out items or some weird macros
1812         if (/^#/ || /%\(/) {
1813                 return tag "\t" value
1814         }
1815         n = split(value, p, / *,? */)
1816         for (i = 1; i <= n; i++) {
1817                 if (p[i+1] ~ /[<=>]/) {
1818                         # add epoch if the version doesn't have it but BuildRequires.txt has
1819                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1820                                 epoch = get_epoch(p[i], p[i+2])
1821                                 if (epoch) {
1822                                         p[i+2] = epoch ":" p[i+2]
1823                                 }
1824                         }
1825                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2]
1826                         i += 2
1827                 } else {
1828                         deps[ndeps++] = p[i]
1829                 }
1830         }
1831         s = ""
1832         for (i in deps) {
1833                 s = s sprintf("%s\t%s\n", tag, deps[i])
1834         }
1835         return substr(s, 1, length(s)-1)
1836 }
1837
1838 function use_tabs()
1839 {
1840         # reverse vim: ts=4 sw=4 et
1841         gsub(/    /, "\t")
1842 }
1843
1844 function add_br(br)
1845 {
1846         BR[BR_count++] = br
1847 }
1848
1849 # Load rpm macros
1850 # you should update the list also in adapter when making changes here
1851 function import_rpm_macros(  v) {
1852         # File with rpm groups
1853         topdir = ENVIRON["_topdir"]
1854
1855         if (!topdir) {
1856                 print "adapter.awk should not not be invoked directly, but via adapter script" > "/dev/stderr"
1857                 do_not_touch_anything = 1
1858                 exit(rc = 1)
1859         }
1860
1861         # update this version dep each time some new macro export is added
1862         v = 1.52
1863         if (!ENVIRON["ADAPTER_REVISION"] || ENVIRON["ADAPTER_REVISION"] < v) {
1864                 printf("adapter shell script is outdated: Need %s, got %s. Please update it.\n", v, ENVIRON["ADAPTER_REVISION"]) > "/dev/stderr"
1865                 do_not_touch_anything = 1
1866                 exit(rc = 1)
1867         }
1868
1869         prefix = ENVIRON["_prefix"]
1870         bindir = ENVIRON["_bindir"]
1871         sbindir = ENVIRON["_sbindir"]
1872         libdir = ENVIRON["_libdir"]
1873         sysconfdir = ENVIRON["_sysconfdir"]
1874         datadir = ENVIRON["_datadir"]
1875         includedir = ENVIRON["_includedir"]
1876         mandir = ENVIRON["_mandir"]
1877         infodir = ENVIRON["_infodir"]
1878         examplesdir = ENVIRON["_examplesdir"]
1879         docdir = ENVIRON["_defaultdocdir"]
1880         kdedocdir = ENVIRON["_kdedocdir"]
1881         gtkdocdir = ENVIRON["_gtkdocdir"]
1882         desktopdir = ENVIRON["_desktopdir"]
1883         pixmapsdir = ENVIRON["_pixmapsdir"]
1884         javadir = ENVIRON["_javadir"]
1885         pkgconfigdir = ENVIRON["_pkgconfigdir"]
1886         npkgconfigdir = ENVIRON["_npkgconfigdir"]
1887         localedir = ENVIRON["_localedir"]
1888
1889         perl_sitearch = ENVIRON["perl_sitearch"]
1890         perl_archlib = ENVIRON["perl_archlib"]
1891         perl_privlib = ENVIRON["perl_privlib"]
1892         perl_vendorlib = ENVIRON["perl_vendorlib"]
1893         perl_vendorarch = ENVIRON["perl_vendorarch"]
1894         perl_sitelib = ENVIRON["perl_sitelib"]
1895
1896         py_sitescriptdir = ENVIRON["py_sitescriptdir"]
1897         py_sitedir = ENVIRON["py_sitedir"]
1898         py_scriptdir = ENVIRON["py_scriptdir"]
1899         py_ver = ENVIRON["py_ver"]
1900
1901         py3_sitescriptdir = ENVIRON["py3_sitescriptdir"]
1902         py3_sitedir = ENVIRON["py3_sitedir"]
1903         py3_scriptdir = ENVIRON["py3_scriptdir"]
1904         py3_ver = ENVIRON["py3_ver"]
1905
1906         ruby_archdir = ENVIRON["ruby_archdir"]
1907         ruby_libdir = ENVIRON["ruby_libdir"]
1908         ruby_sitedir = ENVIRON["ruby_sitedir"]
1909         ruby_sitearchdir = ENVIRON["ruby_sitearchdir"]
1910         ruby_sitelibdir = ENVIRON["ruby_sitelibdir"]
1911         ruby_vendordir = ENVIRON["ruby_vendordir"]
1912         ruby_vendorarchdir = ENVIRON["ruby_vendorarchdir"]
1913         ruby_vendorlibdir = ENVIRON["ruby_vendorlibdir"]
1914         ruby_rubylibdir = ENVIRON["ruby_rubylibdir"] # deprecated
1915         ruby_rdocdir = ENVIRON["ruby_rdocdir"]
1916         ruby_ridir = ENVIRON["ruby_ridir"]
1917         ruby_specdir = ENVIRON["ruby_specdir"]
1918
1919         php_pear_dir = ENVIRON["php_pear_dir"]
1920         php_data_dir = ENVIRON["php_data_dir"]
1921         tmpdir = ENVIRON["tmpdir"]
1922
1923         systemdunitdir = ENVIRON["systemdunitdir"]
1924         systemduserunitdir = ENVIRON["systemduserunitdir"]
1925         systemdtmpfilesdir = ENVIRON["systemdtmpfilesdir"]
1926 }
1927
1928 # replace opam names (caml)
1929 function replace_opam_deps(field,     name) {
1930         name = $2
1931         if (name ~ "^(cryptokit|extlib|xmlm)$") {
1932                 name = "ocaml-" name
1933         } else if (name ~ "^(biniou|easy-format|yojson|gapi-ocaml)$") {
1934                 name = "ocaml-" name "-devel"
1935         } else if (name == "ocamlfind") {
1936                 name = "ocaml-findlib"
1937         } else if (name == "sqlite3-ocaml") {
1938                 name = "ocaml-sqlite"
1939         } else if (name == "ocamlnet") {
1940                 name = "ocaml-net"
1941         } else if (name == "ocurl") {
1942                 name = "ocaml-curl-devel"
1943         } else if (name == "ocamlfuse") {
1944                 name = "ocaml-fuse-devel"
1945         } else if (name == "camlidl") {
1946                 name = "ocaml-idl-devel"
1947         }
1948
1949         if (name != $2) {
1950                 $2 = name
1951         }
1952 }
1953
1954 # php virtual deps as discussed in devel-en
1955 function replace_php_virtual_deps(field) {
1956         pkg = $2
1957 #       if (pkg == "php-program") {
1958 #               $0 = $1 "\t/usr/bin/php"
1959 #               return
1960 #       }
1961
1962         if (field == "requires:" || field == "suggests:") {
1963                 if (pkg ~ /^php-(bcmath|bz2|calendar|ctype|curl|dba|date|dom|enchant|exif|fileinfo|filter|fpm|ftp|gd|gettext|gmp|hash|iconv|imap|interbase|intl|json|ldap|mbstring|mcrypt|mssql|mysql|mysqli|odbc|openssl|pcntl|pcre|pdo|pdo-dblib|pdo-firebird|pdo-mysql|pdo-odbc|pdo-pgsql|pdo-sqlite|pgsql|phar|posix|pspell|readline|recode|reflection|session|shmop|simplexml|snmp|soap|sockets|spl|sqlite|sqlite3|sybase-ct|sysvmsg|sysvsem|sysvshm|tidy|tokenizer|wddx|xml|xmlreader|xmlrpc|xmlwriter|xsl|zip|zlib)/) {
1964                         sub(/^php-/, "php(", pkg)
1965                         sub(/$/, ")", pkg)
1966                         $2 = pkg
1967                 } else if (pkg ~ /^php-pecl-/) {
1968                         sub(/^php-pecl-/, "php(", pkg)
1969                         sub(/$/, ")", pkg)
1970                         $2 = pkg
1971                 }
1972         }
1973
1974         if (pkg == "php" || pkg == "php-common") {
1975                 $2 = "php(core)"
1976                 if ($4 ~ /^[0-9]:/) {
1977                         $4 = substr($4, 3)
1978                 }
1979         }
1980
1981         if (pkg == "php4") {
1982                 $2 = "webserver(php)"
1983                 if ($4 ~ /^[0-9]:/) {
1984                         $4 = substr($4, 3)
1985                 }
1986         }
1987 }
1988
1989 # {{{ replace_groupnames(group)
1990 function replace_groupnames(group) {
1991         group = replace(group, "Amusements/Games", "Applications/Games")
1992         group = replace(group, "Amusements/Games/Strategy/Real Time", "X11/Applications/Games/Strategy")
1993         group = replace(group, "Application/Multimedia", "Applications/Multimedia")
1994         group = replace(group, "Application/System", "Applications/System")
1995         group = replace(group, "Applications/Compilers", "Development/Languages")
1996         group = replace(group, "Applications/Daemons", "Daemons")
1997         group = replace(group, "Applications/Internet", "Applications/Networking")
1998         group = replace(group, "Applications/Internet/Peer to Peer", "Applications/Networking")
1999         group = replace(group, "Applications/Productivity", "X11/Applications")
2000         group = replace(group, "Applications/Security", "Applications/System")
2001         group = replace(group, "Applications/Web", "Applications/WWW")
2002         group = replace(group, "Database", "Applications/Databases")
2003         group = replace(group, "Development/C", "Development/Libraries")
2004         group = replace(group, "Development/Code Generators", "Development")
2005         group = replace(group, "Development/Docs", "Documentation")
2006         group = replace(group, "Development/Documentation", "Documentation")
2007         group = replace(group, "Development/Java", "Development/Languages/Java")
2008         group = replace(group, "Development/Languages/C and C++", "Libraries")
2009         group = replace(group, "Development/Languages/Other", "Development/Languages")
2010         group = replace(group, "Development/Languages/Ruby", "Development/Languages")
2011         group = replace(group, "Development/Libraries/C and C++", "Development/Libraries")
2012         group = replace(group, "Development/Libraries/Java", "Development/Languages/Java")
2013         group = replace(group, "Development/Libraries/Python", "Development/Languages/Python")
2014         group = replace(group, "Development/Libraries/TCL", "Development/Languages/Tcl")
2015         group = replace(group, "Development/Other", "Development")
2016         group = replace(group, "Development/Python", "Development/Languages/Python")
2017         group = replace(group, "Development/Testing", "Development")
2018         group = replace(group, "Editors", "Applications/Text")
2019         group = replace(group, "Emulators", "Applications/Emulators")
2020         group = replace(group, "File tools", "Applications/File")
2021         group = replace(group, "Games", "Applications/Games")
2022         group = replace(group, "Library/Development", "Development/Libraries")
2023         group = replace(group, "Networking/Deamons", "Networking/Daemons")
2024         group = replace(group, "Networking/Mail", "Applications/Mail")
2025         group = replace(group, "Networking/Other", "Networking")
2026         group = replace(group, "Productivity/Databases/Servers", "Applications/Databases")
2027         group = replace(group, "Productivity/Multimedia/Other", "X11/Applications/Multimedia")
2028         group = replace(group, "Productivity/Networking/Web/Servers", "Networking/Daemons/HTTP")
2029         group = replace(group, "Python/Libraries", "Libraries/Python")
2030         group = replace(group, "Shells", "Applications/Shells")
2031         group = replace(group, "System Environment/Base", "Base")
2032         group = replace(group, "System Environment/Daemons", "Daemons")
2033         group = replace(group, "System Environment/Kernel", "Base/Kernel")
2034         group = replace(group, "System Environment/Libraries", "Libraries")
2035         group = replace(group, "System Tools", "Applications/System")
2036         group = replace(group, "System", "Base")
2037         group = replace(group, "System/Base", "Base")
2038         group = replace(group, "System/Kernel and hardware", "Base/Kernel")
2039         group = replace(group, "System/Libraries", "Libraries")
2040         group = replace(group, "System/Servers", "Daemons")
2041         group = replace(group, "Text Processing/Markup/HTML", "Applications/Text")
2042         group = replace(group, "Text Processing/Markup/XML", "Applications/Text")
2043         group = replace(group, "Text tools", "Applications/Text")
2044         group = replace(group, "User Interface/Desktops", "X11/Applications")
2045         group = replace(group, "User Interface/X", "X11/Applications")
2046         group = replace(group, "Utilities/System", "Applications/System")
2047         group = replace(group, "Web/Database", "Applications/WWW")
2048         group = replace(group, "X11/GNOME", "X11/Applications")
2049         group = replace(group, "X11/GNOME/Applications", "X11/Applications")
2050         group = replace(group, "X11/GNOME/Development/Libraries", "X11/Development/Libraries")
2051         group = replace(group, "X11/Games", "X11/Applications/Games")
2052         group = replace(group, "X11/Games/Strategy", "X11/Applications/Games/Strategy")
2053         group = replace(group, "X11/Library", "X11/Libraries")
2054         group = replace(group, "X11/Utilities", "X11/Applications")
2055         group = replace(group, "X11/XFree86", "X11")
2056         group = replace(group, "X11/Xserver", "X11/Servers")
2057
2058         return group
2059 }
2060 # }}}
2061
2062 # {{{ replace_pkgconfig(pkg)
2063 function replace_pkgconfig(pkg,    cmd, path, n, i, line) {
2064         n = split("/usr/lib64/pkgconfig /usr/lib/pkgconfig /usr/share/pkgconfig", path, / /)
2065         for (i = 1; i <= n; i++) {
2066                 cmd = "rpm -qf --qf '%{N}' " path[i] "/" pkg ".pc"
2067                 # Getline returns 0 on end-of-file, -1 on error, otherwise 1.
2068                 if ((cmd | getline line) <= 0) {
2069                         continue
2070                 }
2071
2072                 if (line !~ /No such file or directory/) {
2073                         # @modifies global $2
2074                         $2 = line
2075                         return
2076                 }
2077         }
2078 }
2079 # }}}
2080
2081 # {{{ replace_pythonegg(pkg)
2082 function replace_pythonegg(pkg,    cmd, line) {
2083         cmd = "rpm -q --qf '%{N}' --whatprovides 'pythonegg(" pkg ")'"
2084         # Getline returns 0 on end-of-file, -1 on error, otherwise 1.
2085         if ((cmd | getline line) <= 0) {
2086                 return
2087         }
2088
2089         if (line !~ /no package provides/) {
2090                 # @modifies global $2
2091                 $2 = line
2092                 return
2093         }
2094 }
2095 # }}}
2096
2097 function replace_requires(field,   pkg) {
2098         # pkg-config -> package names
2099         if (match($2, /pkgconfig\(([^)]+)\)/)) {
2100                 pkg = substr($2, RSTART + 10, RLENGTH - 11)
2101                 replace_pkgconfig(pkg)
2102         }
2103
2104         # pythonegg -> package names
2105         if (match($2, /pythonegg\(([^)]+)\)/)) {
2106                 pkg = substr($2, RSTART + 10, RLENGTH - 11)
2107                 replace_pythonegg(pkg)
2108         }
2109
2110         sub(/^python-setuptools-devel$/, "python-distribute", $2)
2111         sub(/^gcc-g77/, "gcc-fortran", $2)
2112
2113         # use virtual, not package name
2114         sub(/^rpm-build-macros$/, "rpmbuild(macros)", $2)
2115
2116         # bad package.xml, see http://pear.php.net/bugs/bug.php?id=17779
2117         sub(/^php-php-gtk/, "php-gtk2", $2)
2118
2119         # {{{ jpackages / fedora java packages
2120         sub(/^antlr3$/, "java-antlr3", $2)
2121         sub(/^aqute-bnd$/, "java-bnd", $2)
2122         sub(/^avalon-framework$/, "java-avalon-framework", $2)
2123         sub(/^avalon-logkit$/, "java-avalon-logkit", $2)
2124         sub(/^axis$/, "java-axis", $2)
2125         sub(/^bouncycastle$/, "java-bcprov", $2)
2126         sub(/^bouncycastle-mail$/, "java-bcmail", $2)
2127         sub(/^bouncycastle-pg$/, "java-bcpg", $2)
2128         sub(/^bouncycastle-tsp$/, "java-bctsp", $2)
2129         sub(/^bsf$/, "java-bsf", $2)
2130         sub(/^dom4j$/, "java-dom4j", $2)
2131         sub(/^flute$/, "java-flute", $2)
2132         sub(/^gnu-regexp$/, "java-gnu-regexp", $2)
2133         sub(/^gnu.regexp$/, "java-gnu-regexp", $2)
2134         sub(/^hamcrest$/, "java-hamcrest", $2)
2135         sub(/^itext$/, "java-itext", $2)
2136         sub(/^jaas$/, "java(jaas)", $2)
2137         sub(/^jaf$/, "java(jaf)", $2)
2138         sub(/^jakarta-ant$/, "ant", $2)
2139         sub(/^jakarta-commons-codec$/, "java-commons-codec", $2)
2140         sub(/^jakarta-commons-httpclient$/, "java-commons-httpclient", $2)
2141         sub(/^jakarta-commons-lang24$/, "java-commons-lang", $2)
2142         sub(/^jakarta-commons-logging$/, "java-commons-logging", $2)
2143         sub(/^jakarta-commons-net$/, "java-commons-net", $2)
2144         sub(/^jakarta-log4j$/, "java-log4j", $2)
2145         sub(/^jakarta-oro$/, "java-oro", $2)
2146         sub(/^jakarta-servletapi$/, "java(servlet)", $2)
2147         sub(/^java-devel$/, "jdk", $2)
2148         sub(/^java-dom$/, "java-dom4j", $2)
2149         sub(/^java\(JSP\)$/, "java(jsp)", $2)
2150         sub(/^java\(JavaServerFaces\)$/, "java(javaserverfaces)", $2)
2151         sub(/^java\(Portlet\)$/, "java(portlet)", $2)
2152         sub(/^java\(Servlet\)$/, "java(servlet)", $2)
2153         sub(/^javamail$/, "java(javamail)", $2)
2154         sub(/^jaxp$/, "java(jaxp)", $2)
2155         sub(/^jaxp_parser_impl$/, "java(jaxp_parser_impl)", $2)
2156         sub(/^jaxp_transform_impl$/, "java(jaxp_transform_impl)", $2)
2157         sub(/^jce$/, "java(jce)", $2)
2158         sub(/^jcommon$/, "java-jcommon", $2)
2159         sub(/^jdbc-stdext$/, "java(jdbc-stdext)", $2)
2160         sub(/^jdepend$/, "java-jdepend", $2)
2161         sub(/^jfreechart$/, "java-jfreechart", $2)
2162         sub(/^jmx$/, "java(jmx)", $2)
2163         sub(/^jndi$/, "java(jndi)", $2)
2164         sub(/^jsch$/, "java-jsch", $2)
2165         sub(/^jsse$/, "java(jsse)", $2)
2166         sub(/^jta$/, "java(jta)", $2)
2167         sub(/^junit$/, "java-junit", $2)
2168         sub(/^junit4$/, "java-junit", $2)
2169         sub(/^ldapjdk$/, "ldapsdk", $2)
2170         sub(/^libbase$/, "java-libbase", $2)
2171         sub(/^libfonts$/, "java-libfonts", $2)
2172         sub(/^libformula$/, "java-libformula", $2)
2173         sub(/^liblayout$/, "java-liblayout", $2)
2174         sub(/^libloader$/, "java-libloader", $2)
2175         sub(/^librepository$/, "java-librepository", $2)
2176         sub(/^libserializer$/, "java-libserializer", $2)
2177         sub(/^log4j$/, "java-log4j", $2)
2178         sub(/^logging-log4j$/, "java-log4j", $2)
2179         sub(/^oro$/, "java-oro", $2)
2180         sub(/^pdf-renderer$/, "java-pdf-renderer", $2)
2181         sub(/^pentaho-libxml$/, "java-libxml", $2)
2182         sub(/^rhino$/, "java-rhino", $2)
2183         sub(/^sac$/, "java-sac", $2)
2184         sub(/^saxon-scripts$/, "saxon", $2)
2185         sub(/^servlet$/, "java(servlet)", $2)
2186         sub(/^uddi4j$/, "java-uddi4j", $2)
2187         sub(/^ws-jaxme$/, "java-jaxme", $2)
2188         sub(/^wsdl4j$/, "java-wsdl4j", $2)
2189         sub(/^xalan-j$/, "java-xalan", $2)
2190         sub(/^xalan-j2$/, "java-xalan", $2)
2191         sub(/^xerces-j$/, "java-xerces", $2)
2192         sub(/^xerces-j2$/, "java-xerces", $2)
2193         sub(/^xml-commons-apis$/, "java-xml-commons", $2)
2194         sub(/^xml-commons-resolver$/, "java-xml-commons-resolver", $2)
2195         sub(/^xmldb-api$/, "java-xmldb", $2)
2196         sub(/^xmldb-api-sdk$/, "java-xmldb-sdk", $2)
2197         # }}}
2198
2199         # {{{ fedora / redhat
2200         sub(/^Django$/, "python-django", $2)
2201         sub(/^GitPython$/, "python-git", $2)
2202         sub(/^MySQL-python$/, "python-MySQLdb", $2)
2203         sub(/^NetworkManager-glib-devel$/, "NetworkManager-devel", $2)
2204         sub(/^PyQt4-devel$/, "python-PyQt4-devel", $2)
2205         sub(/^PyQwt-devel$/, "python-PyQwt-devel", $2)
2206         sub(/^PyYAML$/, "python-PyYAML", $2)
2207         sub(/^ccid$/, "pcsc-driver-ccid", $2)
2208         sub(/^chkconfig$/, "/sbin/chkconfig", $2)
2209         sub(/^db4-devel$/, "db-devel", $2)
2210         sub(/^dbus-python$/, "python-dbus", $2)
2211         sub(/^desktop-notification-daemon$/, "dbus(org.freedesktop.Notifications)", $2)
2212         sub(/^device-mapper-multipath$/, "multipath-tools", $2)
2213         sub(/^django-tagging$/, "python-django_tagging", $2)
2214         sub(/^elfutils-libelf-devel$/, "elfutils-devel", $2)
2215         sub(/^file-devel$/, "libmagic-devel", $2)
2216         sub(/^freetype2-devel$/, "freetype-devel", $2)
2217         sub(/^fuse-devel$/, "libfuse-devel", $2)
2218         sub(/^gamin-python$/, "python-gamin", $2)
2219         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2)
2220         sub(/^gnome-desktop3-devel$/, "gnome-desktop-devel", $2)
2221         sub(/^gnome-python2-extras$/, "python-gnome-extras", $2)
2222         sub(/^gnome-python2-gconf$/, "python-gnome-gconf", $2)
2223         sub(/^gnome-python2-gnomekeyring$/, "python-gnome-desktop-keyring", $2)
2224         sub(/^gnome-python2-gtkspell$/, "python-gnome-extras-gtkspell", $2)
2225         sub(/^gtk-sharp2-devel$/, "dotnet-gtk-sharp2-devel", $2)
2226         sub(/^gtk2$/, "gtk+2", $2)
2227         sub(/^gtk2-devel$/, "gtk+2-devel", $2)
2228         sub(/^gtk3$/, "gtk+3", $2)
2229         sub(/^gtk3-devel$/, "gtk+3-devel", $2)
2230         sub(/^initscripts$/, "rc-scripts", $2)
2231         sub(/^iproute$/, "iproute2", $2)
2232         sub(/^iptables-ipv6$/, "iptables", $2)
2233         sub(/^iscsi-initiator-utils$/, "open-iscsi", $2)
2234         sub(/^keyutils-libs-devel$/, "keyutils-devel", $2)
2235         sub(/^libSM-devel$/, "xorg-lib-libSM-devel", $2)
2236         sub(/^libX11-devel$/, "xorg-lib-libX11-devel", $2)
2237         sub(/^libXScrnSaver-devel$/, "xorg-lib-libXScrnSaver-devel", $2)
2238         sub(/^libXau-devel$/, "xorg-lib-libXau-devel", $2)
2239         sub(/^libXcomposite-devel$/, "xorg-lib-libXcomposite-devel", $2)
2240         sub(/^libXcursor-devel$/, "xorg-lib-libXcursor-devel", $2)
2241         sub(/^libXdamage-devel$/, "xorg-lib-libXdamage-devel", $2)
2242         sub(/^libXext-devel$/, "xorg-lib-libXext-devel", $2)
2243         sub(/^libXft-devel$/, "xorg-lib-libXft-devel", $2)
2244         sub(/^libXinerama-devel$/, "xorg-lib-libXinerama-devel", $2)
2245         sub(/^libXrandr-devel$/, "xorg-lib-libXrandr-devel", $2)
2246         sub(/^libXrender-devel$/, "xorg-lib-libXrender-devel", $2)
2247         sub(/^libXt-devel$/, "xorg-lib-libXt-devel", $2)
2248         sub(/^libXtst-devel$/, "xorg-lib-libXtst-devel", $2)
2249         sub(/^libXv-devel$/, "xorg-lib-libXv-devel", $2)
2250         sub(/^libXxf86misc-devel$/, "xorg-lib-libXxf86misc-devel", $2)
2251         sub(/^libXxf86vm-devel$/, "xorg-lib-libXxf86vm-devel", $2)
2252         sub(/^libacl-devel$/, "acl-devel", $2)
2253         sub(/^libattr-devel$/, "attr-devel", $2)
2254         sub(/^libcurl-devel$/, "curl-devel", $2)
2255         sub(/^libgudev1-devel$/, "udev-glib-devel", $2)
2256         sub(/^libmx-devel$/, "mx-devel", $2)
2257         sub(/^libselinux-python$/, "python-selinux", $2)
2258         sub(/^libsrtp-devel$/, "srtp-devel", $2)
2259         sub(/^libtdb$/, "tdb", $2)
2260         sub(/^libtdb-devel$/, "tdb-devel", $2)
2261         sub(/^libtevent$/, "tevent", $2)
2262         sub(/^libtevent-devel$/, "tevent-devel", $2)
2263         sub(/^libusb1-devel$/, "libusb-devel", $2)
2264         sub(/^libuser-python$/, "python-libuser", $2)
2265         sub(/^libvirt-python$/, "python-libvirt", $2)
2266         sub(/^libxkbfile-devel$/, "xorg-lib-libxkbfile", $2)
2267         sub(/^libxml2-python$/, "python-libxml2", $2)
2268         sub(/^mod_wsgi$/, "apache-mod_wsgi", $2)
2269         sub(/^newt-python$/, "python-snack", $2)
2270         sub(/^notify-python$/, "python-pynotify", $2)
2271         sub(/^pcsc-lite-ccid$/, "pcsc-driver-ccid", $2)
2272         sub(/^pulseaudio-libs-devel$/, "pulseaudio-devel", $2)
2273         sub(/^pyOpenSSL$/, "python-pyOpenSSL", $2)
2274         sub(/^pycairo$/, "python-pycairo", $2)
2275         sub(/^pyflakes$/, "python-pyflakes", $2)
2276         sub(/^pygobject2$/, "python-pygobject", $2)
2277         sub(/^pygobject3$/, "python-pygobject3", $2)
2278         sub(/^pygobject3-devel$/, "python-pygobject3-common-devel", $2)
2279         sub(/^pygtk2$/, "python-pygtk", $2)
2280         sub(/^pygtk2-devel$/, "python-pygtk-devel", $2)
2281         sub(/^pygtk2-libglade$/, "python-pygtk-glade", $2)
2282         sub(/^pykickstart$/, "python-pykickstart", $2)
2283         sub(/^pyparsing$/, "python-pyparsing", $2)
2284         sub(/^pyparted$/, "python-parted", $2)
2285         sub(/^pysvn$/, "python-pysvn", $2)
2286         sub(/^pytalloc$/, "python-talloc", $2)
2287         sub(/^pytalloc-devel$/, "python-talloc-devel", $2)
2288         sub(/^pytest$/, "python-pytest", $2)
2289         sub(/^python-crypto$/, "python-Crypto", $2)
2290         sub(/^python-cups$/, "python-pycups", $2)
2291         sub(/^python-enchant$/, "python-pyenchant", $2)
2292         sub(/^python-imaging$/, "python-PIL", $2)
2293         sub(/^python-imaging-tk$/, "python-PIL-tk", $2)
2294         sub(/^python-newt$/, "python-snack", $2)
2295         sub(/^python-pygtk$/, "python-pygtk-gtk", $2)
2296         sub(/^python-recaptcha-client$/, "python-recaptcha", $2)
2297         sub(/^python-sphinx$/, "python-Sphinx", $2)
2298         sub(/^python-twisted$/, "python-TwistedCore", $2)
2299         sub(/^python-twisted-core$/, "python-TwistedCore", $2)
2300         sub(/^python-twisted-names$/, "python-TwistedNames", $2)
2301         sub(/^python2-devel$/, "python-devel", $2)
2302         sub(/^pytz$/, "python-pytz", $2)
2303         sub(/^pyxdg$/, "python-pyxdg", $2)
2304         sub(/^qt4-devel$/, "qt4-build", $2)
2305         sub(/^qt4-webkit-devel$/, "QtWebKit-devel", $2)
2306         sub(/^qtlockedfile-devel$/, "QtLockedFile-devel", $2)
2307         sub(/^qtsingleapplication-devel$/, "QtSingleApplication-devel", $2)
2308         sub(/^rpm-python$/, "python-rpm", $2)
2309         sub(/^sip-devel$/, "python-sip-devel", $2)
2310         sub(/^tftp-server$/, "tftpdaemon", $2)
2311         sub(/^tkinter$/, "python-tkinter", $2)
2312         sub(/^urw-fonts$/, "fonts-Type1-urw", $2)
2313         sub(/^webkitgtk3-devel$/, "gtk-webkit3-devel", $2)
2314         sub(/^xapian-bindings-python$/, "python-xapian", $2)
2315         sub(/^xorg-x11-server-sdk$/, "xorg-xserver-server-devel", $2)
2316         # }}}
2317
2318         # {{{ mandriva
2319         sub(/^python-gobject-devel$/, "python-pygobject-devel", $2)
2320         sub(/^python-pyrex$/, "python-Pyrex", $2)
2321         sub(/^webkitgtk-devel$/, "gtk-webkit-devel", $2)
2322         sub(/^python-curl$/, "python-pycurl", $2)
2323         sub(/^python-webkitgtk$/, "python-pywebkitgtk", $2)
2324         sub(/^pygtk2.0$/, "python-pygtk-gtk", $2)
2325         sub(/^gnome-python-gconf$/, "python-gnome-gconf", $2)
2326         # }}}
2327
2328         # {{{ debian / ubuntu
2329         sub(/^blkid-dev$/, "libblkid-devel", $2)
2330         sub(/^ext2fs-dev$/, "e2fsprogs-devel", $2)
2331         sub(/^libao-dev$/, "libao-devel", $2)
2332         sub(/^libboost-filesystem[0-9.]+-dev$/, "boost-devel", $2)
2333         sub(/^libboost-program-options[0-9.]+-dev$/, "boost-devel", $2)
2334         sub(/^libboost-regex[0-9.]+-dev$/, "boost-devel", $2)
2335         sub(/^libboost-thread[0-9.]+-dev$/, "boost-devel", $2)
2336         sub(/^libcurl4-openssl-dev$/, "curl-devel", $2)
2337         sub(/^libdnet-dev$/, "libdnet-devel", $2)
2338         sub(/^libesd0-dev$/, "esound-devel", $2)
2339         sub(/^libfishsound1-dev$/, "libfishsound-devel", $2)
2340         sub(/^libgconf2-dev$/, "GConf2-devel", $2)
2341         sub(/^libgl1-mesa-dev$/, "OpenGL-devel", $2)
2342         sub(/^libgl1-mesa-dri$/, "OpenGL", $2)
2343         sub(/^libglib2.0-dev$/, "glib2-devel", $2)
2344         sub(/^libglu1-mesa-dev$/, "OpenGL-GLU-devel", $2)
2345         sub(/^libgtk2.0-dev$/, "gtk+2-devel", $2)
2346         sub(/^libhunspell-dev$/, "hunspell-devel", $2)
2347         sub(/^libmcrypt-dev$/, "libmcrypt-devel", $2)
2348         sub(/^libmhash-dev$/, "mhash-devel", $2)
2349         sub(/^liboggz1-dev$/, "libggz-devel", $2)
2350         sub(/^libpango1.0-dev$/, "pango-devel", $2)
2351         sub(/^libqt4-dev$/, "qt4-build", $2)
2352         sub(/^libshout3-dev$/, "libshout-devel", $2)
2353         sub(/^libslp-dev$/, "openslp-devel", $2)
2354         sub(/^libsndfile1-dev$/, "libsndfile-devel", $2)
2355         sub(/^libspeex-dev$/, "speex-devel", $2)
2356         sub(/^libssl-dev$/, "openssl-devel", $2)
2357         sub(/^libvorbis-dev$/, "libvorbis-devel", $2)
2358         sub(/^libxslt1-dev$/, "libxslt-devel", $2)
2359         sub(/^libxss-dev$/, "xorg-lib-libXScrnSaver-devel", $2)
2360         sub(/^mesa-common-dev$/, "OpenGL-devel", $2)
2361         sub(/^libudev$/, "udev-libs", $2)
2362         sub(/^tcp_wrappers-devel$/, "libwrap-devel", $2)
2363         sub(/^vala-tools$/, "vala", $2)
2364         sub(/^vala-devel$/, "vala", $2)
2365         # }}}
2366
2367         # {{{ altlinux
2368         sub(/^libatk-devel$/, "atk-devel", $2)
2369         sub(/^libgit-devel$/, "git-core-devel", $2)
2370         sub(/^libgtk\+2-devel$/, "gtk+2-devel", $2)
2371         sub(/^libncurses-devel$/, "ncurses-devel", $2)
2372         sub(/^libncursesxx-devel$/, "ncurses-c++-devel", $2)
2373         sub(/^libpango-devel$/, "pango-devel", $2)
2374         sub(/^libpcre-devel$/, "pcre-devel", $2)
2375         sub(/^libpopt-devel$/, "popt-devel", $2)
2376         sub(/^libssl-devel$/, "openssl-devel", $2)
2377         # }}}
2378
2379         # {{{ suse/opensuse
2380         sub(/^alsa-devel$/, "alsa-lib-devel", $2)
2381         sub(/^gtk-sharp2$/, "dotnet-gtk-sharp2", $2)
2382         sub(/^gtkmm2-devel$/, "gtkmm-devel", $2)
2383         sub(/^libexpat-devel$/, "expat-devel", $2)
2384         sub(/^libffmpeg-devel$/, "ffmpeg-devel", $2)
2385         sub(/^libopenssl-devel$/, "openssl-devel", $2)
2386         sub(/^libpulse-devel$/, "pulseaudio-devel", $2)
2387         sub(/^monodoc-core$/, "mono-monodoc", $2)
2388         sub(/^python-cairo$/, "python-pycairo", $2)
2389         sub(/^python-gobject$/, "python-pygobject", $2)
2390         sub(/^python-gstreamer-0_10$/, "python-gstreamer", $2)
2391         sub(/^python-gtk$/, "python-pygtk-gtk", $2)
2392         sub(/^python-xdg$/, "python-pyxdg", $2)
2393         # }}}
2394
2395         replace_php_virtual_deps(field)
2396
2397         replace_opam_deps(field)
2398 }
2399
2400 # vim:ts=4:sw=4 fdm=marker