pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2010 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17 # - support debian/watch http://wiki.debian.org/debian/watch/
  18
  19
  20 function d(s) {
  21         if (!DEBUG) {
  22                 return
  23         }
  24
  25 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  26         print s >> "/dev/stderr"
  27 }
  28
  29 function fixedsub(s1,s2,t,      ind) {
  30 # substitutes fixed strings (not regexps)
  31         if (ind = index(t,s1)) {
  32                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  33         }
  34         return t
  35 }
  36
  37 function ispre(s) {
  38         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  39                 d("pre-version")
  40                 return 1
  41         } else {
  42                 return 0
  43         }
  44 }
  45
  46 function compare_ver(v1,v2) {
  47 # compares version numbers
  48         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  49                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  50         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  51                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  52         sub("^0*","",v1)
  53         sub("^0*","",v2)
  54         gsub("\.0*",".",v1)
  55         gsub("\.0*",".",v2)
  56         d("v1 == " v1)
  57         d("v2 == " v2)
  58         count=split(v1,v1a,"\.")
  59         count2=split(v2,v2a,"\.")
  60
  61         if (count<count2) mincount=count
  62         else mincount=count2
  63
  64         for (i=1; i<=mincount; i++) {
  65                 if (v1a[i]=="") v1a[i]=0
  66                 if (v2a[i]=="") v2a[i]=0
  67                 d("i == " i)
  68                 d("v1[i] == " v1a[i])
  69                 d("v2[i] == " v2a[i])
  70                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  71                         if (length(v2a[i])>length(v1a[i]))
  72                                 return 1
  73                         else if (v2a[i]>v1a[i])
  74                                 return 1
  75                         else if (length(v1a[i])>length(v2a[i]))
  76                                 return 0
  77                         else if (v1a[i]>v2a[i])
  78                                 return 0
  79                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  80                         if (v2a[i]>v1a[i])
  81                                 return 1
  82                         else if (v1a[i]>v2a[i])
  83                                 return 0
  84                 } else if (ispre(v1a[i]) == 1)
  85                         return 1
  86                 else
  87                         return 0
  88         }
  89         if ((count2==mincount)&&(count!=count2)) {
  90                 for (i=count2+1; i<=count; i++)
  91                         if (ispre(v1a[i]) == 1)
  92                                 return 1
  93                 return 0
  94         } else if (count!=count2) {
  95                 for (i=count+1; i<=count2; i++)
  96                         if (ispre(v2a[i]) == 1)
  97                                 return 0
  98                 return 1
  99         }
 100         return 0
 101 }
 102
 103 function compare_ver_dec(v1,v2) {
 104 # compares version numbers as decimal floats
 105         while (match(v1,/[0-9][a-zA-Z]/))
 106                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 107         while (match(v2,/[0-9][a-zA-Z]/))
 108                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 109         sub("^0*","",v1)
 110         sub("^0*","",v2)
 111         d("v1 == " v1)
 112         d("v2 == " v2)
 113         count=split(v1,v1a,"\.")
 114         count2=split(v2,v2a,"\.")
 115
 116         if (count<count2) mincount=count
 117         else mincount=count2
 118
 119         for (i=1; i<=mincount; i++) {
 120                 if (v1a[i]=="") v1a[i]=0
 121                 if (v2a[i]=="") v2a[i]=0
 122                 d("i == " i)
 123                 d("v1[i] == " v1a[i])
 124                 d("v2[i] == " v2a[i])
 125                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 126                         if (i==2) {
 127                                 if (0+("." v2a[i])>0+("." v1a[i]))
 128                                         return 1
 129                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 130                                         return 0
 131                         } else {
 132                                 if (length(v2a[i])>length(v1a[i]))
 133                                         return 1
 134                                 else if (v2a[i]>v1a[i])
 135                                         return 1
 136                                 else if (length(v1a[i])>length(v2a[i]))
 137                                         return 0
 138                                 else if (v1a[i]>v2a[i])
 139                                         return 0
 140                         }
 141                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 142                         if (v2a[i]>v1a[i])
 143                                 return 1
 144                         else if (v1a[i]>v2a[i])
 145                                 return 0
 146                 } else if (ispre(v1a[i]) == 1)
 147                         return 1
 148                 else
 149                         return 0
 150         }
 151         if ((count2==mincount)&&(count!=count2)) {
 152                 for (i=count2+1; i<=count; i++)
 153                         if (ispre(v1a[i]) == 1)
 154                                 return 1
 155                 return 0
 156         } else if (count!=count2) {
 157                 for (i=count+1; i<=count2; i++)
 158                         if (ispre(v2a[i]) == 1)
 159                                 return 0
 160                 return 1
 161         }
 162         return 0
 163 }
 164
 165 function link_seen(link) {
 166         for (seenlink in frameseen) {
 167                 if (seenlink == link) {
 168                         d("Link: [" link "] seen already, skipping...")
 169                         return 1
 170                 }
 171         }
 172         frameseen[link]=1
 173         return 0
 174 }
 175
 176 function mktemp(   _cmd, _tmpfile) {
 177         _cmd = "mktemp /tmp/XXXXXX"
 178         _cmd | getline _tmpfile
 179         close(_cmd)
 180         return _tmpfile
 181 }
 182
 183 # fix link to artificial one that will be recognized rest of this script
 184 function postfix_link(url, link,   oldlink) {
 185         oldlink = link
 186         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 187                 gsub(".*\/tarball\/", "", link)
 188                 link = link ".tar.gz"
 189         }
 190         if (oldlink != link) {
 191                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 192         }
 193         return link
 194 }
 195
 196 # use perl HTML::TreeBuilder module to extract links from html
 197 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 198 function extract_links_cmd(tmpfile) {
 199         return "perl -MHTML::TreeBuilder -e ' \
 200         my $content = join q//, <>; \
 201         my $root = new HTML::TreeBuilder; \
 202         $root->parse($content); \
 203         \
 204         my %links = (); \
 205         for (@{$root->extract_links(qw(a iframe))}) { \
 206                 my($link, $element, $attr, $tag) = @$_; \
 207                 $links{$link} = $tag; \
 208         } \
 209         \
 210         while (my($link, $tag) = each %links) { \
 211                 print $tag, q/ /, $link, $/; \
 212         } \
 213         ' " tmpfile
 214 }
 215
 216 # get all <A HREF=..> tags from specified URL
 217 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 218
 219         wholeerr=""
 220
 221         tmpfile = mktemp()
 222         tmpfileerr = mktemp()
 223
 224         if (url ~ /^http:\/\/(download|downloads|dl)\.(sf|sourceforge)\.net\//) {
 225                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 226                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 227                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 228                 gsub("^http://downloads\.(sf|sourceforge)\.net/project/", "", url)
 229
 230                 gsub("/.*", "", url)
 231                 url = "http://sourceforge.net/projects/" url "/files/"
 232                 d("sf url, mungled url to: " url)
 233         }
 234
 235         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 236                 gsub("^http://", "", url)
 237                 gsub("\..*", "", url)
 238                 url = "http://code.google.com/p/" url "/downloads/list"
 239                 d("googlecode url, mungled url to: " url)
 240         }
 241
 242         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 243                 gsub("-.*", "", filename)
 244                 url = "http://pecl.php.net/package/" filename
 245                 d("pecl.php.net url, mungled url to: " url)
 246         }
 247
 248         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 249                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 250                  d("mysql 5.1 url, mungled url to: " url)
 251         }
 252
 253         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 254                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 255                 gsub("\/.*/", "", url)
 256                 url = "https://code.launchpad.net/" url "/+download"
 257                 d("main launchpad url, mungled url to: " url)
 258         }
 259
 260         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 261                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 262                 gsub("\/.*/", "", url)
 263                 url = "https://edge.launchpad.net/" url "/+download"
 264                 d("edge launchpad url, mungled url to: " url)
 265         }
 266
 267         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 268                 gsub("\/tarball\/.*", "/downloads", url)
 269                 d("github tarball url, mungled url to: " url)
 270         }
 271
 272         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 273                 gsub("\/snapshot\/.*", "/", url)
 274                 d("cgit snapshot tarball url, mungled url to: " url)
 275         }
 276
 277         d("Retrieving: " url)
 278         cmd = "wget --user-agent \"Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6\" -nv -O - \"" url "\" -t 2 -T 45 --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 279         d("Execute: " cmd)
 280         errno = system(cmd)
 281         d("Execute done")
 282
 283         if (errno != 0) {
 284                 d("Reading failure response...")
 285                 wholeerr = ""
 286                 while (getline oneline < tmpfileerr)
 287                         wholeerr = (wholeerr " " oneline)
 288                 d("Error Response: " wholeerr)
 289
 290                 system("rm -f " tmpfile)
 291                 system("rm -f " tmpfileerr)
 292                 retval = ("WGET ERROR: " errno ": " wholeerr)
 293                 return retval
 294         }
 295         system("rm -f " tmpfileerr)
 296
 297         urldir = url;
 298         sub(/[^\/]+$/, "", urldir)
 299
 300 if (USE_PERL) {
 301         cmd = extract_links_cmd(tmpfile)
 302         while (cmd | getline) {
 303                 tag = $1
 304                 link = substr($0, length(tag) + 2)
 305
 306                 if (tag == "iframe") {
 307                         d("Frame: " link)
 308                         if (url !~ /\//) {
 309                                 link = (urldir link)
 310                                 d("Frame->: " link)
 311                         }
 312
 313                         if (link_seen(link)) {
 314                                 continue
 315                         }
 316                         retval = (retval " " get_links(link))
 317                 }
 318
 319                 if (link_seen(link)) {
 320                         continue
 321                 }
 322
 323                 retval = (retval " " link)
 324                 d("href(): " link)
 325         }
 326         close(cmd)
 327         system("rm -f " tmpfile)
 328
 329         d("Returning: [" retval "]")
 330         return retval
 331 }
 332
 333         wholeodp = ""
 334         d("Reading success response...")
 335         while (getline oneline < tmpfile) {
 336                 wholeodp = (wholeodp " " oneline)
 337 #               d("Response: " wholeodp)
 338         }
 339         d("Reponse read done...")
 340         system("rm -f " tmpfile)
 341
 342         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 343                 d("Processing links...")
 344                 odp = substr(wholeodp,RSTART,RLENGTH);
 345                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 346
 347                 lowerodp = tolower(odp);
 348                 if (lowerodp ~ /<frame[ \t]/) {
 349                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 350                         match(odp, /src="[^"]+"/)
 351                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 352                         d("Frame: " newurl)
 353                         if (newurl !~ /\//) {
 354                                 newurl=(urldir newurl)
 355                                 d("Frame->: " newurl)
 356                         }
 357
 358                         if (link_seen(newurl)) {
 359                                 newurl = ""
 360                                 continue
 361                         }
 362
 363                         retval = (retval " " get_links(newurl))
 364                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 365                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 366                         match(odp,/href="[^"]*"/)
 367                         link=substr(odp,RSTART,RLENGTH)
 368                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 369                         link=substr(link,7,length(link)-7)
 370                         link=postfix_link(url, link)
 371
 372                         if (link_seen(link)) {
 373                                 link=""
 374                                 continue
 375                         }
 376
 377                         retval = (retval " " link)
 378                         d("href(\"\"): " link)
 379                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 380                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 381                         match(odp,/href='[^']*'/)
 382                         link=substr(odp,RSTART,RLENGTH)
 383                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 384                         link=substr(link,7,length(link)-7)
 385                         link=postfix_link(url, link)
 386
 387                         if (link_seen(link)) {
 388                                 link=""
 389                                 continue
 390                         }
 391
 392                         retval = (retval " " link)
 393                         d("href(''): " link)
 394                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 395                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 396                         match(odp,/href=[^ \t>]*/)
 397                         link=substr(odp,RSTART,RLENGTH)
 398                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 399                         link=substr(link,6,length(link)-5)
 400
 401                         if (link_seen(link)) {
 402                                 link=""
 403                                 continue
 404                         }
 405
 406                         retval = (retval " " link)
 407                         d("href(): " link)
 408                 } else {
 409                         # <a ...> but not href - skip
 410                         d("skipping <a > without href: " odp)
 411                 }
 412         }
 413
 414         d("Returning: [" retval "]")
 415         return retval
 416 }
 417
 418 function subst_defines(var,defs) {
 419 # substitute all possible RPM macros
 420         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 421                 oldvar=var
 422                 for (j in defs) {
 423                         gsub("%{" j "}", defs[j], var)
 424                         gsub("%" j , defs[j], var)
 425                 }
 426                 if (var==oldvar) {
 427                         if (DEBUG) {
 428                                 for (i in defs) {
 429                                         d(i " == " defs[i])
 430                                 }
 431                         }
 432                         return var
 433                 }
 434         }
 435         return var
 436 }
 437
 438 function find_mirror(url) {
 439
 440         while (succ = (getline line < "mirrors")) {
 441             if (succ==-1) { return url }
 442                 nf=split(line,fields,"|")
 443                 if (nf>1){
 444                         origin=fields[1]
 445                         mirror=fields[2]
 446                         mname=fields[3]
 447                         prefix=substr(url,1,length(origin))
 448                         if (prefix==origin){
 449                                 d("Mirror fount at " mname)
 450                                 close("mirrors")
 451                                 return mirror substr(url,length(origin)+1)
 452                         }
 453                 }
 454         }
 455
 456         return url
 457 }
 458
 459 function process_source(number,lurl,name,version) {
 460 # fetches file list, and compares version numbers
 461         d("Processing " lurl)
 462
 463         if ( index(lurl,version)==0 ) {
 464                 d("There is no version number.")
 465                 return 0
 466         }
 467
 468         sub("://",":",lurl)
 469         sub("/",":/",lurl)
 470         gsub("[^/]*$",":&",lurl)
 471         split(lurl,url,":")
 472         acc=url[1]
 473         host=url[2]
 474         dir=url[3]
 475         filename=url[4]
 476
 477         if (index(dir,version)) {
 478                 # directory name as version maching mode:
 479                 # if /something/version/name-version.tarball then check
 480                 # in /something/ looking for newer directory
 481                 dir=substr(dir,1,index(dir,version)-1)
 482                 sub("[^/]*$","",dir)
 483                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 484         }
 485
 486         d("Will check a directory: " dir)
 487         d("and a file: " filename)
 488
 489         filenameexp=filename
 490         gsub("[+]","\\+",filenameexp)
 491         sub(version,"[A-Za-z0-9.]+",filenameexp)
 492         gsub("[.]","\\.",filenameexp)
 493         d("Expression: " filenameexp)
 494         match(filename,version)
 495         prever=substr(filename,1,RSTART-1)
 496         postver=substr(filename,RSTART+RLENGTH)
 497         d("Before number: " prever)
 498         d("and after: " postver)
 499         newurl=find_mirror(acc "://" host dir)
 500         #print acc "://" host dir
 501         #newurl=url[1]"://"url[2]url[3]url[4]
 502         #newurl=acc "://" host dir filename
 503         d("Looking at " newurl)
 504
 505         references=0
 506         finished=0
 507         oldversion=version
 508         odp = get_links(newurl, filename)
 509         if( odp ~ "ERROR: ") {
 510                 print name "(" number ") " odp
 511         } else {
 512                 d("WebPage downloaded")
 513                 c=split(odp,linki)
 514                 for (nr=1; nr<=c; nr++) {
 515                         addr=linki[nr]
 516
 517                         d("Found link: " addr)
 518
 519                         # github has very different tarball links that clash with this safe check
 520                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 521                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 522                                         continue
 523                                 }
 524                         }
 525
 526                         if (addr ~ filenameexp) {
 527                                 match(addr,filenameexp)
 528                                 newfilename=substr(addr,RSTART,RLENGTH)
 529                                 d("Hypothetical new: " newfilename)
 530                                 newfilename=fixedsub(prever,"",newfilename)
 531                                 newfilename=fixedsub(postver,"",newfilename)
 532                                 d("Version: " newfilename)
 533                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 534                                 # strip ending (happens when in directiory name as version matching mode)
 535                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 536                                 if (NUMERIC) {
 537                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 538                                                 d("Yes, there is new one")
 539                                                 version=newfilename
 540                                                 finished=1
 541                                         }
 542                                 } else if ( compare_ver(version, newfilename)==1 ) {
 543                                         d("Yes, there is new one")
 544                                         version=newfilename
 545                                         finished=1
 546                                 }
 547                         }
 548                 }
 549                 if (finished==0)
 550                         print name "(" number ") seems ok: " oldversion
 551                 else
 552                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 553         }
 554 }
 555
 556 function rss_upgrade(name, ver, url, regex, cmd, nver) {
 557         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 558         cmd = "wget -q -O - " url " | sed -nre '" regex "' | head -n1"
 559
 560         d("rss_upgrade_cmd: " cmd)
 561         cmd | getline nver
 562         close(cmd)
 563
 564         if (compare_ver(ver, nver)) {
 565                 print name " [OLD] " ver " [NEW] " nver
 566         } else {
 567                 print name " seems ok: " ver
 568         }
 569 }
 570
 571 # check for ZF upgrade from rss
 572 function zf_upgrade(name, ver) {
 573         rss_upgrade(name, ver, \
 574                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 575                 "Zend Framework ([^\\s]+) Released" \
 576         );
 577 }
 578
 579 function hudson_upgrade(name, ver) {
 580         rss_upgrade(name, ver, \
 581                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 582                 "Hudson ([0-9.]+) released" \
 583         );
 584 }
 585
 586 # upgrade check for pear package using PEAR CLI
 587 function pear_upgrade(name, ver,    pname, pearcmd, nver) {
 588         pname = name;
 589         sub(/^php-pear-/, "", pname);
 590
 591         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 592         d("pearcmd: " pearcmd)
 593         pearcmd | getline nver
 594         close(pearcmd)
 595
 596         if (compare_ver(ver, nver)) {
 597                 print name " [OLD] " ver " [NEW] " nver
 598         } else {
 599                 print name " seems ok: " ver
 600         }
 601
 602         return
 603 }
 604
 605 function vim_upgrade(name, ver,     mver, nver, vimcmd) {
 606         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 607         mver = substr(ver, 0, 4)
 608         vimcmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/"mver"/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 609         d("vimcmd: " vimcmd)
 610         vimcmd | getline nver
 611         close(vimcmd)
 612
 613         if (compare_ver(ver, nver)) {
 614                 print name " [OLD] " ver " [NEW] " nver
 615         } else {
 616                 print name " seems ok: " ver
 617         }
 618 }
 619
 620 function process_data(name,ver,rel,src) {
 621         if (name ~ /^php-pear-/) {
 622                 return pear_upgrade(name, ver);
 623         }
 624         if (name == "ZendFramework") {
 625                 return zf_upgrade(name, ver);
 626         }
 627         if (name == "hudson") {
 628                 return hudson_upgrade(name, ver);
 629         }
 630         if (name == "vim") {
 631                 return vim_upgrade(name, ver);
 632         }
 633
 634 # this function checks if substitutions were valid, and if true:
 635 # processes each URL and tries to get current file list
 636         for (i in src) {
 637                 if ( src[i] ~ /%{nil}/ ) {
 638                         gsub(/\%\{nil\}/, "", src[i])
 639                 }
 640                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 641                         d("Source: " src[i])
 642                         process_source(i,src[i],name,ver)
 643                 } else {
 644                         print FNAME ":" i ": impossible substitution: " src[i]
 645                 }
 646         }
 647 }
 648
 649 BEGIN {
 650         # if U want to use DEBUG, run script with "-v DEBUG=1"
 651         # or uncomment the line below
 652         # DEBUG = 1
 653
 654         errno=system("wget --help > /dev/null 2>&1")
 655         if (errno) {
 656                 print "No wget installed!"
 657                 exit 1
 658         }
 659         if (ARGC>=3 && ARGV[2]=="-n") {
 660                 NUMERIC=1
 661                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 662                 ARGC=ARGC-1
 663         }
 664 }
 665
 666 FNR==1 {
 667         if ( ARGIND != 1 ) {
 668                 # clean frameseen for each ARG
 669                 for (i in frameseen) {
 670                         delete frameseen[i]
 671                 }
 672                 frameseen[0] = 1
 673
 674                 process_data(NAME,VER,REL,SRC)
 675                 NAME="" ; VER="" ; REL=""
 676                 for (i in DEFS) delete DEFS[i]
 677                 for (i in SRC) delete SRC[i]
 678         }
 679         FNAME=FILENAME
 680         DEFS["_alt_kernel"]=""
 681         DEFS["20"]="\\ "
 682 }
 683
 684 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 685 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 686 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 687 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 688 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 689 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 690
 691 END {
 692         process_data(NAME,VER,REL,SRC)
 693 }