adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # Adapter adapts .spec files for PLD Linux.
   4 #
   5 # Copyright (C) 1999-2008 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Michał Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Jakub Bogusz <qboosh@pld-linux.org>
  13 #       Elan Ruusamäe <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - really long sourceX make preamble sorting totally fcked up (try snake.spec r1.1)
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27 # - it should change: /%source([0-9]+)/i to %{SOURCE\1}
  28 # - extra quote on LDFLAGS line: https://bugs.launchpad.net/pld-linux/+bug/385836
  29
  30 BEGIN {
  31         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  32         SECTIONS = "^%(" RPM_SECTIONS ")"
  33
  34         RCSID = "$Id$"
  35         rev = RCSID # TODO: parse from RCSID
  36         VERSION = "0.35/" rev
  37
  38         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests|Auto(Req|Prov))"
  39
  40         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  41
  42         preamble = 1    # Is it part of preamble? Default - yes
  43         boc = 4                 # Beginning of %changelog
  44         bod = 0                 # Beginning of %description
  45         tw = 70                 # Descriptions width
  46
  47         b_idx = 0               # index of BR/R arrays
  48         BR_count = 0    # number of additional BuildRequires
  49
  50         # If variable removed, then 1 (for removing it from export)
  51         removed["LDFLAGS"] = 0
  52         removed["CFLAGS"] = 0
  53         removed["CXXFLAGS"] = 0
  54
  55         # If 1, we are inside of comment block (started with /^#%/)
  56         comment_block = 0
  57
  58         import_rpm_macros()
  59
  60         packages_dir = topdir "/packages"
  61         groups_file = packages_dir "/rpm.groups"
  62
  63         system("cd "packages_dir"; [ -f rpm.groups ] || cvs up rpm.groups > /dev/null")
  64         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  65
  66         # Temporary file for changelog section
  67         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  68 }
  69
  70 # There should be a comment with CVS keywords on the first line of file.
  71 FNR == 1 {
  72         if (!/# \$Revision:/)   # If this line is already OK?
  73                 print "# $" "Revision:$, " "$" "Date:$" # No
  74         else {
  75                 print $0                                # Yes
  76                 next            # It is enough for first line
  77         }
  78 }
  79
  80 # If the latest line matched /%files/
  81 defattr == 1 {
  82         if (ENVIRON["SKIP_DEFATTR"] != 1) {
  83                 if ($0 !~ /defattr/) {  # If no %defattr
  84                         print "%defattr(644,root,root,755)"     # Add it
  85                 } else {
  86                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  87                 }
  88         }
  89         defattr = 0
  90 }
  91
  92 function b_makekey(a, b,        s) {
  93         s = a "" b;
  94         # kill bcond
  95         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
  96
  97         # kill commented out items
  98         gsub(/^#[ \t]*/, "", s);
  99
 100         # force order
 101         gsub(/^Summary\(/, "11Summary(", s);
 102         gsub(/^Summary/, "10Summary", s);
 103
 104         gsub(/^Name/, "2Name", s);
 105         gsub(/^Version/, "3Version", s);
 106         gsub(/^Release/, "4Release", s);
 107         gsub(/^Epoch/, "5Epoch", s);
 108         gsub(/^License/, "5License", s);
 109         gsub(/^Group/, "6Group", s);
 110         gsub(/^URL/, "7URL", s);
 111
 112         gsub(/^BuildRequires/, "B1BuildRequires", s);
 113         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 114
 115         gsub(/^Suggests/, "X1Suggests", s);
 116         gsub(/^Provides/, "X2Provides", s);
 117         gsub(/^Obsoletes/, "X3Obsoletes", s);
 118         gsub(/^Conflicts/, "X4Conflicts", s);
 119         gsub(/^BuildArch/, "X5BuildArch", s);
 120         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 121         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 122         gsub(/^BuildRoot/, "X9BuildRoot", s);
 123
 124         gsub(/^AutoProv/, "Xx1AutoProv", s);
 125         gsub(/^AutoReq/, "Xx2AutoReq", s);
 126
 127 #       printf("%s -> %s\n", a""b, s);
 128         return s;
 129 }
 130
 131 # Comments
 132 /^#/ && (description == 0) {
 133         if (/This file does not like to be adapterized!/) {
 134                 print                   # print this message
 135                 while (getline)         # print the rest of spec as it is
 136                         print
 137                 do_not_touch_anything = 1 # do not touch anything in END()
 138                 exit 0
 139         }
 140
 141         # Generally, comments are printed without touching
 142         sub(/[ \t]+$/, "")
 143
 144         if (/#[ \t]*Source.*md5/) {
 145                 if (usedigest == 1) {
 146                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 147                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 148                 }
 149                 print $0
 150                 next
 151         }
 152 }
 153
 154 /^%define/ {
 155         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 156         if ($2 == "_applnkdir") {
 157                 next
 158         }
 159         if ($2 == "date") {
 160                 date = 1
 161                 if (did_files == 0) {
 162                         print "%files"
 163                         print ""
 164                         did_files = 1
 165                 }
 166         }
 167
 168         # Do not add %define of _prefix if it already is.
 169         if ($2 ~ /^_prefix/) {
 170                 sub("^"prefix, $3, bindir)
 171                 sub("^"prefix, $3, sbindir)
 172                 sub("^"prefix, $3, libdir)
 173                 sub("^"prefix, $3, datadir)
 174                 sub("^"prefix, $3, includedir)
 175                 prefix = $3
 176         }
 177
 178         if ($2 ~ /_bindir/ && !/_sbindir/)
 179                 bindir = $3
 180         if ($2 ~ /_sbindir/)
 181                 sbindir = $3
 182         if ($2 ~ /_libdir/) {
 183                 if ($3 ~ /^%\(/) {
 184                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 185                         libdir = "%%%%%%%%%%%%%%"
 186                 } else {
 187                         libdir = $3
 188                 }
 189         }
 190         if ($2 ~ /_sysconfdir/) {
 191                 if ($3 ~ /^%\(/) {
 192                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 193                         sysconfdir = "%%%%%%%%%%%%%%"
 194                 } else {
 195                         sysconfdir = $3
 196                 }
 197         }
 198         if ($2 ~ /_datadir/) {
 199                 if ($3 ~ /^%\(/) {
 200                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 201                         datadir = "%%%%%%%%%%%%%%"
 202                 } else {
 203                         datadir = $3
 204                 }
 205         }
 206         if ($2 ~ /_includedir/)
 207                 includedir = $3
 208         if ($2 ~ /_mandir/)
 209                 mandir = $3
 210         if ($2 ~ /_infodir/)
 211                 infodir = $3
 212         if ($2 ~ /_docdir/)
 213                 docdir = $3
 214
 215         # version related macros
 216         if ($2 ~ /^_beta$/)
 217                 _beta = $3
 218         if ($2 ~ /^_rc$/)
 219                 _rc = $3
 220         if ($2 ~ /^_pre$/)
 221                 _pre = $3
 222         if ($2 ~ /^_snap$/)
 223                 _snap = $3
 224         if ($2 ~ /^subver$/)
 225                 subver = $3
 226
 227         # these are used usually when adapterizing external spec
 228         if ($2 ~ /^name$/)
 229                 name = $3
 230         if ($2 ~ /^version$/)
 231                 version = $3
 232         if ($2 ~ /^release$/)
 233                 release = $3
 234
 235         if ($2 ~ /^mod_name$/)
 236                 mod_name = $3
 237
 238         sub(/[ \t]+$/, "");
 239         # do nothing further, otherwise adapter thinks we're at preamble
 240         print
 241         next
 242 }
 243
 244 # Obsolete
 245 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 246         next
 247 }
 248
 249 ################
 250 # %description #
 251 ################
 252 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 253         preamble = 0
 254
 255         if (/^%description/) {
 256                 bod++
 257                 format_line = ""
 258                 format_indent = -1
 259         }
 260
 261         # Format description
 262         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 263                 if (/^[ \t]*$/) {
 264                         format_flush(format_line, format_indent)
 265                         print ""
 266                         format_line = ""
 267                         format_indent = -1
 268                 } else if (/^[ \t]*[-\*][ \t]*/) {
 269                         format_flush(format_line, format_indent)
 270                         match($0, /^[ \t]*/)
 271                         format_indent = RLENGTH
 272                         match($0, /^[ \t]*[-\*][ \t]/)
 273                         format_line = substr($0, RLENGTH)
 274                 } else
 275                         format_line = format_line " " $0
 276                 next
 277         }
 278
 279         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 280                 if (NF > 3 && $2 == "-l") {
 281                         ll = $1
 282                         for (i = 4; i <= NF; i++)
 283                                 ll = ll " " $i
 284                         $0 = ll " -l " $3
 285                 }
 286                 format_flush(format_line, format_indent)
 287                 if (bod == 2) {
 288                         bod = 1
 289                         description = 1
 290                 } else {
 291                         bod = 0
 292                         description = 0
 293                 }
 294         } else
 295                 description = 1
 296 }
 297
 298 #########
 299 # %prep #
 300 #########
 301 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 302         preamble = 0
 303         did_prep = 1
 304
 305         use_macros()
 306
 307         # Add '-q' to %setup
 308         if (/^%setup/ && !/-q/) {
 309                 sub(/^%setup/, "%setup -q")
 310         }
 311
 312         if (/^%setup/ && name != "setup") {
 313                 $0 = fixedsub(name, "%{name}", $0);
 314                 $0 = fixedsub(version, "%{version}", $0);
 315                 if (_beta) {
 316                         $0 = fixedsub(_beta, "%{_beta}", $0);
 317                 }
 318                 if (_rc) {
 319                         $0 = fixedsub(_rc, "%{_rc}", $0);
 320                 }
 321                 if (_pre) {
 322                         $0 = fixedsub(_pre, "%{_pre}", $0);
 323                 }
 324                 if (_snap) {
 325                         $0 = fixedsub(_snap, "%{_snap}", $0);
 326                 }
 327                 if (subver) {
 328                         $0 = fixedsub(subver, "%{subver}", $0);
 329                 }
 330         }
 331
 332         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 333                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 334         }
 335         sub("^%patch ", "%patch0 ");
 336
 337         # invalid in %prep
 338         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 339 }
 340
 341 ##########
 342 # %build #
 343 ##########
 344 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 345         preamble = 0
 346
 347         if (did_prep == 0) {
 348                 print "%prep"
 349                 print ""
 350                 did_prep = 1
 351         }
 352
 353         use_macros()
 354         use_tabs()
 355
 356         if (/^automake$/)
 357                 sub(/$/, " -a -c")
 358
 359         if (/LDFLAGS/) {
 360                 if (/LDFLAGS="-s"/) {
 361                         removed["LDFLAGS"] = 1
 362                         next
 363                 } else {
 364                         split($0, tmp, "LDFLAGS=")
 365                         count = split(tmp[2], flags, "\"")
 366                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 367                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 368                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 369                                 for (i = 2; i < count; i++)
 370                                         $0 = $0 flags[i] "\""
 371                         }
 372                 }
 373         }
 374
 375         if (/CFLAGS=/)
 376                 if (cflags("CFLAGS") == 0)
 377                         next
 378
 379         if (/CXXFLAGS=/)
 380                 if (cflags("CXXFLAGS") == 0)
 381                         next
 382
 383         if (/^export /) {
 384                 if (removed["LDFLAGS"])
 385                         sub(" LDFLAGS", "")
 386                 if (removed["CFLAGS"])
 387                         sub(" CFLAGS", "")
 388                 if (removed["CXXFLAGS"])
 389                         sub(" CXXFLAGS", "")
 390                 # Is there still something?
 391                 if (/^export[ ]*$/)
 392                         next
 393         }
 394
 395         # quote CC
 396         if (/CC=%{__cc} /) {
 397                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 398         }
 399
 400         # use PLD Linux macros
 401         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 402         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 403         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 404         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 405         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 406         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 407         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 408         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 409
 410         sub(/^aclocal$/, "%{__aclocal}");
 411         sub(/^autoheader$/, "%{__autoheader}");
 412         sub(/^autoconf$/, "%{__autoconf}");
 413         sub(/^automake$/, "%{__automake}");
 414         sub(/^libtoolize$/, "%{__libtoolize}");
 415
 416         # atrpms
 417         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 418         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 419 }
 420
 421 ##########
 422 # %clean #
 423 ##########
 424 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 425         did_clean = 1
 426
 427         use_macros()
 428 }
 429
 430 ############
 431 # %install #
 432 ############
 433 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 434
 435         preamble = 0
 436
 437         # foreign rpms
 438         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 439         sub("%buildroot", "$RPM_BUILD_ROOT");
 440         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 441
 442         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 443                 did_rmroot=1
 444                 print "rm -rf $RPM_BUILD_ROOT"
 445                 next
 446         }
 447
 448         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 449                 print "rm -rf $RPM_BUILD_ROOT"
 450                 did_rmroot=1
 451         }
 452
 453         if (tmpdir) {
 454                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 455                 gsub(buildroot, "$RPM_BUILD_ROOT")
 456         }
 457
 458         if (!/%{_lib}/) {
 459                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 460         }
 461
 462         use_macros()
 463
 464         # 'install -d' instead 'mkdir -p'
 465         if (/mkdir -p/)
 466                 sub(/mkdir -p/, "install -d")
 467
 468         # cp -a already implies cp -r
 469         sub(/^cp -ar/, "cp -a")
 470
 471         # No '-u root' or '-g root' for 'install'
 472         if (/^install/ && /-[ug][ \t]*root/)
 473                 gsub(/-[ug][ \t]*root /, "")
 474
 475         if (/^install/ && /-m[ \t]*[0-9]+/)
 476                 gsub(/-m[ \t]*[0-9]+ /, "")
 477
 478         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 479         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 480                 next
 481
 482         # No lines contain 'chmod' if it sets the modes to '644'
 483         if ($1 ~ /chmod/ && $2 ~ /644/)
 484                 next
 485
 486         # atrpms
 487         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 488 }
 489
 490 ##########
 491 # %files #
 492 ##########
 493 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 494         preamble = 0
 495         did_files = 1
 496
 497         if ($0 ~ /^%files/)
 498                 defattr = 1
 499
 500         if (!use_files_macros()) {
 501                 next
 502         }
 503 }
 504
 505 ##############
 506 # %changelog #
 507 ##############
 508 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 509         preamble = 0
 510         has_changelog = 1
 511         skip = 0
 512         # There should be some CVS keywords on the first line of %changelog.
 513         if (boc == 3) {
 514                 if ($0 !~ _cvsmailfeedback) {
 515                         print "* %{date} " _cvsmailfeedback > changelog_file
 516                 } else {
 517                         skip = 1
 518                 }
 519                 boc = 2
 520         }
 521         if (boc == 2 && !skip) {
 522                 if (!/All persons listed below/) {
 523                         printf "All persons listed below can be reached at " > changelog_file
 524                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 525                 } else {
 526                         skip = 1
 527                 }
 528                 boc = 1
 529         }
 530         if (boc == 1 && !skip) {
 531                 if (!/^$/) {
 532                         if (!/\$.*Log:.*\$/) {
 533                                 print "$" "Log:$" > changelog_file
 534                         }
 535                         boc = 0
 536                 }
 537         }
 538         # Define date macro.
 539         if (boc == 4) {
 540                 if (date == 0) {
 541                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 542                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 543                         date = 1
 544                 }
 545                 boc = 3
 546         }
 547
 548         sub(/[ \t]+$/, "");
 549         if (!/^%[a-z]+$/ || /changelog/) {
 550                 # stop changelog if "real" changelog starts
 551                 if (boc == 0 && /^\* /) {
 552                         boc = -1
 553                 }
 554                 if (boc == -1) {
 555                         next;
 556                 }
 557                 print > changelog_file
 558         } else {
 559                 print
 560         }
 561         next
 562 }
 563
 564 ###########
 565 # SCRIPTS #
 566 ###########
 567 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 568         preamble = 0
 569
 570         if (gsub("/usr/sbin/useradd", "%useradd")) {
 571                 sub(" 2> /dev/null \|\| :", "");
 572                 sub(" >/dev/null 2>&1 \|\|:", "");
 573         }
 574
 575         # %useradd and %groupadd may not be wrapped
 576         if (/%(useradd|groupadd).*\\$/) {
 577                 a = $0; getline;
 578                 sub(/^[\s\t]*/, "");
 579                 $0 = substr(a, 1, length(a) - 1) $0;
 580         }
 581         use_script_macros()
 582 }
 583
 584 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 585         preamble = 0
 586         use_macros()
 587 }
 588 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 589         preamble = 0
 590         use_macros()
 591 }
 592 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 593         preamble = 0
 594         use_script_macros()
 595 }
 596 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 597         preamble = 0
 598         use_script_macros()
 599 }
 600 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 601         preamble = 0
 602         use_script_macros()
 603 }
 604 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 605         preamble = 0
 606         use_script_macros()
 607 }
 608 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 609         preamble = 0
 610         use_script_macros()
 611 }
 612 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 613         preamble = 0
 614         use_script_macros()
 615 }
 616 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 617         preamble = 0
 618         use_script_macros()
 619 }
 620 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 621         preamble = 0
 622         use_script_macros()
 623 }
 624
 625 #############
 626 # PREAMBLES #
 627 #############
 628 preamble == 1 {
 629         # There should not be a space after the name of field
 630         # and before the colon.
 631         sub(/[ \t]*:/, ":")
 632
 633         if (/^%perl_module_wo_prefix/) {
 634                 name = $2
 635                 version = $3
 636                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 637         }
 638
 639         field = tolower($1)
 640         fieldnlower = $1
 641         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 642                 sub(/\.$/, "", $0);
 643         }
 644         if (field ~ /group(\([^)]+\)):/)
 645                 next
 646         if (field ~ /group:/) {
 647                 format_preamble()
 648                 group = $0;
 649                 sub(/^[^ \t]*[ \t]*/, "", group);
 650                 group = replace_groupnames(group);
 651                 $0 = "Group:\t\t" group
 652
 653                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 654                         x11 = 1
 655
 656                 byl_plik_z_groupmi = 0
 657                 byl_opis_grupy = 0
 658                 while ((getline linia_grup < groups_file) > 0) {
 659                         byl_plik_z_groupmi = 1
 660                         if (linia_grup == group) {
 661                                 byl_opis_grupy = 1
 662                                 break
 663                         }
 664                 }
 665
 666                 if (!byl_plik_z_groupmi)
 667                         print "######\t\t" groups_file ": no such file"
 668                 else if (!byl_opis_grupy)
 669                         print "######\t\t" "Unknown group!"
 670
 671                 close(groups_file)
 672                 did_groups = 1
 673         }
 674
 675         if (field ~ /prereq:/) {
 676                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 677         }
 678
 679         # split (build)requires, obsoletes on commas
 680         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 681                 value = substr($0, index($0, $2));
 682                 $0 = format_requires($1, value);
 683         }
 684
 685         # BR: tar (and others) is to common (rpm-build requires it)
 686         if (field ~ /^buildrequires:/) {
 687                 l = substr($0, index($0, $2));
 688                 if (l == "awk" ||
 689                         l == "binutils" ||
 690                         l == "bzip2" ||
 691                         l == "cpio" ||
 692                         l == "diffutils" ||
 693                         l == "elfutils" ||
 694                         l == "fileutils" ||
 695                         l == "findutils" ||
 696                         l == "glibc-devel" ||
 697                         l == "grep" ||
 698                         l == "gzip" ||
 699                         l == "make" ||
 700                         l == "patch" ||
 701                         l == "sed" ||
 702                         l == "sh-utils" ||
 703                         l == "tar" ||
 704                         l == "textutils") {
 705                         next
 706                 }
 707
 708                 replace_requires();
 709         }
 710
 711         if (field ~ /^requires:/) {
 712                 replace_requires();
 713         }
 714
 715
 716         # obsolete/unwanted tags
 717         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 718                 next
 719         }
 720
 721         if (field ~ /buildroot:/) {
 722                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 723                 did_build_root = 1
 724         }
 725
 726         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 727         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 728                 $1 = "License:"
 729         }
 730
 731         if (field ~ /license:/) {
 732                 l = substr($0, index($0, $2));
 733                 if (l == "Python Software Foundation License") {
 734                         l = "PSF"
 735                 }
 736                 if (l == "Apache License 2.0" || l == "Apache 2.0" || l == "Apache License Version 2.0" || l == "Apache License, Version 2.0" || l == "Apache Software License v2") {
 737                         l = "Apache v2.0"
 738                 }
 739                 if (l == "Apache Group License" || l == "Apache Software License" || l == "Apache License") {
 740                         l = "Apache"
 741                 }
 742                 if (l == "Apache-style License" || l == "Apache-style Software License") {
 743                         l = "Apache-like"
 744                 }
 745                 if (l == "Apache Software License 1.1" || l == "Apache 1.1") {
 746                         l = "Apache v1.1"
 747                 }
 748                 if (l == "GPLv2") {
 749                         l = "GPL v2"
 750                 }
 751                 if (l == "GPLv2+") {
 752                         l = "GPL v2+"
 753                 }
 754                 $0 = "License:\t" l;
 755         }
 756
 757
 758         if (field ~ /name:/) {
 759                 if ($2 == "%{name}" && name) {
 760                         $2 = name
 761                 }
 762                 name = $2
 763                 name_seen = 1;
 764         }
 765
 766         if (field ~ /version:/) {
 767                 if ($2 == "%{version}" && version) {
 768                         $2 = version
 769                 }
 770                 version = $2
 771                 version_seen = 1;
 772         }
 773
 774         if (field ~ /release:/) {
 775                 if ($2 == "%{release}" && release) {
 776                         $2 = release
 777                 }
 778                 sub(/%atrelease /, "0.", $0)
 779                 release = $2
 780                 release_seen = 1;
 781         }
 782
 783
 784         if (field ~ /serial:/)
 785                 $1 = "Epoch:"
 786
 787         if (field ~ /home-page:/)
 788                 $1 = "URL:"
 789
 790         # proper caps
 791         if (field ~ /^url:$/)
 792                 $1 = "URL:"
 793
 794         if (field ~ /^description:$/)
 795                 $1 = "\n%description\n"
 796
 797         # Use %{name} and %{version} in the filenames in "Source:"
 798         if (field ~ /^source/ || field ~ /patch/) {
 799                 n = split($2, url, /\//)
 800                 if (url[n] ~ /\.gz$/) {
 801                         url[n+1] = ".gz" url[n+1]
 802                         sub(/\.gz$/,"",url[n])
 803                 }
 804                 if (url[n] ~ /\.zip$/) {
 805                         url[n+1] = ".zip" url[n+1]
 806                         sub(/\.zip$/,"",url[n])
 807                 }
 808                 if (url[n] ~ /\.tar$/) {
 809                         url[n+1] = ".tar" url[n+1]
 810                         sub(/\.tar$/,"",url[n])
 811                 }
 812                 if (url[n] ~ /\.patch$/) {
 813                         url[n+1] = ".patch" url[n+1]
 814                         sub(/\.patch$/,"",url[n])
 815                 }
 816                 if (url[n] ~ /\.bz2$/) {
 817                         url[n+1] = ".bz2" url[n+1]
 818                         sub(/\.bz2$/,"",url[n])
 819                 }
 820                 if (url[n] ~ /\.logrotate$/) {
 821                         url[n+1] = ".logrotate" url[n+1]
 822                         sub(/\.logrotate$/,"",url[n])
 823                 }
 824                 if (url[n] ~ /\.pamd$/) {
 825                         url[n+1] = ".pamd" url[n+1]
 826                         sub(/\.pamd$/,"",url[n])
 827                 }
 828
 829                 # allow %{name} only in last url component
 830                 s = ""
 831                 for (i = 1; i <= n; i++) {
 832                         url[i] = fixedsub("%{name}", name, url[i])
 833                         if (s) {
 834                                 s = s "/" url[i]
 835                         } else {
 836                                 s = url[i]
 837                         }
 838                 }
 839                 $2 = s url[n+1]
 840
 841                 filename = url[n]
 842                 if (name) {
 843                         url[n] = fixedsub(name, "%{name}", url[n])
 844                 }
 845                 if (field ~ /source/) {
 846                         if (version) {
 847                                 url[n] = fixedsub(version, "%{version}", url[n])
 848                         }
 849                         if (_beta) {
 850                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 851                         }
 852                         if (_rc) {
 853                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 854                         }
 855                         if (_pre) {
 856                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 857                         }
 858                         if (_snap) {
 859                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 860                         }
 861                         if (subver) {
 862                                 url[n] = fixedsub(subver, "%{subver}", url[n])
 863                         }
 864                 }
 865                 # assigning to $2 kills preamble formatting
 866                 $2 = fixedsub(filename, url[n], $2)
 867
 868                 $2 = unify_url($2)
 869         }
 870
 871
 872         if (field ~ /^source:/)
 873                 $1 = "Source0:"
 874
 875         if (field ~ /^patch:/)
 876                 $1 = "Patch0:"
 877
 878         kill_preamble_macros();
 879         format_preamble()
 880
 881         if (field ~ /requires/) {
 882                 # atrpms
 883                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 884         }
 885 }
 886
 887 /^%bcond_/ {
 888         # do nothing
 889         print
 890         next
 891 }
 892
 893 # sort BR/R!
 894 #
 895 # NOTES:
 896 # - mixing BR/R and anything else confuses this (all will be sorted together)
 897 #       so don't do that.
 898 # - comments leading the BR/R can not be associated,
 899 #       so don't adapterize when the BR/R are mixed with comments
 900 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 901         if ($1 ~ /Pre[Rr]eq:/) {
 902                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 903         }
 904         if ($1 == "BR:" ) {
 905                 $1 = "BuildRequires:"
 906         }
 907         if ($1 == "R:" ) {
 908                 $1 = "Requires:"
 909         }
 910         format_preamble()
 911 #       kill_preamble_macros(); # breaks tabbing
 912
 913         b_idx++;
 914         l = substr($0, index($0, $2));
 915         b_ktmp = b_makekey($1, l);
 916         b_key[b_idx] = b_ktmp;
 917         b_val[b_ktmp] = $0;
 918
 919         next;
 920 }
 921
 922 preamble == 1 {
 923         if (b_idx > 0) {
 924                 isort(b_key, b_idx);
 925                 for (i = 1; i <= b_idx; i++) {
 926                         v = b_val[b_key[i]];
 927                         sub(/[ \t]+$/, "", v);
 928                         print "" v;
 929                 }
 930                 b_idx = 0
 931         }
 932 }
 933
 934 # main() ;-)
 935 {
 936         preamble = 1
 937
 938         sub(/[ \t]+$/, "")
 939         print
 940
 941         if (name_seen == 0 && name) {
 942                 print "Name:\t\t" name
 943                 name_seen = 1
 944         }
 945
 946         if (version_seen == 0 && version) {
 947                 print "Version:\t" version
 948                 version_seen = 1
 949         }
 950
 951         if (release_seen == 0 && release) {
 952                 print "Release:\t" release
 953                 release_seen = 1
 954         }
 955
 956         if (did_build_root == 0) {
 957 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 958                 did_build_root = 1
 959         }
 960         if (did_groups == 0) {
 961 #               print "Group:\t\tunknown"
 962                 did_groups = 1
 963         }
 964 }
 965
 966
 967 END {
 968         if (do_not_touch_anything)
 969                 exit 0
 970
 971         # TODO: need to output these in proper place
 972         if (BR_count > 0) {
 973                 for (i = 0; i <= BR_count; i++) {
 974                         print BR[i];
 975                 }
 976         }
 977
 978         close(changelog_file)
 979         while ((getline < changelog_file) > 0)
 980                 print
 981         system("rm -f " changelog_file)
 982
 983         if (did_clean == 0) {
 984                 print ""
 985                 print "%clean"
 986                 print "rm -rf $RPM_BUILD_ROOT"
 987         }
 988
 989         if (date == 0) {
 990                 print ""
 991                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 992         }
 993
 994         if (has_changelog == 0) {
 995                 print "%changelog"
 996         }
 997
 998         if (boc > 2) {
 999                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1000         }
1001         if (boc > 1) {
1002                 printf "All persons listed below can be reached at "
1003                 print "<cvs_login>@pld-linux.org\n"
1004         }
1005         if (boc > 0) {
1006                 print "$" "Log:$"
1007         }
1008 }
1009
1010 # substitutes fixed strings (not regexps)
1011 function fixedsub(s1,s2,t, ind) {
1012         if (ind = index(t,s1))
1013                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1014         return t
1015 }
1016
1017 # replace s with s2 if it equals to s1
1018 function replace(s, s1, s2) {
1019         if (s == s1) {
1020                 return s2;
1021         } else {
1022                 return s;
1023         }
1024 }
1025
1026 # There should be one or two tabs after the colon.
1027 function format_preamble()
1028 {
1029         if (/^#/ || /^%bcond_with/) {
1030                 return;
1031         }
1032         sub(/:[ \t]*/, ":")
1033         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1034                 if (RLENGTH < 8) {
1035                         sub(/:/, ":\t\t")
1036                 } else {
1037                         sub(/:/, ":\t")
1038                 }
1039         }
1040 }
1041
1042 # Replace directly specified directories with macros
1043 function use_macros()
1044 {
1045         # -m, --skip-macros, --no-macros -- skip macros subst
1046         if (ENVIRON["SKIP_MACROS"]) {
1047                 return
1048         }
1049
1050         # leave inline sed lines alone
1051         if (/(%{__sed}|sed) -i -e/) {
1052                 return;
1053         }
1054
1055         sub("%{_defaultdocdir}", "%{_docdir}");
1056         sub("%{_bindir}/perl", "%{__perl}");
1057         sub("%{_bindir}/python", "%{__python}");
1058
1059         gsub(infodir, "%{_infodir}")
1060
1061         gsub(perl_sitearch, "%{perl_sitearch}")
1062         gsub(perl_archlib, "%{perl_archlib}")
1063         gsub(perl_privlib, "%{perl_privlib}")
1064         gsub(perl_vendorlib, "%{perl_vendorlib}")
1065         gsub(perl_vendorarch, "%{perl_vendorarch}")
1066         gsub(perl_sitelib, "%{perl_sitelib}")
1067
1068         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1069         gsub(py_sitedir, "%{py_sitedir}")
1070         gsub(py_scriptdir, "%{py_scriptdir}")
1071         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1072         gsub("%{python_sitelib}", "%{py_sitedir}")
1073
1074         gsub(ruby_archdir, "%{ruby_archdir}")
1075         gsub(ruby_ridir, "%{ruby_ridir}")
1076         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1077         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1078         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1079         gsub(ruby_rdocdir, "%{ruby_rdocdir}")
1080
1081         gsub("%{_datadir}/applications", "%{_desktopdir}")
1082         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1083         gsub("%{_datadir}/java", "%{_javadir}")
1084
1085         gsub(libdir, "%{_libdir}")
1086         gsub(javadir, "%{_javadir}")
1087
1088         gsub(bindir, "%{_bindir}")
1089         gsub("%{prefix}/bin", "%{_bindir}")
1090         if (prefix"/bin" == bindir)
1091                 gsub("%{_prefix}/bin", "%{_bindir}")
1092
1093         for (c = 1; c <= NF; c++) {
1094                 if ($c ~ sbindir "/fix-info-dir")
1095                         continue;
1096                 if ($c ~ sbindir "/webapp")
1097                         continue;
1098                 if ($c ~ sbindir "/ldconfig")
1099                         continue;
1100                 if ($c ~ sbindir "/chsh")
1101                         continue;
1102                 if ($c ~ sbindir "/usermod")
1103                         continue;
1104                 if ($c ~ sbindir "/chkconfig")
1105                         continue;
1106                 if ($c ~ sbindir "/installzope(product|3package)")
1107                         continue;
1108                 gsub(sbindir, "%{_sbindir}", $c)
1109         }
1110
1111         gsub("%{prefix}/sbin", "%{_sbindir}")
1112         if (prefix"/sbin" == sbindir) {
1113                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1114         }
1115
1116         for (c = 1; c <= NF; c++) {
1117                 if ($c ~ sysconfdir "/{?cron.")
1118                         continue;
1119                 if ($c ~ sysconfdir "/{?crontab.d")
1120                         continue;
1121                 if ($c ~ sysconfdir "/{?env.d")
1122                         continue;
1123                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1124                         continue;
1125                 if ($c ~ sysconfdir "/{?udev")
1126                         continue;
1127                 if ($c ~ sysconfdir "/{?hotplug")
1128                         continue;
1129                 if ($c ~ sysconfdir "/{?logrotate.d")
1130                         continue;
1131                 if ($c ~ sysconfdir "/{?pam.d")
1132                         continue;
1133                 if ($c ~ sysconfdir "/{?profile.d")
1134                         continue;
1135                 if ($c ~ sysconfdir "/{?rc.d")
1136                         continue;
1137                 if ($c ~ sysconfdir "/{?security")
1138                         continue;
1139                 if ($c ~ sysconfdir "/{?skel")
1140                         continue;
1141                 if ($c ~ sysconfdir "/{?sysconfig")
1142                         continue;
1143                 if ($c ~ sysconfdir "/{?shrc.d")
1144                         continue;
1145                 if ($c ~ sysconfdir "/{?certs")
1146                         continue;
1147                 if ($c ~ sysconfdir "/{?X11")
1148                         continue;
1149                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1150                         continue;
1151                 if ($c ~ sysconfdir "/{?rpm")
1152                         continue;
1153                 if ($c ~ sysconfdir "/{?bash_completion.d")
1154                         continue;
1155                 if ($c ~ sysconfdir "/{?samba")
1156                         continue;
1157                 if ($c ~ sysconfdir "/shells")
1158                         continue;
1159                 if ($c ~ sysconfdir "/ppp")
1160                         continue;
1161                 if ($c ~ sysconfdir "/dbus-1")
1162                         continue;
1163                 if ($c ~ sysconfdir "/tmpwatch")
1164                         continue;
1165                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1166         }
1167
1168         gsub(docdir, "%{_docdir}")
1169
1170         gsub(kdedocdir, "%{_kdedocdir}")
1171
1172         gsub(gtkdocdir, "%{_gtkdocdir}")
1173         gsub("%{_docdir}/gtk-doc/html", "%{_gtkdocdir}")
1174
1175         gsub(php_pear_dir, "%{php_pear_dir}")
1176         gsub(php_data_dir, "%{php_data_dir}")
1177
1178         for (c = 1; c <= NF; c++) {
1179                 if ($c ~ datadir "/automake")
1180                         continue;
1181                 if ($c ~ datadir "/unsermake")
1182                         continue;
1183                 if ($c ~ datadir "/file/magic.mime")
1184                         continue;
1185                 gsub(datadir, "%{_datadir}", $c)
1186         }
1187
1188         gsub("%{prefix}/share", "%{_datadir}")
1189         if (prefix"/share" == datadir)
1190                 gsub("%{_prefix}/share", "%{_datadir}")
1191
1192         # CFLAGS="-I/usr/include/ncurses is usually correct.
1193         if (!/-I\/usr\/include/) {
1194                 gsub(includedir, "%{_includedir}")
1195         }
1196
1197         gsub("%{prefix}/include", "%{_includedir}")
1198         if (prefix"/include" == includedir) {
1199                 gsub("%{_prefix}/include", "%{_includedir}")
1200         }
1201
1202         gsub(mandir, "%{_mandir}")
1203         if ($0 !~ "%{_datadir}/manual") {
1204                 gsub("%{_datadir}/man", "%{_mandir}")
1205         }
1206         gsub("%{_prefix}/share/man", "%{_mandir}")
1207         gsub("%{prefix}/share/man", "%{_mandir}")
1208         gsub("%{prefix}/man", "%{_mandir}")
1209         gsub("%{_prefix}/man", "%{_mandir}")
1210
1211         gsub(infodir, "%{_infodir}")
1212         gsub("%{prefix}/info", "%{_infodir}")
1213         gsub("%{_prefix}/info", "%{_infodir}")
1214
1215         if (prefix !~ "/X11R6") {
1216                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1217         }
1218
1219         gsub(examplesdir, "%{_examplesdir}")
1220
1221         if (prefix != "/") {
1222                 # leave --with-foo=/usr alone
1223                 if ($0 !~ "--with.*=.*" prefix) {
1224                         for (c = 1; c <= NF; c++) {
1225                                 if ($c ~ prefix "/sbin/fix-info-dir")
1226                                         continue;
1227                                 if ($c ~ prefix "/sbin/webapp")
1228                                         continue;
1229                                 if ($c ~ prefix "/sbin/chsh")
1230                                         continue;
1231                                 if ($c ~ prefix "/sbin/usermod")
1232                                         continue;
1233                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1234                                         continue;
1235                                 if ($c ~ prefix "/share/automake")
1236                                         continue;
1237                                 if ($c ~ prefix "/share/unsermake")
1238                                         continue;
1239                                 if ($c ~ prefix "/lib/sendmail")
1240                                         continue;
1241                                 if ($c ~ prefix "/lib/pkgconfig")
1242                                         continue;
1243
1244                                 # CFLAGS="-I/usr..." is usually correct.
1245                                 if (/-I\/usr/)
1246                                         continue;
1247                                 # same for LDFLAGS="-L/usr..."
1248                                 if (/-L\/usr/)
1249                                         continue;
1250
1251                                 gsub(prefix, "%{_prefix}", $c)
1252                         }
1253                 }
1254                 gsub("%{prefix}", "%{_prefix}")
1255         }
1256
1257         # replace back
1258         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1259         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1260
1261         gsub("%{PACKAGE_VERSION}", "%{version}")
1262         gsub("%{PACKAGE_NAME}", "%{name}")
1263
1264         gsub("^make$", "%{__make}")
1265         gsub("^make ", "%{__make} ")
1266         gsub("^gcc ", "%{__cc} ")
1267         gsub("^rm --interactive=never ", "%{__rm} ")
1268
1269         # mandrake specs
1270         gsub("^%make$", "%{__make}")
1271         gsub("^%make ", "%{__make} ")
1272         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1273         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1274         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1275         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1276         gsub("^%{__install}", "install")
1277         gsub("%optflags", "%{rpmcflags}")
1278         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1279
1280         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1281         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1282         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1283         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1284         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1285         $0 = fixedsub("%__install", "install", $0);
1286
1287         # split configure line to multiple lines
1288         if (/%configure / && !/\\$/) {
1289                 $0 = format_configure($0);
1290         }
1291
1292         gsub("%_bindir", "%{_bindir}")
1293         gsub("%_datadir", "%{_datadir}")
1294         gsub("%_iconsdir", "%{_iconsdir}")
1295         gsub("%_sbindir", "%{_sbindir}")
1296         gsub("%_mandir", "%{_mandir}")
1297         gsub("%name", "%{name}")
1298         gsub(/%__rm/, "rm");
1299         gsub(/%__mkdir_p/, "install -d");
1300         gsub(/%__cp/, "cp");
1301         gsub(/%__ln_s/, "ln -s");
1302         gsub(/%__sed/, "%{__sed}");
1303         gsub(/%__cat/, "cat");
1304         gsub(/%__chmod/, "chmod");
1305
1306         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1307         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1308
1309         if (/^ant / || /^%{ant}/) {
1310                 sub(/^ant/, "%ant")
1311                 sub(/^%{ant}/, "%ant")
1312                 add_br("BuildRequires:  jpackage-utils");
1313                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1314         }
1315
1316         $0 = fixedsub("%(%{__cc} -dumpversion)", "%{cc_version}", $0);
1317         $0 = fixedsub("%(%{__cxx} -dumpversion)", "%{cxx_version}", $0);
1318 }
1319
1320 function format_configure(line,         n, a, s) {
1321         n = split(line, a, / /);
1322         s = a[1] " \\\n";
1323         for (i = 2; i <= n; i++) {
1324                 s = s "\t" a[i] " \\\n"
1325         }
1326         return s
1327 }
1328
1329
1330 # insertion sort of A[1..n]
1331 # copied from mawk manual
1332 function isort(A,n,             i,j,hold) {
1333         for (i = 2; i <= n; i++) {
1334                 hold = A[j = i]
1335                 while (A[j-1] > hold) {
1336                         j-- ; A[j+1] = A[j]
1337                 }
1338                 A[j] = hold
1339         }
1340         # sentinel A[0] = "" will be created if needed
1341 }
1342
1343
1344 function use_files_macros(      i, n, t, a, l)
1345 {
1346         use_macros()
1347
1348         # skip comments
1349         if (/^#/) {
1350                 return 1;
1351         }
1352
1353         sub("^%doc %{_mandir}", "%{_mandir}")
1354
1355         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1356         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1357
1358         # uid/gid nobody is not valid in %files
1359         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1360                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1361         }
1362
1363         # s[gu]id programs with globs are evil
1364         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1365                 $0 = $0 " # FIXME no globs for suid/sgid files"
1366         }
1367
1368         # replace back
1369         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1370         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1371         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1372         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1373         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1374         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1375         gsub("%{_sysconfdir}/security", "/etc/security")
1376         gsub("%{_sysconfdir}/skel", "/etc/skel")
1377         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1378         gsub("%{_sysconfdir}/certs", "/etc/certs")
1379         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1380         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1381         gsub("%{_sysconfdir}/pki", "/etc/pki")
1382         gsub("%{_sysconfdir}/tmpwatch", "/etc/tmpwatch")
1383
1384         # /etc/init.d -> /etc/rc.d/init.d
1385         if (!/^\/etc\/init\.d$/) {
1386                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1387         }
1388
1389         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1390                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1391                         $0 = "%attr(754,root,root) " $0
1392                 }
1393                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1394                         gsub("^%attr\\(... *,", "%attr(754,");
1395                 }
1396         }
1397
1398         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1399                 $0 = "%attr(755,root,root) " $0
1400         }
1401
1402         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1403                 $0 = "%attr(755,root,root) " $0
1404         }
1405
1406         # /etc/sysconfig files
1407         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1408         # attr not required, allow default 644 attr
1409         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1410                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1411                         gsub("%config", "%config(noreplace)")
1412                 }
1413
1414                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1415                         $NF = "%config(noreplace) " $NF
1416                 }
1417
1418                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1419                         gsub("^%attr\\(... *,", "%attr(640,");
1420                 }
1421
1422                 if (/\/etc\/sysconfig\// && !/%verify/) {
1423                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1424                 }
1425         }
1426
1427         # kill leading zeros
1428         if (/%attr\(0[1-9]/) {
1429                 gsub("%attr\\(0", "%attr(")
1430         }
1431
1432         # kill leading whitespace
1433         gsub(/^ +/, "");
1434
1435         # kill default attrs
1436         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1437         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1438         if (!/%dir/) {
1439                 gsub(/%attr\(644,root,root\) /, "");
1440         }
1441
1442         # sort %verify attrs
1443         if (match($0, /%verify\(not([^)]+)\)/)) {
1444                 t = substr($0, RSTART, RLENGTH)
1445                 # kill commas: %verify(not,md5,size,mtime)
1446                 gsub(/,/, " ", t);
1447
1448                 gsub(/^%verify\(not |\)$/, "", t)
1449                 n = split(t, a, / /)
1450                 isort(a, n)
1451
1452                 s = "%verify(not"
1453                 for (i = 1 ; i <= n; i++) {
1454                         s = s " " a[i]
1455                 }
1456                 s = s ")"
1457
1458                 gsub(/%verify\(not[^)]+\)/, s)
1459         }
1460
1461         if (/%{_mandir}/) {
1462                 gsub("\.gz$", "*")
1463         }
1464
1465         # locale dir and no %lang -> bad
1466         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1467                 $(NF + 1) = "# FIXME consider using %find_lang"
1468         }
1469
1470         # python egg-infos
1471         if (match($0, "^%{py_site(script)?dir}/.+-py"py_ver".egg-info$")) {
1472                 # tests:
1473                 #%{py_sitedir}/*-py2.4.egg-info
1474                 #%{py_sitescriptdir}/GnuPGInterface-%{version}-py2.4.egg-info
1475                 #%{py_sitescriptdir}/python_mpd-%{version}-py2.4.egg-info
1476                 #%{py_sitescriptdir}/mechanize-0.1.6b-py2.4.egg-info
1477
1478                 l = index($0, "/");
1479                 t = substr($0, 0, l);
1480                 s = substr($0, l + 1, RLENGTH - l - length("-py"py_ver".egg-info"));
1481                 if (match(s, "[^-]+$")) {
1482 #printf("s[%s]; start[%d]; length[%d]\n", s, RSTART, RLENGTH);
1483                         if (RSTART > 1) {
1484                                 s = substr(s, 0, RSTART - 1);
1485                         }
1486 #printf("s2[%s]\n", s);
1487                         print "%if \"%{py_ver}\" > \"2.4\""
1488 #print t "/.+.egg-info"
1489                         gsub(t "/.+.egg-info", t "/" s "-*.egg-info");
1490                         print
1491                         print "%endif"
1492                         return 0;
1493                 }
1494         }
1495
1496         # atrpms
1497         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1498         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1499         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1500
1501         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1502         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1503         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1504
1505         gsub("%{_datadir}/applications", "%{_desktopdir}");
1506         gsub("%{_datadir}/icons", "%{_iconsdir}");
1507         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1508         gsub("%{_datadir}/pear", "%{php_pear_dir}");
1509         gsub("%{_datadir}/php", "%{php_data_dir}");
1510
1511         return 1
1512 }
1513
1514 function use_script_macros()
1515 {
1516         if (gsub("/sbin/service", "%service")) {
1517                 sub(" >/dev/null 2>&1 \|\|:", "");
1518                 sub(" 2> /dev/null \|\| :", "");
1519         }
1520 }
1521
1522 function fill(ch, n, i) {
1523         for (i = 0; i < n; i++)
1524                 printf("%c", ch)
1525 }
1526
1527 function format_flush(line, indent, newline, word, first_word) {
1528         first_word = 1
1529         if (format_indent == -1)
1530                 newline = ""
1531         else
1532                 newline = fill(" ", format_indent) "- "
1533
1534         while (match(line, /[^\t ]+/)) {
1535                 word = substr(line, RSTART, RLENGTH)
1536                 if (length(newline) + length(word) + 1 > tw) {
1537                         print newline
1538
1539                         if (format_indent == -1)
1540                                 newline = ""
1541                         else
1542                                 newline = fill(" ", format_indent + 2)
1543                         first_word = 1
1544                 }
1545
1546                 if (first_word) {
1547                         newline = newline word
1548                         first_word = 0
1549                 } else
1550                         newline = newline " " word
1551
1552                 line = substr(line, RSTART + RLENGTH)
1553         }
1554         if (newline ~ /[^\t ]/) {
1555                 print newline
1556         }
1557 }
1558
1559 function cflags(var)
1560 {
1561         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1562                 removed[var] = 1
1563                 return 0
1564         }
1565
1566         if (!/!\?debug/)
1567                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1568         return 1
1569 }
1570
1571 function unify_url(url)
1572 {
1573
1574         # sourceforge urls
1575         # Docs about sourceforge mirror system: http://sourceforge.net/docs/B05/
1576         sub("[?&]big_mirror=.*$", "", url);
1577         sub("[?&]modtime=.*$", "", url);
1578         sub("[?]use_mirror=.*$", "", url);
1579         sub("[?]download$", "", url);
1580
1581         sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1582         sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", url)
1583         sub("^http://download\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1584         sub("^http://downloads\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1585
1586         sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1587         sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", url)
1588         sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", url)
1589
1590         sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", url)
1591         sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", url)
1592
1593         # apache urls
1594         sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", url)
1595
1596         # gnu.org
1597         sub("^ftp://ftp.gnu.org/", "http://ftp.gnu.org/", url)
1598         sub("^http://ftp.gnu.org/pub/gnu/", "http://ftp.gnu.org/gnu/", url)
1599
1600         return url
1601 }
1602
1603 function demacroize(str)
1604 {
1605         if (mod_name) {
1606                 sub("%{mod_name}", mod_name, str);
1607         }
1608         if (name) {
1609                 sub("%{name}", name, str);
1610         }
1611         if (version) {
1612                 sub("%{version}", version, str);
1613         }
1614         if (_beta) {
1615                 sub("%{_beta}", _beta, str);
1616         }
1617         if (_rc) {
1618                 sub("%{_rc}", _rc, str);
1619         }
1620         if (_pre) {
1621                 sub("%{_pre}", _pre, str);
1622         }
1623         if (_snap) {
1624                 sub("%{_snap}", _snap, str);
1625         }
1626         if (subver) {
1627                 sub("%{subver}", subver, str);
1628         }
1629         return str;
1630 }
1631
1632 function kill_preamble_macros()
1633 {
1634         if ($1 ~ /^Obsoletes:/) {
1635                 # NB! assigning $2 a value breaks tabbing
1636                 $2 = demacroize($2);
1637         }
1638         if ($1 ~ /^URL:/) {
1639                 # NB! assigning $2 a value breaks tabbing
1640                 $2 = demacroize($2);
1641                 $2 = unify_url($2)
1642         }
1643 }
1644
1645 function get_epoch(pkg, ver,    epoch)
1646 {
1647         return
1648 # should parse the BR lines more adequately:
1649 #       freetype = 2.0.0 -> correct
1650 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1651
1652         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1653         shell | getline epoch;
1654         return epoch;
1655 }
1656
1657 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1658         # skip any formatting for commented out items or some weird macros
1659         if (/^#/ || /%\(/) {
1660                 return tag "\t" value
1661         }
1662         n = split(value, p, / *,? */);
1663         for (i = 1; i <= n; i++) {
1664                 if (p[i+1] ~ /[<=>]/) {
1665                         # add epoch if the version doesn't have it but BuildRequires.txt has
1666                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1667                                 epoch = get_epoch(p[i], p[i+2])
1668                                 if (epoch) {
1669                                         p[i+2] = epoch ":" p[i+2];
1670                                 }
1671                         }
1672                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1673                         i += 2;
1674                 } else {
1675                         deps[ndeps++] = p[i];
1676                 }
1677         }
1678         s = ""
1679         for (i in deps) {
1680                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1681         }
1682         return substr(s, 1, length(s)-1);
1683 }
1684
1685 function use_tabs()
1686 {
1687         # reverse vim: ts=4 sw=4 et
1688         gsub(/    /, "\t");
1689 }
1690
1691 function add_br(br)
1692 {
1693         BR[BR_count++] = br
1694 }
1695
1696 function replace_requires()
1697 {
1698
1699         # jpackages
1700         sub(/^java-devel$/, "jdk", $2);
1701         sub(/^log4j$/, "java-log4j", $2);
1702         sub(/^logging-log4j$/, "java-log4j", $2);
1703         sub(/^jakarta-log4j$/, "java-log4j", $2);
1704         sub(/^oro$/, "java-oro", $2);
1705         sub(/^jakarta-oro$/, "java-oro", $2);
1706         sub(/^jakarta-ant$/, "ant", $2);
1707         sub(/^xerces-j2$/, "java-xerces", $2);
1708         sub(/^xerces-j$/, "java-xerces", $2);
1709         sub(/^ldapjdk$/, "ldapsdk", $2);
1710         sub(/^saxon-scripts$/, "saxon", $2);
1711         sub(/^xalan-j2$/, "java-xalan", $2);
1712         sub(/^xalan-j$/, "java-xalan", $2);
1713         sub(/^gnu-regexp$/, "java-gnu-regexp", $2);
1714         sub(/^gnu.regexp$/, "java-gnu-regexp", $2);
1715         sub(/^jakarta-commons-httpclient$/, "java-commons-httpclient", $2);
1716         sub(/^xml-commons-resolver$/, "java-xml-commons-resolver", $2);
1717         sub(/^axis$/, "java-axis", $2);
1718         sub(/^wsdl4j$/, "java-wsdl4j", $2);
1719         sub(/^uddi4j$/, "java-uddi4j", $2);
1720         sub(/^hamcrest$/, "java-hamcrest", $2);
1721
1722         # redhat virtual
1723         sub(/^tftp-server$/, "tftpdaemon", $2);
1724
1725         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2);
1726         sub(/^chkconfig$/, "/sbin/chkconfig", $2);
1727
1728         # fedora
1729         sub(/^iscsi-initiator-utils$/, "open-iscsi", $2);
1730
1731         replace_php_virtual_deps()
1732 }
1733
1734 # php virtual deps as discussed in devel-en
1735 function replace_php_virtual_deps()
1736 {
1737         pkg = $2
1738 #       if (pkg == "php-program") {
1739 #               $0 = $1 "\t/usr/bin/php"
1740 #               return
1741 #       }
1742
1743 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1744 #               sub(/^php-/, "php(", pkg);
1745 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1746 #               $2 = pkg
1747 #       }
1748
1749         if (pkg ~/^php$/) {
1750                 $2 = "webserver(php)";
1751                 if ($4 ~ /^[0-9]:/) {
1752                         $4 = substr($4, 3);
1753                 }
1754         }
1755
1756         if (pkg ~/^php4$/) {
1757                 $2 = "webserver(php)";
1758                 if ($4 ~ /^[0-9]:/) {
1759                         $4 = substr($4, 3);
1760                 }
1761         }
1762 }
1763
1764 # Load rpm macros
1765 # you should update the list also in adapter when making changes here
1766 function import_rpm_macros() {
1767         # File with rpm groups
1768         topdir = ENVIRON["_topdir"]
1769
1770         if (!topdir) {
1771                 print "adapter.awk should not not be invoked directly, but via adapter script" > "/dev/stderr"
1772                 do_not_touch_anything = 1
1773                 exit(1);
1774         }
1775
1776         # get cvsaddress for changelog section
1777         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
1778         _cvsmaildomain = ENVIRON["_cvsmaildomain"]
1779         _cvsmailfeedback = ENVIRON["_cvsmailfeedback"]
1780
1781         prefix = ENVIRON["_prefix"]
1782         bindir = ENVIRON["_bindir"]
1783         sbindir = ENVIRON["_sbindir"]
1784         libdir = ENVIRON["_libdir"]
1785         sysconfdir = ENVIRON["_sysconfdir"]
1786         datadir = ENVIRON["_datadir"]
1787         includedir = ENVIRON["_includedir"]
1788         mandir = ENVIRON["_mandir"]
1789         infodir = ENVIRON["_infodir"]
1790         examplesdir = ENVIRON["_examplesdir"]
1791         docdir = ENVIRON["_defaultdocdir"]
1792         kdedocdir = ENVIRON["_kdedocdir"]
1793         gtkdocdir = ENVIRON["_gtkdocdir"]
1794         desktopdir = ENVIRON["_desktopdir"]
1795         pixmapsdir = ENVIRON["_pixmapsdir"]
1796         javadir = ENVIRON["_javadir"]
1797
1798         perl_sitearch = ENVIRON["perl_sitearch"]
1799         perl_archlib = ENVIRON["perl_archlib"]
1800         perl_privlib = ENVIRON["perl_privlib"]
1801         perl_vendorlib = ENVIRON["perl_vendorlib"]
1802         perl_vendorarch = ENVIRON["perl_vendorarch"]
1803         perl_sitelib = ENVIRON["perl_sitelib"]
1804
1805         py_sitescriptdir = ENVIRON["py_sitescriptdir"]
1806         py_sitedir = ENVIRON["py_sitedir"]
1807         py_scriptdir = ENVIRON["py_scriptdir"]
1808         py_ver = ENVIRON["py_ver"]
1809
1810         ruby_archdir = ENVIRON["ruby_archdir"]
1811         ruby_ridir = ENVIRON["ruby_ridir"]
1812         ruby_rubylibdir = ENVIRON["ruby_rubylibdir"]
1813         ruby_sitearchdir = ENVIRON["ruby_sitearchdir"]
1814         ruby_sitelibdir = ENVIRON["ruby_sitelibdir"]
1815         ruby_rdocdir = ENVIRON["ruby_rdocdir"]
1816
1817         php_pear_dir = ENVIRON["php_pear_dir"]
1818         php_data_dir = ENVIRON["php_data_dir"]
1819         tmpdir = ENVIRON["tmpdir"]
1820 }
1821
1822 function replace_groupnames(group) {
1823         group = replace(group, "Amusements/Games/Strategy/Real Time", "X11/Applications/Games/Strategy");
1824         group = replace(group, "Application/Multimedia", "Applications/Multimedia");
1825         group = replace(group, "Application/System", "Applications/System");
1826         group = replace(group, "Applications/Compilers", "Development/Languages");
1827         group = replace(group, "Applications/Daemons", "Daemons");
1828         group = replace(group, "Applications/Internet", "Applications/Networking");
1829         group = replace(group, "Applications/Internet/Peer to Peer", "Applications/Networking");
1830         group = replace(group, "Applications/Productivity", "X11/Applications");
1831         group = replace(group, "Database", "Applications/Databases");
1832         group = replace(group, "Development/C", "Development/Libraries");
1833         group = replace(group, "Development/Code Generators", "Development");
1834         group = replace(group, "Development/Docs", "Documentation");
1835         group = replace(group, "Development/Documentation", "Documentation");
1836         group = replace(group, "Development/Java", "Development/Languages/Java");
1837         group = replace(group, "Development/Languages/Other", "Development/Languages");;
1838         group = replace(group, "Development/Languages/Ruby", "Development/Languages");
1839         group = replace(group, "Development/Libraries/C and C++", "Development/Libraries");
1840         group = replace(group, "Development/Libraries/Java", "Development/Languages/Java");
1841         group = replace(group, "Development/Libraries/Python", "Development/Languages/Python");
1842         group = replace(group, "Development/Libraries/TCL", "Development/Languages/Tcl");;
1843         group = replace(group, "Development/Other", "Development");
1844         group = replace(group, "Development/Python", "Development/Languages/Python");
1845         group = replace(group, "Development/Testing", "Development");
1846         group = replace(group, "Emulators", "Applications/Emulators");
1847         group = replace(group, "Games", "Applications/Games");
1848         group = replace(group, "Library/Development", "Development/Libraries");
1849         group = replace(group, "Networking/Deamons", "Networking/Daemons");
1850         group = replace(group, "Productivity/Databases/Servers", "Applications/Databases");
1851         group = replace(group, "Productivity/Networking/Web/Servers", "Networking/Daemons/HTTP");;
1852         group = replace(group, "Shells", "Applications/Shells");
1853         group = replace(group, "System Environment/Base", "Base");
1854         group = replace(group, "System Environment/Daemons", "Daemons");
1855         group = replace(group, "System Environment/Kernel", "Base/Kernel");
1856         group = replace(group, "System Environment/Libraries", "Libraries");
1857         group = replace(group, "System", "Base");
1858         group = replace(group, "System/Base", "Base");
1859         group = replace(group, "System/Kernel and hardware", "Base/Kernel");
1860         group = replace(group, "System/Libraries", "Libraries");
1861         group = replace(group, "System/Servers", "Daemons");
1862         group = replace(group, "Text Processing/Markup/HTML", "Applications/Text");
1863         group = replace(group, "Text Processing/Markup/XML", "Applications/Text");
1864         group = replace(group, "Web/Database", "Applications/WWW");
1865         group = replace(group, "X11/GNOME", "X11/Applications");
1866         group = replace(group, "X11/GNOME/Applications", "X11/Applications");
1867         group = replace(group, "X11/GNOME/Development/Libraries", "X11/Development/Libraries");
1868         group = replace(group, "X11/Games", "X11/Applications/Games");
1869         group = replace(group, "X11/Games/Strategy", "X11/Applications/Games/Strategy");
1870         group = replace(group, "X11/Library", "X11/Libraries");
1871         group = replace(group, "X11/Utilities", "X11/Applications");
1872         group = replace(group, "X11/XFree86", "X11");
1873         group = replace(group, "X11/Xserver", "X11/Servers");
1874
1875         return group;
1876 }
1877
1878 # vim:ts=4:sw=4