pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|downloads|dl)\.(sf|sourceforge)\.net\//) {
 236                 newurl = url
 237                 # http://dl.sourceforge.net/threestore/
 238                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 239                 gsub("^http://(download|downloads|dl)\.(sf|sourceforge)\.net/", "", newurl)
 240                 gsub("^project/", "", newurl)
 241                 gsub("/.*", "", newurl)
 242                 newurl = sf_url(newurl)
 243                 if (newurl ~ /^http/) {
 244                         url = newurl
 245                         d("sf url, mungled url to: " url)
 246                 }
 247
 248         } else if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 249                 gsub("^http://", "", url)
 250                 gsub("\..*", "", url)
 251                 url = "http://code.google.com/p/" url "/downloads/list"
 252                 d("googlecode url, mungled url to: " url)
 253
 254         } else if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 255                 gsub("-.*", "", filename)
 256                 url = "http://pecl.php.net/package/" filename
 257                 d("pecl.php.net url, mungled url to: " url)
 258
 259         } else if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 260                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 261                 d("mysql 5.1 url, mungled url to: " url)
 262
 263         } else if (url ~ /^(http|https):\/\/launchpad\.net\/(.*)\//) {
 264                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 265                 gsub("\/.*/", "", url)
 266                 url = "https://code.launchpad.net/" url "/+download"
 267                 d("main launchpad url, mungled url to: " url)
 268
 269         } else if (url ~ /^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 270                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 271                 gsub("\/.*/", "", url)
 272                 url = "https://edge.launchpad.net/" url "/+download"
 273                 d("edge launchpad url, mungled url to: " url)
 274
 275         } else if (url ~ /^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 276                 gsub("\/tarball\/.*", "/downloads", url)
 277                 d("github tarball url, mungled url to: " url)
 278
 279         } else if (url ~ /^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 280                 gsub("\/archive\/.*", "/tags", url)
 281                 d("github archive url, mungled url to: " url)
 282
 283         } else if (url ~ /^(http|https):\/\/bitbucket.org\/.*\/get\/.*/) {
 284                 # https://bitbucket.org/logilab/pylint/get/tip.tar.bz2 -> https://bitbucket.org/logilab/pylint/downloads
 285                 gsub("\/get\/.*", "/downloads", url)
 286                 d("github bitbucket url, mungled url to: " url)
 287
 288         } else if (url ~ /^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 289                 gsub("\/snapshot\/.*", "/", url)
 290                 d("cgit snapshot tarball url, mungled url to: " url)
 291
 292         } else if (url ~ /^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 293                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 294                 d("aquamaniac.de tarball url, mungled url to: " url)
 295
 296         } else if (url ~ /^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 297                 url = "http://www.process-one.net/en/ejabberd/archive/"
 298                 d("ejabberd tarball url, mungled url to: " url)
 299
 300         } else if (url ~ /^(http|https):\/\/llvm.org\/releases\//) {
 301                 url = "http://llvm.org/releases/download.html"
 302                 d("llvm tarball url, mungled url to: " url)
 303
 304         } else if (url ~ /^(http|https):\/\/download\.owncloud\.org\/community\//) {
 305                 url = "http://owncloud.org/changelog/"
 306                 d("owncloud tarball url, mungled url to: " url)
 307
 308         } else if (url ~ /^(http|https):\/\/hackage\.haskell\.org\/packages\/archive\//) {
 309                 gsub("\/packages\/archive","/package",url)
 310                 d("hackage haskell tarball url, mungled url to: " url)
 311
 312         } else if (url ~ /^http:\/\/www.taskwarrior.org\/download\//) {
 313                 url = "http://taskwarrior.org/projects/taskwarrior/wiki/Download"
 314                 d("taskwarrior tarball url, mungled url to: " url)
 315         } else if (url ~/^http:\/\/www.rarlab.com\/rar\// && filename ~ /^unrarsrc/) {
 316                 url = "http://www.rarlab.com/rar_add.htm"
 317                 d("unrar tarball url, mungled url to: " url)
 318         } else if (url ~/^http:\/\/www.rarlab.com\/rar\//) {
 319                 url = "http://www.rarlab.com/download.htm"
 320                 d("rar tarball url, mungled url to: " url)
 321         }
 322
 323         d("Retrieving: " url)
 324         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 325         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 326         d("Execute: " cmd)
 327         errno = system(cmd)
 328         d("Execute done")
 329
 330         if (errno != 0) {
 331                 d("Reading failure response...")
 332                 wholeerr = ""
 333                 while (getline oneline < tmpfileerr)
 334                         wholeerr = (wholeerr " " oneline)
 335                 d("Error Response: " wholeerr)
 336
 337                 system("rm -f " tmpfile)
 338                 system("rm -f " tmpfileerr)
 339                 retval = ("WGET ERROR: " errno ": " wholeerr)
 340                 return retval
 341         }
 342         system("rm -f " tmpfileerr)
 343
 344         urldir = url;
 345         sub(/[^\/]+$/, "", urldir)
 346
 347 if (USE_PERL) {
 348         cmd = extract_links_cmd(tmpfile)
 349         while (cmd | getline) {
 350                 tag = $1
 351                 link = substr($0, length(tag) + 2)
 352
 353                 if (tag == "iframe") {
 354                         d("Frame: " link)
 355                         if (url !~ /\//) {
 356                                 link = (urldir link)
 357                                 d("Frame->: " link)
 358                         }
 359
 360                         if (link_seen(link)) {
 361                                 continue
 362                         }
 363                         retval = (retval " " get_links(link))
 364                 }
 365
 366                 if (link_seen(link)) {
 367                         continue
 368                 }
 369
 370                 retval = (retval " " link)
 371                 d("href(): " link)
 372         }
 373         close(cmd)
 374         system("rm -f " tmpfile)
 375
 376         d("Returning: [" retval "]")
 377         return retval
 378 }
 379
 380         wholeodp = ""
 381         d("Reading success response...")
 382         while (getline oneline < tmpfile) {
 383                 wholeodp = (wholeodp " " oneline)
 384 #               d("Response: " wholeodp)
 385         }
 386         d("Reponse read done...")
 387         system("rm -f " tmpfile)
 388
 389         # MATCH one of these:
 390         #while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 391         #while (match(wholeodp, /<link>[^<]*<\/link>/) > 0) {
 392
 393         while (match(wholeodp, /(<link>[^<]*<\/link>|<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>)/) > 0) {
 394                 d("Processing links...")
 395                 odp = substr(wholeodp,RSTART,RLENGTH);
 396                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 397
 398                 lowerodp = tolower(odp);
 399                 if (lowerodp ~ /<frame[ \t]/) {
 400                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 401                         match(odp, /src="[^"]+"/)
 402                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 403                         d("Frame: " newurl)
 404                         if (newurl !~ /\//) {
 405                                 newurl=(urldir newurl)
 406                                 d("Frame->: " newurl)
 407                         }
 408
 409                         if (link_seen(newurl)) {
 410                                 newurl = ""
 411                                 continue
 412                         }
 413
 414                         retval = (retval " " get_links(newurl))
 415                         d("href('condition1': " newurl)
 416                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 417                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 418                         match(odp,/href="[^"]*"/)
 419                         link=substr(odp,RSTART,RLENGTH)
 420                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 421                         link=substr(link,7,length(link)-7)
 422                         link=postfix_link(url, link)
 423
 424                         if (link_seen(link)) {
 425                                 link=""
 426                                 continue
 427                         }
 428
 429                         # link ends with at least 2 digit version
 430                         mlink = ""
 431                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 432                                 mlink = get_links(link)
 433
 434                         retval = (retval " " link " " mlink)
 435                         d("href('condition2'): " link)
 436                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 437                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 438                         match(odp,/href='[^']*'/)
 439                         link=substr(odp,RSTART,RLENGTH)
 440                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 441                         link=substr(link,7,length(link)-7)
 442                         link=postfix_link(url, link)
 443
 444                         if (link_seen(link)) {
 445                                 link=""
 446                                 continue
 447                         }
 448
 449                         retval = (retval " " link)
 450                         d("href('condition3'): " link)
 451                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 452                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 453                         match(odp,/href=[^ \t>]*/)
 454                         link=substr(odp,RSTART,RLENGTH)
 455                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 456                         link=substr(link,6,length(link)-5)
 457
 458                         if (link_seen(link)) {
 459                                 link=""
 460                                 continue
 461                         }
 462
 463                         retval = (retval " " link)
 464                         d("href('condition4'): " link)
 465                 } else if (lowerodp ~ /<link>/) {
 466                         link=lowerodp
 467                         sub("/<link>/", link)
 468                         sub("/\/download<\/link>/", link)
 469
 470                         if (link_seen(link)) {
 471                                 link=""
 472                                 continue
 473                         }
 474
 475                         retval = (retval " " link)
 476                         d("href('condition5'): " link)
 477                 } else {
 478                         # <a ...> but not href - skip
 479                         d("skipping <a > without href: " odp)
 480                 }
 481         }
 482
 483         d("Returning: [" retval "]")
 484         return retval
 485 }
 486
 487 function subst_defines(var,defs) {
 488 # substitute all possible RPM macros
 489         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 490                 oldvar=var
 491                 for (j in defs) {
 492                         gsub("%{" j "}", defs[j], var)
 493                         gsub("%" j , defs[j], var)
 494                 }
 495                 if (var==oldvar) {
 496                         if (DEBUG) {
 497                                 for (i in defs) {
 498                                         d(i " == " defs[i])
 499                                 }
 500                         }
 501                         return var
 502                 }
 503         }
 504         return var
 505 }
 506
 507 function find_mirror(url) {
 508
 509         while (succ = (getline line < "mirrors")) {
 510             if (succ==-1) { return url }
 511                 nf=split(line,fields,"|")
 512                 if (nf>1){
 513                         origin=fields[1]
 514                         mirror=fields[2]
 515                         mname=fields[3]
 516                         prefix=substr(url,1,length(origin))
 517                         if (prefix==origin){
 518                                 d("Mirror found at " mname)
 519                                 close("mirrors")
 520                                 return mirror substr(url,length(origin)+1)
 521                         }
 522                 }
 523         }
 524
 525         return url
 526 }
 527
 528 # fetches file list, and compares version numbers
 529 function process_source(number, lurl, name, version) {
 530         d("Processing " lurl)
 531
 532         if (index(lurl, version) == 0) {
 533                 d("There is no version number ["version"] in ["lurl"]")
 534                 return 0
 535         }
 536
 537         sub("://",":",lurl)
 538         sub("/",":/",lurl)
 539         gsub("[^/]*$",":&",lurl)
 540         split(lurl,url,":")
 541         acc=url[1]
 542         host=url[2]
 543         dir=url[3]
 544         filename=url[4]
 545
 546         if (index(dir,version)) {
 547                 # directory name as version maching mode:
 548                 # if /something/version/name-version.tarball then check
 549                 # in /something/ looking for newer directory
 550                 dir=substr(dir,1,index(dir,version)-1)
 551                 sub("[^/]*$","",dir)
 552                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 553         }
 554
 555         d("Will check a directory: " dir)
 556         d("and a file: " filename)
 557
 558         filenameexp=filename
 559         gsub("[+]","\\+",filenameexp)
 560         sub(version,"[A-Za-z0-9.]+",filenameexp)
 561         gsub("[.]","\\.",filenameexp)
 562         sub("\.(bz|bz2|gz|lzma|xz|zip)$",".(bz|bz2|gz|lzma|xz|zip)",filenameexp)
 563         d("Expression: " filenameexp)
 564         match(filename,version)
 565         prever=substr(filename,1,RSTART-1)
 566         postver=substr(filename,RSTART+RLENGTH)
 567         d("Before number: " prever)
 568         d("and after: " postver)
 569         newurl=find_mirror(acc "://" host dir)
 570         #print acc "://" host dir
 571         #newurl=url[1]"://"url[2]url[3]url[4]
 572         #newurl=acc "://" host dir filename
 573         d("Looking at " newurl)
 574
 575         references=0
 576         finished=0
 577         oldversion=version
 578         odp = get_links(newurl, filename)
 579         if( odp ~ "ERROR: ") {
 580                 print name "(" number ") " odp
 581         } else {
 582                 d("WebPage downloaded")
 583                 c=split(odp,linki)
 584                 for (nr=1; nr<=c; nr++) {
 585                         addr=linki[nr]
 586
 587                         d("Found link: " addr)
 588
 589                         # github has very different tarball links that clash with this safe check
 590                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 591                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 592                                         continue
 593                                 }
 594                         }
 595
 596                         if (addr ~ filenameexp) {
 597                                 match(addr,filenameexp)
 598                                 newfilename=substr(addr,RSTART,RLENGTH)
 599                                 d("Hypothetical new: " newfilename)
 600                                 newfilename=fixedsub(prever,"",newfilename)
 601                                 newfilename=fixedsub(postver,"",newfilename)
 602                                 d("Version: " newfilename)
 603                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 604                                 # strip ending (happens when in directiory name as version matching mode)
 605                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 606                                 if (NUMERIC) {
 607                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 608                                                 d("Yes, there is new one")
 609                                                 version=newfilename
 610                                                 finished=1
 611                                         }
 612                                 } else if ( compare_ver(version, newfilename)==1 ) {
 613                                         d("Yes, there is new one")
 614                                         version=newfilename
 615                                         finished=1
 616                                 }
 617                         }
 618                 }
 619                 if (finished == 0)
 620                         print name "(" number ") seems ok: " oldversion
 621                 else
 622                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 623         }
 624 }
 625
 626 function sf_url(sf_project) {
 627         sf_url_new = ""
 628         sf_idurl="http://sourceforge.net/api/project/name/" sf_project "/json"
 629         cmd = "wget -t 2 -T 45 -q -O - " sf_idurl " |  awk -F: '/\"id\":/ { gsub(\",\", \"\", $2); print $2 } '"
 630         d("sf_url_cmd: " cmd)
 631         cmd | getline sf_id
 632         d("sf_url_id: " sf_id)
 633         if (sf_id ~ /^[0-9]+$/) {
 634                 sf_url_new = "http://sourceforge.net/api/file/index/project-id/" sf_id "/mtime/desc/limit/20/rss"
 635                 d("sf_url_new: " sf_url_new)
 636         }
 637         return sf_url_new
 638 }
 639
 640 function rss_upgrade(name, ver, url, regex, cmd) {
 641         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 642         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 643
 644         d("rss_upgrade_cmd: " cmd)
 645         cmd | getline ver
 646         close(cmd)
 647
 648         return ver
 649 }
 650
 651 # check for ZF upgrade from rss
 652 function zf_upgrade(name, ver) {
 653         return rss_upgrade(name, ver, \
 654                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 655                 "Zend Framework ([^\\s]+) Released" \
 656         );
 657 }
 658
 659 function hudson_upgrade(name, ver) {
 660         return rss_upgrade(name, ver, \
 661                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 662                 "Hudson ([0-9.]+) released" \
 663         );
 664 }
 665
 666 # upgrade check for pear package using PEAR CLI
 667 function pear_upgrade(name, ver,    cmd) {
 668         sub(/^php-pear-/, "", name);
 669
 670         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 671         d("PEAR: " cmd)
 672         cmd | getline ver
 673         close(cmd)
 674
 675         return ver
 676 }
 677
 678 function vim_upgrade(name, ver,     cmd) {
 679         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 680         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 681         d("VIM: " cmd)
 682         cmd | getline ver
 683         close(cmd)
 684         return ver
 685 }
 686
 687 function nodejs_upgrade(name, ver,   cmd) {
 688         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 689         if (DEFS["pkg"]) {
 690                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 691         } else {
 692                 cmd = "npm info " name " dist-tags.latest"
 693         }
 694         cmd | getline ver
 695         close(cmd)
 696
 697         return ver
 698 }
 699
 700 function rubygem_upgrade(name, ver,   cmd, pkg) {
 701         if (DEFS["gem_name"]) {
 702                 pkg = DEFS["gem_name"];
 703
 704         } else if (DEFS["gemname"]) {
 705                 pkg = DEFS["gemname"];
 706
 707         } else if (DEFS["pkgname"]) {
 708                 pkg = DEFS["pkgname"];
 709
 710         } else {
 711                 pkg = name;
 712                 gsub(/^ruby-/, "", pkg);
 713         }
 714
 715         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); print v}'"
 716         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 717         cmd | getline ver
 718
 719         close(cmd)
 720
 721         return ver
 722 }
 723
 724 function google_linux_repo(name, ver, reponame,   cmd, sourceurl) {
 725         sourceurl = "http://dl.google.com/linux/" reponame "/rpm/stable/x86_64/repodata/primary.xml.gz"
 726         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>" name "-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 727         d("google repo: " cmd);
 728         cmd | getline ver
 729         close(cmd)
 730
 731         return ver
 732 }
 733
 734 function jenkins_upgrade(name, ver, urls,  url, i, c, chunks, nver) {
 735         for (i in urls) {
 736                 url = urls[i]
 737                 # http://mirrors.jenkins-ci.org/war-stable/1.509.1/jenkins.war?/jenkins-1.509.1.war
 738                 gsub("/" ver "/jenkins.war\?/jenkins-" ver ".war", "/", url);
 739                 c = split(get_links(url), chunks, "/")
 740                 # new version is second one from the bottom
 741                 nver = chunks[c - 2]
 742                 gsub(/ /, "", nver)
 743                 return nver;
 744         }
 745 }
 746
 747 function process_data(name, ver, rel,     src, nver, i) {
 748         if (name ~ /^php-pear-/) {
 749                 nver = pear_upgrade(name, ver);
 750         } else if (name == "ZendFramework") {
 751                 nver = zf_upgrade(name, ver);
 752         } else if (name == "hudson") {
 753                 nver = hudson_upgrade(name, ver);
 754         } else if (name == "vim") {
 755                 nver = vim_upgrade(name, ver);
 756         } else if (name == "google-chrome") {
 757                 nver = google_linux_repo(name, ver, "chrome");
 758         } else if (name == "google-talkplugin") {
 759                 nver = google_linux_repo(name, ver, "talkplugin");
 760         } else if (name ~ "^nodejs-") {
 761                 nver = nodejs_upgrade(name, ver);
 762         } else if (name ~ "^ruby-" || name == "chef") {
 763                 nver = rubygem_upgrade(name, ver);
 764         } else if (name ~ "jenkins") {
 765                 nver = jenkins_upgrade(name, ver, src);
 766         }
 767
 768         if (nver) {
 769                 if (compare_ver(ver, nver)) {
 770                         print name " [OLD] " ver " [NEW] " nver
 771                 } else {
 772                         print name " seems ok: " ver
 773                 }
 774                 return;
 775         }
 776
 777         if (name == "xulrunner") {
 778                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 779                 d("package xulrunner, change version to firefox ["ver"]")
 780         }
 781
 782 # this function checks if substitutions were valid, and if true:
 783 # processes each URL and tries to get current file list
 784         for (i in src) {
 785                 if (src[i] ~ /%{nil}/) {
 786                         gsub(/\%\{nil\}/, "", src[i])
 787                 }
 788                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 789                         d("Source: " src[i])
 790                         process_source(i, src[i], name, ver)
 791                 } else {
 792                         print FNAME ":" i ": impossible substitution: " src[i]
 793                 }
 794         }
 795 }
 796
 797 BEGIN {
 798         # if you want to use DEBUG, run script with "-v DEBUG=1"
 799         # or uncomment the line below
 800         # DEBUG = 1
 801
 802         errno=system("wget --help > /dev/null 2>&1")
 803         if (errno && errno != 3) {
 804                 print "No wget installed!"
 805                 exit 1
 806         }
 807         if (ARGC>=3 && ARGV[2]=="-n") {
 808                 NUMERIC=1
 809                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 810                 ARGC=ARGC-1
 811         }
 812 }
 813
 814 FNR==1 {
 815         if ( ARGIND != 1 ) {
 816                 # clean frameseen for each ARG
 817                 for (i in frameseen) {
 818                         delete frameseen[i]
 819                 }
 820                 frameseen[0] = 1
 821
 822                 process_data(NAME,VER,REL,SRC)
 823                 NAME="" ; VER="" ; REL=""
 824                 for (i in DEFS) delete DEFS[i]
 825                 for (i in SRC) delete SRC[i]
 826         }
 827         FNAME=FILENAME
 828         DEFS["_alt_kernel"]=""
 829         DEFS["20"]="\\ "
 830         DEFS["nil"]=""
 831 }
 832
 833 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 834 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 835 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 836 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 837 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 838 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 839
 840 END {
 841         process_data(NAME,VER,REL,SRC)
 842 }