pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|dl)\.(sf|sourceforge)\.net\//) {
 236                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 237                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 238
 239                 gsub("/.*", "", url)
 240                 url = "http://sourceforge.net/projects/" url "/files/"
 241                 d("sf url, mungled url to: " url)
 242
 243         } else if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 244                 gsub("^http://", "", url)
 245                 gsub("\..*", "", url)
 246                 url = "http://code.google.com/p/" url "/downloads/list"
 247                 d("googlecode url, mungled url to: " url)
 248
 249         } else if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 250                 gsub("-.*", "", filename)
 251                 url = "http://pecl.php.net/package/" filename
 252                 d("pecl.php.net url, mungled url to: " url)
 253
 254         } else if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 255                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 256                 d("mysql 5.1 url, mungled url to: " url)
 257
 258         } else if (url ~ /^(http|https):\/\/launchpad\.net\/(.*)\//) {
 259                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 260                 gsub("\/.*/", "", url)
 261                 url = "https://code.launchpad.net/" url "/+download"
 262                 d("main launchpad url, mungled url to: " url)
 263
 264         } else if (url ~ /^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 265                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 266                 gsub("\/.*/", "", url)
 267                 url = "https://edge.launchpad.net/" url "/+download"
 268                 d("edge launchpad url, mungled url to: " url)
 269
 270         } else if (url ~ /^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 271                 gsub("\/tarball\/.*", "/downloads", url)
 272                 d("github tarball url, mungled url to: " url)
 273
 274         } else if (url ~ /^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 275                 gsub("\/archive\/.*", "/tags", url)
 276                 d("github archive url, mungled url to: " url)
 277
 278         } else if (url ~ /^(http|https):\/\/bitbucket.org\/.*\/get\/.*/) {
 279                 # https://bitbucket.org/logilab/pylint/get/tip.tar.bz2 -> https://bitbucket.org/logilab/pylint/downloads
 280                 gsub("\/get\/.*", "/downloads", url)
 281                 d("github bitbucket url, mungled url to: " url)
 282
 283         } else if (url ~ /^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 284                 gsub("\/snapshot\/.*", "/", url)
 285                 d("cgit snapshot tarball url, mungled url to: " url)
 286
 287         } else if (url ~ /^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 288                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 289                 d("aquamaniac.de tarball url, mungled url to: " url)
 290
 291         } else if (url ~ /^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 292                 url = "http://www.process-one.net/en/ejabberd/archive/"
 293                 d("ejabberd tarball url, mungled url to: " url)
 294
 295         } else if (url ~ /^(http|https):\/\/llvm.org\/releases\//) {
 296                 url = "http://llvm.org/releases/download.html"
 297                 d("llvm tarball url, mungled url to: " url)
 298
 299         } else if (url ~ /^(http|https):\/\/download\.owncloud\.org\/community\//) {
 300                 url = "http://owncloud.org/changelog/"
 301                 d("owncloud tarball url, mungled url to: " url)
 302
 303         } else if (url ~ /^(http|https):\/\/hackage\.haskell\.org\/packages\/archive\//) {
 304                 gsub("\/packages\/archive","/package",url)
 305                 d("hackage haskell tarball url, mungled url to: " url)
 306
 307         } else if (url ~ /^http:\/\/www.taskwarrior.org\/download\//) {
 308                 url = "http://taskwarrior.org/projects/taskwarrior/wiki/Download"
 309                 d("taskwarrior tarball url, mungled url to: " url)
 310         }
 311
 312         d("Retrieving: " url)
 313         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 314         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 315         d("Execute: " cmd)
 316         errno = system(cmd)
 317         d("Execute done")
 318
 319         if (errno != 0) {
 320                 d("Reading failure response...")
 321                 wholeerr = ""
 322                 while (getline oneline < tmpfileerr)
 323                         wholeerr = (wholeerr " " oneline)
 324                 d("Error Response: " wholeerr)
 325
 326                 system("rm -f " tmpfile)
 327                 system("rm -f " tmpfileerr)
 328                 retval = ("WGET ERROR: " errno ": " wholeerr)
 329                 return retval
 330         }
 331         system("rm -f " tmpfileerr)
 332
 333         urldir = url;
 334         sub(/[^\/]+$/, "", urldir)
 335
 336 if (USE_PERL) {
 337         cmd = extract_links_cmd(tmpfile)
 338         while (cmd | getline) {
 339                 tag = $1
 340                 link = substr($0, length(tag) + 2)
 341
 342                 if (tag == "iframe") {
 343                         d("Frame: " link)
 344                         if (url !~ /\//) {
 345                                 link = (urldir link)
 346                                 d("Frame->: " link)
 347                         }
 348
 349                         if (link_seen(link)) {
 350                                 continue
 351                         }
 352                         retval = (retval " " get_links(link))
 353                 }
 354
 355                 if (link_seen(link)) {
 356                         continue
 357                 }
 358
 359                 retval = (retval " " link)
 360                 d("href(): " link)
 361         }
 362         close(cmd)
 363         system("rm -f " tmpfile)
 364
 365         d("Returning: [" retval "]")
 366         return retval
 367 }
 368
 369         wholeodp = ""
 370         d("Reading success response...")
 371         while (getline oneline < tmpfile) {
 372                 wholeodp = (wholeodp " " oneline)
 373 #               d("Response: " wholeodp)
 374         }
 375         d("Reponse read done...")
 376         system("rm -f " tmpfile)
 377
 378         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 379                 d("Processing links...")
 380                 odp = substr(wholeodp,RSTART,RLENGTH);
 381                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 382
 383                 lowerodp = tolower(odp);
 384                 if (lowerodp ~ /<frame[ \t]/) {
 385                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 386                         match(odp, /src="[^"]+"/)
 387                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 388                         d("Frame: " newurl)
 389                         if (newurl !~ /\//) {
 390                                 newurl=(urldir newurl)
 391                                 d("Frame->: " newurl)
 392                         }
 393
 394                         if (link_seen(newurl)) {
 395                                 newurl = ""
 396                                 continue
 397                         }
 398
 399                         retval = (retval " " get_links(newurl))
 400                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 401                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 402                         match(odp,/href="[^"]*"/)
 403                         link=substr(odp,RSTART,RLENGTH)
 404                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 405                         link=substr(link,7,length(link)-7)
 406                         link=postfix_link(url, link)
 407
 408                         if (link_seen(link)) {
 409                                 link=""
 410                                 continue
 411                         }
 412
 413                         # link ends with at least 2 digit version
 414                         mlink = ""
 415                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 416                                 mlink = get_links(link)
 417
 418                         retval = (retval " " link " " mlink)
 419                         d("href(\"\"): " link)
 420                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 421                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 422                         match(odp,/href='[^']*'/)
 423                         link=substr(odp,RSTART,RLENGTH)
 424                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 425                         link=substr(link,7,length(link)-7)
 426                         link=postfix_link(url, link)
 427
 428                         if (link_seen(link)) {
 429                                 link=""
 430                                 continue
 431                         }
 432
 433                         retval = (retval " " link)
 434                         d("href(''): " link)
 435                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 436                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 437                         match(odp,/href=[^ \t>]*/)
 438                         link=substr(odp,RSTART,RLENGTH)
 439                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 440                         link=substr(link,6,length(link)-5)
 441
 442                         if (link_seen(link)) {
 443                                 link=""
 444                                 continue
 445                         }
 446
 447                         retval = (retval " " link)
 448                         d("href(): " link)
 449                 } else {
 450                         # <a ...> but not href - skip
 451                         d("skipping <a > without href: " odp)
 452                 }
 453         }
 454
 455         d("Returning: [" retval "]")
 456         return retval
 457 }
 458
 459 function subst_defines(var,defs) {
 460 # substitute all possible RPM macros
 461         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 462                 oldvar=var
 463                 for (j in defs) {
 464                         gsub("%{" j "}", defs[j], var)
 465                         gsub("%" j , defs[j], var)
 466                 }
 467                 if (var==oldvar) {
 468                         if (DEBUG) {
 469                                 for (i in defs) {
 470                                         d(i " == " defs[i])
 471                                 }
 472                         }
 473                         return var
 474                 }
 475         }
 476         return var
 477 }
 478
 479 function find_mirror(url) {
 480
 481         while (succ = (getline line < "mirrors")) {
 482             if (succ==-1) { return url }
 483                 nf=split(line,fields,"|")
 484                 if (nf>1){
 485                         origin=fields[1]
 486                         mirror=fields[2]
 487                         mname=fields[3]
 488                         prefix=substr(url,1,length(origin))
 489                         if (prefix==origin){
 490                                 d("Mirror found at " mname)
 491                                 close("mirrors")
 492                                 return mirror substr(url,length(origin)+1)
 493                         }
 494                 }
 495         }
 496
 497         return url
 498 }
 499
 500 # fetches file list, and compares version numbers
 501 function process_source(number, lurl, name, version) {
 502         d("Processing " lurl)
 503
 504         if (index(lurl, version) == 0) {
 505                 d("There is no version number ["version"] in ["lurl"]")
 506                 return 0
 507         }
 508
 509         sub("://",":",lurl)
 510         sub("/",":/",lurl)
 511         gsub("[^/]*$",":&",lurl)
 512         split(lurl,url,":")
 513         acc=url[1]
 514         host=url[2]
 515         dir=url[3]
 516         filename=url[4]
 517
 518         if (index(dir,version)) {
 519                 # directory name as version maching mode:
 520                 # if /something/version/name-version.tarball then check
 521                 # in /something/ looking for newer directory
 522                 dir=substr(dir,1,index(dir,version)-1)
 523                 sub("[^/]*$","",dir)
 524                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 525         }
 526
 527         d("Will check a directory: " dir)
 528         d("and a file: " filename)
 529
 530         filenameexp=filename
 531         gsub("[+]","\\+",filenameexp)
 532         sub(version,"[A-Za-z0-9.]+",filenameexp)
 533         gsub("[.]","\\.",filenameexp)
 534         sub("\.(bz|bz2|gz|lzma|xz|zip)$",".(bz|bz2|gz|lzma|xz|zip)",filenameexp)
 535         d("Expression: " filenameexp)
 536         match(filename,version)
 537         prever=substr(filename,1,RSTART-1)
 538         postver=substr(filename,RSTART+RLENGTH)
 539         d("Before number: " prever)
 540         d("and after: " postver)
 541         newurl=find_mirror(acc "://" host dir)
 542         #print acc "://" host dir
 543         #newurl=url[1]"://"url[2]url[3]url[4]
 544         #newurl=acc "://" host dir filename
 545         d("Looking at " newurl)
 546
 547         references=0
 548         finished=0
 549         oldversion=version
 550         odp = get_links(newurl, filename)
 551         if( odp ~ "ERROR: ") {
 552                 print name "(" number ") " odp
 553         } else {
 554                 d("WebPage downloaded")
 555                 c=split(odp,linki)
 556                 for (nr=1; nr<=c; nr++) {
 557                         addr=linki[nr]
 558
 559                         d("Found link: " addr)
 560
 561                         # github has very different tarball links that clash with this safe check
 562                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 563                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 564                                         continue
 565                                 }
 566                         }
 567
 568                         if (addr ~ filenameexp) {
 569                                 match(addr,filenameexp)
 570                                 newfilename=substr(addr,RSTART,RLENGTH)
 571                                 d("Hypothetical new: " newfilename)
 572                                 newfilename=fixedsub(prever,"",newfilename)
 573                                 newfilename=fixedsub(postver,"",newfilename)
 574                                 d("Version: " newfilename)
 575                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 576                                 # strip ending (happens when in directiory name as version matching mode)
 577                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 578                                 if (NUMERIC) {
 579                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 580                                                 d("Yes, there is new one")
 581                                                 version=newfilename
 582                                                 finished=1
 583                                         }
 584                                 } else if ( compare_ver(version, newfilename)==1 ) {
 585                                         d("Yes, there is new one")
 586                                         version=newfilename
 587                                         finished=1
 588                                 }
 589                         }
 590                 }
 591                 if (finished == 0)
 592                         print name "(" number ") seems ok: " oldversion
 593                 else
 594                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 595         }
 596 }
 597
 598 function rss_upgrade(name, ver, url, regex, cmd) {
 599         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 600         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 601
 602         d("rss_upgrade_cmd: " cmd)
 603         cmd | getline ver
 604         close(cmd)
 605
 606         return ver
 607 }
 608
 609 # check for ZF upgrade from rss
 610 function zf_upgrade(name, ver) {
 611         return rss_upgrade(name, ver, \
 612                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 613                 "Zend Framework ([^\\s]+) Released" \
 614         );
 615 }
 616
 617 function hudson_upgrade(name, ver) {
 618         return rss_upgrade(name, ver, \
 619                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 620                 "Hudson ([0-9.]+) released" \
 621         );
 622 }
 623
 624 # upgrade check for pear package using PEAR CLI
 625 function pear_upgrade(name, ver,    cmd) {
 626         sub(/^php-pear-/, "", name);
 627
 628         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 629         d("PEAR: " cmd)
 630         cmd | getline ver
 631         close(cmd)
 632
 633         return ver
 634 }
 635
 636 function vim_upgrade(name, ver,     cmd) {
 637         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 638         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 639         d("VIM: " cmd)
 640         cmd | getline ver
 641         close(cmd)
 642         return ver
 643 }
 644
 645 function nodejs_upgrade(name, ver,   cmd) {
 646         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 647         if (DEFS["pkg"]) {
 648                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 649         } else {
 650                 cmd = "npm info " name " dist-tags.latest"
 651         }
 652         cmd | getline ver
 653         close(cmd)
 654
 655         return ver
 656 }
 657
 658 function rubygem_upgrade(name, ver,   cmd, pkg) {
 659         if (DEFS["gem_name"]) {
 660                 pkg = DEFS["gem_name"];
 661
 662         } else if (DEFS["gemname"]) {
 663                 pkg = DEFS["gemname"];
 664
 665         } else if (DEFS["pkgname"]) {
 666                 pkg = DEFS["pkgname"];
 667
 668         } else {
 669                 pkg = name;
 670                 gsub(/^ruby-/, "", pkg);
 671         }
 672
 673         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); print v}'"
 674         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 675         cmd | getline ver
 676
 677         close(cmd)
 678
 679         return ver
 680 }
 681
 682 function google_linux_repo(name, ver, reponame,   cmd, sourceurl) {
 683         sourceurl = "http://dl.google.com/linux/" reponame "/rpm/stable/x86_64/repodata/primary.xml.gz"
 684         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>" name "-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 685         d("google repo: " cmd);
 686         cmd | getline ver
 687         close(cmd)
 688
 689         return ver
 690 }
 691
 692 function jenkins_upgrade(name, ver, urls,  url, i, c, chunks, nver) {
 693         for (i in urls) {
 694                 url = urls[i]
 695                 # http://mirrors.jenkins-ci.org/war-stable/1.509.1/jenkins.war?/jenkins-1.509.1.war
 696                 gsub("/" ver "/jenkins.war\?/jenkins-" ver ".war", "/", url);
 697                 c = split(get_links(url), chunks, "/")
 698                 # new version is second one from the bottom
 699                 nver = chunks[c - 2]
 700                 gsub(/ /, "", nver)
 701                 return nver;
 702         }
 703 }
 704
 705 function process_data(name, ver, rel,     src, nver, i) {
 706         if (name ~ /^php-pear-/) {
 707                 nver = pear_upgrade(name, ver);
 708         } else if (name == "ZendFramework") {
 709                 nver = zf_upgrade(name, ver);
 710         } else if (name == "hudson") {
 711                 nver = hudson_upgrade(name, ver);
 712         } else if (name == "vim") {
 713                 nver = vim_upgrade(name, ver);
 714         } else if (name == "google-chrome") {
 715                 nver = google_linux_repo(name, ver, "chrome");
 716         } else if (name == "google-talkplugin") {
 717                 nver = google_linux_repo(name, ver, "talkplugin");
 718         } else if (name ~ "^nodejs-") {
 719                 nver = nodejs_upgrade(name, ver);
 720         } else if (name ~ "^ruby-" || name == "chef") {
 721                 nver = rubygem_upgrade(name, ver);
 722         } else if (name ~ "jenkins") {
 723                 nver = jenkins_upgrade(name, ver, src);
 724         }
 725
 726         if (nver) {
 727                 if (compare_ver(ver, nver)) {
 728                         print name " [OLD] " ver " [NEW] " nver
 729                 } else {
 730                         print name " seems ok: " ver
 731                 }
 732                 return;
 733         }
 734
 735         if (name == "xulrunner") {
 736                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 737                 d("package xulrunner, change version to firefox ["ver"]")
 738         }
 739
 740 # this function checks if substitutions were valid, and if true:
 741 # processes each URL and tries to get current file list
 742         for (i in src) {
 743                 if (src[i] ~ /%{nil}/) {
 744                         gsub(/\%\{nil\}/, "", src[i])
 745                 }
 746                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 747                         d("Source: " src[i])
 748                         process_source(i, src[i], name, ver)
 749                 } else {
 750                         print FNAME ":" i ": impossible substitution: " src[i]
 751                 }
 752         }
 753 }
 754
 755 BEGIN {
 756         # if you want to use DEBUG, run script with "-v DEBUG=1"
 757         # or uncomment the line below
 758         # DEBUG = 1
 759
 760         errno=system("wget --help > /dev/null 2>&1")
 761         if (errno && errno != 3) {
 762                 print "No wget installed!"
 763                 exit 1
 764         }
 765         if (ARGC>=3 && ARGV[2]=="-n") {
 766                 NUMERIC=1
 767                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 768                 ARGC=ARGC-1
 769         }
 770 }
 771
 772 FNR==1 {
 773         if ( ARGIND != 1 ) {
 774                 # clean frameseen for each ARG
 775                 for (i in frameseen) {
 776                         delete frameseen[i]
 777                 }
 778                 frameseen[0] = 1
 779
 780                 process_data(NAME,VER,REL,SRC)
 781                 NAME="" ; VER="" ; REL=""
 782                 for (i in DEFS) delete DEFS[i]
 783                 for (i in SRC) delete SRC[i]
 784         }
 785         FNAME=FILENAME
 786         DEFS["_alt_kernel"]=""
 787         DEFS["20"]="\\ "
 788         DEFS["nil"]=""
 789 }
 790
 791 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 792 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 793 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 794 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 795 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 796 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 797
 798 END {
 799         process_data(NAME,VER,REL,SRC)
 800 }