spec.vim

   1 " Filename:    spec.vim
   2 " Purpose:     Vim syntax file
   3 " Language:    SPEC: Build/install scripts for PLD Linux RPM packages
   4 " Maintainer:  PLD Linux <feedback@pld-linux.org>
   5 " URL:         http://www.pld-linux.org/
   6 " Last Change: $Date$ (UTC)
   7 " Version:     $Id$
   8
   9 " For version 5.x: Clear all syntax items
  10 " For version 6.x: Quit when a syntax file was already loaded
  11 if version < 600
  12   syntax clear
  13 elseif exists("b:current_syntax")
  14   finish
  15 endif
  16
  17 syn sync minlines=1000
  18
  19 syn match specSpecialChar contained '[][!$()\\|>^;:]'
  20 syn match specColon       contained ':'
  21 syn match specPercent     contained '%'
  22 syn match specSubstChar   contained '[#%]'
  23
  24 syn match specVariables   contained '\$\h\w*' contains=specSpecialVariablesNames,specSpecialChar
  25 syn match specVariables   contained '\${\w*}' contains=specSpecialVariablesNames,specSpecialChar
  26 syn match specVariables   contained '\${\w*[#%][^}]*}' contains=specSubstChar
  27
  28 syn match specMacroIdentifier contained '%\h\w*' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  29 "syn match specMacroIdentifier contained '%{\w*}' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  30 syn region specMacroIdentifier oneline matchgroup=Special start='%{' skip='\\}' end='}' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  31 syn match specBcond contained '%{with\(out\)\?\s\+[a-zA-Z0-9_-]\+}'
  32
  33 syn match specSpecialVariables contained '\$[0-9]\|\${[0-9]}'
  34 syn match specCommandOpts      contained '\s\(-\w\+\|--\w[a-zA-Z0-9_-]\+\)'ms=s+1
  35 syn match specComment '^\s*#.*$'
  36
  37 syn case match
  38
  39 " matches with no highlight
  40 syn match specNoNumberHilite 'X11\|X11R6\|[a-zA-Z]*\.\d\|[a-zA-Z][-/]\d'
  41 syn match specManpageFile '[a-zA-Z]\.1'
  42
  43 " Day, Month and most used license acronyms
  44 syn keyword specLicense contained GPL LGPL BSD MIT GNU Apache PHP
  45 syn keyword specLicenseWarning contained unknown
  46 syn match specLicenseWarning contained /same as perl/
  47 syn match specLicenseWarning contained "(enter GPL/LGPL/BSD/BSD-like/Artistic/other license name here)"
  48 syn keyword specWeekday contained Mon Tue Wed Thu Fri Sat Sun
  49 syn keyword specMonth   contained Jan Feb Mar Apr Jun Jul Aug Sep Oct Nov Dec
  50 syn keyword specMonth   contained January February March April May June July August September October November December
  51
  52 " #, @, www
  53 syn match specNumber '\(^-\=\|[ \t]-\=\|-\)[0-9.-]*[0-9]'
  54 syn match specEmail contained "<\=\<[A-Za-z0-9_.-]\+@\([A-Za-z0-9_-]\+\.\)\+[A-Za-z]\+\>>\="
  55 syn match specURL      contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#?=-]\+\>'
  56 syn match specURLMacro contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#%{}-]\+\>' contains=specMacroIdentifier
  57
  58 " TODO take specSpecialVariables out of the cluster for the sh* contains (ALLBUT)
  59 " Special system directories
  60 syn match specListedFilesPrefix contained '/\(usr\|local\|opt\|X11R6\|X11\)/'me=e-1
  61 syn match specListedFilesBin    contained '/s\=bin/'me=e-1
  62 syn match specListedFilesLib    contained '/\(lib\|include\)/'me=e-1
  63 syn match specListedFilesDoc    contained '/\(man\d*\|doc\|info\)\>'
  64 syn match specListedFilesEtc    contained '/etc/'me=e-1
  65 syn match specListedFilesShare  contained '/share/'me=e-1
  66 syn cluster specListedFiles contains=specListedFilesBin,specListedFilesLib,specListedFilesDoc,specListedFilesEtc,specListedFilesShare,specListedFilesPrefix,specSpecialChar
  67
  68 " specComands
  69 syn match   specConfigure  contained '\./configure'
  70 syn match   specTarCommand contained '\<tar\s\+[cxvpzjf]\{,5}\s*'
  71
  72 " XXX don't forget to update specScriptArea when updating specMacro
  73 syn match   specMacro contained '%\(group\|user\)\(add\|remove\)'
  74 syn match   specMacro contained '%\(depmod\|banner\|service\|addusertogroup\|env_update\)'
  75 syn match   specMacro contained '%\(\(nsplugin\|apache_config\)_\(un\)\?install\)'
  76 syn match   specMacro contained '%\(\(openldap_schema\|webapp\)_\(un\)\?register\)'
  77 syn match   specMacro contained '%\(pear_package_\(setup\|install\)\)'
  78 syn match   specMacro contained '%\(py_o\?comp\|py_postclean\)'
  79 syn match   specMacro contained '%\(build\|install\)_kernel_modules'
  80 syn match   specMacro contained '%ant'
  81 syn match   specMacro contained '%\(php\|php4\)_webserver_restart'
  82 syn match   specMacro contained '%update_browser_plugins\|%browser_plugins_add_browser'
  83
  84 syn keyword specCommandSpecial contained root
  85 syn keyword specCommand         contained make xmkmf mkdir chmod find sed rm strip moc echo grep ls rm mv mkdir chown install cp pwd cat tail then else elif cd gzip rmdir ln eval export touch unzip bzip2
  86 syn cluster specCommands contains=specCommand,specTarCommand,specConfigure,specCommandSpecial,specMacro
  87
  88 " frequently used rpm env vars
  89 syn keyword specSpecialVariablesNames contained RPM_BUILD_ROOT RPM_BUILD_DIR RPM_SOURCE_DIR RPM_OPT_FLAGS LDFLAGS CC CC_FLAGS CPPNAME CFLAGS CXX CXXFLAGS CPPFLAGS
  90
  91 " valid macro names from /usr/lib/rpm/macros*
  92 syn keyword specMacroNameOther contained ix86 x8664 ppc
  93 syn keyword specMacroNameOther contained buildroot buildsubdir distribution disturl name nil optflags perl_sitearch release requires_eq vendor version
  94 syn keyword specMacroNameOther contained __kernel_ver date debugcflags debuginfocflags epoch kgcc kgcc_package packager
  95 syn keyword specMacroNameOther contained pear_package_install pear_package_setup perl_archlib perl_privlib perl_sitelib
  96 syn keyword specMacroNameOther contained perl_vendorarch perl_vendorlib php_pear_dir py_sitedir py_scriptdir py_sitescriptdir
  97 syn keyword specMacroNameOther contained requires_php_extension requires_php_pdo_module
  98 syn keyword specMacroNameOther contained requires_zend_extension ruby_mod_ver_requires_eq ruby_ver_requires_eq rpmcflags rpmcxxflags rpmldflags tmpdir
  99 syn keyword specMacroNameOther contained ruby_archdir ruby_rubylibdir ruby_vendorarchdir ruby_vendorlibdir ruby_ridir ruby_sitearchdir ruby_sitelibdir ruby_version
 100 syn keyword specMacroNameOther contained apache_modules_api php_sysconfdir php_includedir php_extensiondir _browserpluginsdir _browserpluginsconfdir
 101 syn keyword specMacroNameOther contained releq_kernel releq_kernel_up releq_kernel_smp requires_releq_kernel requires_releq_kernel_up requires_releq_kernel_smp
 102
 103 syn match   specMacroNameOther contained '\<\(PATCH\|SOURCE\)\d*\>'
 104
 105 " valid _macro names from /usr/lib/rpm/macros*
 106 syn keyword specMacroNameLocal contained _aclocaldir _applnkdir _arch _binary_payload _bindir _build _build_arch _build_alias
 107 syn keyword specMacroNameLocal contained _build_cpu _builddir _build_os _buildshell _buildsubdir _build_vendor _bzip2bin _datadir
 108 syn keyword specMacroNameLocal contained _dbpath _dbpath_rebuild _defaultdocdir _desktopdir _docdir _examplesdir _excludedocs _kdedocdir
 109 syn keyword specMacroNameLocal contained _exec_prefix _fixgroup _fixowner _fixperms _fontsdir _ftpport _ftpproxy _gnu _gpg_name
 110 syn keyword specMacroNameLocal contained _gpg_path _gtkdocdir _gzipbin _host _host_alias _host_cpu _host_os _host_vendor
 111 syn keyword specMacroNameLocal contained _httpport _httpproxy _iconsdir _includedir _infodir _initrddir _install_langs
 112 syn keyword specMacroNameLocal contained _install_script_path _instchangelog _javaclasspath _javadir _javadocdir _kernelsrcdir
 113 syn keyword specMacroNameLocal contained _kernel_ver _kernel_ver_str _langpatt _lib _libdir _libexecdir _localstatedir _mandir
 114 syn keyword specMacroNameLocal contained _netsharedpath _oldincludedir _omf_dest_dir _os _package_version _pgpbin _pgp_name
 115 syn keyword specMacroNameLocal contained _pgp_path _pixmapsdir _pkgconfigdir _prefix _preScriptEnvironment _provides _rpmdir
 116 syn keyword specMacroNameLocal contained _rpmfilename _sbindir _sharedstatedir _signature _smp_mflags _sourcedir _source_payload
 117 syn keyword specMacroNameLocal contained _specdir _srcrpmdir _sysconfdir _target _target_alias _target_cpu _target_os _target_platform
 118 syn keyword specMacroNameLocal contained _target_vendor _target_base_arch _timecheck _tmppath _topdir _usr _usrsrc _var _vendor
 119 syn keyword specMacroNameLocal contained __cxx __cc __libtoolize __autopoint __aclocal __autoconf __automake __autoheader
 120 syn keyword specMacroNameLocal contained __gettextize __glib_gettextize __intltoolize
 121 syn keyword specMacroNameLocal contained __bzip2 __cat __chgrp __chmod __chown __cp   __cpio __file __gpg __grep __gzip
 122 syn keyword specMacroNameLocal contained __id  __install __ld   __make   __mkdir __mkdir_p __mv __nm  __objcopy __objdump
 123 syn keyword specMacroNameLocal contained __patch __perl __pgp __python __rm __rsh  __sed __ssh __strip  __tar __unzip
 124
 125
 126
 127 " ------------------------------------------------------------------------------
 128 " here's is all the spec sections definitions: PreAmble, Description, Package,
 129 "   Scripts, Files and Changelog
 130
 131 " One line macros - valid in all ScriptAreas
 132 " tip: remember do include new items on specScriptArea's skip section
 133 syn region specSectionMacroArea oneline matchgroup=specSectionMacro start='^%\(\(un\)\?define\|dump\|trace\|patch\d*\|setup\|configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|scons\|waf\|bcond_with\(out\)\?\|include\)\>' end='$' contains=specCommandOpts,specMacroIdentifier,specSectionMacroBcondArea
 134 syn region specSectionMacroBracketArea oneline matchgroup=specSectionMacro start='^%{\(configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|scons\|waf\)}' end='$' contains=specCommandOpts,specMacroIdentifier
 135 syn region specSectionMacroBcondArea oneline matchgroup=specBlock start='%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):' skip='\\}' end='}' contains=ALLBUT,shCase
 136
 137 " %% Files Section %%
 138 " TODO %config valid parameters: missingok\|noreplace
 139 " TODO %verify valid parameters: \(not\)\= \(md5\|atime\|...\)
 140 syn region specFilesArea matchgroup=specSection start="^%files\>"
 141         \ skip="%\(attrib\|defattr\|attr\|dir\|config\|docdir\|doc\|lang\|verify\|ghost\|exclude\|dev\|if\|ifarch\|ifnarch\|else\|endif\)\>"
 142         \ end='^%[a-zA-Z]'me=e-2
 143         \ contains=specFilesOpts,specFilesDirective,@specListedFiles,specComment,specCommandSpecial,specMacroIdentifier,specSectionMacroBcondArea,specIf
 144
 145 " tip: remember to include new items in specFilesArea above
 146 syn match  specFilesDirective contained '%\(dir\|docdir\|doc\|ghost\|exclude\)\>'
 147 syn region specFilesDirective contained start="%\(attrib\|attr\|defattr\|config\|lang\|verify\|dev\)(" end=")" contains=specAttr transparent
 148 syn match  specAttr contained "%\(attrib\|attr\|defattr\|config\|lang\|verify\|dev\)"
 149
 150 " valid options for certain section headers
 151 syn match specDescriptionOpts contained '\s-[ln]\s*\a'ms=s+1,me=e-1
 152 syn match specPackageOpts     contained    '\s-n\s*\w'ms=s+1,me=e-1
 153 syn match specFilesOpts       contained    '\s-f\s*\w'ms=s+1,me=e-1
 154
 155
 156 syn case ignore
 157
 158
 159 " %% PreAmble Section %%
 160 " Copyright and Serial were deprecated by License and Epoch
 161 " PreReq and BuildPreReq deprecated by Requires ans BuildRequires
 162 syn region specPreAmbleDeprecated oneline matchgroup=specError start='^\(Copyright\|Serial\|PreReq\|BuildPreReq\(uires\)\?\)' end='$' contains=specEmail,specURL,specURLMacro,specLicense,specColon,specVariables,specSpecialChar,specMacroIdentifier
 163 syn region specPreAmble oneline matchgroup=specCommand
 164         \ start='\(^\|\(^%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):\)\@<=\)\(Summary\|Name\|Version\|Packager\|Requires\|Suggests\|Icon\|URL\|Source\d*\|Patch\d*\|Prefix\|Packager\|Group\|License\|Release\|BuildRoot\|Distribution\|Vendor\|Provides\|ExclusiveArch\|ExcludeArch\|ExclusiveOS\|Obsoletes\|BuildArch\|BuildArchitectures\|BuildRequires\|BuildConflicts\|Conflicts\|AutoRequires\|AutoReqProv\|AutoReq\|AutoProv\|Epoch\|NoSource\)'
 165         \ end='$\|}\@='
 166         \ contains=specEmail,specURL,specURLMacro,specLicense,specLicenseWarning,specColon,specVariables,specSpecialChar,specMacroIdentifier,specSectionMacroBcondArea
 167
 168 " %% Description Section %%
 169 syn region specDescriptionArea matchgroup=specSection start='^%description' end='^%'me=e-1
 170         \ contains=specDescriptionOpts,specEmail,specURL,specNumber,specMacroIdentifier,specComment
 171
 172 " %% Package Section %%
 173 syn region specPackageArea matchgroup=specSection start='^%package' end='^%'me=e-1
 174         \ contains=specPackageOpts,specPreAmble,specComment,specMacroNameOther
 175
 176 " %% Scripts Section %%
 177 syn region specScriptArea matchgroup=specSection
 178         \ start='^%\(prep\|build\|install\|clean\|pre\|postun\|preun\|post\|triggerin\|triggerun\|triggerpostun\|pretrans\|posttrans\|verifyscript\|check\)\>'
 179         \ skip='^%{\|^%\(define\|patch\d*\|configure2_13\|configure\|ant\|GNUconfigure\|setup\|find_lang\|makeinstall\|cmake\|scons\|waf\|useradd\|groupadd\|addusertogroup\|banner\|service\|env_update\|py_o\?comp\|py_postclean\|\(openldap_schema\|webapp\)_\(un\)\?register\|depmod\|pear_package_\(setup\|install\)\|\(build\|install\)_kernel_modules\|php_webserver_restart\|php4_webserver_restart\|update_browser_plugins\)\>'
 180         \ end='^%'me=e-1
 181         \ contains=specSpecialVariables,specVariables,@specCommands,specVariables,shDo,shFor,shCaseEsac,specNoNumberHilite,specCommandOpts,shComment,shIf,specSpecialChar,specMacroIdentifier,specSectionMacroArea,specSectionMacroBracketArea,shOperator,shQuote1,shQuote2,specSectionMacroBcondArea
 182 " XXX don't forget to update specMacro when updating specScriptArea skip definition
 183
 184 " %% Changelog Section %%
 185 syn region specChangelogArea matchgroup=specSection start='^%changelog' end='^%'me=e-1
 186         \ contains=specEmail,specURL,specWeekday,specMonth,specNumber,specComment,specLicense,specRevision,specLogMessage,specLogError
 187
 188 syn match specRevision contained "^Revision [.0-9]\+  [-/0-9]\+ [:0-9]\+  [a-zA-Z0-9]\+$"
 189 syn region specLogMessage contained start="^[- ] " end="$" contains=specLogError,specURL,specEmail
 190 syn match specLogError contained "%%"
 191
 192 " ------------------------------------------------------------------------------
 193 " here's the shell syntax for all the Script Sections
 194
 195
 196 syn case match
 197
 198
 199 " sh-like comment style, only valid in script part
 200 syn match shComment contained '#.*$'
 201
 202 syn region shQuote1 contained matchgroup=shQuoteDelim start=+'+ skip=+\\'+ end=+'+ contains=specMacroIdentifier
 203 syn region shQuote2 contained matchgroup=shQuoteDelim start=+"+ skip=+\\"+ end=+"+ contains=specVariables,specMacroIdentifier,specSectionMacroBcondArea
 204
 205 syn match shOperator contained '[><|!&;]\|[!=]='
 206 syn region shDo transparent matchgroup=specBlock start="\(^\|\s\)do\(\s\|$\)" end="\(^\|\s\)done\(\s\|$\)" contains=ALLBUT,shDoError,shCase,specPreAmble,@specListedFiles
 207 syn region shIf transparent matchgroup=specBlock start="\(^\|\s\)if\(\s\|$\)" end="\(^\|\s\)fi\(\s\|$\)" contains=ALLBUT,shIfError,shCase,@specListedFiles
 208
 209 syn region shFor  matchgroup=specBlock start="\(^\|\s\)for\(\s\|$\)" end="\(^\|\s\)in\(\s\|$\)" contains=ALLBUT,shInError,shCase,@specListedFiles
 210
 211 syn region shCaseEsac transparent matchgroup=specBlock start="\(^\|\s\)case\(\s\|$\)" matchgroup=NONE end="\(^\|\s\)in\(\s\|$\)"me=s-1 contains=ALLBUT,@specListedFiles nextgroup=shCaseEsac
 212 syn region shCaseEsac matchgroup=specBlock start="\(^\|\s\)in\(\s\|$\)" end="\(^\|\s\)esac\(\s\|$\)" contains=ALLBUT,@specListedFilesBin
 213 syn region shCase matchgroup=specBlock contained start=")"  end=";;" contains=ALLBUT,shCase,@specListedFiles
 214
 215 syn sync match shDoSync       grouphere  shDo       "\<do\>"
 216 syn sync match shDoSync       groupthere shDo       "\<done\>"
 217 syn sync match shIfSync       grouphere  shIf       "\<if\>"
 218 syn sync match shIfSync       groupthere shIf       "\<fi\>"
 219 syn sync match shForSync      grouphere  shFor      "\<for\>"
 220 syn sync match shForSync      groupthere shFor      "\<in\>"
 221 syn sync match shCaseEsacSync grouphere  shCaseEsac "\<case\>"
 222 syn sync match shCaseEsacSync groupthere shCaseEsac "\<esac\>"
 223
 224 syn region specIf  matchgroup=specBlock start="%ifosf\|%ifos\|%ifnos\|%ifarch\|%ifnarch\|ifdef\|ifndef\|%if\|%else"  end='%endif' contains=ALLBUT, specOutSkip, specOut2
 225
 226 " %if 0 handing
 227 syn region specOut start="^\s*%if\s\+0$" end="$" contains=specOut2
 228 syn region specOut2 contained start="\<0" end="^\s*%\(endif\>\|else\>\)" contains=specOutSkip
 229
 230 syn region specOutSkip contained start="^\s*%if\>" end="^\s*%endif\>" contains=specOutSkip
 231
 232 syn sync match specIfSync     grouphere  specIf     "%ifarch\|%ifos\|%ifnos"
 233 syn sync match specIfSync     groupthere specIf     "%endIf"
 234
 235 " Define the default highlighting.
 236 " For version 5.7 and earlier: only when not done already
 237 " For version 5.8 and later: only when an item doesn't have highlighting yet
 238 if version >= 508 || !exists("did_spec_syntax_inits")
 239   if version < 508
 240     let did_spec_syntax_inits = 1
 241     command -nargs=+ HiLink hi link <args>
 242   else
 243     command -nargs=+ HiLink hi def link <args>
 244   endif
 245
 246   "main types color definitions
 247   HiLink specSection                    Structure
 248   HiLink specSectionMacro               Macro
 249   HiLink specWWWlink                    PreProc
 250   HiLink specOpts                       Operator
 251
 252   "yes, it's ugly, but white is sooo cool
 253   if &background == "dark"
 254     hi def specGlobalMacro              ctermfg=white
 255   else
 256     HiLink specGlobalMacro              Identifier
 257   endif
 258
 259   "sh colors
 260   HiLink shComment                      Comment
 261   HiLink shIf                           Statement
 262   HiLink shOperator                     Special
 263   HiLink shQuote1                       String
 264   HiLink shQuote2                       String
 265   HiLink shQuoteDelim                   Statement
 266
 267   " spec colors
 268   HiLink specBlock                      Function
 269   HiLink specBcond                      Function
 270   HiLink specColon                      Special
 271   HiLink specCommand                    Statement
 272   HiLink specCommandOpts                specOpts
 273   HiLink specCommandSpecial             Special
 274   HiLink specComment                    Comment
 275   HiLink specConfigure                  specCommand
 276   HiLink specDate                       String
 277   HiLink specDescriptionOpts            specOpts
 278   HiLink specEmail                      specWWWlink
 279   HiLink specError                      Error
 280   HiLink specFilesDirective             specSectionMacro
 281   HiLink specAttr                       specSectionMacro
 282   HiLink specFilesOpts                  specOpts
 283   HiLink specLicense                    String
 284   HiLink specLicenseWarning             specError
 285   HiLink specMacroNameLocal             specGlobalMacro
 286   HiLink specMacroNameOther             specGlobalMacro
 287   HiLink specManpageFile                NONE
 288   HiLink specMonth                      specDate
 289   HiLink specNoNumberHilite             NONE
 290   HiLink specNumber                     Number
 291   HiLink specPackageOpts                specOpts
 292   HiLink specPercent                    Special
 293   HiLink specSpecialChar                Special
 294   HiLink specSubstChar                  Special
 295   HiLink specSpecialVariables           specGlobalMacro
 296   HiLink specSpecialVariablesNames      specGlobalMacro
 297   HiLink specTarCommand                 specCommand
 298   HiLink specMacro                      Macro
 299   HiLink specURL                        specWWWlink
 300   HiLink specURLMacro                   specWWWlink
 301   HiLink specVariables                  Identifier
 302   HiLink specWeekday                    specDate
 303   HiLink specListedFilesBin             Statement
 304   HiLink specListedFilesDoc             Statement
 305   HiLink specListedFilesEtc             Statement
 306   HiLink specListedFilesLib             Statement
 307   HiLink specListedFilesPrefix          Statement
 308   HiLink specListedFilesShare           Statement
 309
 310   HiLink specRevision                   Number
 311   HiLink specLogMessage                 Identifier
 312   HiLink specLogError                   Error
 313
 314   HiLink specOutSkip            specOut
 315   HiLink specOut2            specOut
 316   HiLink specOut             Comment
 317
 318   delcommand HiLink
 319 endif
 320
 321 let b:current_syntax = "spec"
 322
 323 " vim: ts=8