adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.26. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2001 PLD-Team <pld-list@pld.org.pl>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld.org.pl>
  11 #       Michal Kochanowicz <mkochano@ee.pw.edu.pl>
  12 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  13
  14 BEGIN {
  15         preamble = 1            # Is it part of preamble? Default - yes
  16         boc = 2                 # Beggining of %changelog
  17         bod = 0                 # Beggining of %description
  18         tw = 70                 # Descriptions width
  19
  20         # If variable removed, then 1 (for removing it from export)
  21         removed["LDFLAGS"] = 0
  22         removed["CFLAGS"] = 0
  23         removed["CXXFLAGS"] = 0
  24
  25         # If 1, we are inside of comment block (started with /^#%/)
  26         comment_block = 0
  27
  28         # File with rpm groups
  29         "rpm --eval %_sourcedir" | getline groups_file
  30         groups_file = groups_file "/rpm.groups"
  31         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups 1>&2")
  32
  33         # Temporary file for changelog section
  34         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  35
  36         # Load rpm macros
  37         "rpm --eval %_prefix"   | getline prefix
  38         "rpm --eval %_bindir"   | getline bindir
  39         "rpm --eval %_sbindir"  | getline sbindir
  40         "rpm --eval %_libdir"   | getline libdir
  41         "rpm --eval %_sysconfdir" | getline sysconfdir
  42         "rpm --eval %_datadir"  | getline datadir
  43         "rpm --eval %_includedir" | getline includedir
  44         "rpm --eval %_mandir"   | getline mandir
  45         "rpm --eval %_infodir"  | getline infodir
  46 }
  47
  48 # There should be a comment with CVS keywords on the first line of file.
  49 FNR == 1 {
  50         if (!/# \$Revision:/)   # If this line is already OK?
  51                 print "# $" "Revision:$, " "$" "Date:$" # No
  52         else {
  53                 print $0                                # Yes
  54                 next            # It is enough for first line
  55         }
  56 }
  57
  58 # If the latest line matched /%files/
  59 defattr == 1 {
  60         if ($0 !~ /defattr/)    # If no %defattr
  61                 print "%defattr(644,root,root,755)"     # Add it
  62         else
  63                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  64         defattr = 0
  65 }
  66
  67 # Comments
  68 /^#/ {
  69         if (/This file does not like to be adapterized!/) {
  70                 print                   # print this message
  71                 while (getline)         # print the rest of spec as it is
  72                         print
  73                 do_not_touch_anything = 1 # do not touch anything in END()
  74                 exit 0
  75         }
  76
  77         # Generally, comments are printed without touching
  78         print $0
  79         next
  80 }
  81
  82 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
  83 /^%define/ {
  84         if ($2 == "_applnkdir")
  85                 next
  86         if ($2 == "date")
  87                 date = 1
  88 }
  89
  90 ################
  91 # %description #
  92 ################
  93 /^%description/, (/^%[a-z]+/ && !/^%description/) {
  94         preamble = 0
  95
  96         if (/^%description/) {
  97                 bod++
  98                 format_line = ""
  99                 format_indent = -1
 100         }
 101
 102         # Define _prefix and _mandir if it is X11 application
 103         if (/^%description$/ && x11 == 1) {
 104                 print "%define\t\t_prefix\t\t/usr/X11R6"
 105                 print "%define\t\t_mandir\t\t%{_prefix}/man\n"
 106                 prefix = "/usr/X11R6"
 107                 x11 = 2
 108         }
 109
 110         # Format description
 111         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 112                 if (/^[ \t]*$/) {
 113                         format_flush(format_line, format_indent)
 114                         print ""
 115                         format_line = ""
 116                         format_indent = -1
 117                 } else if (/^[ \t]*[-\*][ \t]*/) {
 118                         format_flush(format_line, format_indent)
 119                         match($0, /^[ \t]*/)
 120                         format_indent = RLENGTH
 121                         match($0, /^[ \t]*[-\*][ \t]/)
 122                         format_line = substr($0, RLENGTH)
 123                 } else
 124                         format_line = format_line " " $0
 125                 next
 126         }
 127
 128         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 129                 format_flush(format_line, format_indent)
 130                 if (bod == 2) {
 131                         bod = 1
 132                         description = 1
 133                 } else {
 134                         bod = 0
 135                         description = 0
 136                 }
 137         } else
 138                 description = 1
 139 }
 140
 141 #########
 142 # %prep #
 143 #########
 144 /^%prep/, (/^%[a-z]+$/ && !/^%prep/) {
 145         preamble = 0
 146
 147         # Add '-q' to %setup
 148         if (/^%setup/ && !/-q/)
 149                 sub(/^%setup/, "%setup -q")
 150 }
 151
 152 ##########
 153 # %build #
 154 ##########
 155 /^%build/, (/^%[a-z]+$/ && !/^%build/) {
 156         preamble = 0
 157
 158         use_macros()
 159
 160         if (/^automake$/)
 161                 sub(/$/, " -a -c")
 162
 163         if (/LDFLAGS/) {
 164                 if (/LDFLAGS="-s"/) {
 165                         removed["LDFLAGS"] = 1
 166                         next
 167                 } else {
 168                         split($0, tmp, "LDFLAGS=")
 169                         count = split(tmp[2], flags, "\"")
 170                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 171                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 172                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 173                                 for (i = 2; i < count; i++)
 174                                         $0 = $0 flags[i] "\""
 175                         }
 176                 }
 177         }
 178
 179         if (/CFLAGS=/)
 180                 if (cflags("CFLAGS") == 0)
 181                         next
 182
 183         if (/CXXFLAGS=/)
 184                 if (cflags("CXXFLAGS") == 0)
 185                         next
 186
 187         if (/^export /) {
 188                 if (removed["LDFLAGS"])
 189                         sub(" LDFLAGS", "")
 190                 if (removed["CFLAGS"])
 191                         sub(" CFLAGS", "")
 192                 if (removed["CXXFLAGS"])
 193                         sub(" CXXFLAGS", "")
 194                 # Is there still something?
 195                 if (/^export[ ]*$/)
 196                         next
 197         }
 198
 199 }
 200
 201 ##########
 202 # %clean #
 203 ##########
 204 /^%clean/, (/^%[a-z]+$/ && !/^%clean/) {
 205         did_clean = 1
 206 }
 207
 208 ############
 209 # %install #
 210 ############
 211 /^%install/, (/^%[a-z]+$/ && !/^%install/) {
 212
 213         preamble = 0
 214
 215         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 216                 did_rmroot=1
 217                 print "rm -rf $RPM_BUILD_ROOT"
 218                 next
 219         }
 220
 221         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 222                 print "rm -rf $RPM_BUILD_ROOT"
 223                 did_rmroot=1
 224         }
 225
 226         use_macros()
 227
 228         # 'install -d' instead 'mkdir -p'
 229         if (/mkdir -p/)
 230                 sub(/mkdir -p/, "install -d")
 231
 232         # No '-u root' or '-g root' for 'install'
 233         if (/^install/ && /-[ug][ \t]*root/)
 234                 gsub(/-[ug][ \t]*root /, "")
 235
 236         if (/^install/ && /-m[ \t]*644/)
 237                 gsub(/-m[ \t]*644 /, "")
 238
 239         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 240         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 241                 next
 242
 243         # No lines contain 'chmod' if it sets the modes to '644'
 244         if ($1 ~ /chmod/ && $2 ~ /644/)
 245                 next
 246 }
 247
 248 ##########
 249 # %files #
 250 ##########
 251 /^%files/, (/^%[a-z \-]+$/ && !/^%files/) {
 252         preamble = 0
 253
 254         if ($0 ~ /^%files/)
 255                 defattr = 1
 256
 257         use_macros()
 258         use_files_macros()
 259 }
 260
 261 ##############
 262 # %changelog #
 263 ##############
 264 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 265         preamble = 0
 266         has_changelog = 1
 267         # There should be some CVS keywords on the first line of %changelog.
 268         if (boc == 1) {
 269                 if (!/PLD Team/) {
 270                         print "* %{date} PLD Team <pld-list@pld.org.pl>" > changelog_file
 271                         printf "All persons listed below can be reached at " > changelog_file
 272                         print "<cvs_login>@pld.org.pl\n" > changelog_file
 273                         print "$" "Log:$" > changelog_file
 274                 }
 275                 boc = 0
 276         }
 277
 278         # Define date macro.
 279         if (boc == 2) {
 280                 if (date == 0) {
 281                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 282                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 283                         date = 1
 284                 }
 285                 boc = 1
 286         }
 287
 288         if (!/^%[a-z]+$/ || /changelog/)
 289                 print > changelog_file
 290         else
 291                 print
 292         next
 293 }
 294
 295 ###########
 296 # SCRIPTS #
 297 ###########
 298 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 299         preamble = 0
 300 }
 301 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 302         preamble = 0
 303 }
 304 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 305         preamble = 0
 306 }
 307 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 308         preamble = 0
 309 }
 310
 311 #############
 312 # PREAMBLES #
 313 #############
 314 preamble == 1 {
 315         # There should not be a space after the name of field
 316         # and before the colon.
 317         sub(/[ \t]*:/, ":")
 318
 319         field = tolower($1)
 320         if (Byla_grupa == 1 && field ~ /^#/)
 321                 next
 322         if (Byla_grupa == 1 && field !~ /group(\(..\))?:/) {
 323                 Byla_grupa = 0
 324                 print "Group:\t\t" Grupa["en"]
 325                 if (Grupa["en"] ~ /^X11/ && x11 == 0)   # Is it X11 application?
 326                        x11 = 1
 327
 328                 byl_plik_z_grupami = 0
 329                 byl_opis_grupy = 0
 330                 while ((getline linia_grup < groups_file) > 0) {
 331                         byl_plik_z_grupami = 1
 332                         if (linia_grup == Grupa["en"]) {
 333                                 byl_opis_grupy = 1
 334                                 break
 335                         }
 336                 }
 337
 338                 if (!byl_plik_z_grupami)
 339                         print "######\t\t" groups_file ": no such file"
 340                 else if (!byl_opis_grupy)
 341                         print "######\t\t" "Unknown group!"
 342                 else
 343                         while (getline linia_grup < groups_file) {
 344                                 if (linia_grup == "")
 345                                         break
 346                                 split(linia_grup, g, /[\[\]:]/)
 347                                 sub(/^[ \t]*/,"",g[4])
 348                                 Grupa[g[2]]=g[4]
 349                         }
 350
 351                 close(groups_file)
 352
 353                 delete Grupa["en"]
 354                 for (jezyk in Grupa) {
 355                         print "Group(" jezyk "):\t" Grupa[jezyk] | "sort"
 356                         delete Grupa[jezyk]
 357                 }
 358                 close ("sort")
 359         }
 360
 361         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 362                 next
 363
 364         if (field ~ /buildroot:/)
 365                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 366
 367         if (field ~ /group(\(..\))?:/) {
 368                 format_preamble()
 369                 sub(/^Utilities\//,"Applications/",$2)
 370                 sub(/^Games/,"Applications/Games",$2)
 371                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 372                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 373                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 374                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 375                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 376                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 377                 sub(/^Shells/,"Applications/Shells",$2)
 378
 379                 if (!match(field,/\(..\):/))
 380                         glang="en"
 381                 else
 382                         glang=substr(field,RSTART+1,2)
 383                 sub(/^[^ \t]*[ \t]*/,"")
 384                 Grupa[glang] = $0
 385                 Byla_grupa = 1
 386
 387                 next    # Line is already formatted and printed
 388         }
 389
 390         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 391         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 392                 $1 = "License:"
 393
 394         if (field ~ /name:/)
 395                 name = $2
 396
 397         if (field ~ /version:/)
 398                 version = $2
 399
 400         if (field ~ /serial:/)
 401                 $1 = "Epoch:"
 402
 403         # Use %{name} and %{version} in the filenames in "Source:"
 404         if (field ~ /source/ || field ~ /patch/) {
 405                 n = split($2, url, /\//)
 406                 if (url[n] ~ /\.gz$/) {
 407                         url[n+1] = ".gz" url[n+1]
 408                         sub(/\.gz$/,"",url[n])
 409                 }
 410                 if (url[n] ~ /\.zip$/) {
 411                         url[n+1] = ".zip" url[n+1]
 412                         sub(/\.zip$/,"",url[n])
 413                 }
 414                 if (url[n] ~ /\.tar$/) {
 415                         url[n+1] = ".tar" url[n+1]
 416                         sub(/\.tar$/,"",url[n])
 417                 }
 418                 if (url[n] ~ /\.patch$/) {
 419                         url[n+1] = ".patch" url[n+1]
 420                         sub(/\.patch$/,"",url[n])
 421                 }
 422                 if (url[n] ~ /\.bz2$/) {
 423                         url[n+1] = ".bz2" url[n+1]
 424                         sub(/\.bz2$/,"",url[n])
 425                 }
 426                 if (url[n] ~ /\.logrotate$/) {
 427                         url[n+1] = ".logrotate" url[n+1]
 428                         sub(/\.logrotate$/,"",url[n])
 429                 }
 430                 if (url[n] ~ /\.pamd$/) {
 431                         url[n+1] = ".pamd" url[n+1]
 432                         sub(/\.pamd$/,"",url[n])
 433                 }
 434
 435                 filename = url[n]
 436                 url[n] = fixedsub(name, "%{name}", url[n])
 437                 if (field ~ /source/)
 438                         url[n] = fixedsub(version, "%{version}", url[n])
 439                 $2 = fixedsub(filename, url[n], $2)
 440         }
 441
 442         if (field ~ /source:/)
 443                 $1 = "Source0:"
 444
 445         if (field ~ /patch:/)
 446                 $1 = "Patch0:"
 447
 448         format_preamble()
 449
 450         if ($1 ~ /%define/) {
 451                 # Do not add %define of _prefix if it already is.
 452                 if ($2 ~ /_prefix/) {
 453                         sub("^"prefix, $3, bindir)
 454                         sub("^"prefix, $3, sbindir)
 455                         sub("^"prefix, $3, libdir)
 456                         sub("^"prefix, $3, datadir)
 457                         sub("^"prefix, $3, includedir)
 458                         prefix = $3
 459                         x11 = 2
 460                 }
 461                 if ($2 ~ /_bindir/ && !/_sbindir/)
 462                         bindir = $3
 463                 if ($2 ~ /_sbindir/)
 464                         sbindir = $3
 465                 if ($2 ~ /_libdir/)
 466                         libdir = $3
 467                 if ($2 ~ /_sysconfdir/)
 468                         sysconfdir = $3
 469                 if ($2 ~ /_datadir/)
 470                         datadir = $3
 471                 if ($2 ~ /_includedir/)
 472                         includedir = $3
 473                 if ($2 ~ /_mandir/)
 474                         mandir = $3
 475                 if ($2 ~ /_infodir/)
 476                         infodir = $3
 477         }
 478 }
 479
 480
 481 # main()  ;-)
 482 {
 483         preamble = 1
 484
 485         print
 486 }
 487
 488
 489 END {
 490         if (do_not_touch_anything)
 491                 exit 0
 492
 493         close(changelog_file)
 494         while ((getline < changelog_file) > 0)
 495                 print
 496         system("rm -f " changelog_file)
 497
 498         if (did_clean == 0) {
 499                 print ""
 500                 print "%clean"
 501                 print "rm -rf $RPM_BUILD_ROOT"
 502         }
 503
 504         if (date == 0) {
 505                 print ""
 506                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 507         }
 508
 509         if (has_changelog == 0)
 510                 print "%changelog"
 511
 512         if (boc > 0) {
 513                 print "* %{date} PLD Team <pld-list@pld.org.pl>"
 514                 printf "All persons listed below can be reached at "
 515                 print "<cvs_login>@pld.org.pl\n"
 516                 print "$" "Log:$"
 517         }
 518 }
 519
 520 function fixedsub(s1,s2,t,      ind) {
 521 # substitutes fixed strings (not regexps)
 522         if (ind = index(t,s1))
 523                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 524         return t
 525 }
 526
 527 # There should be one or two tabs after the colon.
 528 function format_preamble()
 529 {
 530         sub(/:[ \t]*/, ":")
 531         if (match($0, /[A-Za-z0-9()# \t]+[ \t]*:[ \t]*/) == 1) {
 532                 if (RLENGTH < 8)
 533                         sub(/:/, ":\t\t")
 534                 else
 535                         sub(/:/, ":\t")
 536         }
 537 }
 538
 539 # Replace directly specified directories with macros
 540 function use_macros()
 541 {
 542         gsub(bindir, "%{_bindir}")
 543         gsub("%{_prefix}/bin", "%{_bindir}")
 544         gsub("%{prefix}/bin", "%{_bindir}")
 545
 546         for (c = 1; c <= NF; c++) {
 547                 if ($c ~ sbindir "/fix-info-dir")
 548                         continue;
 549                 gsub(sbindir, "%{_sbindir}", $c)
 550         }
 551
 552         gsub("%{prefix}/sbin", "%{_sbindir}")
 553         gsub("%{_prefix}/sbib", "%{_sbindir}")
 554
 555         gsub(libdir, "%{_libdir}")
 556         gsub("%{prefix}/lib", "%{_libdir}")
 557         gsub("%{_prefix}/lib", "%{_libdir}")
 558
 559         for (c = 1; c <= NF; c++) {
 560                 if ($c ~ sysconfdir "/cron.d")
 561                         continue;
 562                 if ($c ~ sysconfdir "/crontab.d")
 563                         continue;
 564                 if ($c ~ sysconfdir "/logrotate.d")
 565                         continue;
 566                 if ($c ~ sysconfdir "/pam.d")
 567                         continue;
 568                 if ($c ~ sysconfdir "/profile.d")
 569                         continue;
 570                 if ($c ~ sysconfdir "/rc.d")
 571                         continue;
 572                 if ($c ~ sysconfdir "/security")
 573                         continue;
 574                 if ($c ~ sysconfdir "/skel")
 575                         continue;
 576                 if ($c ~ sysconfdir "/sysconfig")
 577                         continue;
 578                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 579         }
 580
 581         gsub(datadir, "%{_datadir}")
 582         gsub("%{prefix}/share", "%{_datadir}")
 583         gsub("%{_prefix}/share", "%{_datadir}")
 584
 585         gsub(includedir, "%{_includedir}")
 586         gsub("%{prefix}/include", "%{_includedir}")
 587         gsub("%{_prefix}/include", "%{_includedir}")
 588
 589         gsub(mandir, "%{_mandir}")
 590         gsub("%{_datadir}/man", "%{_mandir}")
 591         gsub("%{_prefix}/share/man", "%{_mandir}")
 592         gsub("%{prefix}/share/man", "%{_mandir}")
 593         gsub("%{prefix}/man", "%{_mandir}")
 594         gsub("%{_prefix}/man", "%{_mandir}")
 595
 596         gsub(infodir, "%{_infodir}")
 597         gsub("%{prefix}/info", "%{_infodir}")
 598         gsub("%{_prefix}/info", "%{_infodir}")
 599
 600         gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 601
 602         if (prefix != "/") {
 603                 for (c = 1; c <= NF; c++) {
 604                         if ($c ~ prefix "/sbin/fix-info-dir")
 605                                 continue;
 606                         gsub(prefix, "%{_prefix}", $c)
 607                 }
 608                 gsub("%{prefix}", "%{_prefix}")
 609         }
 610
 611         gsub("%{PACKAGE_VERSION}", "%{version}")
 612         gsub("%{PACKAGE_NAME}", "%{name}")
 613
 614         gsub("%{_datadir}/gnome/apps", "%{_applnkdir}")
 615         gsub("%{_datadir}/applnk", "%{_applnkdir}")
 616
 617         gsub("^make$", "%{__make}")
 618         gsub("^make ", "%{__make} ")
 619 }
 620
 621 function use_files_macros()
 622 {
 623         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 624         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 625 }
 626
 627 function fill(ch, n, i) {
 628         for (i = 0; i < n; i++)
 629                 printf("%c", ch)
 630 }
 631
 632 function format_flush(line, indent, newline, word, first_word) {
 633         first_word = 1
 634         if (format_indent == -1)
 635                 newline = ""
 636         else
 637                 newline = fill(" ", format_indent) "- "
 638
 639         while (match(line, /[^\t ]+/)) {
 640                 word = substr(line, RSTART, RLENGTH)
 641                 if (length(newline) + length(word) + 1 > tw) {
 642                         print newline
 643
 644                         if (format_indent == -1)
 645                                 newline = ""
 646                         else
 647                                 newline = fill(" ", format_indent + 2)
 648                         first_word = 1
 649                 }
 650
 651                 if (first_word) {
 652                         newline = newline word
 653                         first_word = 0
 654                 } else
 655                         newline = newline " " word
 656
 657                 line = substr(line, RSTART + RLENGTH)
 658         }
 659         if (newline ~ /[^\t ]/) {
 660                 print newline
 661         }
 662 }
 663
 664 function cflags(var)
 665 {
 666         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
 667                 removed[var] = 1
 668                 return 0
 669         }
 670
 671         if (!/!\?debug/)
 672                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
 673         return 1
 674 }
 675