adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # Adapter adapts .spec files for PLD Linux.
   4 #
   5 # Copyright (C) 1999-2010 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Michał Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Jakub Bogusz <qboosh@pld-linux.org>
  13 #       Elan Ruusamäe <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - really long sourceX make preamble sorting totally fcked up (try snake.spec r1.1)
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27 # - it should change: /%source([0-9]+)/i to %{SOURCE\1}
  28 # - extra quote on LDFLAGS line: https://bugs.launchpad.net/pld-linux/+bug/385836
  29 # - %{with_foo:%attr()...} gets converted to %attr() %{with_foo:...} [vlc.spec]
  30 # - 'R: foo ' (with traliling space) gets coverted to "R: foo\nR: " [vlc.spec @ 1.199 ]
  31
  32 BEGIN {
  33         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  34         SECTIONS = "^%(" RPM_SECTIONS ")"
  35
  36         RCSID = "$Id$"
  37         rev = RCSID # TODO: parse from RCSID
  38         VERSION = "0.35/" rev
  39
  40         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests|Auto(Req|Prov))"
  41
  42         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  43
  44         preamble = 1    # Is it part of preamble? Default - yes
  45         boc = 4                 # Beginning of %changelog
  46         bod = 0                 # Beginning of %description
  47         tw = 70                 # Descriptions width
  48
  49         b_idx = 0               # index of BR/R arrays
  50         BR_count = 0    # number of additional BuildRequires
  51
  52         # If variable removed, then 1 (for removing it from export)
  53         removed["LDFLAGS"] = 0
  54         removed["CFLAGS"] = 0
  55         removed["CXXFLAGS"] = 0
  56
  57         # If 1, we are inside of comment block (started with /^#%/)
  58         comment_block = 0
  59
  60         import_rpm_macros()
  61
  62         packages_dir = topdir
  63         groups_file = packages_dir "/rpm.groups"
  64
  65         system("cd "packages_dir"; [ -f rpm.groups ] || cvs up rpm.groups > /dev/null")
  66         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  67
  68         # Temporary file for changelog section
  69         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  70 }
  71
  72 # There should be a comment with CVS keywords on the first line of file.
  73 FNR == 1 {
  74         if (!/# \$Revision:/)   # If this line is already OK?
  75                 print "# $" "Revision:$, " "$" "Date:$" # No
  76         else {
  77                 print $0                                # Yes
  78                 next            # It is enough for first line
  79         }
  80 }
  81
  82 # If the latest line matched /%files/
  83 defattr == 1 {
  84         if (ENVIRON["SKIP_DEFATTR"] != 1) {
  85                 if ($0 !~ /defattr/) {  # If no %defattr
  86                         print "%defattr(644,root,root,755)"     # Add it
  87                 } else {
  88                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  89                 }
  90         }
  91         defattr = 0
  92 }
  93
  94 function b_makekey(a, b,        s) {
  95         s = a "" b;
  96         # kill bcond
  97         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
  98
  99         # kill commented out items
 100         gsub(/^#[ \t]*/, "", s);
 101
 102         # force order
 103         gsub(/^Summary\(/, "11Summary(", s);
 104         gsub(/^Summary/, "10Summary", s);
 105
 106         gsub(/^Name/, "2Name", s);
 107         gsub(/^Version/, "3Version", s);
 108         gsub(/^Release/, "4Release", s);
 109         gsub(/^Epoch/, "5Epoch", s);
 110         gsub(/^License/, "5License", s);
 111         gsub(/^Group/, "6Group", s);
 112         gsub(/^URL/, "7URL", s);
 113
 114         gsub(/^BuildRequires/, "B1BuildRequires", s);
 115         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 116
 117         gsub(/^Suggests/, "X1Suggests", s);
 118         gsub(/^Provides/, "X2Provides", s);
 119         gsub(/^Obsoletes/, "X3Obsoletes", s);
 120         gsub(/^Conflicts/, "X4Conflicts", s);
 121         gsub(/^BuildArch/, "X5BuildArch", s);
 122         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 123         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 124         gsub(/^BuildRoot/, "X9BuildRoot", s);
 125
 126         gsub(/^AutoProv/, "Xx1AutoProv", s);
 127         gsub(/^AutoReq/, "Xx2AutoReq", s);
 128
 129 #       printf("%s -> %s\n", a""b, s);
 130         return s;
 131 }
 132
 133 # Comments
 134 /^#/ && (description == 0) {
 135         if (/This file does not like to be adapterized!/) {
 136                 print                   # print this message
 137                 while (getline)         # print the rest of spec as it is
 138                         print
 139                 do_not_touch_anything = 1 # do not touch anything in END()
 140                 exit(rc = 0)
 141         }
 142
 143         # Generally, comments are printed without touching
 144         sub(/[ \t]+$/, "")
 145
 146         if (/#[ \t]*Source.*md5/) {
 147                 if (usedigest == 1) {
 148                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 149                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 150                 }
 151                 print $0
 152                 next
 153         }
 154 }
 155
 156 /^%define/ {
 157         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 158         if ($2 == "_applnkdir") {
 159                 next
 160         }
 161         if ($2 == "date") {
 162                 date = 1
 163                 if (did_files == 0) {
 164                         print "%files"
 165                         print ""
 166                         did_files = 1
 167                 }
 168         }
 169
 170         # Do not add %define of _prefix if it already is.
 171         if ($2 ~ /^_prefix/) {
 172                 sub("^"prefix, $3, bindir)
 173                 sub("^"prefix, $3, sbindir)
 174                 sub("^"prefix, $3, libdir)
 175                 sub("^"prefix, $3, datadir)
 176                 sub("^"prefix, $3, includedir)
 177                 prefix = $3
 178         }
 179
 180         if ($2 ~ /_bindir/ && !/_sbindir/)
 181                 bindir = $3
 182         if ($2 ~ /_sbindir/)
 183                 sbindir = $3
 184         if ($2 ~ /_libdir/) {
 185                 if ($3 ~ /^%\(/) {
 186                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 187                         libdir = "%%%%%%%%%%%%%%"
 188                 } else {
 189                         libdir = $3
 190                 }
 191         }
 192         if ($2 ~ /_sysconfdir/) {
 193                 if ($3 ~ /^%\(/) {
 194                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 195                         sysconfdir = "%%%%%%%%%%%%%%"
 196                 } else {
 197                         sysconfdir = $3
 198                 }
 199         }
 200         if ($2 ~ /_datadir/) {
 201                 if ($3 ~ /^%\(/) {
 202                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 203                         datadir = "%%%%%%%%%%%%%%"
 204                 } else {
 205                         datadir = $3
 206                 }
 207         }
 208         if ($2 ~ /_includedir/)
 209                 includedir = $3
 210         if ($2 ~ /_mandir/)
 211                 mandir = $3
 212         if ($2 ~ /_infodir/)
 213                 infodir = $3
 214         if ($2 ~ /_docdir/)
 215                 docdir = $3
 216
 217         # version related macros
 218         if ($2 ~ /^_beta$/)
 219                 _beta = $3
 220         if ($2 ~ /^_rc$/)
 221                 _rc = $3
 222         if ($2 ~ /^_pre$/)
 223                 _pre = $3
 224         if ($2 ~ /^_snap$/)
 225                 _snap = $3
 226         if ($2 ~ /^subver$/)
 227                 subver = $3
 228
 229         # these are used usually when adapterizing external spec
 230         if ($2 ~ /^name$/)
 231                 name = $3
 232         if ($2 ~ /^version$/)
 233                 version = $3
 234         if ($2 ~ /^release$/)
 235                 release = $3
 236
 237         if ($2 ~ /^mod_name$/)
 238                 mod_name = $3
 239
 240         sub(/[ \t]+$/, "");
 241         # do nothing further, otherwise adapter thinks we're at preamble
 242         print
 243         next
 244 }
 245
 246 # Obsolete
 247 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 248         next
 249 }
 250
 251 ################
 252 # %description #
 253 ################
 254 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 255         preamble = 0
 256
 257         if (/^%description/) {
 258                 bod++
 259                 format_line = ""
 260                 format_indent = -1
 261         }
 262
 263         # Format description
 264         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 265                 if (/^[ \t]*$/) {
 266                         format_flush(format_line, format_indent)
 267                         print ""
 268                         format_line = ""
 269                         format_indent = -1
 270                 } else if (/^[ \t]*[-\*][ \t]*/) {
 271                         format_flush(format_line, format_indent)
 272                         match($0, /^[ \t]*/)
 273                         format_indent = RLENGTH
 274                         match($0, /^[ \t]*[-\*][ \t]/)
 275                         format_line = substr($0, RLENGTH)
 276                 } else
 277                         format_line = format_line " " $0
 278                 next
 279         }
 280
 281         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 282                 if (NF > 3 && $2 == "-l") {
 283                         ll = $1
 284                         for (i = 4; i <= NF; i++)
 285                                 ll = ll " " $i
 286                         $0 = ll " -l " $3
 287                 }
 288                 format_flush(format_line, format_indent)
 289                 if (bod == 2) {
 290                         bod = 1
 291                         description = 1
 292                 } else {
 293                         bod = 0
 294                         description = 0
 295                 }
 296         } else
 297                 description = 1
 298 }
 299
 300 #########
 301 # %prep #
 302 #########
 303 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 304         preamble = 0
 305         did_prep = 1
 306
 307         use_macros()
 308
 309         # Add '-q' to %setup
 310         if (/^%setup/ && !/-q/) {
 311                 sub(/^%setup/, "%setup -q")
 312         }
 313
 314         if (/^%setup/ && name != "setup") {
 315                 $0 = fixedsub(name, "%{name}", $0);
 316                 $0 = fixedsub(version, "%{version}", $0);
 317                 if (_beta) {
 318                         $0 = fixedsub(_beta, "%{_beta}", $0);
 319                 }
 320                 if (_rc) {
 321                         $0 = fixedsub(_rc, "%{_rc}", $0);
 322                 }
 323                 if (_pre) {
 324                         $0 = fixedsub(_pre, "%{_pre}", $0);
 325                 }
 326                 if (_snap) {
 327                         $0 = fixedsub(_snap, "%{_snap}", $0);
 328                 }
 329                 if (subver) {
 330                         $0 = fixedsub(subver, "%{subver}", $0);
 331                 }
 332         }
 333
 334         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 335                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 336         }
 337         sub("^%patch ", "%patch0 ");
 338
 339         # invalid in %prep
 340         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 341 }
 342
 343 ##########
 344 # %build #
 345 ##########
 346 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 347         preamble = 0
 348
 349         if (did_prep == 0) {
 350                 print "%prep"
 351                 print ""
 352                 did_prep = 1
 353         }
 354
 355         use_macros()
 356         use_tabs()
 357
 358         if (/^automake$/)
 359                 sub(/$/, " -a -c")
 360
 361         if (/LDFLAGS/) {
 362                 if (/LDFLAGS="-s"/) {
 363                         removed["LDFLAGS"] = 1
 364                         next
 365                 } else {
 366                         split($0, tmp, "LDFLAGS=")
 367                         count = split(tmp[2], flags, "\"")
 368                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 369                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 370                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 371                                 for (i = 2; i < count; i++)
 372                                         $0 = $0 flags[i] "\""
 373                         }
 374                 }
 375         }
 376
 377         if (/CFLAGS=/)
 378                 if (cflags("CFLAGS") == 0)
 379                         next
 380
 381         if (/CXXFLAGS=/)
 382                 if (cflags("CXXFLAGS") == 0)
 383                         next
 384
 385         if (/^export /) {
 386                 if (removed["LDFLAGS"])
 387                         sub(" LDFLAGS", "")
 388                 if (removed["CFLAGS"])
 389                         sub(" CFLAGS", "")
 390                 if (removed["CXXFLAGS"])
 391                         sub(" CXXFLAGS", "")
 392                 # Is there still something?
 393                 if (/^export[ ]*$/)
 394                         next
 395         }
 396
 397         # quote CC
 398         if (/CC=%{__cc} /) {
 399                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 400         }
 401
 402         # use PLD Linux macros
 403         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 404         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 405         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 406         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 407         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 408         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 409         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 410         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 411
 412         sub(/^aclocal$/, "%{__aclocal}");
 413         sub(/^autoheader$/, "%{__autoheader}");
 414         sub(/^autoconf$/, "%{__autoconf}");
 415         sub(/^automake$/, "%{__automake}");
 416         sub(/^libtoolize$/, "%{__libtoolize}");
 417
 418         # atrpms
 419         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 420         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 421
 422         # alt linux
 423         $0 = fixedsub("%make_build", "%{__make}", $0);
 424 }
 425
 426 ##########
 427 # %clean #
 428 ##########
 429 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 430         did_clean = 1
 431
 432         use_macros()
 433 }
 434
 435 ############
 436 # %install #
 437 ############
 438 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 439
 440         preamble = 0
 441
 442         # foreign rpms
 443         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 444         sub("%buildroot", "$RPM_BUILD_ROOT");
 445         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 446
 447         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 448                 did_rmroot=1
 449                 print "rm -rf $RPM_BUILD_ROOT"
 450                 next
 451         }
 452
 453         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 454                 print "rm -rf $RPM_BUILD_ROOT"
 455                 did_rmroot=1
 456         }
 457
 458         if (tmpdir) {
 459                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 460                 gsub(buildroot, "$RPM_BUILD_ROOT")
 461         }
 462
 463         if (!/%{_lib}/) {
 464                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 465         }
 466
 467         use_macros()
 468
 469         # 'install -d' instead 'mkdir -p'
 470         if (/mkdir -p/)
 471                 sub(/mkdir -p/, "install -d")
 472
 473         # cp -a already implies cp -r
 474         sub(/^cp -ar/, "cp -a")
 475
 476         # No '-u root' or '-g root' for 'install'
 477         if (/^install/ && /-[ug][ \t]*root/)
 478                 gsub(/-[ug][ \t]*root /, "")
 479
 480         if (/^install/ && /-m[ \t]*[0-9]+/)
 481                 gsub(/-m[ \t]*[0-9]+ /, "")
 482
 483         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 484         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 485                 next
 486
 487         # No lines contain 'chmod' if it sets the modes to '644'
 488         if ($1 ~ /chmod/ && $2 ~ /644/)
 489                 next
 490
 491         # atrpms
 492         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 493
 494         # alt linux
 495         $0 = fixedsub("%make_install DESTDIR=$RPM_BUILD_ROOT install", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 496 }
 497
 498 ##########
 499 # %files #
 500 ##########
 501 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 502         preamble = 0
 503         did_files = 1
 504
 505         if ($0 ~ /^%files/)
 506                 defattr = 1
 507
 508         if (!use_files_macros()) {
 509                 next
 510         }
 511 }
 512
 513 ##############
 514 # %changelog #
 515 ##############
 516 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 517         preamble = 0
 518         has_changelog = 1
 519         skip = 0
 520         # There should be some CVS keywords on the first line of %changelog.
 521         if (boc == 3) {
 522                 if ($0 !~ _cvsmailfeedback) {
 523                         print "* %{date} " _cvsmailfeedback > changelog_file
 524                 } else {
 525                         skip = 1
 526                 }
 527                 boc = 2
 528         }
 529         if (boc == 2 && !skip) {
 530                 if (!/All persons listed below/) {
 531                         printf "All persons listed below can be reached at " > changelog_file
 532                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 533                 } else {
 534                         skip = 1
 535                 }
 536                 boc = 1
 537         }
 538         if (boc == 1 && !skip) {
 539                 if (!/^$/) {
 540                         if (!/\$.*Log:.*\$/) {
 541                                 print "$" "Log:$" > changelog_file
 542                         }
 543                         boc = 0
 544                 }
 545         }
 546         # Define date macro.
 547         if (boc == 4) {
 548                 if (date == 0) {
 549                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 550                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 551                         date = 1
 552                 }
 553                 boc = 3
 554         }
 555
 556         sub(/[ \t]+$/, "");
 557         if (!/^%[a-z]+$/ || /changelog/) {
 558                 # stop changelog if "real" changelog starts
 559                 if (boc == 0 && /^\* /) {
 560                         boc = -1
 561                 }
 562                 if (boc == -1) {
 563                         next;
 564                 }
 565                 print > changelog_file
 566         } else {
 567                 print
 568         }
 569         next
 570 }
 571
 572 ###########
 573 # SCRIPTS #
 574 ###########
 575 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 576         preamble = 0
 577
 578         if (gsub("/usr/sbin/useradd", "%useradd")) {
 579                 sub(" 2> /dev/null \|\| :", "");
 580                 sub(" >/dev/null 2>&1 \|\|:", "");
 581         }
 582
 583         # %useradd and %groupadd may not be wrapped
 584         if (/%(useradd|groupadd).*\\$/) {
 585                 a = $0; getline;
 586                 sub(/^[\s\t]*/, "");
 587                 $0 = substr(a, 1, length(a) - 1) $0;
 588         }
 589         use_script_macros()
 590 }
 591
 592 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 593         preamble = 0
 594         use_macros()
 595 }
 596 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 597         preamble = 0
 598         use_macros()
 599 }
 600 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 601         preamble = 0
 602         use_script_macros()
 603 }
 604 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 605         preamble = 0
 606         use_script_macros()
 607 }
 608 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 609         preamble = 0
 610         use_script_macros()
 611 }
 612 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 613         preamble = 0
 614         use_script_macros()
 615 }
 616 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 617         preamble = 0
 618         use_script_macros()
 619 }
 620 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 621         preamble = 0
 622         use_script_macros()
 623 }
 624 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 625         preamble = 0
 626         use_script_macros()
 627 }
 628 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 629         preamble = 0
 630         use_script_macros()
 631 }
 632
 633 #############
 634 # PREAMBLES #
 635 #############
 636 preamble == 1 {
 637         # There should not be a space after the name of field
 638         # and before the colon.
 639         sub(/[ \t]*:/, ":")
 640
 641         if (/^%perl_module_wo_prefix/) {
 642                 name = $2
 643                 version = $3
 644                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 645         }
 646
 647         field = tolower($1)
 648         fieldnlower = $1
 649         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 650                 sub(/\.$/, "", $0);
 651         }
 652         if (field ~ /group(\([^)]+\)):/)
 653                 next
 654         if (field ~ /group:/) {
 655                 format_preamble()
 656                 group = $0;
 657                 sub(/^[^ \t]*[ \t]*/, "", group);
 658                 group = replace_groupnames(group);
 659                 $0 = "Group:\t\t" group
 660
 661                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 662                         x11 = 1
 663
 664                 byl_plik_z_groupmi = 0
 665                 byl_opis_grupy = 0
 666                 while ((getline linia_grup < groups_file) > 0) {
 667                         byl_plik_z_groupmi = 1
 668                         if (linia_grup == group) {
 669                                 byl_opis_grupy = 1
 670                                 break
 671                         }
 672                 }
 673
 674                 if (!byl_plik_z_groupmi)
 675                         print "######\t\t" groups_file ": no such file"
 676                 else if (!byl_opis_grupy)
 677                         print "######\t\t" "Unknown group!"
 678
 679                 close(groups_file)
 680                 did_groups = 1
 681         }
 682
 683         if (field ~ /prereq:/) {
 684                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 685         }
 686
 687         # split (build)requires, obsoletes on commas
 688         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 689                 value = substr($0, index($0, $2));
 690                 $0 = format_requires($1, value);
 691         }
 692
 693         # BR: tar (and others) is to common (rpm-build requires it)
 694         if (field ~ /^buildrequires:/) {
 695                 l = substr($0, index($0, $2));
 696                 if (l == "awk" ||
 697                         l == "binutils" ||
 698                         l == "bzip2" ||
 699                         l == "cpio" ||
 700                         l == "diffutils" ||
 701                         l == "elfutils" ||
 702                         l == "fileutils" ||
 703                         l == "findutils" ||
 704                         l == "glibc-devel" ||
 705                         l == "grep" ||
 706                         l == "gzip" ||
 707                         l == "make" ||
 708                         l == "patch" ||
 709                         l == "sed" ||
 710                         l == "sh-utils" ||
 711                         l == "tar" ||
 712                         l == "textutils") {
 713                         next
 714                 }
 715
 716                 replace_requires();
 717         }
 718
 719         if (field ~ /^requires:/ || field ~ /^requires\(/) {
 720                 replace_requires();
 721         }
 722
 723
 724         # obsolete/unwanted tags
 725         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 726                 next
 727         }
 728
 729         if (field ~ /buildroot:/) {
 730                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 731                 did_build_root = 1
 732         }
 733
 734         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 735         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 736                 $1 = "License:"
 737         }
 738
 739         # ease updating from debian .dsc
 740         if (field ~ /homepage:/) {
 741                 $1 = "URL:"
 742         }
 743
 744         if (field ~ /license:/) {
 745                 l = substr($0, index($0, $2));
 746                 if (l == "Python Software Foundation License") {
 747                         l = "PSF"
 748                 }
 749                 if (l == "Apache License 2.0" || l == "Apache 2.0" || l == "Apache License Version 2.0" || l == "Apache License, Version 2.0" || l == "Apache Software License v2") {
 750                         l = "Apache v2.0"
 751                 }
 752                 if (l == "Apache Group License" || l == "Apache Software License" || l == "Apache License") {
 753                         l = "Apache"
 754                 }
 755                 if (l == "Apache-style License" || l == "Apache-style Software License") {
 756                         l = "Apache-like"
 757                 }
 758                 if (l == "Apache Software License 1.1" || l == "Apache 1.1") {
 759                         l = "Apache v1.1"
 760                 }
 761                 if (l == "GPLv2") {
 762                         l = "GPL v2"
 763                 }
 764                 if (l == "GPLv2+") {
 765                         l = "GPL v2+"
 766                 }
 767                 if (l == "LGPLv2+") {
 768                         l = "LGPL v2+"
 769                 }
 770                 if (l == "GPLv3") {
 771                         l = "GPL v3"
 772                 }
 773                 if (l == "GPLv3+") {
 774                         l = "GPL v3+"
 775                 }
 776                 if (l == "MPLv1.1") {
 777                         l = "MPL v1.1"
 778                 }
 779                 $0 = "License:\t" l;
 780         }
 781
 782
 783         if (field ~ /name:/) {
 784                 if ($2 == "%{name}" && name) {
 785                         $2 = name
 786                 }
 787                 name = $2
 788                 name_seen = 1;
 789         }
 790
 791         if (field ~ /version:/) {
 792                 if ($2 == "%{version}" && version) {
 793                         $2 = version
 794                 }
 795                 version = $2
 796                 version_seen = 1;
 797         }
 798
 799         if (field ~ /release:/) {
 800                 if ($2 == "%{release}" && release) {
 801                         $2 = release
 802                 }
 803                 sub(/%atrelease /, "0.", $0)
 804                 release = $2
 805                 release_seen = 1;
 806         }
 807
 808
 809         if (field ~ /serial:/)
 810                 $1 = "Epoch:"
 811
 812         if (field ~ /home-page:/)
 813                 $1 = "URL:"
 814
 815         # proper caps
 816         if (field ~ /^url:$/)
 817                 $1 = "URL:"
 818
 819         if (field ~ /^patch/)
 820                 $1 = "Patch" substr(field, 6);
 821
 822         if (field ~ /^description:$/)
 823                 $1 = "\n%description\n"
 824
 825         # Use %{name} and %{version} in the filenames in "Source:"
 826         if (field ~ /^source/ || field ~ /patch/) {
 827                 n = split($2, url, /\//)
 828                 if (url[n] ~ /\.gz$/) {
 829                         url[n+1] = ".gz" url[n+1]
 830                         sub(/\.gz$/,"",url[n])
 831                 }
 832                 if (url[n] ~ /\.zip$/) {
 833                         url[n+1] = ".zip" url[n+1]
 834                         sub(/\.zip$/,"",url[n])
 835                 }
 836                 if (url[n] ~ /\.tar$/) {
 837                         url[n+1] = ".tar" url[n+1]
 838                         sub(/\.tar$/,"",url[n])
 839                 }
 840                 if (url[n] ~ /\.patch$/) {
 841                         url[n+1] = ".patch" url[n+1]
 842                         sub(/\.patch$/,"",url[n])
 843                 }
 844                 if (url[n] ~ /\.bz2$/) {
 845                         url[n+1] = ".bz2" url[n+1]
 846                         sub(/\.bz2$/,"",url[n])
 847                 }
 848                 if (url[n] ~ /\.logrotate$/) {
 849                         url[n+1] = ".logrotate" url[n+1]
 850                         sub(/\.logrotate$/,"",url[n])
 851                 }
 852                 if (url[n] ~ /\.pamd$/) {
 853                         url[n+1] = ".pamd" url[n+1]
 854                         sub(/\.pamd$/,"",url[n])
 855                 }
 856
 857                 # allow %{name} only in last url component
 858                 s = ""
 859                 for (i = 1; i <= n; i++) {
 860                         url[i] = fixedsub("%{name}", name, url[i])
 861                         if (s) {
 862                                 s = s "/" url[i]
 863                         } else {
 864                                 s = url[i]
 865                         }
 866                 }
 867                 $2 = s url[n+1]
 868
 869                 filename = url[n]
 870                 if (name) {
 871                         url[n] = fixedsub(name, "%{name}", url[n])
 872                 }
 873                 if (field ~ /source/) {
 874                         if (version) {
 875                                 url[n] = fixedsub(version, "%{version}", url[n])
 876                         }
 877                         if (_beta) {
 878                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 879                         }
 880                         if (_rc) {
 881                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 882                         }
 883                         if (_pre) {
 884                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 885                         }
 886                         if (_snap) {
 887                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 888                         }
 889                         if (subver) {
 890                                 url[n] = fixedsub(subver, "%{subver}", url[n])
 891                         }
 892                 }
 893                 # assigning to $2 kills preamble formatting
 894                 $2 = fixedsub(filename, url[n], $2)
 895
 896                 $2 = unify_url($2)
 897         }
 898
 899
 900         if (field ~ /^source:/)
 901                 $1 = "Source0:"
 902
 903         if (field ~ /^patch:/)
 904                 $1 = "Patch0:"
 905
 906         kill_preamble_macros();
 907         format_preamble()
 908
 909         if (field ~ /requires/) {
 910                 # atrpms
 911                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 912         }
 913 }
 914
 915 /^%bcond_/ {
 916         # do nothing
 917         print
 918         next
 919 }
 920
 921 # sort BR/R!
 922 #
 923 # NOTES:
 924 # - mixing BR/R and anything else confuses this (all will be sorted together)
 925 #       so don't do that.
 926 # - comments leading the BR/R can not be associated,
 927 #       so don't adapterize when the BR/R are mixed with comments
 928 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 929         if ($1 ~ /Pre[Rr]eq:/) {
 930                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 931         }
 932         if ($1 == "BR:" ) {
 933                 $1 = "BuildRequires:"
 934         }
 935         if ($1 == "R:" ) {
 936                 $1 = "Requires:"
 937         }
 938         format_preamble()
 939 #       kill_preamble_macros(); # breaks tabbing
 940
 941         b_idx++;
 942         l = substr($0, index($0, $2));
 943         b_ktmp = b_makekey($1, l);
 944         b_key[b_idx] = b_ktmp;
 945         b_val[b_ktmp] = $0;
 946
 947         next;
 948 }
 949
 950 preamble == 1 {
 951         if (b_idx > 0) {
 952                 isort(b_key, b_idx);
 953                 for (i = 1; i <= b_idx; i++) {
 954                         v = b_val[b_key[i]];
 955                         sub(/[ \t]+$/, "", v);
 956                         print "" v;
 957                 }
 958                 b_idx = 0
 959         }
 960 }
 961
 962 # main() ;-)
 963 {
 964         preamble = 1
 965
 966         sub(/[ \t]+$/, "")
 967         print
 968
 969         if (name_seen == 0 && name) {
 970                 print "Name:\t\t" name
 971                 name_seen = 1
 972         }
 973
 974         if (version_seen == 0 && version) {
 975                 print "Version:\t" version
 976                 version_seen = 1
 977         }
 978
 979         if (release_seen == 0 && release) {
 980                 print "Release:\t" release
 981                 release_seen = 1
 982         }
 983
 984         if (did_build_root == 0) {
 985 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 986                 did_build_root = 1
 987         }
 988         if (did_groups == 0) {
 989 #               print "Group:\t\tunknown"
 990                 did_groups = 1
 991         }
 992 }
 993
 994
 995 END {
 996         if (do_not_touch_anything) {
 997                 exit(rc)
 998         }
 999
1000         # TODO: need to output these in proper place
1001         if (BR_count > 0) {
1002                 for (i = 0; i <= BR_count; i++) {
1003                         print BR[i];
1004                 }
1005         }
1006
1007         close(changelog_file)
1008         while ((getline < changelog_file) > 0)
1009                 print
1010         system("rm -f " changelog_file)
1011
1012         if (did_clean == 0) {
1013                 print ""
1014                 print "%clean"
1015                 print "rm -rf $RPM_BUILD_ROOT"
1016         }
1017
1018         if (date == 0) {
1019                 print ""
1020                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1021         }
1022
1023         if (has_changelog == 0) {
1024                 print "%changelog"
1025         }
1026
1027         if (boc > 2) {
1028                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1029         }
1030         if (boc > 1) {
1031                 printf "All persons listed below can be reached at "
1032                 print "<cvs_login>@pld-linux.org\n"
1033         }
1034         if (boc > 0) {
1035                 print "$" "Log:$"
1036         }
1037 }
1038
1039 # substitutes fixed strings (not regexps)
1040 function fixedsub(s1,s2,t, ind) {
1041         if (ind = index(t,s1))
1042                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1043         return t
1044 }
1045
1046 # replace s with s2 if it equals to s1
1047 function replace(s, s1, s2) {
1048         if (s == s1) {
1049                 return s2;
1050         } else {
1051                 return s;
1052         }
1053 }
1054
1055 # There should be one or two tabs after the colon.
1056 function format_preamble()
1057 {
1058         if (/^#/ || /^%bcond_with/) {
1059                 return;
1060         }
1061         sub(/:[ \t]*/, ":")
1062         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1063                 if (RLENGTH < 8) {
1064                         sub(/:/, ":\t\t")
1065                 } else {
1066                         sub(/:/, ":\t")
1067                 }
1068         }
1069 }
1070
1071 # Replace directly specified directories with macros
1072 function use_macros()
1073 {
1074         # -m, --skip-macros, --no-macros -- skip macros subst
1075         if (ENVIRON["SKIP_MACROS"]) {
1076                 return
1077         }
1078
1079         # leave inline sed lines alone
1080         if (/(%{__sed}|sed) -i -e/) {
1081                 return;
1082         }
1083
1084         sub("%{_defaultdocdir}", "%{_docdir}");
1085         sub("%{_bindir}/perl", "%{__perl}");
1086         sub("%{_bindir}/python", "%{__python}");
1087
1088         gsub(infodir, "%{_infodir}")
1089
1090         gsub(perl_sitearch, "%{perl_sitearch}")
1091         gsub(perl_archlib, "%{perl_archlib}")
1092         gsub(perl_privlib, "%{perl_privlib}")
1093         gsub(perl_vendorlib, "%{perl_vendorlib}")
1094         gsub(perl_vendorarch, "%{perl_vendorarch}")
1095         gsub(perl_sitelib, "%{perl_sitelib}")
1096
1097         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1098         gsub(py_sitedir, "%{py_sitedir}")
1099         gsub(py_scriptdir, "%{py_scriptdir}")
1100         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1101
1102         gsub(ruby_archdir, "%{ruby_archdir}")
1103         gsub(ruby_ridir, "%{ruby_ridir}")
1104         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1105         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1106         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1107         gsub(ruby_rdocdir, "%{ruby_rdocdir}")
1108
1109         gsub("%{_datadir}/applications", "%{_desktopdir}")
1110         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1111         gsub("%{_datadir}/java", "%{_javadir}")
1112
1113         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}")
1114         gsub(pkgconfigdir, "%{_pkgconfigdir}")
1115
1116         gsub(libdir, "%{_libdir}")
1117         gsub(javadir, "%{_javadir}")
1118
1119         gsub(bindir, "%{_bindir}")
1120         gsub("%{prefix}/bin", "%{_bindir}")
1121         if (prefix"/bin" == bindir)
1122                 gsub("%{_prefix}/bin", "%{_bindir}")
1123
1124         for (c = 1; c <= NF; c++) {
1125                 if ($c ~ sbindir "/fix-info-dir")
1126                         continue;
1127                 if ($c ~ sbindir "/webapp")
1128                         continue;
1129                 if ($c ~ sbindir "/ldconfig")
1130                         continue;
1131                 if ($c ~ sbindir "/chsh")
1132                         continue;
1133                 if ($c ~ sbindir "/usermod")
1134                         continue;
1135                 if ($c ~ sbindir "/chkconfig")
1136                         continue;
1137                 if ($c ~ sbindir "/installzope(product|3package)")
1138                         continue;
1139                 gsub(sbindir, "%{_sbindir}", $c)
1140         }
1141
1142         gsub("%{prefix}/sbin", "%{_sbindir}")
1143         if (prefix"/sbin" == sbindir) {
1144                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1145         }
1146
1147         for (c = 1; c <= NF; c++) {
1148                 if ($c ~ sysconfdir "/{?cron.")
1149                         continue;
1150                 if ($c ~ sysconfdir "/{?crontab.d")
1151                         continue;
1152                 if ($c ~ sysconfdir "/{?env.d")
1153                         continue;
1154                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1155                         continue;
1156                 if ($c ~ sysconfdir "/{?udev")
1157                         continue;
1158                 if ($c ~ sysconfdir "/{?hotplug")
1159                         continue;
1160                 if ($c ~ sysconfdir "/{?logrotate.d")
1161                         continue;
1162                 if ($c ~ sysconfdir "/{?pam.d")
1163                         continue;
1164                 if ($c ~ sysconfdir "/{?profile.d")
1165                         continue;
1166                 if ($c ~ sysconfdir "/{?rc.d")
1167                         continue;
1168                 if ($c ~ sysconfdir "/{?security")
1169                         continue;
1170                 if ($c ~ sysconfdir "/{?skel")
1171                         continue;
1172                 if ($c ~ sysconfdir "/{?sysconfig")
1173                         continue;
1174                 if ($c ~ sysconfdir "/{?shrc.d")
1175                         continue;
1176                 if ($c ~ sysconfdir "/{?certs")
1177                         continue;
1178                 if ($c ~ sysconfdir "/{?X11")
1179                         continue;
1180                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1181                         continue;
1182                 if ($c ~ sysconfdir "/{?rpm")
1183                         continue;
1184                 if ($c ~ sysconfdir "/{?bash_completion.d")
1185                         continue;
1186                 if ($c ~ sysconfdir "/{?samba")
1187                         continue;
1188                 if ($c ~ sysconfdir "/shells")
1189                         continue;
1190                 if ($c ~ sysconfdir "/ppp")
1191                         continue;
1192                 if ($c ~ sysconfdir "/dbus-1")
1193                         continue;
1194                 if ($c ~ sysconfdir "/tmpwatch")
1195                         continue;
1196                 if ($c ~ sysconfdir "/acpi")
1197                         continue;
1198                 if ($c ~ sysconfdir "/apm")
1199                         continue;
1200                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1201         }
1202
1203         gsub(docdir, "%{_docdir}")
1204
1205         gsub(kdedocdir, "%{_kdedocdir}")
1206
1207         gsub(gtkdocdir, "%{_gtkdocdir}")
1208         gsub("%{_docdir}/gtk-doc/html", "%{_gtkdocdir}")
1209
1210         gsub(php_pear_dir, "%{php_pear_dir}")
1211         gsub(php_data_dir, "%{php_data_dir}")
1212
1213         for (c = 1; c <= NF; c++) {
1214                 if ($c ~ datadir "/automake")
1215                         continue;
1216                 if ($c ~ datadir "/unsermake")
1217                         continue;
1218                 if ($c ~ datadir "/file/magic.mime")
1219                         continue;
1220                 gsub(datadir, "%{_datadir}", $c)
1221         }
1222
1223         gsub("%{prefix}/share", "%{_datadir}")
1224         if (prefix"/share" == datadir)
1225                 gsub("%{_prefix}/share", "%{_datadir}")
1226
1227         # CFLAGS="-I/usr/include/ncurses is usually correct.
1228         if (!/-I\/usr\/include/) {
1229                 gsub(includedir, "%{_includedir}")
1230         }
1231
1232         gsub("%{prefix}/include", "%{_includedir}")
1233         if (prefix"/include" == includedir) {
1234                 gsub("%{_prefix}/include", "%{_includedir}")
1235         }
1236
1237         gsub(mandir, "%{_mandir}")
1238         if ($0 !~ "%{_datadir}/manual") {
1239                 gsub("%{_datadir}/man", "%{_mandir}")
1240         }
1241         gsub("%{_prefix}/share/man", "%{_mandir}")
1242         gsub("%{prefix}/share/man", "%{_mandir}")
1243         gsub("%{prefix}/man", "%{_mandir}")
1244         gsub("%{_prefix}/man", "%{_mandir}")
1245
1246         gsub(infodir, "%{_infodir}")
1247         gsub("%{prefix}/info", "%{_infodir}")
1248         gsub("%{_prefix}/info", "%{_infodir}")
1249
1250         if (prefix !~ "/X11R6") {
1251                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1252         }
1253
1254         gsub(examplesdir, "%{_examplesdir}")
1255
1256         if (prefix != "/") {
1257                 # leave --with-foo=/usr alone
1258                 if ($0 !~ "--with.*=.*" prefix) {
1259                         for (c = 1; c <= NF; c++) {
1260                                 if ($c ~ prefix "/sbin/fix-info-dir")
1261                                         continue;
1262                                 if ($c ~ prefix "/sbin/webapp")
1263                                         continue;
1264                                 if ($c ~ prefix "/sbin/chsh")
1265                                         continue;
1266                                 if ($c ~ prefix "/sbin/usermod")
1267                                         continue;
1268                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1269                                         continue;
1270                                 if ($c ~ prefix "/share/automake")
1271                                         continue;
1272                                 if ($c ~ prefix "/share/unsermake")
1273                                         continue;
1274                                 if ($c ~ prefix "/lib/sendmail")
1275                                         continue;
1276                                 if ($c ~ prefix "/lib/pkgconfig")
1277                                         continue;
1278
1279                                 # CFLAGS="-I/usr..." is usually correct.
1280                                 if (/-I\/usr/)
1281                                         continue;
1282                                 # same for LDFLAGS="-L/usr..."
1283                                 if (/-L\/usr/)
1284                                         continue;
1285
1286                                 gsub(prefix, "%{_prefix}", $c)
1287                         }
1288                 }
1289                 gsub("%{prefix}", "%{_prefix}")
1290         }
1291
1292         # replace back
1293         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1294         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1295
1296         gsub("%{PACKAGE_VERSION}", "%{version}")
1297         gsub("%{PACKAGE_NAME}", "%{name}")
1298
1299         gsub("^make$", "%{__make}")
1300         gsub("^make ", "%{__make} ")
1301         gsub("^gcc ", "%{__cc} ")
1302         gsub("^rm --interactive=never ", "%{__rm} ")
1303
1304         # fedora
1305         gsub("%{ruby_sitearch}", "%{ruby_sitearchdir}")
1306         gsub("%{python_sitearch}", "%{py_sitedir}")
1307         gsub("%{python_sitelib}", "%{py_sitescriptdir}")
1308
1309         # alt linux
1310         gsub("%_man1dir", "%{_mandir}/man1")
1311
1312         # mandrake specs
1313         gsub("^%make$", "%{__make}")
1314         gsub("^%make ", "%{__make} ")
1315         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1316         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1317         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1318         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1319         gsub("^%{__install}", "install")
1320         gsub("%optflags", "%{rpmcflags}")
1321         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1322
1323         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1324         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1325         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1326         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1327         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1328         $0 = fixedsub("%__install", "install", $0);
1329
1330         # split configure line to multiple lines
1331         if (/%configure / && !/\\$/) {
1332                 $0 = format_configure($0);
1333         }
1334
1335         gsub("%_bindir", "%{_bindir}")
1336         gsub("%_datadir", "%{_datadir}")
1337         gsub("%_iconsdir", "%{_iconsdir}")
1338         gsub("%_sbindir", "%{_sbindir}")
1339         gsub("%_mandir", "%{_mandir}")
1340         gsub("%name", "%{name}")
1341         gsub(/%__rm/, "rm");
1342         gsub(/%__mkdir_p/, "install -d");
1343         gsub(/%__cp/, "cp");
1344         gsub(/%__ln_s/, "ln -s");
1345         gsub(/%__sed/, "%{__sed}");
1346         gsub(/%__cat/, "cat");
1347         gsub(/%__chmod/, "chmod");
1348
1349         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1350         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1351
1352         if (/^ant / || /^%{ant}/) {
1353                 sub(/^ant/, "%ant")
1354                 sub(/^%{ant}/, "%ant")
1355                 add_br("BuildRequires:  jpackage-utils");
1356                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1357         }
1358
1359         $0 = fixedsub("%(%{__cc} -dumpversion)", "%{cc_version}", $0);
1360         $0 = fixedsub("%(%{__cxx} -dumpversion)", "%{cxx_version}", $0);
1361 }
1362
1363 function format_configure(line,         n, a, s) {
1364         n = split(line, a, / /);
1365         s = a[1] " \\\n";
1366         for (i = 2; i <= n; i++) {
1367                 s = s "\t" a[i] " \\\n"
1368         }
1369         return s
1370 }
1371
1372
1373 # insertion sort of A[1..n]
1374 # copied from mawk manual
1375 function isort(A,n,             i,j,hold) {
1376         for (i = 2; i <= n; i++) {
1377                 hold = A[j = i]
1378                 while (A[j-1] > hold) {
1379                         j-- ; A[j+1] = A[j]
1380                 }
1381                 A[j] = hold
1382         }
1383         # sentinel A[0] = "" will be created if needed
1384 }
1385
1386
1387 function use_files_macros(      i, n, t, a, l)
1388 {
1389         use_macros()
1390
1391         # skip comments
1392         if (/^#/) {
1393                 return 1;
1394         }
1395
1396         sub("^%doc %{_mandir}", "%{_mandir}")
1397
1398         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1399         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1400
1401         # uid/gid nobody is not valid in %files
1402         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1403                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1404         }
1405
1406         # s[gu]id programs with globs are evil
1407         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1408                 $0 = $0 " # FIXME no globs for suid/sgid files"
1409         }
1410
1411         # replace back
1412         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1413         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1414         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1415         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1416         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1417         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1418         gsub("%{_sysconfdir}/security", "/etc/security")
1419         gsub("%{_sysconfdir}/skel", "/etc/skel")
1420         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1421         gsub("%{_sysconfdir}/certs", "/etc/certs")
1422         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1423         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1424         gsub("%{_sysconfdir}/pki", "/etc/pki")
1425         gsub("%{_sysconfdir}/tmpwatch", "/etc/tmpwatch")
1426
1427         # /etc/init.d -> /etc/rc.d/init.d
1428         if (!/^\/etc\/init\.d$/) {
1429                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1430         }
1431
1432         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1433                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1434                         $0 = "%attr(754,root,root) " $0
1435                 }
1436                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1437                         gsub("^%attr\\(... *,", "%attr(754,");
1438                 }
1439         }
1440
1441         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1442                 $0 = "%attr(755,root,root) " $0
1443         }
1444
1445         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1446                 $0 = "%attr(755,root,root) " $0
1447         }
1448
1449         # remove attrs from man pages
1450         if (/%{_mandir}/ && /^%attr/) {
1451                 sub("^%attr\\(.*\\) *", "");
1452         }
1453
1454         # /etc/sysconfig files
1455         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1456         # attr not required, allow default 644 attr
1457         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1458                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1459                         gsub("%config", "%config(noreplace)")
1460                 }
1461
1462                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1463                         $NF = "%config(noreplace) " $NF
1464                 }
1465
1466                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1467                         gsub("^%attr\\(... *,", "%attr(640,");
1468                 }
1469
1470                 if (/\/etc\/sysconfig\// && !/%verify/) {
1471                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1472                 }
1473         }
1474
1475         # kill leading zeros
1476         if (/%attr\(0[1-9]/) {
1477                 gsub("%attr\\(0", "%attr(")
1478         }
1479
1480         # kill leading whitespace
1481         gsub(/^ +/, "");
1482
1483         # kill default attrs
1484         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1485         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1486         if (!/%dir/) {
1487                 gsub(/%attr\(644,root,root\) /, "");
1488         }
1489
1490         # sort %verify attrs
1491         if (match($0, /%verify\(not([^)]+)\)/)) {
1492                 t = substr($0, RSTART, RLENGTH)
1493                 # kill commas: %verify(not,md5,size,mtime)
1494                 gsub(/,/, " ", t);
1495
1496                 gsub(/^%verify\(not |\)$/, "", t)
1497                 n = split(t, a, / /)
1498                 isort(a, n)
1499
1500                 s = "%verify(not"
1501                 for (i = 1 ; i <= n; i++) {
1502                         s = s " " a[i]
1503                 }
1504                 s = s ")"
1505
1506                 gsub(/%verify\(not[^)]+\)/, s)
1507         }
1508
1509         if (/%{_mandir}/) {
1510                 gsub("\.gz$", "*")
1511         }
1512
1513         # locale dir and no %lang -> bad
1514         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1515                 $(NF + 1) = "# FIXME consider using %find_lang"
1516         }
1517
1518         # python egg-infos
1519         if (match($0, "^%{py_site(script)?dir}/.+-py"py_ver".egg-info$")) {
1520                 # tests:
1521                 #%{py_sitedir}/*-py2.4.egg-info
1522                 #%{py_sitescriptdir}/GnuPGInterface-%{version}-py2.4.egg-info
1523                 #%{py_sitescriptdir}/python_mpd-%{version}-py2.4.egg-info
1524                 #%{py_sitescriptdir}/mechanize-0.1.6b-py2.4.egg-info
1525
1526                 l = index($0, "/");
1527                 t = substr($0, 0, l);
1528                 s = substr($0, l + 1, RLENGTH - l - length("-py"py_ver".egg-info"));
1529                 if (match(s, "[^-]+$")) {
1530 #printf("s[%s]; start[%d]; length[%d]\n", s, RSTART, RLENGTH);
1531                         if (RSTART > 1) {
1532                                 s = substr(s, 0, RSTART - 1);
1533                         }
1534 #printf("s2[%s]\n", s);
1535                         print "%if \"%{py_ver}\" > \"2.4\""
1536 #print t "/.+.egg-info"
1537                         gsub(t "/.+.egg-info", t "/" s "-*.egg-info");
1538                         print
1539                         print "%endif"
1540                         return 0;
1541                 }
1542         }
1543
1544         # atrpms
1545         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1546         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1547         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1548
1549         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1550         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1551         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1552
1553         gsub("%{_datadir}/applications", "%{_desktopdir}");
1554         gsub("%{_datadir}/icons", "%{_iconsdir}");
1555         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1556         gsub("%{_datadir}/pear", "%{php_pear_dir}");
1557         gsub("%{_datadir}/php", "%{php_data_dir}");
1558
1559         return 1
1560 }
1561
1562 function use_script_macros()
1563 {
1564         if (gsub("/sbin/service", "%service")) {
1565                 sub(" >/dev/null 2>&1 \|\|:", "");
1566                 sub(" 2> /dev/null \|\| :", "");
1567         }
1568 }
1569
1570 function fill(ch, n, i) {
1571         for (i = 0; i < n; i++)
1572                 printf("%c", ch)
1573 }
1574
1575 function format_flush(line, indent, newline, word, first_word) {
1576         first_word = 1
1577         if (format_indent == -1)
1578                 newline = ""
1579         else
1580                 newline = fill(" ", format_indent) "- "
1581
1582         while (match(line, /[^\t ]+/)) {
1583                 word = substr(line, RSTART, RLENGTH)
1584                 if (length(newline) + length(word) + 1 > tw) {
1585                         print newline
1586
1587                         if (format_indent == -1)
1588                                 newline = ""
1589                         else
1590                                 newline = fill(" ", format_indent + 2)
1591                         first_word = 1
1592                 }
1593
1594                 if (first_word) {
1595                         newline = newline word
1596                         first_word = 0
1597                 } else
1598                         newline = newline " " word
1599
1600                 line = substr(line, RSTART + RLENGTH)
1601         }
1602         if (newline ~ /[^\t ]/) {
1603                 print newline
1604         }
1605 }
1606
1607 function cflags(var)
1608 {
1609         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1610                 removed[var] = 1
1611                 return 0
1612         }
1613
1614         if (!/!\?debug/)
1615                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1616         return 1
1617 }
1618
1619 function unify_url(url)
1620 {
1621
1622         # sourceforge urls
1623         # Docs about sourceforge mirror system: http://sourceforge.net/apps/trac/sourceforge/wiki/Mirrors
1624         sub("^http://prdownloads\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1625         sub("^http://download\.sf\.net/", "http://downloads.sourceforge.net/", url)
1626         sub("^http://download\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1627         sub("^http://dl\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1628         sub("^http://.*\.dl\.sourceforge\.net/", "http://downloads.sourceforge.net/", url)
1629         sub("^http://dl\.sf\.net/", "http://downloads.sourceforge.net/", url)
1630         sub("^http://downloads\.sourceforge\.net/sourceforge/", "http://downloads.sourceforge.net/", url)
1631         # new style urls, strip "files/" between and prepend dl.
1632         if (match(url, "^http://sourceforge.net/projects/[^/]+/files/")) {
1633                 url = substr(url, 1, RLENGTH - length("files/")) substr(url, RSTART + RLENGTH);
1634                 sub("^http://sourceforge.net/projects/", "http://downloads.sourceforge.net/project/", url);
1635         }
1636         if (url ~ /sourceforge.net/) {
1637                 sub("[?&]big_mirror=.*$", "", url);
1638                 sub("[?&]modtime=.*$", "", url);
1639                 sub("[?]use_mirror=.*$", "", url);
1640                 sub("[?]download$", "", url);
1641                 sub("/download$", "", url);
1642         }
1643
1644         sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", url)
1645         sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", url)
1646
1647         # apache urls
1648         sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", url)
1649
1650         # gnu.org
1651         sub("^ftp://ftp\.gnu\.org/", "http://ftp.gnu.org/", url)
1652         sub("^http://ftp\.gnu\.org/pub/gnu/", "http://ftp.gnu.org/gnu/", url)
1653
1654         # debian.org
1655         sub("^ftp://ftp\.[^.]+\.debian\.org/", "ftp://ftp.debian.org/", url)
1656         sub("^http://ftp\.[^.]+\.debian\.org/", "ftp://ftp.debian.org/", url)
1657         sub("^ftp://ftp\.debian\.org/pub/debian/", "ftp://ftp.debian.org/debian/", url)
1658
1659         return url
1660 }
1661
1662 function demacroize(str)
1663 {
1664         if (mod_name) {
1665                 sub("%{mod_name}", mod_name, str);
1666         }
1667         if (name) {
1668                 sub("%{name}", name, str);
1669         }
1670         if (version) {
1671                 sub("%{version}", version, str);
1672         }
1673         if (_beta) {
1674                 sub("%{_beta}", _beta, str);
1675         }
1676         if (_rc) {
1677                 sub("%{_rc}", _rc, str);
1678         }
1679         if (_pre) {
1680                 sub("%{_pre}", _pre, str);
1681         }
1682         if (_snap) {
1683                 sub("%{_snap}", _snap, str);
1684         }
1685         if (subver) {
1686                 sub("%{subver}", subver, str);
1687         }
1688         return str;
1689 }
1690
1691 function kill_preamble_macros()
1692 {
1693         if ($1 ~ /^Obsoletes:/) {
1694                 # NB! assigning $2 a value breaks tabbing
1695                 $2 = demacroize($2);
1696         }
1697         if ($1 ~ /^URL:/) {
1698                 # NB! assigning $2 a value breaks tabbing
1699                 $2 = demacroize($2);
1700                 $2 = unify_url($2)
1701         }
1702 }
1703
1704 function get_epoch(pkg, ver,    epoch)
1705 {
1706         return
1707 # should parse the BR lines more adequately:
1708 #       freetype = 2.0.0 -> correct
1709 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1710
1711         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1712         shell | getline epoch;
1713         return epoch;
1714 }
1715
1716 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1717         # skip any formatting for commented out items or some weird macros
1718         if (/^#/ || /%\(/) {
1719                 return tag "\t" value
1720         }
1721         n = split(value, p, / *,? */);
1722         for (i = 1; i <= n; i++) {
1723                 if (p[i+1] ~ /[<=>]/) {
1724                         # add epoch if the version doesn't have it but BuildRequires.txt has
1725                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1726                                 epoch = get_epoch(p[i], p[i+2])
1727                                 if (epoch) {
1728                                         p[i+2] = epoch ":" p[i+2];
1729                                 }
1730                         }
1731                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1732                         i += 2;
1733                 } else {
1734                         deps[ndeps++] = p[i];
1735                 }
1736         }
1737         s = ""
1738         for (i in deps) {
1739                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1740         }
1741         return substr(s, 1, length(s)-1);
1742 }
1743
1744 function use_tabs()
1745 {
1746         # reverse vim: ts=4 sw=4 et
1747         gsub(/    /, "\t");
1748 }
1749
1750 function add_br(br)
1751 {
1752         BR[BR_count++] = br
1753 }
1754
1755
1756 # Load rpm macros
1757 # you should update the list also in adapter when making changes here
1758 function import_rpm_macros() {
1759         # File with rpm groups
1760         topdir = ENVIRON["_topdir"]
1761
1762         if (!topdir) {
1763                 print "adapter.awk should not not be invoked directly, but via adapter script" > "/dev/stderr"
1764                 do_not_touch_anything = 1
1765                 exit(rc = 1);
1766         }
1767
1768         if (!ENVIRON["ADAPTER_REVISION"] || ENVIRON["ADAPTER_REVISION"] < 1.44) {
1769                 print "adapter shell script is outdated, please cvs up it" > "/dev/stderr"
1770                 do_not_touch_anything = 1
1771                 exit(rc = 1);
1772         }
1773
1774         # get cvsaddress for changelog section
1775         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
1776         _cvsmaildomain = ENVIRON["_cvsmaildomain"]
1777         _cvsmailfeedback = ENVIRON["_cvsmailfeedback"]
1778
1779         prefix = ENVIRON["_prefix"]
1780         bindir = ENVIRON["_bindir"]
1781         sbindir = ENVIRON["_sbindir"]
1782         libdir = ENVIRON["_libdir"]
1783         sysconfdir = ENVIRON["_sysconfdir"]
1784         datadir = ENVIRON["_datadir"]
1785         includedir = ENVIRON["_includedir"]
1786         mandir = ENVIRON["_mandir"]
1787         infodir = ENVIRON["_infodir"]
1788         examplesdir = ENVIRON["_examplesdir"]
1789         docdir = ENVIRON["_defaultdocdir"]
1790         kdedocdir = ENVIRON["_kdedocdir"]
1791         gtkdocdir = ENVIRON["_gtkdocdir"]
1792         desktopdir = ENVIRON["_desktopdir"]
1793         pixmapsdir = ENVIRON["_pixmapsdir"]
1794         javadir = ENVIRON["_javadir"]
1795         pkgconfigdir = ENVIRON["_pkgconfigdir"]
1796
1797         perl_sitearch = ENVIRON["perl_sitearch"]
1798         perl_archlib = ENVIRON["perl_archlib"]
1799         perl_privlib = ENVIRON["perl_privlib"]
1800         perl_vendorlib = ENVIRON["perl_vendorlib"]
1801         perl_vendorarch = ENVIRON["perl_vendorarch"]
1802         perl_sitelib = ENVIRON["perl_sitelib"]
1803
1804         py_sitescriptdir = ENVIRON["py_sitescriptdir"]
1805         py_sitedir = ENVIRON["py_sitedir"]
1806         py_scriptdir = ENVIRON["py_scriptdir"]
1807         py_ver = ENVIRON["py_ver"]
1808
1809         ruby_archdir = ENVIRON["ruby_archdir"]
1810         ruby_ridir = ENVIRON["ruby_ridir"]
1811         ruby_rubylibdir = ENVIRON["ruby_rubylibdir"]
1812         ruby_sitearchdir = ENVIRON["ruby_sitearchdir"]
1813         ruby_sitelibdir = ENVIRON["ruby_sitelibdir"]
1814         ruby_rdocdir = ENVIRON["ruby_rdocdir"]
1815
1816         php_pear_dir = ENVIRON["php_pear_dir"]
1817         php_data_dir = ENVIRON["php_data_dir"]
1818         tmpdir = ENVIRON["tmpdir"]
1819 }
1820
1821
1822 # php virtual deps as discussed in devel-en
1823 function replace_php_virtual_deps() {
1824         pkg = $2
1825 #       if (pkg == "php-program") {
1826 #               $0 = $1 "\t/usr/bin/php"
1827 #               return
1828 #       }
1829
1830 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1831 #               sub(/^php-/, "php(", pkg);
1832 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1833 #               $2 = pkg
1834 #       }
1835
1836         if (pkg ~/^php$/) {
1837                 $2 = "webserver(php)";
1838                 if ($4 ~ /^[0-9]:/) {
1839                         $4 = substr($4, 3);
1840                 }
1841         }
1842
1843         if (pkg ~/^php4$/) {
1844                 $2 = "webserver(php)";
1845                 if ($4 ~ /^[0-9]:/) {
1846                         $4 = substr($4, 3);
1847                 }
1848         }
1849 }
1850
1851 function replace_requires() {
1852
1853         # jpackages
1854         sub(/^antlr3$/, "java-antlr3", $2);
1855         sub(/^avalon-framework$/, "java-avalon-framework", $2);
1856         sub(/^avalon-logkit$/, "java-avalon-logkit", $2);
1857         sub(/^axis$/, "java-axis", $2);
1858         sub(/^bsf$/, "java-bsf", $2);
1859         sub(/^gnu-regexp$/, "java-gnu-regexp", $2);
1860         sub(/^gnu.regexp$/, "java-gnu-regexp", $2);
1861         sub(/^hamcrest$/, "java-hamcrest", $2);
1862         sub(/^jaas$/, "java(jaas)", $2);
1863         sub(/^jaf$/, "java(jaf)", $2);
1864         sub(/^jakarta-ant$/, "ant", $2);
1865         sub(/^jakarta-commons-httpclient$/, "java-commons-httpclient", $2);
1866         sub(/^jakarta-log4j$/, "java-log4j", $2);
1867         sub(/^jakarta-oro$/, "java-oro", $2);
1868         sub(/^jakarta-servletapi$/, "java(servlet)", $2);
1869         sub(/^java-devel$/, "jdk", $2);
1870         sub(/^java\(JSP\)$/, "java(jsp)", $2);
1871         sub(/^java\(JavaServerFaces\)$/, "java(javaserverfaces)", $2);
1872         sub(/^java\(Portlet\)$/, "java(portlet)", $2);
1873         sub(/^java\(Servlet\)$/, "java(servlet)", $2);
1874         sub(/^javamail$/, "java(javamail)", $2);
1875         sub(/^jaxp$/, "java(jaxp)", $2);
1876         sub(/^jaxp_parser_impl$/, "java(jaxp_parser_impl)", $2);
1877         sub(/^jaxp_transform_impl$/, "java(jaxp_transform_impl)", $2);
1878         sub(/^jce$/, "java(jce)", $2);
1879         sub(/^jcommon$/, "java-jcommon", $2);
1880         sub(/^jdbc-stdext$/, "java(jdbc-stdext)", $2);
1881         sub(/^jdepend$/, "java-jdepend", $2);
1882         sub(/^jfreechart$/, "java-jfreechart", $2);
1883         sub(/^jmx$/, "java(jmx)", $2);
1884         sub(/^jndi$/, "java(jndi)", $2);
1885         sub(/^jsch$/, "java-jsch", $2);
1886         sub(/^jsse$/, "java(jsse)", $2);
1887         sub(/^jta$/, "java(jta)", $2);
1888         sub(/^junit$/, "java-junit", $2);
1889         sub(/^ldapjdk$/, "ldapsdk", $2);
1890         sub(/^log4j$/, "java-log4j", $2);
1891         sub(/^logging-log4j$/, "java-log4j", $2);
1892         sub(/^oro$/, "java-oro", $2);
1893         sub(/^rhino$/, "java-rhino", $2);
1894         sub(/^saxon-scripts$/, "saxon", $2);
1895         sub(/^servlet$/, "java(servlet)", $2);
1896         sub(/^uddi4j$/, "java-uddi4j", $2);
1897         sub(/^wsdl4j$/, "java-wsdl4j", $2);
1898         sub(/^xalan-j$/, "java-xalan", $2);
1899         sub(/^xalan-j2$/, "java-xalan", $2);
1900         sub(/^xerces-j$/, "java-xerces", $2);
1901         sub(/^xerces-j2$/, "java-xerces", $2);
1902         sub(/^xml-commons-apis$/, "java-xml-commons-apis", $2);
1903         sub(/^xml-commons-resolver$/, "java-xml-commons-resolver", $2);
1904
1905         # fedora / redhat
1906         sub(/^Django$/, "python-django", $2);
1907         sub(/^chkconfig$/, "/sbin/chkconfig", $2);
1908         sub(/^db4-devel$/, "db-devel", $2);
1909         sub(/^dbus-python$/, "python-dbus", $2);
1910         sub(/^file-devel$/, "libmagic-devel", $2);
1911         sub(/^gamin-python$/, "python-gamin", $2);
1912         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2);
1913         sub(/^gnome-python2-extras$/, "python-gnome-extras", $2);
1914         sub(/^gnome-python2-gtkspell$/, "python-gnome-extras-gtkspell", $2);
1915         sub(/^gtk2$/, "gtk+2", $2);
1916         sub(/^gtk2-devel$/, "gtk+2-devel", $2);
1917         sub(/^initscripts$/, "rc-scripts", $2);
1918         sub(/^iscsi-initiator-utils$/, "open-iscsi", $2);
1919         sub(/^libXft-devel$/, "xorg-lib-libXft-devel", $2);
1920         sub(/^libXrandr-devel$/, "xorg-lib-libXrandr-devel", $2);
1921         sub(/^mod_wsgi$/, "apache-mod_wsgi", $2);
1922         sub(/^notify-python$/, "python-pynotify", $2);
1923         sub(/^pygobject2$/, "python-pygobject", $2);
1924         sub(/^pygtk2$/, "python-pygtk", $2);
1925         sub(/^pygtk2-devel$/, "python-pygtk-devel", $2);
1926         sub(/^python-enchant$/, "python-pyenchant", $2);
1927         sub(/^python-imaging$/, "python-PIL", $2);
1928         sub(/^python-imaging-tk$/, "python-PIL-tk", $2);
1929         sub(/^python-pygtk$/, "python-pygtk-gtk", $2);
1930         sub(/^python2-devel$/, "python-devel", $2);
1931         sub(/^qt4-devel$/, "qt4-build", $2);
1932         sub(/^qtlockedfile-devel$/, "QtLockedFile-devel", $2);
1933         sub(/^tftp-server$/, "tftpdaemon", $2);
1934         sub(/^tkinter$/, "python-tkinter", $2);
1935         sub(/^xapian-bindings-python$/, "python-xapian", $2);
1936
1937         # debian / ubuntu
1938         sub(/^blkid-dev$/, "libblkid-devel", $2);
1939         sub(/^ext2fs-dev$/, "e2fsprogs-devel", $2);
1940         sub(/^libao-dev$/, "libao-devel", $2);
1941         sub(/^libboost-filesystem[0-9.]+-dev$/, "boost-devel", $2);
1942         sub(/^libboost-program-options[0-9.]+-dev$/, "boost-devel", $2);
1943         sub(/^libboost-regex[0-9.]+-dev$/, "boost-devel", $2);
1944         sub(/^libboost-thread[0-9.]+-dev$/, "boost-devel", $2);
1945         sub(/^libcurl4-openssl-dev$/, "curl-devel", $2);
1946         sub(/^libdnet-dev$/, "libdnet-devel", $2);
1947         sub(/^libesd0-dev$/, "esound-devel", $2);
1948         sub(/^libfishsound1-dev$/, "libfishsound-devel", $2);
1949         sub(/^libgconf2-dev$/, "GConf2-devel", $2);
1950         sub(/^libgl1-mesa-dev$/, "OpenGL-devel", $2);
1951         sub(/^libgl1-mesa-dri$/, "OpenGL", $2);
1952         sub(/^libglib2.0-dev$/, "glib2-devel", $2);
1953         sub(/^libglu1-mesa-dev$/, "OpenGL-GLU-devel", $2);
1954         sub(/^libgtk2.0-dev$/, "gtk+2-devel", $2);
1955         sub(/^libhunspell-dev$/, "hunspell-devel", $2);
1956         sub(/^libmcrypt-dev$/, "libmcrypt-devel", $2);
1957         sub(/^libmhash-dev$/, "mhash-devel", $2);
1958         sub(/^liboggz1-dev$/, "libggz-devel", $2);
1959         sub(/^libpango1.0-dev$/, "pango-devel", $2);
1960         sub(/^libqt4-dev$/, "qt4-build", $2);
1961         sub(/^libshout3-dev$/, "libshout-devel", $2);
1962         sub(/^libslp-dev$/, "openslp-devel", $2);
1963         sub(/^libsndfile1-dev$/, "libsndfile-devel", $2);
1964         sub(/^libspeex-dev$/, "speex-devel", $2);
1965         sub(/^libssl-dev$/, "openssl-devel", $2);
1966         sub(/^libvorbis-dev$/, "libvorbis-devel", $2);
1967         sub(/^libxslt1-dev$/, "libxslt-devel", $2);
1968         sub(/^libxss-dev$/, "xorg-lib-libXScrnSaver-devel", $2);
1969         sub(/^mesa-common-dev$/, "OpenGL-devel", $2);
1970
1971         replace_php_virtual_deps()
1972 }
1973
1974 function replace_groupnames(group) {
1975         group = replace(group, "Amusements/Games", "Applications/Games");
1976         group = replace(group, "Amusements/Games/Strategy/Real Time", "X11/Applications/Games/Strategy");
1977         group = replace(group, "Application/Multimedia", "Applications/Multimedia");
1978         group = replace(group, "Application/System", "Applications/System");
1979         group = replace(group, "Applications/Compilers", "Development/Languages");
1980         group = replace(group, "Applications/Daemons", "Daemons");
1981         group = replace(group, "Applications/Internet", "Applications/Networking");
1982         group = replace(group, "Applications/Internet/Peer to Peer", "Applications/Networking");
1983         group = replace(group, "Applications/Productivity", "X11/Applications");
1984         group = replace(group, "Database", "Applications/Databases");
1985         group = replace(group, "Development/C", "Development/Libraries");
1986         group = replace(group, "Development/Code Generators", "Development");
1987         group = replace(group, "Development/Docs", "Documentation");
1988         group = replace(group, "Development/Documentation", "Documentation");
1989         group = replace(group, "Development/Java", "Development/Languages/Java");
1990         group = replace(group, "Development/Languages/Other", "Development/Languages");;
1991         group = replace(group, "Development/Languages/Ruby", "Development/Languages");
1992         group = replace(group, "Development/Libraries/C and C++", "Development/Libraries");
1993         group = replace(group, "Development/Libraries/Java", "Development/Languages/Java");
1994         group = replace(group, "Development/Libraries/Python", "Development/Languages/Python");
1995         group = replace(group, "Development/Libraries/TCL", "Development/Languages/Tcl");;
1996         group = replace(group, "Development/Other", "Development");
1997         group = replace(group, "Development/Python", "Development/Languages/Python");
1998         group = replace(group, "Development/Testing", "Development");
1999         group = replace(group, "Emulators", "Applications/Emulators");
2000         group = replace(group, "File tools", "Applications/File");
2001         group = replace(group, "Games", "Applications/Games");
2002         group = replace(group, "Library/Development", "Development/Libraries");
2003         group = replace(group, "Networking/Deamons", "Networking/Daemons");
2004         group = replace(group, "Productivity/Databases/Servers", "Applications/Databases");
2005         group = replace(group, "Productivity/Networking/Web/Servers", "Networking/Daemons/HTTP");;
2006         group = replace(group, "Shells", "Applications/Shells");
2007         group = replace(group, "System Environment/Base", "Base");
2008         group = replace(group, "System Environment/Daemons", "Daemons");
2009         group = replace(group, "System Environment/Kernel", "Base/Kernel");
2010         group = replace(group, "System Environment/Libraries", "Libraries");
2011         group = replace(group, "System Tools", "Applications/System");
2012         group = replace(group, "System", "Base");
2013         group = replace(group, "System/Base", "Base");
2014         group = replace(group, "System/Kernel and hardware", "Base/Kernel");
2015         group = replace(group, "System/Libraries", "Libraries");
2016         group = replace(group, "System/Servers", "Daemons");
2017         group = replace(group, "Text Processing/Markup/HTML", "Applications/Text");
2018         group = replace(group, "Text Processing/Markup/XML", "Applications/Text");
2019         group = replace(group, "User Interface/Desktops", "X11/Applications");
2020         group = replace(group, "Utilities/System", "Applications/System");
2021         group = replace(group, "Web/Database", "Applications/WWW");
2022         group = replace(group, "X11/GNOME", "X11/Applications");
2023         group = replace(group, "X11/GNOME/Applications", "X11/Applications");
2024         group = replace(group, "X11/GNOME/Development/Libraries", "X11/Development/Libraries");
2025         group = replace(group, "X11/Games", "X11/Applications/Games");
2026         group = replace(group, "X11/Games/Strategy", "X11/Applications/Games/Strategy");
2027         group = replace(group, "X11/Library", "X11/Libraries");
2028         group = replace(group, "X11/Utilities", "X11/Applications");
2029         group = replace(group, "X11/XFree86", "X11");
2030         group = replace(group, "X11/Xserver", "X11/Servers");
2031
2032         return group;
2033 }
2034
2035 # vim:ts=4:sw=4