pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 # TODO: "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
   4
   5 function fixedsub(s1,s2,t,      ind) {
   6 # substitutes fixed strings (not regexps)
   7         if (ind = index(t,s1)) {
   8                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
   9         }
  10         return t
  11 }
  12
  13 function ispre(s) {
  14         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  15                 if (DEBUG) print "pre-version"
  16                 return 1
  17         } else {
  18                 return 0
  19         }
  20 }
  21
  22 function compare_ver(v1,v2) {
  23 # compares version numbers
  24         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  25                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  26         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  27                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  28         sub("^0*","",v1)
  29         sub("^0*","",v2)
  30         gsub("\.0*",".",v1)
  31         gsub("\.0*",".",v2)
  32         if (DEBUG) print "v1 == " v1
  33         if (DEBUG) print "v2 == " v2
  34         count=split(v1,v1a,"\.")
  35         count2=split(v2,v2a,"\.")
  36
  37         if (count<count2) mincount=count
  38         else mincount=count2
  39
  40         for (i=1; i<=mincount; i++) {
  41                 if (v1a[i]=="") v1a[i]=0
  42                 if (v2a[i]=="") v2a[i]=0
  43                 if (DEBUG) print "i == " i
  44                 if (DEBUG) print "v1[i] == " v1a[i]
  45                 if (DEBUG) print "v2[i] == " v2a[i]
  46                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  47                         if (length(v2a[i])>length(v1a[i]))
  48                                 return 1
  49                         else if (v2a[i]>v1a[i])
  50                                 return 1
  51                         else if (length(v1a[i])>length(v2a[i]))
  52                                 return 0
  53                         else if (v1a[i]>v2a[i])
  54                                 return 0
  55                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  56                         if (v2a[i]>v1a[i])
  57                                 return 1
  58                         else if (v1a[i]>v2a[i])
  59                                 return 0
  60                 } else if (ispre(v1a[i]) == 1)
  61                         return 1
  62                 else
  63                         return 0
  64         }
  65         if ((count2==mincount)&&(count!=count2)) {
  66                 for (i=count2+1; i<=count; i++)
  67                         if (ispre(v1a[i]) == 1)
  68                                 return 1
  69                 return 0
  70         } else if (count!=count2) {
  71                 for (i=count+1; i<=count2; i++)
  72                         if (ispre(v2a[i]) == 1)
  73                                 return 0
  74                 return 1
  75         }
  76         return 0
  77 }
  78
  79 function compare_ver_dec(v1,v2) {
  80 # compares version numbers as decimal floats
  81         while (match(v1,/[0-9][a-zA-Z]/))
  82                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  83         while (match(v2,/[0-9][a-zA-Z]/))
  84                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  85         sub("^0*","",v1)
  86         sub("^0*","",v2)
  87         if (DEBUG) print "v1 == " v1
  88         if (DEBUG) print "v2 == " v2
  89         count=split(v1,v1a,"\.")
  90         count2=split(v2,v2a,"\.")
  91
  92         if (count<count2) mincount=count
  93         else mincount=count2
  94
  95         for (i=1; i<=mincount; i++) {
  96                 if (v1a[i]=="") v1a[i]=0
  97                 if (v2a[i]=="") v2a[i]=0
  98                 if (DEBUG) print "i == " i
  99                 if (DEBUG) print "v1[i] == " v1a[i]
 100                 if (DEBUG) print "v2[i] == " v2a[i]
 101                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 102                         if (i==2) {
 103                                 if (0+("." v2a[i])>0+("." v1a[i]))
 104                                         return 1
 105                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 106                                         return 0
 107                         } else {
 108                                 if (length(v2a[i])>length(v1a[i]))
 109                                         return 1
 110                                 else if (v2a[i]>v1a[i])
 111                                         return 1
 112                                 else if (length(v1a[i])>length(v2a[i]))
 113                                         return 0
 114                                 else if (v1a[i]>v2a[i])
 115                                         return 0
 116                         }
 117                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 118                         if (v2a[i]>v1a[i])
 119                                 return 1
 120                         else if (v1a[i]>v2a[i])
 121                                 return 0
 122                 } else if (ispre(v1a[i]) == 1)
 123                         return 1
 124                 else
 125                         return 0
 126         }
 127         if ((count2==mincount)&&(count!=count2)) {
 128                 for (i=count2+1; i<=count; i++)
 129                         if (ispre(v1a[i]) == 1)
 130                                 return 1
 131                 return 0
 132         } else if (count!=count2) {
 133                 for (i=count+1; i<=count2; i++)
 134                         if (ispre(v2a[i]) == 1)
 135                                 return 0
 136                 return 1
 137         }
 138         return 0
 139 }
 140
 141 function get_links(url, errno,link,oneline,retval,odp,tmpfile) {
 142 # get all <A HREF=..> tags from specified URL
 143         "mktemp /tmp/XXXXXX" | getline tmpfile
 144         close("mktemp /tmp/XXXXXX")
 145
 146         if (url ~ /^http:\/\/(download|dl).(sf|sourceforge).net\//) {
 147                 gsub("^http://(download|dl).(sf|sourceforge).net/", "", url)
 148                 url = "http://prdownloads.sourceforge.net/" substr(url, 1, 1) "/" substr(url, 1, 2) "/" url
 149                 if (DEBUG) print "sf url, mungled url to: " url
 150         }
 151
 152         if (DEBUG) print "Retrieving: " url
 153         errno=system("wget -O - \"" url "\" -t 3 -T 300 --passive-ftp > " tmpfile " 2>/dev/null" )
 154
 155         if (errno==0) {
 156                 while (getline oneline < tmpfile)
 157                         odp=(odp " " oneline)
 158                 if ( DEBUG ) print "Response: " odp
 159         }
 160
 161         close(tmpfile)
 162         system("rm -f " tmpfile)
 163         urldir=url;
 164         sub(/[^\/]+$/,"",urldir)
 165         if ( errno==0) {
 166                 while ((tolower(odp) ~ /<frame[ \t]/)||(tolower(odp) ~ /href=/)) {
 167                         if (tolower(odp) ~ /<frame[ \t]/) {
 168                                 match(tolower(odp),/<frame[ \t][^>]*>/)
 169                                 ramka=substr(odp,RSTART,RLENGTH)
 170                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 171                                 sub(/[sS][rR][cC]=[ \t]*/,"src=",ramka);
 172                                 match(ramka,/src="[^"]+"/)
 173                                 newurl=substr(ramka,RSTART+5,RLENGTH-6)
 174                                 if (DEBUG) print "Frame: " newurl
 175                                 if (newurl !~ /\//) {
 176                                         newurl=(urldir newurl)
 177                                         if (DEBUG) print "Frame->: " newurl
 178                                 }
 179                                 retval=(retval " " get_links(newurl))
 180                         } else if (tolower(odp) ~ /href=[ \t]*"[^"]*"/) {
 181                                 sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 182                                 match(odp,/href="[^"]*"/)
 183                                 link=substr(odp,RSTART,RLENGTH)
 184                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 185                                 link=substr(link,7,length(link)-7)
 186                                 retval=(retval " " link)
 187                                 if (DEBUG) print "href(\"\"): " link
 188                         } else if (tolower(odp) ~ /href=[ \t]*'[^']*'/) {
 189                                 sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 190                                 match(odp,/href='[^']*'/)
 191                                 link=substr(odp,RSTART,RLENGTH)
 192                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 193                                 link=substr(link,7,length(link)-7)
 194                                 retval=(retval " " link)
 195                                 if (DEBUG) print "href(''): " link
 196                         } else if (tolower(odp) ~ /href=[ \t]*[^ \t>]*/) {
 197                                 sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 198                                 match(odp,/href=[^ \t>]*/)
 199                                 link=substr(odp,RSTART,RLENGTH)
 200                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 201                                 link=substr(link,6,length(link)-5)
 202                                 retval=(retval " " link)
 203                                 if (DEBUG) print "href(): " link
 204                         } else {
 205                                 retval=(retval " INTERNAL_ERROR")
 206                                 break
 207                         }
 208                 }
 209         } else {
 210                 retval=("WGET ERROR: " errno)
 211         }
 212
 213
 214         if (DEBUG) print "Returning: " retval
 215         return retval
 216 }
 217
 218 function subst_defines(var,defs) {
 219 # substitute all possible RPM macros
 220         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 221                 oldvar=var
 222                 for (j in defs) {
 223                         gsub("%{" j "}", defs[j], var)
 224                         gsub("%" j , defs[j], var)
 225                 }
 226                 if (var==oldvar) {
 227                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 228                         return var
 229                 }
 230         }
 231         return var
 232 }
 233
 234 function find_mirror(url) {
 235
 236         while (succ = (getline line < "mirrors")) {
 237             if (succ==-1) { return url }
 238                 nf=split(line,fields,"|")
 239                 if (nf>1){
 240                         origin=fields[1]
 241                         mirror=fields[2]
 242                         mname=fields[3]
 243                         prefix=substr(url,1,length(origin))
 244                         if (prefix==origin){
 245                                 if ( DEBUG ) print "Mirror fount at " mname
 246                                 close("mirrors")
 247                                 return mirror substr(url,length(origin)+1)
 248                         }
 249                 }
 250         }
 251
 252         return url
 253 }
 254
 255 function process_source(number,lurl,name,version) {
 256 # fetches file list, and compares version numbers
 257         if ( DEBUG ) print "Processing " lurl
 258
 259         if ( index(lurl,version)==0 ) {
 260                 if (DEBUG) print "There is no version number."
 261                 return 0
 262         }
 263
 264         sub("://",":",lurl)
 265         sub("/",":/",lurl)
 266         gsub("[^/]*$",":&",lurl)
 267         split(lurl,url,":")
 268         acc=url[1]
 269         host=url[2]
 270         dir=url[3]
 271         filename=url[4]
 272
 273         if (index(dir,version)) {
 274                 dir=substr(dir,1,index(dir,version)-1)
 275                 sub("[^/]*$","",dir)
 276                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 277                 if ( DEBUG ) print "Will check a directory: " dir
 278                 if ( DEBUG ) print "and a file: " filename
 279         }
 280
 281         filenameexp=filename
 282         gsub("\+","\\+",filenameexp)
 283         sub(version,"[A-Za-z0-9.]+",filenameexp)
 284         gsub("\.","\\.",filenameexp)
 285         if ( DEBUG ) print "Expression: " filenameexp
 286         match(filename,version)
 287         prever=substr(filename,1,RSTART-1)
 288         postver=substr(filename,RSTART+RLENGTH)
 289         if ( DEBUG ) print "Before number: " prever
 290         if ( DEBUG ) print "and after: " postver
 291         newurl=find_mirror(acc "://" host dir)
 292         #print acc "://" host dir
 293         #newurl=url[1]"://"url[2]url[3]url[4]
 294         #newurl=acc "://" host dir filename
 295         if ( DEBUG ) print "Looking at " newurl
 296
 297         references=0
 298         finished=0
 299         oldversion=version
 300         odp=get_links(newurl)
 301         if( odp ~ "ERROR: ") {
 302                 print name "(" number ") " odp
 303         } else {
 304                 if (DEBUG) print "WebPage downloaded"
 305                 c=split(odp,linki)
 306                 for (nr=1; nr<=c; nr++) {
 307                         addr=linki[nr]
 308                         if (DEBUG) print "Found link: " addr
 309                         if ((addr ~ filenameexp) && !(addr ~ "[-_.0-9A-Za-z~]" filenameexp)) {
 310                                 match(addr,filenameexp)
 311                                 newfilename=substr(addr,RSTART,RLENGTH)
 312                                 if (DEBUG) print "Hipotetical new: " newfilename
 313                                 newfilename=fixedsub(prever,"",newfilename)
 314                                 newfilename=fixedsub(postver,"",newfilename)
 315                                 if (DEBUG) print "Version: " newfilename
 316                                 if (newfilename ~ /\.(pkg|bin|binary|built)$/) continue
 317                                 if (NUMERIC) {
 318                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 319                                                 if (DEBUG) print "Yes, there is new one"
 320                                                 version=newfilename
 321                                                 finished=1
 322                                         }
 323                                 } else if ( compare_ver(version, newfilename)==1 ) {
 324                                         if (DEBUG) print "Yes, there is new one"
 325                                         version=newfilename
 326                                         finished=1
 327                                 }
 328                         }
 329                 }
 330                 if (finished==0)
 331                         print name "(" number ") seems ok: " oldversion
 332                 else
 333                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 334         }
 335 }
 336
 337 function process_data(name,ver,rel,src) {
 338 # this function checks if substitutions were valid, and if true:
 339 # processes each URL and tries to get current file list
 340         for (i in src) {
 341                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 342                         if ( DEBUG ) print "Source: " src[i]
 343                         process_source(i,src[i],name,ver)
 344                 } else {
 345                         print FNAME ":" i ": niemozliwe podstawienie: " src[i]
 346                 }
 347         }
 348 }
 349
 350 BEGIN {
 351         # if U want to use DEBUG, run script with "-v DEBUG=1"
 352         # or uncomment the line below
 353         # DEBUG = 1
 354
 355         errno=system("wget --help > /dev/null 2>&1")
 356         if (errno) {
 357                 print "No wget installed!"
 358                 exit 1
 359         }
 360         if (ARGC>=3 && ARGV[2]=="-n") {
 361                 NUMERIC=1
 362                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 363                 ARGC=ARGC-1
 364         }
 365 }
 366
 367 FNR==1 {
 368         if ( ARGIND != 1 ) {
 369                 process_data(NAME,VER,REL,SRC)
 370                 NAME="" ; VER="" ; REL=""
 371                 for (i in DEFS) delete DEFS[i]
 372                 for (i in SRC) delete SRC[i]
 373         }
 374         FNAME=FILENAME
 375 }
 376
 377 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 378 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 379 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 380 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 381 /^[Ss]ource[0-9]*:/ { if (/(ftp|http):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 382 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 383
 384 END {
 385         process_data(NAME,VER,REL,SRC)
 386 }