adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # Adapter adapts .spec files for PLD Linux.
   4 #
   5 # Copyright (C) 1999-2008 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Michał Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Jakub Bogusz <qboosh@pld-linux.org>
  13 #       Elan Ruusamäe <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - really long sourceX make preamble sorting totally fcked up (try snake.spec r1.1)
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27 # - it should change: /%source([0-9]+)/i to %{SOURCE\1}
  28 # - extra quote on LDFLAGS line: https://bugs.launchpad.net/pld-linux/+bug/385836
  29 # - %{with_foo:%attr()...} gets converted to %attr() %{with_foo:...} [vlc.spec]
  30 # - 'R: foo ' (with traliling space) gets coverted to "R: foo\nR: " [vlc.spec @ 1.199 ]
  31
  32 BEGIN {
  33         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  34         SECTIONS = "^%(" RPM_SECTIONS ")"
  35
  36         RCSID = "$Id$"
  37         rev = RCSID # TODO: parse from RCSID
  38         VERSION = "0.35/" rev
  39
  40         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests|Auto(Req|Prov))"
  41
  42         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  43
  44         preamble = 1    # Is it part of preamble? Default - yes
  45         boc = 4                 # Beginning of %changelog
  46         bod = 0                 # Beginning of %description
  47         tw = 70                 # Descriptions width
  48
  49         b_idx = 0               # index of BR/R arrays
  50         BR_count = 0    # number of additional BuildRequires
  51
  52         # If variable removed, then 1 (for removing it from export)
  53         removed["LDFLAGS"] = 0
  54         removed["CFLAGS"] = 0
  55         removed["CXXFLAGS"] = 0
  56
  57         # If 1, we are inside of comment block (started with /^#%/)
  58         comment_block = 0
  59
  60         import_rpm_macros()
  61
  62         packages_dir = topdir "/packages"
  63         groups_file = packages_dir "/rpm.groups"
  64
  65         system("cd "packages_dir"; [ -f rpm.groups ] || cvs up rpm.groups > /dev/null")
  66         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  67
  68         # Temporary file for changelog section
  69         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  70 }
  71
  72 # There should be a comment with CVS keywords on the first line of file.
  73 FNR == 1 {
  74         if (!/# \$Revision:/)   # If this line is already OK?
  75                 print "# $" "Revision:$, " "$" "Date:$" # No
  76         else {
  77                 print $0                                # Yes
  78                 next            # It is enough for first line
  79         }
  80 }
  81
  82 # If the latest line matched /%files/
  83 defattr == 1 {
  84         if (ENVIRON["SKIP_DEFATTR"] != 1) {
  85                 if ($0 !~ /defattr/) {  # If no %defattr
  86                         print "%defattr(644,root,root,755)"     # Add it
  87                 } else {
  88                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  89                 }
  90         }
  91         defattr = 0
  92 }
  93
  94 function b_makekey(a, b,        s) {
  95         s = a "" b;
  96         # kill bcond
  97         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
  98
  99         # kill commented out items
 100         gsub(/^#[ \t]*/, "", s);
 101
 102         # force order
 103         gsub(/^Summary\(/, "11Summary(", s);
 104         gsub(/^Summary/, "10Summary", s);
 105
 106         gsub(/^Name/, "2Name", s);
 107         gsub(/^Version/, "3Version", s);
 108         gsub(/^Release/, "4Release", s);
 109         gsub(/^Epoch/, "5Epoch", s);
 110         gsub(/^License/, "5License", s);
 111         gsub(/^Group/, "6Group", s);
 112         gsub(/^URL/, "7URL", s);
 113
 114         gsub(/^BuildRequires/, "B1BuildRequires", s);
 115         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 116
 117         gsub(/^Suggests/, "X1Suggests", s);
 118         gsub(/^Provides/, "X2Provides", s);
 119         gsub(/^Obsoletes/, "X3Obsoletes", s);
 120         gsub(/^Conflicts/, "X4Conflicts", s);
 121         gsub(/^BuildArch/, "X5BuildArch", s);
 122         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 123         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 124         gsub(/^BuildRoot/, "X9BuildRoot", s);
 125
 126         gsub(/^AutoProv/, "Xx1AutoProv", s);
 127         gsub(/^AutoReq/, "Xx2AutoReq", s);
 128
 129 #       printf("%s -> %s\n", a""b, s);
 130         return s;
 131 }
 132
 133 # Comments
 134 /^#/ && (description == 0) {
 135         if (/This file does not like to be adapterized!/) {
 136                 print                   # print this message
 137                 while (getline)         # print the rest of spec as it is
 138                         print
 139                 do_not_touch_anything = 1 # do not touch anything in END()
 140                 exit 0
 141         }
 142
 143         # Generally, comments are printed without touching
 144         sub(/[ \t]+$/, "")
 145
 146         if (/#[ \t]*Source.*md5/) {
 147                 if (usedigest == 1) {
 148                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 149                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 150                 }
 151                 print $0
 152                 next
 153         }
 154 }
 155
 156 /^%define/ {
 157         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 158         if ($2 == "_applnkdir") {
 159                 next
 160         }
 161         if ($2 == "date") {
 162                 date = 1
 163                 if (did_files == 0) {
 164                         print "%files"
 165                         print ""
 166                         did_files = 1
 167                 }
 168         }
 169
 170         # Do not add %define of _prefix if it already is.
 171         if ($2 ~ /^_prefix/) {
 172                 sub("^"prefix, $3, bindir)
 173                 sub("^"prefix, $3, sbindir)
 174                 sub("^"prefix, $3, libdir)
 175                 sub("^"prefix, $3, datadir)
 176                 sub("^"prefix, $3, includedir)
 177                 prefix = $3
 178         }
 179
 180         if ($2 ~ /_bindir/ && !/_sbindir/)
 181                 bindir = $3
 182         if ($2 ~ /_sbindir/)
 183                 sbindir = $3
 184         if ($2 ~ /_libdir/) {
 185                 if ($3 ~ /^%\(/) {
 186                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 187                         libdir = "%%%%%%%%%%%%%%"
 188                 } else {
 189                         libdir = $3
 190                 }
 191         }
 192         if ($2 ~ /_sysconfdir/) {
 193                 if ($3 ~ /^%\(/) {
 194                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 195                         sysconfdir = "%%%%%%%%%%%%%%"
 196                 } else {
 197                         sysconfdir = $3
 198                 }
 199         }
 200         if ($2 ~ /_datadir/) {
 201                 if ($3 ~ /^%\(/) {
 202                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 203                         datadir = "%%%%%%%%%%%%%%"
 204                 } else {
 205                         datadir = $3
 206                 }
 207         }
 208         if ($2 ~ /_includedir/)
 209                 includedir = $3
 210         if ($2 ~ /_mandir/)
 211                 mandir = $3
 212         if ($2 ~ /_infodir/)
 213                 infodir = $3
 214         if ($2 ~ /_docdir/)
 215                 docdir = $3
 216
 217         # version related macros
 218         if ($2 ~ /^_beta$/)
 219                 _beta = $3
 220         if ($2 ~ /^_rc$/)
 221                 _rc = $3
 222         if ($2 ~ /^_pre$/)
 223                 _pre = $3
 224         if ($2 ~ /^_snap$/)
 225                 _snap = $3
 226         if ($2 ~ /^subver$/)
 227                 subver = $3
 228
 229         # these are used usually when adapterizing external spec
 230         if ($2 ~ /^name$/)
 231                 name = $3
 232         if ($2 ~ /^version$/)
 233                 version = $3
 234         if ($2 ~ /^release$/)
 235                 release = $3
 236
 237         if ($2 ~ /^mod_name$/)
 238                 mod_name = $3
 239
 240         sub(/[ \t]+$/, "");
 241         # do nothing further, otherwise adapter thinks we're at preamble
 242         print
 243         next
 244 }
 245
 246 # Obsolete
 247 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 248         next
 249 }
 250
 251 ################
 252 # %description #
 253 ################
 254 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 255         preamble = 0
 256
 257         if (/^%description/) {
 258                 bod++
 259                 format_line = ""
 260                 format_indent = -1
 261         }
 262
 263         # Format description
 264         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 265                 if (/^[ \t]*$/) {
 266                         format_flush(format_line, format_indent)
 267                         print ""
 268                         format_line = ""
 269                         format_indent = -1
 270                 } else if (/^[ \t]*[-\*][ \t]*/) {
 271                         format_flush(format_line, format_indent)
 272                         match($0, /^[ \t]*/)
 273                         format_indent = RLENGTH
 274                         match($0, /^[ \t]*[-\*][ \t]/)
 275                         format_line = substr($0, RLENGTH)
 276                 } else
 277                         format_line = format_line " " $0
 278                 next
 279         }
 280
 281         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 282                 if (NF > 3 && $2 == "-l") {
 283                         ll = $1
 284                         for (i = 4; i <= NF; i++)
 285                                 ll = ll " " $i
 286                         $0 = ll " -l " $3
 287                 }
 288                 format_flush(format_line, format_indent)
 289                 if (bod == 2) {
 290                         bod = 1
 291                         description = 1
 292                 } else {
 293                         bod = 0
 294                         description = 0
 295                 }
 296         } else
 297                 description = 1
 298 }
 299
 300 #########
 301 # %prep #
 302 #########
 303 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 304         preamble = 0
 305         did_prep = 1
 306
 307         use_macros()
 308
 309         # Add '-q' to %setup
 310         if (/^%setup/ && !/-q/) {
 311                 sub(/^%setup/, "%setup -q")
 312         }
 313
 314         if (/^%setup/ && name != "setup") {
 315                 $0 = fixedsub(name, "%{name}", $0);
 316                 $0 = fixedsub(version, "%{version}", $0);
 317                 if (_beta) {
 318                         $0 = fixedsub(_beta, "%{_beta}", $0);
 319                 }
 320                 if (_rc) {
 321                         $0 = fixedsub(_rc, "%{_rc}", $0);
 322                 }
 323                 if (_pre) {
 324                         $0 = fixedsub(_pre, "%{_pre}", $0);
 325                 }
 326                 if (_snap) {
 327                         $0 = fixedsub(_snap, "%{_snap}", $0);
 328                 }
 329                 if (subver) {
 330                         $0 = fixedsub(subver, "%{subver}", $0);
 331                 }
 332         }
 333
 334         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 335                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 336         }
 337         sub("^%patch ", "%patch0 ");
 338
 339         # invalid in %prep
 340         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 341 }
 342
 343 ##########
 344 # %build #
 345 ##########
 346 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 347         preamble = 0
 348
 349         if (did_prep == 0) {
 350                 print "%prep"
 351                 print ""
 352                 did_prep = 1
 353         }
 354
 355         use_macros()
 356         use_tabs()
 357
 358         if (/^automake$/)
 359                 sub(/$/, " -a -c")
 360
 361         if (/LDFLAGS/) {
 362                 if (/LDFLAGS="-s"/) {
 363                         removed["LDFLAGS"] = 1
 364                         next
 365                 } else {
 366                         split($0, tmp, "LDFLAGS=")
 367                         count = split(tmp[2], flags, "\"")
 368                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 369                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 370                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 371                                 for (i = 2; i < count; i++)
 372                                         $0 = $0 flags[i] "\""
 373                         }
 374                 }
 375         }
 376
 377         if (/CFLAGS=/)
 378                 if (cflags("CFLAGS") == 0)
 379                         next
 380
 381         if (/CXXFLAGS=/)
 382                 if (cflags("CXXFLAGS") == 0)
 383                         next
 384
 385         if (/^export /) {
 386                 if (removed["LDFLAGS"])
 387                         sub(" LDFLAGS", "")
 388                 if (removed["CFLAGS"])
 389                         sub(" CFLAGS", "")
 390                 if (removed["CXXFLAGS"])
 391                         sub(" CXXFLAGS", "")
 392                 # Is there still something?
 393                 if (/^export[ ]*$/)
 394                         next
 395         }
 396
 397         # quote CC
 398         if (/CC=%{__cc} /) {
 399                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 400         }
 401
 402         # use PLD Linux macros
 403         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 404         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 405         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 406         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 407         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 408         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 409         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 410         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 411
 412         sub(/^aclocal$/, "%{__aclocal}");
 413         sub(/^autoheader$/, "%{__autoheader}");
 414         sub(/^autoconf$/, "%{__autoconf}");
 415         sub(/^automake$/, "%{__automake}");
 416         sub(/^libtoolize$/, "%{__libtoolize}");
 417
 418         # atrpms
 419         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 420         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 421 }
 422
 423 ##########
 424 # %clean #
 425 ##########
 426 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 427         did_clean = 1
 428
 429         use_macros()
 430 }
 431
 432 ############
 433 # %install #
 434 ############
 435 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 436
 437         preamble = 0
 438
 439         # foreign rpms
 440         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 441         sub("%buildroot", "$RPM_BUILD_ROOT");
 442         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 443
 444         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 445                 did_rmroot=1
 446                 print "rm -rf $RPM_BUILD_ROOT"
 447                 next
 448         }
 449
 450         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 451                 print "rm -rf $RPM_BUILD_ROOT"
 452                 did_rmroot=1
 453         }
 454
 455         if (tmpdir) {
 456                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 457                 gsub(buildroot, "$RPM_BUILD_ROOT")
 458         }
 459
 460         if (!/%{_lib}/) {
 461                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 462         }
 463
 464         use_macros()
 465
 466         # 'install -d' instead 'mkdir -p'
 467         if (/mkdir -p/)
 468                 sub(/mkdir -p/, "install -d")
 469
 470         # cp -a already implies cp -r
 471         sub(/^cp -ar/, "cp -a")
 472
 473         # No '-u root' or '-g root' for 'install'
 474         if (/^install/ && /-[ug][ \t]*root/)
 475                 gsub(/-[ug][ \t]*root /, "")
 476
 477         if (/^install/ && /-m[ \t]*[0-9]+/)
 478                 gsub(/-m[ \t]*[0-9]+ /, "")
 479
 480         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 481         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 482                 next
 483
 484         # No lines contain 'chmod' if it sets the modes to '644'
 485         if ($1 ~ /chmod/ && $2 ~ /644/)
 486                 next
 487
 488         # atrpms
 489         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 490 }
 491
 492 ##########
 493 # %files #
 494 ##########
 495 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 496         preamble = 0
 497         did_files = 1
 498
 499         if ($0 ~ /^%files/)
 500                 defattr = 1
 501
 502         if (!use_files_macros()) {
 503                 next
 504         }
 505 }
 506
 507 ##############
 508 # %changelog #
 509 ##############
 510 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 511         preamble = 0
 512         has_changelog = 1
 513         skip = 0
 514         # There should be some CVS keywords on the first line of %changelog.
 515         if (boc == 3) {
 516                 if ($0 !~ _cvsmailfeedback) {
 517                         print "* %{date} " _cvsmailfeedback > changelog_file
 518                 } else {
 519                         skip = 1
 520                 }
 521                 boc = 2
 522         }
 523         if (boc == 2 && !skip) {
 524                 if (!/All persons listed below/) {
 525                         printf "All persons listed below can be reached at " > changelog_file
 526                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 527                 } else {
 528                         skip = 1
 529                 }
 530                 boc = 1
 531         }
 532         if (boc == 1 && !skip) {
 533                 if (!/^$/) {
 534                         if (!/\$.*Log:.*\$/) {
 535                                 print "$" "Log:$" > changelog_file
 536                         }
 537                         boc = 0
 538                 }
 539         }
 540         # Define date macro.
 541         if (boc == 4) {
 542                 if (date == 0) {
 543                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 544                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 545                         date = 1
 546                 }
 547                 boc = 3
 548         }
 549
 550         sub(/[ \t]+$/, "");
 551         if (!/^%[a-z]+$/ || /changelog/) {
 552                 # stop changelog if "real" changelog starts
 553                 if (boc == 0 && /^\* /) {
 554                         boc = -1
 555                 }
 556                 if (boc == -1) {
 557                         next;
 558                 }
 559                 print > changelog_file
 560         } else {
 561                 print
 562         }
 563         next
 564 }
 565
 566 ###########
 567 # SCRIPTS #
 568 ###########
 569 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 570         preamble = 0
 571
 572         if (gsub("/usr/sbin/useradd", "%useradd")) {
 573                 sub(" 2> /dev/null \|\| :", "");
 574                 sub(" >/dev/null 2>&1 \|\|:", "");
 575         }
 576
 577         # %useradd and %groupadd may not be wrapped
 578         if (/%(useradd|groupadd).*\\$/) {
 579                 a = $0; getline;
 580                 sub(/^[\s\t]*/, "");
 581                 $0 = substr(a, 1, length(a) - 1) $0;
 582         }
 583         use_script_macros()
 584 }
 585
 586 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 587         preamble = 0
 588         use_macros()
 589 }
 590 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 591         preamble = 0
 592         use_macros()
 593 }
 594 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 595         preamble = 0
 596         use_script_macros()
 597 }
 598 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 599         preamble = 0
 600         use_script_macros()
 601 }
 602 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 603         preamble = 0
 604         use_script_macros()
 605 }
 606 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 607         preamble = 0
 608         use_script_macros()
 609 }
 610 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 611         preamble = 0
 612         use_script_macros()
 613 }
 614 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 615         preamble = 0
 616         use_script_macros()
 617 }
 618 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 619         preamble = 0
 620         use_script_macros()
 621 }
 622 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 623         preamble = 0
 624         use_script_macros()
 625 }
 626
 627 #############
 628 # PREAMBLES #
 629 #############
 630 preamble == 1 {
 631         # There should not be a space after the name of field
 632         # and before the colon.
 633         sub(/[ \t]*:/, ":")
 634
 635         if (/^%perl_module_wo_prefix/) {
 636                 name = $2
 637                 version = $3
 638                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 639         }
 640
 641         field = tolower($1)
 642         fieldnlower = $1
 643         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 644                 sub(/\.$/, "", $0);
 645         }
 646         if (field ~ /group(\([^)]+\)):/)
 647                 next
 648         if (field ~ /group:/) {
 649                 format_preamble()
 650                 group = $0;
 651                 sub(/^[^ \t]*[ \t]*/, "", group);
 652                 group = replace_groupnames(group);
 653                 $0 = "Group:\t\t" group
 654
 655                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 656                         x11 = 1
 657
 658                 byl_plik_z_groupmi = 0
 659                 byl_opis_grupy = 0
 660                 while ((getline linia_grup < groups_file) > 0) {
 661                         byl_plik_z_groupmi = 1
 662                         if (linia_grup == group) {
 663                                 byl_opis_grupy = 1
 664                                 break
 665                         }
 666                 }
 667
 668                 if (!byl_plik_z_groupmi)
 669                         print "######\t\t" groups_file ": no such file"
 670                 else if (!byl_opis_grupy)
 671                         print "######\t\t" "Unknown group!"
 672
 673                 close(groups_file)
 674                 did_groups = 1
 675         }
 676
 677         if (field ~ /prereq:/) {
 678                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 679         }
 680
 681         # split (build)requires, obsoletes on commas
 682         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 683                 value = substr($0, index($0, $2));
 684                 $0 = format_requires($1, value);
 685         }
 686
 687         # BR: tar (and others) is to common (rpm-build requires it)
 688         if (field ~ /^buildrequires:/) {
 689                 l = substr($0, index($0, $2));
 690                 if (l == "awk" ||
 691                         l == "binutils" ||
 692                         l == "bzip2" ||
 693                         l == "cpio" ||
 694                         l == "diffutils" ||
 695                         l == "elfutils" ||
 696                         l == "fileutils" ||
 697                         l == "findutils" ||
 698                         l == "glibc-devel" ||
 699                         l == "grep" ||
 700                         l == "gzip" ||
 701                         l == "make" ||
 702                         l == "patch" ||
 703                         l == "sed" ||
 704                         l == "sh-utils" ||
 705                         l == "tar" ||
 706                         l == "textutils") {
 707                         next
 708                 }
 709
 710                 replace_requires();
 711         }
 712
 713         if (field ~ /^requires:/) {
 714                 replace_requires();
 715         }
 716
 717
 718         # obsolete/unwanted tags
 719         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 720                 next
 721         }
 722
 723         if (field ~ /buildroot:/) {
 724                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 725                 did_build_root = 1
 726         }
 727
 728         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 729         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 730                 $1 = "License:"
 731         }
 732
 733         # ease updating from debian .dsc
 734         if (field ~ /homepage:/) {
 735                 $1 = "URL:"
 736         }
 737
 738         if (field ~ /license:/) {
 739                 l = substr($0, index($0, $2));
 740                 if (l == "Python Software Foundation License") {
 741                         l = "PSF"
 742                 }
 743                 if (l == "Apache License 2.0" || l == "Apache 2.0" || l == "Apache License Version 2.0" || l == "Apache License, Version 2.0" || l == "Apache Software License v2") {
 744                         l = "Apache v2.0"
 745                 }
 746                 if (l == "Apache Group License" || l == "Apache Software License" || l == "Apache License") {
 747                         l = "Apache"
 748                 }
 749                 if (l == "Apache-style License" || l == "Apache-style Software License") {
 750                         l = "Apache-like"
 751                 }
 752                 if (l == "Apache Software License 1.1" || l == "Apache 1.1") {
 753                         l = "Apache v1.1"
 754                 }
 755                 if (l == "GPLv2") {
 756                         l = "GPL v2"
 757                 }
 758                 if (l == "GPLv2+") {
 759                         l = "GPL v2+"
 760                 }
 761                 if (l == "LGPLv2+") {
 762                         l = "LGPL v2+"
 763                 }
 764                 $0 = "License:\t" l;
 765         }
 766
 767
 768         if (field ~ /name:/) {
 769                 if ($2 == "%{name}" && name) {
 770                         $2 = name
 771                 }
 772                 name = $2
 773                 name_seen = 1;
 774         }
 775
 776         if (field ~ /version:/) {
 777                 if ($2 == "%{version}" && version) {
 778                         $2 = version
 779                 }
 780                 version = $2
 781                 version_seen = 1;
 782         }
 783
 784         if (field ~ /release:/) {
 785                 if ($2 == "%{release}" && release) {
 786                         $2 = release
 787                 }
 788                 sub(/%atrelease /, "0.", $0)
 789                 release = $2
 790                 release_seen = 1;
 791         }
 792
 793
 794         if (field ~ /serial:/)
 795                 $1 = "Epoch:"
 796
 797         if (field ~ /home-page:/)
 798                 $1 = "URL:"
 799
 800         # proper caps
 801         if (field ~ /^url:$/)
 802                 $1 = "URL:"
 803
 804         if (field ~ /^description:$/)
 805                 $1 = "\n%description\n"
 806
 807         # Use %{name} and %{version} in the filenames in "Source:"
 808         if (field ~ /^source/ || field ~ /patch/) {
 809                 n = split($2, url, /\//)
 810                 if (url[n] ~ /\.gz$/) {
 811                         url[n+1] = ".gz" url[n+1]
 812                         sub(/\.gz$/,"",url[n])
 813                 }
 814                 if (url[n] ~ /\.zip$/) {
 815                         url[n+1] = ".zip" url[n+1]
 816                         sub(/\.zip$/,"",url[n])
 817                 }
 818                 if (url[n] ~ /\.tar$/) {
 819                         url[n+1] = ".tar" url[n+1]
 820                         sub(/\.tar$/,"",url[n])
 821                 }
 822                 if (url[n] ~ /\.patch$/) {
 823                         url[n+1] = ".patch" url[n+1]
 824                         sub(/\.patch$/,"",url[n])
 825                 }
 826                 if (url[n] ~ /\.bz2$/) {
 827                         url[n+1] = ".bz2" url[n+1]
 828                         sub(/\.bz2$/,"",url[n])
 829                 }
 830                 if (url[n] ~ /\.logrotate$/) {
 831                         url[n+1] = ".logrotate" url[n+1]
 832                         sub(/\.logrotate$/,"",url[n])
 833                 }
 834                 if (url[n] ~ /\.pamd$/) {
 835                         url[n+1] = ".pamd" url[n+1]
 836                         sub(/\.pamd$/,"",url[n])
 837                 }
 838
 839                 # allow %{name} only in last url component
 840                 s = ""
 841                 for (i = 1; i <= n; i++) {
 842                         url[i] = fixedsub("%{name}", name, url[i])
 843                         if (s) {
 844                                 s = s "/" url[i]
 845                         } else {
 846                                 s = url[i]
 847                         }
 848                 }
 849                 $2 = s url[n+1]
 850
 851                 filename = url[n]
 852                 if (name) {
 853                         url[n] = fixedsub(name, "%{name}", url[n])
 854                 }
 855                 if (field ~ /source/) {
 856                         if (version) {
 857                                 url[n] = fixedsub(version, "%{version}", url[n])
 858                         }
 859                         if (_beta) {
 860                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 861                         }
 862                         if (_rc) {
 863                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 864                         }
 865                         if (_pre) {
 866                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 867                         }
 868                         if (_snap) {
 869                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 870                         }
 871                         if (subver) {
 872                                 url[n] = fixedsub(subver, "%{subver}", url[n])
 873                         }
 874                 }
 875                 # assigning to $2 kills preamble formatting
 876                 $2 = fixedsub(filename, url[n], $2)
 877
 878                 $2 = unify_url($2)
 879         }
 880
 881
 882         if (field ~ /^source:/)
 883                 $1 = "Source0:"
 884
 885         if (field ~ /^patch:/)
 886                 $1 = "Patch0:"
 887
 888         kill_preamble_macros();
 889         format_preamble()
 890
 891         if (field ~ /requires/) {
 892                 # atrpms
 893                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 894         }
 895 }
 896
 897 /^%bcond_/ {
 898         # do nothing
 899         print
 900         next
 901 }
 902
 903 # sort BR/R!
 904 #
 905 # NOTES:
 906 # - mixing BR/R and anything else confuses this (all will be sorted together)
 907 #       so don't do that.
 908 # - comments leading the BR/R can not be associated,
 909 #       so don't adapterize when the BR/R are mixed with comments
 910 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 911         if ($1 ~ /Pre[Rr]eq:/) {
 912                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 913         }
 914         if ($1 == "BR:" ) {
 915                 $1 = "BuildRequires:"
 916         }
 917         if ($1 == "R:" ) {
 918                 $1 = "Requires:"
 919         }
 920         format_preamble()
 921 #       kill_preamble_macros(); # breaks tabbing
 922
 923         b_idx++;
 924         l = substr($0, index($0, $2));
 925         b_ktmp = b_makekey($1, l);
 926         b_key[b_idx] = b_ktmp;
 927         b_val[b_ktmp] = $0;
 928
 929         next;
 930 }
 931
 932 preamble == 1 {
 933         if (b_idx > 0) {
 934                 isort(b_key, b_idx);
 935                 for (i = 1; i <= b_idx; i++) {
 936                         v = b_val[b_key[i]];
 937                         sub(/[ \t]+$/, "", v);
 938                         print "" v;
 939                 }
 940                 b_idx = 0
 941         }
 942 }
 943
 944 # main() ;-)
 945 {
 946         preamble = 1
 947
 948         sub(/[ \t]+$/, "")
 949         print
 950
 951         if (name_seen == 0 && name) {
 952                 print "Name:\t\t" name
 953                 name_seen = 1
 954         }
 955
 956         if (version_seen == 0 && version) {
 957                 print "Version:\t" version
 958                 version_seen = 1
 959         }
 960
 961         if (release_seen == 0 && release) {
 962                 print "Release:\t" release
 963                 release_seen = 1
 964         }
 965
 966         if (did_build_root == 0) {
 967 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 968                 did_build_root = 1
 969         }
 970         if (did_groups == 0) {
 971 #               print "Group:\t\tunknown"
 972                 did_groups = 1
 973         }
 974 }
 975
 976
 977 END {
 978         if (do_not_touch_anything)
 979                 exit 0
 980
 981         # TODO: need to output these in proper place
 982         if (BR_count > 0) {
 983                 for (i = 0; i <= BR_count; i++) {
 984                         print BR[i];
 985                 }
 986         }
 987
 988         close(changelog_file)
 989         while ((getline < changelog_file) > 0)
 990                 print
 991         system("rm -f " changelog_file)
 992
 993         if (did_clean == 0) {
 994                 print ""
 995                 print "%clean"
 996                 print "rm -rf $RPM_BUILD_ROOT"
 997         }
 998
 999         if (date == 0) {
1000                 print ""
1001                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1002         }
1003
1004         if (has_changelog == 0) {
1005                 print "%changelog"
1006         }
1007
1008         if (boc > 2) {
1009                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1010         }
1011         if (boc > 1) {
1012                 printf "All persons listed below can be reached at "
1013                 print "<cvs_login>@pld-linux.org\n"
1014         }
1015         if (boc > 0) {
1016                 print "$" "Log:$"
1017         }
1018 }
1019
1020 # substitutes fixed strings (not regexps)
1021 function fixedsub(s1,s2,t, ind) {
1022         if (ind = index(t,s1))
1023                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1024         return t
1025 }
1026
1027 # replace s with s2 if it equals to s1
1028 function replace(s, s1, s2) {
1029         if (s == s1) {
1030                 return s2;
1031         } else {
1032                 return s;
1033         }
1034 }
1035
1036 # There should be one or two tabs after the colon.
1037 function format_preamble()
1038 {
1039         if (/^#/ || /^%bcond_with/) {
1040                 return;
1041         }
1042         sub(/:[ \t]*/, ":")
1043         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1044                 if (RLENGTH < 8) {
1045                         sub(/:/, ":\t\t")
1046                 } else {
1047                         sub(/:/, ":\t")
1048                 }
1049         }
1050 }
1051
1052 # Replace directly specified directories with macros
1053 function use_macros()
1054 {
1055         # -m, --skip-macros, --no-macros -- skip macros subst
1056         if (ENVIRON["SKIP_MACROS"]) {
1057                 return
1058         }
1059
1060         # leave inline sed lines alone
1061         if (/(%{__sed}|sed) -i -e/) {
1062                 return;
1063         }
1064
1065         sub("%{_defaultdocdir}", "%{_docdir}");
1066         sub("%{_bindir}/perl", "%{__perl}");
1067         sub("%{_bindir}/python", "%{__python}");
1068
1069         gsub(infodir, "%{_infodir}")
1070
1071         gsub(perl_sitearch, "%{perl_sitearch}")
1072         gsub(perl_archlib, "%{perl_archlib}")
1073         gsub(perl_privlib, "%{perl_privlib}")
1074         gsub(perl_vendorlib, "%{perl_vendorlib}")
1075         gsub(perl_vendorarch, "%{perl_vendorarch}")
1076         gsub(perl_sitelib, "%{perl_sitelib}")
1077
1078         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1079         gsub(py_sitedir, "%{py_sitedir}")
1080         gsub(py_scriptdir, "%{py_scriptdir}")
1081         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1082         gsub("%{python_sitelib}", "%{py_sitedir}")
1083
1084         gsub(ruby_archdir, "%{ruby_archdir}")
1085         gsub(ruby_ridir, "%{ruby_ridir}")
1086         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1087         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1088         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1089         gsub(ruby_rdocdir, "%{ruby_rdocdir}")
1090
1091         gsub("%{_datadir}/applications", "%{_desktopdir}")
1092         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1093         gsub("%{_datadir}/java", "%{_javadir}")
1094
1095         gsub(libdir, "%{_libdir}")
1096         gsub(javadir, "%{_javadir}")
1097
1098         gsub(bindir, "%{_bindir}")
1099         gsub("%{prefix}/bin", "%{_bindir}")
1100         if (prefix"/bin" == bindir)
1101                 gsub("%{_prefix}/bin", "%{_bindir}")
1102
1103         for (c = 1; c <= NF; c++) {
1104                 if ($c ~ sbindir "/fix-info-dir")
1105                         continue;
1106                 if ($c ~ sbindir "/webapp")
1107                         continue;
1108                 if ($c ~ sbindir "/ldconfig")
1109                         continue;
1110                 if ($c ~ sbindir "/chsh")
1111                         continue;
1112                 if ($c ~ sbindir "/usermod")
1113                         continue;
1114                 if ($c ~ sbindir "/chkconfig")
1115                         continue;
1116                 if ($c ~ sbindir "/installzope(product|3package)")
1117                         continue;
1118                 gsub(sbindir, "%{_sbindir}", $c)
1119         }
1120
1121         gsub("%{prefix}/sbin", "%{_sbindir}")
1122         if (prefix"/sbin" == sbindir) {
1123                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1124         }
1125
1126         for (c = 1; c <= NF; c++) {
1127                 if ($c ~ sysconfdir "/{?cron.")
1128                         continue;
1129                 if ($c ~ sysconfdir "/{?crontab.d")
1130                         continue;
1131                 if ($c ~ sysconfdir "/{?env.d")
1132                         continue;
1133                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1134                         continue;
1135                 if ($c ~ sysconfdir "/{?udev")
1136                         continue;
1137                 if ($c ~ sysconfdir "/{?hotplug")
1138                         continue;
1139                 if ($c ~ sysconfdir "/{?logrotate.d")
1140                         continue;
1141                 if ($c ~ sysconfdir "/{?pam.d")
1142                         continue;
1143                 if ($c ~ sysconfdir "/{?profile.d")
1144                         continue;
1145                 if ($c ~ sysconfdir "/{?rc.d")
1146                         continue;
1147                 if ($c ~ sysconfdir "/{?security")
1148                         continue;
1149                 if ($c ~ sysconfdir "/{?skel")
1150                         continue;
1151                 if ($c ~ sysconfdir "/{?sysconfig")
1152                         continue;
1153                 if ($c ~ sysconfdir "/{?shrc.d")
1154                         continue;
1155                 if ($c ~ sysconfdir "/{?certs")
1156                         continue;
1157                 if ($c ~ sysconfdir "/{?X11")
1158                         continue;
1159                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1160                         continue;
1161                 if ($c ~ sysconfdir "/{?rpm")
1162                         continue;
1163                 if ($c ~ sysconfdir "/{?bash_completion.d")
1164                         continue;
1165                 if ($c ~ sysconfdir "/{?samba")
1166                         continue;
1167                 if ($c ~ sysconfdir "/shells")
1168                         continue;
1169                 if ($c ~ sysconfdir "/ppp")
1170                         continue;
1171                 if ($c ~ sysconfdir "/dbus-1")
1172                         continue;
1173                 if ($c ~ sysconfdir "/tmpwatch")
1174                         continue;
1175                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1176         }
1177
1178         gsub(docdir, "%{_docdir}")
1179
1180         gsub(kdedocdir, "%{_kdedocdir}")
1181
1182         gsub(gtkdocdir, "%{_gtkdocdir}")
1183         gsub("%{_docdir}/gtk-doc/html", "%{_gtkdocdir}")
1184
1185         gsub(php_pear_dir, "%{php_pear_dir}")
1186         gsub(php_data_dir, "%{php_data_dir}")
1187
1188         for (c = 1; c <= NF; c++) {
1189                 if ($c ~ datadir "/automake")
1190                         continue;
1191                 if ($c ~ datadir "/unsermake")
1192                         continue;
1193                 if ($c ~ datadir "/file/magic.mime")
1194                         continue;
1195                 gsub(datadir, "%{_datadir}", $c)
1196         }
1197
1198         gsub("%{prefix}/share", "%{_datadir}")
1199         if (prefix"/share" == datadir)
1200                 gsub("%{_prefix}/share", "%{_datadir}")
1201
1202         # CFLAGS="-I/usr/include/ncurses is usually correct.
1203         if (!/-I\/usr\/include/) {
1204                 gsub(includedir, "%{_includedir}")
1205         }
1206
1207         gsub("%{prefix}/include", "%{_includedir}")
1208         if (prefix"/include" == includedir) {
1209                 gsub("%{_prefix}/include", "%{_includedir}")
1210         }
1211
1212         gsub(mandir, "%{_mandir}")
1213         if ($0 !~ "%{_datadir}/manual") {
1214                 gsub("%{_datadir}/man", "%{_mandir}")
1215         }
1216         gsub("%{_prefix}/share/man", "%{_mandir}")
1217         gsub("%{prefix}/share/man", "%{_mandir}")
1218         gsub("%{prefix}/man", "%{_mandir}")
1219         gsub("%{_prefix}/man", "%{_mandir}")
1220
1221         gsub(infodir, "%{_infodir}")
1222         gsub("%{prefix}/info", "%{_infodir}")
1223         gsub("%{_prefix}/info", "%{_infodir}")
1224
1225         if (prefix !~ "/X11R6") {
1226                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1227         }
1228
1229         gsub(examplesdir, "%{_examplesdir}")
1230
1231         if (prefix != "/") {
1232                 # leave --with-foo=/usr alone
1233                 if ($0 !~ "--with.*=.*" prefix) {
1234                         for (c = 1; c <= NF; c++) {
1235                                 if ($c ~ prefix "/sbin/fix-info-dir")
1236                                         continue;
1237                                 if ($c ~ prefix "/sbin/webapp")
1238                                         continue;
1239                                 if ($c ~ prefix "/sbin/chsh")
1240                                         continue;
1241                                 if ($c ~ prefix "/sbin/usermod")
1242                                         continue;
1243                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1244                                         continue;
1245                                 if ($c ~ prefix "/share/automake")
1246                                         continue;
1247                                 if ($c ~ prefix "/share/unsermake")
1248                                         continue;
1249                                 if ($c ~ prefix "/lib/sendmail")
1250                                         continue;
1251                                 if ($c ~ prefix "/lib/pkgconfig")
1252                                         continue;
1253
1254                                 # CFLAGS="-I/usr..." is usually correct.
1255                                 if (/-I\/usr/)
1256                                         continue;
1257                                 # same for LDFLAGS="-L/usr..."
1258                                 if (/-L\/usr/)
1259                                         continue;
1260
1261                                 gsub(prefix, "%{_prefix}", $c)
1262                         }
1263                 }
1264                 gsub("%{prefix}", "%{_prefix}")
1265         }
1266
1267         # replace back
1268         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1269         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1270
1271         gsub("%{PACKAGE_VERSION}", "%{version}")
1272         gsub("%{PACKAGE_NAME}", "%{name}")
1273
1274         gsub("^make$", "%{__make}")
1275         gsub("^make ", "%{__make} ")
1276         gsub("^gcc ", "%{__cc} ")
1277         gsub("^rm --interactive=never ", "%{__rm} ")
1278
1279         # mandrake specs
1280         gsub("^%make$", "%{__make}")
1281         gsub("^%make ", "%{__make} ")
1282         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1283         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1284         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1285         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1286         gsub("^%{__install}", "install")
1287         gsub("%optflags", "%{rpmcflags}")
1288         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1289
1290         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1291         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1292         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1293         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1294         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1295         $0 = fixedsub("%__install", "install", $0);
1296
1297         # split configure line to multiple lines
1298         if (/%configure / && !/\\$/) {
1299                 $0 = format_configure($0);
1300         }
1301
1302         gsub("%_bindir", "%{_bindir}")
1303         gsub("%_datadir", "%{_datadir}")
1304         gsub("%_iconsdir", "%{_iconsdir}")
1305         gsub("%_sbindir", "%{_sbindir}")
1306         gsub("%_mandir", "%{_mandir}")
1307         gsub("%name", "%{name}")
1308         gsub(/%__rm/, "rm");
1309         gsub(/%__mkdir_p/, "install -d");
1310         gsub(/%__cp/, "cp");
1311         gsub(/%__ln_s/, "ln -s");
1312         gsub(/%__sed/, "%{__sed}");
1313         gsub(/%__cat/, "cat");
1314         gsub(/%__chmod/, "chmod");
1315
1316         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1317         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1318
1319         if (/^ant / || /^%{ant}/) {
1320                 sub(/^ant/, "%ant")
1321                 sub(/^%{ant}/, "%ant")
1322                 add_br("BuildRequires:  jpackage-utils");
1323                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1324         }
1325
1326         $0 = fixedsub("%(%{__cc} -dumpversion)", "%{cc_version}", $0);
1327         $0 = fixedsub("%(%{__cxx} -dumpversion)", "%{cxx_version}", $0);
1328 }
1329
1330 function format_configure(line,         n, a, s) {
1331         n = split(line, a, / /);
1332         s = a[1] " \\\n";
1333         for (i = 2; i <= n; i++) {
1334                 s = s "\t" a[i] " \\\n"
1335         }
1336         return s
1337 }
1338
1339
1340 # insertion sort of A[1..n]
1341 # copied from mawk manual
1342 function isort(A,n,             i,j,hold) {
1343         for (i = 2; i <= n; i++) {
1344                 hold = A[j = i]
1345                 while (A[j-1] > hold) {
1346                         j-- ; A[j+1] = A[j]
1347                 }
1348                 A[j] = hold
1349         }
1350         # sentinel A[0] = "" will be created if needed
1351 }
1352
1353
1354 function use_files_macros(      i, n, t, a, l)
1355 {
1356         use_macros()
1357
1358         # skip comments
1359         if (/^#/) {
1360                 return 1;
1361         }
1362
1363         sub("^%doc %{_mandir}", "%{_mandir}")
1364
1365         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1366         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1367
1368         # uid/gid nobody is not valid in %files
1369         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1370                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1371         }
1372
1373         # s[gu]id programs with globs are evil
1374         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1375                 $0 = $0 " # FIXME no globs for suid/sgid files"
1376         }
1377
1378         # replace back
1379         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1380         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1381         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1382         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1383         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1384         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1385         gsub("%{_sysconfdir}/security", "/etc/security")
1386         gsub("%{_sysconfdir}/skel", "/etc/skel")
1387         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1388         gsub("%{_sysconfdir}/certs", "/etc/certs")
1389         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1390         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1391         gsub("%{_sysconfdir}/pki", "/etc/pki")
1392         gsub("%{_sysconfdir}/tmpwatch", "/etc/tmpwatch")
1393
1394         # /etc/init.d -> /etc/rc.d/init.d
1395         if (!/^\/etc\/init\.d$/) {
1396                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1397         }
1398
1399         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1400                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1401                         $0 = "%attr(754,root,root) " $0
1402                 }
1403                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1404                         gsub("^%attr\\(... *,", "%attr(754,");
1405                 }
1406         }
1407
1408         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1409                 $0 = "%attr(755,root,root) " $0
1410         }
1411
1412         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1413                 $0 = "%attr(755,root,root) " $0
1414         }
1415
1416         # remove attrs from man pages
1417         if (/%{_mandir}/ && /^%attr/) {
1418                 sub("^%attr\\(.*\\) *", "");
1419         }
1420
1421         # /etc/sysconfig files
1422         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1423         # attr not required, allow default 644 attr
1424         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1425                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1426                         gsub("%config", "%config(noreplace)")
1427                 }
1428
1429                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1430                         $NF = "%config(noreplace) " $NF
1431                 }
1432
1433                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1434                         gsub("^%attr\\(... *,", "%attr(640,");
1435                 }
1436
1437                 if (/\/etc\/sysconfig\// && !/%verify/) {
1438                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1439                 }
1440         }
1441
1442         # kill leading zeros
1443         if (/%attr\(0[1-9]/) {
1444                 gsub("%attr\\(0", "%attr(")
1445         }
1446
1447         # kill leading whitespace
1448         gsub(/^ +/, "");
1449
1450         # kill default attrs
1451         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1452         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1453         if (!/%dir/) {
1454                 gsub(/%attr\(644,root,root\) /, "");
1455         }
1456
1457         # sort %verify attrs
1458         if (match($0, /%verify\(not([^)]+)\)/)) {
1459                 t = substr($0, RSTART, RLENGTH)
1460                 # kill commas: %verify(not,md5,size,mtime)
1461                 gsub(/,/, " ", t);
1462
1463                 gsub(/^%verify\(not |\)$/, "", t)
1464                 n = split(t, a, / /)
1465                 isort(a, n)
1466
1467                 s = "%verify(not"
1468                 for (i = 1 ; i <= n; i++) {
1469                         s = s " " a[i]
1470                 }
1471                 s = s ")"
1472
1473                 gsub(/%verify\(not[^)]+\)/, s)
1474         }
1475
1476         if (/%{_mandir}/) {
1477                 gsub("\.gz$", "*")
1478         }
1479
1480         # locale dir and no %lang -> bad
1481         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1482                 $(NF + 1) = "# FIXME consider using %find_lang"
1483         }
1484
1485         # python egg-infos
1486         if (match($0, "^%{py_site(script)?dir}/.+-py"py_ver".egg-info$")) {
1487                 # tests:
1488                 #%{py_sitedir}/*-py2.4.egg-info
1489                 #%{py_sitescriptdir}/GnuPGInterface-%{version}-py2.4.egg-info
1490                 #%{py_sitescriptdir}/python_mpd-%{version}-py2.4.egg-info
1491                 #%{py_sitescriptdir}/mechanize-0.1.6b-py2.4.egg-info
1492
1493                 l = index($0, "/");
1494                 t = substr($0, 0, l);
1495                 s = substr($0, l + 1, RLENGTH - l - length("-py"py_ver".egg-info"));
1496                 if (match(s, "[^-]+$")) {
1497 #printf("s[%s]; start[%d]; length[%d]\n", s, RSTART, RLENGTH);
1498                         if (RSTART > 1) {
1499                                 s = substr(s, 0, RSTART - 1);
1500                         }
1501 #printf("s2[%s]\n", s);
1502                         print "%if \"%{py_ver}\" > \"2.4\""
1503 #print t "/.+.egg-info"
1504                         gsub(t "/.+.egg-info", t "/" s "-*.egg-info");
1505                         print
1506                         print "%endif"
1507                         return 0;
1508                 }
1509         }
1510
1511         # atrpms
1512         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1513         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1514         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1515
1516         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1517         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1518         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1519
1520         gsub("%{_datadir}/applications", "%{_desktopdir}");
1521         gsub("%{_datadir}/icons", "%{_iconsdir}");
1522         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1523         gsub("%{_datadir}/pear", "%{php_pear_dir}");
1524         gsub("%{_datadir}/php", "%{php_data_dir}");
1525
1526         return 1
1527 }
1528
1529 function use_script_macros()
1530 {
1531         if (gsub("/sbin/service", "%service")) {
1532                 sub(" >/dev/null 2>&1 \|\|:", "");
1533                 sub(" 2> /dev/null \|\| :", "");
1534         }
1535 }
1536
1537 function fill(ch, n, i) {
1538         for (i = 0; i < n; i++)
1539                 printf("%c", ch)
1540 }
1541
1542 function format_flush(line, indent, newline, word, first_word) {
1543         first_word = 1
1544         if (format_indent == -1)
1545                 newline = ""
1546         else
1547                 newline = fill(" ", format_indent) "- "
1548
1549         while (match(line, /[^\t ]+/)) {
1550                 word = substr(line, RSTART, RLENGTH)
1551                 if (length(newline) + length(word) + 1 > tw) {
1552                         print newline
1553
1554                         if (format_indent == -1)
1555                                 newline = ""
1556                         else
1557                                 newline = fill(" ", format_indent + 2)
1558                         first_word = 1
1559                 }
1560
1561                 if (first_word) {
1562                         newline = newline word
1563                         first_word = 0
1564                 } else
1565                         newline = newline " " word
1566
1567                 line = substr(line, RSTART + RLENGTH)
1568         }
1569         if (newline ~ /[^\t ]/) {
1570                 print newline
1571         }
1572 }
1573
1574 function cflags(var)
1575 {
1576         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1577                 removed[var] = 1
1578                 return 0
1579         }
1580
1581         if (!/!\?debug/)
1582                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1583         return 1
1584 }
1585
1586 function unify_url(url)
1587 {
1588
1589         # sourceforge urls
1590         # Docs about sourceforge mirror system: http://sourceforge.net/apps/trac/sourceforge/wiki/Mirrors
1591         sub("^http://prdownloads\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1592         sub("^http://download\.sf\.net/", "http://downloads.sourceforge.net/", url)
1593         sub("^http://download\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1594         sub("^http://dl\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1595         sub("^http://.*\.dl\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1596         sub("^http://dl\.sf\.net/", "http://downloads.sourceforge.net/", url)
1597         sub("^http://downloads\.sourceforge\.net/sourceforge/", "http://downloads.sourceforge.net/", url)
1598         # new style urls, strip "files/" between and prepend dl.
1599         if (match(url, "^http://sourceforge.net/projects/[^/]+/files/")) {
1600                 url = substr(url, 1, RLENGTH - length("files/")) substr(url, RSTART + RLENGTH);
1601                 sub("^http://sourceforge.net/projects/", "http://downloads.sourceforge.net/project/", url);
1602         }
1603         if (url ~ /sourceforge.net/) {
1604                 sub("[?&]big_mirror=.*$", "", url);
1605                 sub("[?&]modtime=.*$", "", url);
1606                 sub("[?]use_mirror=.*$", "", url);
1607                 sub("[?]download$", "", url);
1608                 sub("/download$", "", url);
1609         }
1610
1611         sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", url)
1612         sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", url)
1613
1614         # apache urls
1615         sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", url)
1616
1617         # gnu.org
1618         sub("^ftp://ftp.gnu.org/", "http://ftp.gnu.org/", url)
1619         sub("^http://ftp.gnu.org/pub/gnu/", "http://ftp.gnu.org/gnu/", url)
1620
1621         return url
1622 }
1623
1624 function demacroize(str)
1625 {
1626         if (mod_name) {
1627                 sub("%{mod_name}", mod_name, str);
1628         }
1629         if (name) {
1630                 sub("%{name}", name, str);
1631         }
1632         if (version) {
1633                 sub("%{version}", version, str);
1634         }
1635         if (_beta) {
1636                 sub("%{_beta}", _beta, str);
1637         }
1638         if (_rc) {
1639                 sub("%{_rc}", _rc, str);
1640         }
1641         if (_pre) {
1642                 sub("%{_pre}", _pre, str);
1643         }
1644         if (_snap) {
1645                 sub("%{_snap}", _snap, str);
1646         }
1647         if (subver) {
1648                 sub("%{subver}", subver, str);
1649         }
1650         return str;
1651 }
1652
1653 function kill_preamble_macros()
1654 {
1655         if ($1 ~ /^Obsoletes:/) {
1656                 # NB! assigning $2 a value breaks tabbing
1657                 $2 = demacroize($2);
1658         }
1659         if ($1 ~ /^URL:/) {
1660                 # NB! assigning $2 a value breaks tabbing
1661                 $2 = demacroize($2);
1662                 $2 = unify_url($2)
1663         }
1664 }
1665
1666 function get_epoch(pkg, ver,    epoch)
1667 {
1668         return
1669 # should parse the BR lines more adequately:
1670 #       freetype = 2.0.0 -> correct
1671 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1672
1673         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1674         shell | getline epoch;
1675         return epoch;
1676 }
1677
1678 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1679         # skip any formatting for commented out items or some weird macros
1680         if (/^#/ || /%\(/) {
1681                 return tag "\t" value
1682         }
1683         n = split(value, p, / *,? */);
1684         for (i = 1; i <= n; i++) {
1685                 if (p[i+1] ~ /[<=>]/) {
1686                         # add epoch if the version doesn't have it but BuildRequires.txt has
1687                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1688                                 epoch = get_epoch(p[i], p[i+2])
1689                                 if (epoch) {
1690                                         p[i+2] = epoch ":" p[i+2];
1691                                 }
1692                         }
1693                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1694                         i += 2;
1695                 } else {
1696                         deps[ndeps++] = p[i];
1697                 }
1698         }
1699         s = ""
1700         for (i in deps) {
1701                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1702         }
1703         return substr(s, 1, length(s)-1);
1704 }
1705
1706 function use_tabs()
1707 {
1708         # reverse vim: ts=4 sw=4 et
1709         gsub(/    /, "\t");
1710 }
1711
1712 function add_br(br)
1713 {
1714         BR[BR_count++] = br
1715 }
1716
1717 function replace_requires()
1718 {
1719
1720         # jpackages
1721         sub(/^java-devel$/, "jdk", $2);
1722         sub(/^log4j$/, "java-log4j", $2);
1723         sub(/^logging-log4j$/, "java-log4j", $2);
1724         sub(/^jakarta-log4j$/, "java-log4j", $2);
1725         sub(/^oro$/, "java-oro", $2);
1726         sub(/^jakarta-oro$/, "java-oro", $2);
1727         sub(/^jakarta-ant$/, "ant", $2);
1728         sub(/^xerces-j2$/, "java-xerces", $2);
1729         sub(/^xerces-j$/, "java-xerces", $2);
1730         sub(/^ldapjdk$/, "ldapsdk", $2);
1731         sub(/^saxon-scripts$/, "saxon", $2);
1732         sub(/^xalan-j2$/, "java-xalan", $2);
1733         sub(/^xalan-j$/, "java-xalan", $2);
1734         sub(/^gnu-regexp$/, "java-gnu-regexp", $2);
1735         sub(/^gnu.regexp$/, "java-gnu-regexp", $2);
1736         sub(/^jakarta-commons-httpclient$/, "java-commons-httpclient", $2);
1737         sub(/^xml-commons-resolver$/, "java-xml-commons-resolver", $2);
1738         sub(/^axis$/, "java-axis", $2);
1739         sub(/^wsdl4j$/, "java-wsdl4j", $2);
1740         sub(/^uddi4j$/, "java-uddi4j", $2);
1741         sub(/^hamcrest$/, "java-hamcrest", $2);
1742
1743         # redhat virtual
1744         sub(/^tftp-server$/, "tftpdaemon", $2);
1745
1746         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2);
1747         sub(/^chkconfig$/, "/sbin/chkconfig", $2);
1748
1749         # fedora
1750         sub(/^iscsi-initiator-utils$/, "open-iscsi", $2);
1751         sub(/^gnome-python2-extras$/, "python-gnome-extras", $2);
1752         sub(/^gtk2$/, "gtk+2", $2);
1753         sub(/^gtk2-devel$/, "gtk+2-devel", $2);
1754         sub(/^pygtk2-devel$/, "python-pygtk-devel", $2);
1755         sub(/^pygtk2$/, "python-pygtk", $2);
1756         sub(/^qt4-devel$/, "qt4-build", $2);
1757         sub(/^file-devel$/, "libmagic-devel", $2);
1758
1759         # debian
1760         sub(/^libgconf2-dev$/, "GConf2-devel", $2);
1761         sub(/^libglib2.0-dev$/, "glib2-devel", $2);
1762         sub(/^libgtk2.0-dev$/, "gtk+2-devel", $2);
1763         sub(/^libhunspell-dev$/, "hunspell-devel", $2);
1764         sub(/^libpango1.0-dev$/, "pango-devel", $2);
1765         sub(/^libxslt1-dev$/, "libxslt-devel", $2);
1766
1767         replace_php_virtual_deps()
1768 }
1769
1770 # php virtual deps as discussed in devel-en
1771 function replace_php_virtual_deps()
1772 {
1773         pkg = $2
1774 #       if (pkg == "php-program") {
1775 #               $0 = $1 "\t/usr/bin/php"
1776 #               return
1777 #       }
1778
1779 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1780 #               sub(/^php-/, "php(", pkg);
1781 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1782 #               $2 = pkg
1783 #       }
1784
1785         if (pkg ~/^php$/) {
1786                 $2 = "webserver(php)";
1787                 if ($4 ~ /^[0-9]:/) {
1788                         $4 = substr($4, 3);
1789                 }
1790         }
1791
1792         if (pkg ~/^php4$/) {
1793                 $2 = "webserver(php)";
1794                 if ($4 ~ /^[0-9]:/) {
1795                         $4 = substr($4, 3);
1796                 }
1797         }
1798 }
1799
1800 # Load rpm macros
1801 # you should update the list also in adapter when making changes here
1802 function import_rpm_macros() {
1803         # File with rpm groups
1804         topdir = ENVIRON["_topdir"]
1805
1806         if (!topdir) {
1807                 print "adapter.awk should not not be invoked directly, but via adapter script" > "/dev/stderr"
1808                 do_not_touch_anything = 1
1809                 exit(1);
1810         }
1811
1812         # get cvsaddress for changelog section
1813         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
1814         _cvsmaildomain = ENVIRON["_cvsmaildomain"]
1815         _cvsmailfeedback = ENVIRON["_cvsmailfeedback"]
1816
1817         prefix = ENVIRON["_prefix"]
1818         bindir = ENVIRON["_bindir"]
1819         sbindir = ENVIRON["_sbindir"]
1820         libdir = ENVIRON["_libdir"]
1821         sysconfdir = ENVIRON["_sysconfdir"]
1822         datadir = ENVIRON["_datadir"]
1823         includedir = ENVIRON["_includedir"]
1824         mandir = ENVIRON["_mandir"]
1825         infodir = ENVIRON["_infodir"]
1826         examplesdir = ENVIRON["_examplesdir"]
1827         docdir = ENVIRON["_defaultdocdir"]
1828         kdedocdir = ENVIRON["_kdedocdir"]
1829         gtkdocdir = ENVIRON["_gtkdocdir"]
1830         desktopdir = ENVIRON["_desktopdir"]
1831         pixmapsdir = ENVIRON["_pixmapsdir"]
1832         javadir = ENVIRON["_javadir"]
1833
1834         perl_sitearch = ENVIRON["perl_sitearch"]
1835         perl_archlib = ENVIRON["perl_archlib"]
1836         perl_privlib = ENVIRON["perl_privlib"]
1837         perl_vendorlib = ENVIRON["perl_vendorlib"]
1838         perl_vendorarch = ENVIRON["perl_vendorarch"]
1839         perl_sitelib = ENVIRON["perl_sitelib"]
1840
1841         py_sitescriptdir = ENVIRON["py_sitescriptdir"]
1842         py_sitedir = ENVIRON["py_sitedir"]
1843         py_scriptdir = ENVIRON["py_scriptdir"]
1844         py_ver = ENVIRON["py_ver"]
1845
1846         ruby_archdir = ENVIRON["ruby_archdir"]
1847         ruby_ridir = ENVIRON["ruby_ridir"]
1848         ruby_rubylibdir = ENVIRON["ruby_rubylibdir"]
1849         ruby_sitearchdir = ENVIRON["ruby_sitearchdir"]
1850         ruby_sitelibdir = ENVIRON["ruby_sitelibdir"]
1851         ruby_rdocdir = ENVIRON["ruby_rdocdir"]
1852
1853         php_pear_dir = ENVIRON["php_pear_dir"]
1854         php_data_dir = ENVIRON["php_data_dir"]
1855         tmpdir = ENVIRON["tmpdir"]
1856 }
1857
1858 function replace_groupnames(group) {
1859         group = replace(group, "Amusements/Games/Strategy/Real Time", "X11/Applications/Games/Strategy");
1860         group = replace(group, "Application/Multimedia", "Applications/Multimedia");
1861         group = replace(group, "Application/System", "Applications/System");
1862         group = replace(group, "Applications/Compilers", "Development/Languages");
1863         group = replace(group, "Applications/Daemons", "Daemons");
1864         group = replace(group, "Applications/Internet", "Applications/Networking");
1865         group = replace(group, "Applications/Internet/Peer to Peer", "Applications/Networking");
1866         group = replace(group, "Applications/Productivity", "X11/Applications");
1867         group = replace(group, "Database", "Applications/Databases");
1868         group = replace(group, "Development/C", "Development/Libraries");
1869         group = replace(group, "Development/Code Generators", "Development");
1870         group = replace(group, "Development/Docs", "Documentation");
1871         group = replace(group, "Development/Documentation", "Documentation");
1872         group = replace(group, "Development/Java", "Development/Languages/Java");
1873         group = replace(group, "Development/Languages/Other", "Development/Languages");;
1874         group = replace(group, "Development/Languages/Ruby", "Development/Languages");
1875         group = replace(group, "Development/Libraries/C and C++", "Development/Libraries");
1876         group = replace(group, "Development/Libraries/Java", "Development/Languages/Java");
1877         group = replace(group, "Development/Libraries/Python", "Development/Languages/Python");
1878         group = replace(group, "Development/Libraries/TCL", "Development/Languages/Tcl");;
1879         group = replace(group, "Development/Other", "Development");
1880         group = replace(group, "Development/Python", "Development/Languages/Python");
1881         group = replace(group, "Development/Testing", "Development");
1882         group = replace(group, "Emulators", "Applications/Emulators");
1883         group = replace(group, "Games", "Applications/Games");
1884         group = replace(group, "Library/Development", "Development/Libraries");
1885         group = replace(group, "Networking/Deamons", "Networking/Daemons");
1886         group = replace(group, "Productivity/Databases/Servers", "Applications/Databases");
1887         group = replace(group, "Productivity/Networking/Web/Servers", "Networking/Daemons/HTTP");;
1888         group = replace(group, "Shells", "Applications/Shells");
1889         group = replace(group, "System Environment/Base", "Base");
1890         group = replace(group, "System Environment/Daemons", "Daemons");
1891         group = replace(group, "System Environment/Kernel", "Base/Kernel");
1892         group = replace(group, "System Environment/Libraries", "Libraries");
1893         group = replace(group, "System Tools", "Applications/System");
1894         group = replace(group, "System", "Base");
1895         group = replace(group, "System/Base", "Base");
1896         group = replace(group, "System/Kernel and hardware", "Base/Kernel");
1897         group = replace(group, "System/Libraries", "Libraries");
1898         group = replace(group, "System/Servers", "Daemons");
1899         group = replace(group, "Text Processing/Markup/HTML", "Applications/Text");
1900         group = replace(group, "Text Processing/Markup/XML", "Applications/Text");
1901         group = replace(group, "User Interface/Desktops", "X11/Applications");
1902         group = replace(group, "Utilities/System", "Applications/System");
1903         group = replace(group, "Web/Database", "Applications/WWW");
1904         group = replace(group, "X11/GNOME", "X11/Applications");
1905         group = replace(group, "X11/GNOME/Applications", "X11/Applications");
1906         group = replace(group, "X11/GNOME/Development/Libraries", "X11/Development/Libraries");
1907         group = replace(group, "X11/Games", "X11/Applications/Games");
1908         group = replace(group, "X11/Games/Strategy", "X11/Applications/Games/Strategy");
1909         group = replace(group, "X11/Library", "X11/Libraries");
1910         group = replace(group, "X11/Utilities", "X11/Applications");
1911         group = replace(group, "X11/XFree86", "X11");
1912         group = replace(group, "X11/Xserver", "X11/Servers");
1913
1914         return group;
1915 }
1916
1917 # vim:ts=4:sw=4