SConstruct

   1 # vim:ft=python
   2 import os
   3
   4 double_conversion_sources = ['src/' + x for x in SConscript('src/SConscript')]
   5 double_conversion_test_sources = ['test/cctest/' + x for x in SConscript('test/cctest/SConscript')]
   6
   7 DESTDIR = ARGUMENTS.get('DESTDIR', '')
   8 prefix = ARGUMENTS.get('prefix', '/usr/local')
   9 lib = ARGUMENTS.get('libsuffix', 'lib')
  10 libdir = os.path.join(DESTDIR + prefix, lib)
  11
  12 env = Environment(CPPPATH='#/src', LIBS=['m', 'stdc++'],
  13     CXXFLAGS=ARGUMENTS.get('CXXFLAGS', ''))
  14 debug = ARGUMENTS.get('debug', 0)
  15 optimize = ARGUMENTS.get('optimize', 0)
  16 env.Replace(CXX = ARGUMENTS.get('CXX', 'g++'))
  17
  18 # for shared lib, requires scons 2.3.0
  19 env['SHLIBVERSION'] = '0.0.0'
  20
  21 CCFLAGS = []
  22 if int(debug):
  23   CCFLAGS.append(ARGUMENTS.get('CXXFLAGS', '-g -Wall -Werror'))
  24 if int(optimize):
  25   CCFLAGS.append(ARGUMENTS.get('CXXFLAGS', '-O3'))
  26
  27 env.Append(CCFLAGS = " ".join(CCFLAGS))
  28
  29 double_conversion_shared_objects = [
  30     env.SharedObject(src) for src in double_conversion_sources]
  31 double_conversion_static_objects = [
  32     env.StaticObject(src) for src in double_conversion_sources]
  33
  34 library_name = 'double-conversion'
  35
  36 static_lib = env.StaticLibrary(library_name, double_conversion_static_objects)
  37 static_lib_pic = env.StaticLibrary(library_name + '_pic', double_conversion_shared_objects)
  38 shared_lib = env.SharedLibrary(library_name, double_conversion_shared_objects)
  39
  40 env.Program('run_tests', double_conversion_test_sources, LIBS=[static_lib])
  41
  42 # InstallVersionedLib, requires scons 2.3.0
  43 env.InstallVersionedLib(libdir, shared_lib)
  44 env.Install(libdir, static_lib)
  45 env.Install(libdir, static_lib_pic)
  46
  47 env.Alias('install', libdir)