spec.vim

   1 " Filename:    spec.vim
   2 " Purpose:     Vim syntax file
   3 " Language:    SPEC: Build/install scripts for PLD Linux RPM packages
   4 " Maintainer:  PLD Linux <feedback@pld-linux.org>
   5 " URL:         http://www.pld-linux.org/
   6 " Last Change: $Date$ (UTC)
   7 " Version:     $Revision$
   8
   9 " For version 5.x: Clear all syntax items
  10 " For version 6.x: Quit when a syntax file was already loaded
  11 if version < 600
  12   syntax clear
  13 elseif exists("b:current_syntax")
  14   finish
  15 endif
  16
  17 " we're quite strict on spec syntax, so match case for everything
  18 syn case match
  19
  20 syn sync minlines=1000
  21
  22 syn match specSpecialChar contained '[][!$()\\|>^;:]'
  23 syn match specColon       contained ':'
  24 syn match specPercent     contained '%'
  25 syn match specSubstChar   contained '[#%]'
  26
  27 syn match specVariables   contained '\$\h\w*' contains=specSpecialVariablesNames,specSpecialChar
  28 syn match specVariables   contained '\${\w*}' contains=specSpecialVariablesNames,specSpecialChar
  29 syn match specVariables   contained '\${\w*[#%][^}]*}' contains=specSubstChar
  30
  31 syn match specMacroIdentifier contained '%\h\w*' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  32 syn region specMacroIdentifier oneline matchgroup=Special start='%{' skip='\\}' end='}' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  33 syn match specBcond contained '%{with\(out\)\?\s\+[a-zA-Z0-9_-]\+}'
  34
  35 syn match specSpecialVariables contained '\$[0-9]\|\${[0-9]}'
  36 syn match specCommandOpts      contained '\s\(-\w\+\|--\w[a-zA-Z0-9_-]\+\)'ms=s+1
  37 syn match specComment '^\s*#.*$'
  38
  39 " matches with no highlight
  40 syn match specNoNumberHilite 'X11\|X11R6\|[a-zA-Z]*\.\d\|[a-zA-Z][-/]\d'
  41 syn match specManpageFile '[a-zA-Z]\.1'
  42
  43 " Day, Month and most used license acronyms
  44 syn keyword specLicense contained GPL LGPL BSD MIT GNU Apache PHP
  45 syn keyword specLicenseWarning contained unknown
  46 syn match specLicenseWarning contained /same as perl/
  47 syn match specLicenseWarning contained "(enter GPL/LGPL/BSD/BSD-like/Artistic/other license name here)"
  48 syn keyword specWeekday contained Mon Tue Wed Thu Fri Sat Sun
  49 syn keyword specMonth   contained Jan Feb Mar Apr Jun Jul Aug Sep Oct Nov Dec
  50 syn keyword specMonth   contained January February March April May June July August September October November December
  51
  52 " #, @, www
  53 syn match specNumber '\(^-\=\|[ \t]-\=\|-\)[0-9.-]*[0-9]'
  54 syn match specEmail contained "<\=\<[A-Za-z0-9_.-]\+@\([A-Za-z0-9_-]\+\.\)\+[A-Za-z]\+\>>\="
  55 syn match specURL      contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#?=-]\+\>'
  56 syn match specURLMacro contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#%{}-]\+\>' contains=specMacroIdentifier
  57
  58 " TODO take specSpecialVariables out of the cluster for the sh* contains (ALLBUT)
  59 " Special system directories
  60 syn match specListedFilesPrefix contained '/\(usr\|local\|opt\|X11R6\|X11\)/'me=e-1
  61 syn match specListedFilesBin    contained '/s\=bin/'me=e-1
  62 syn match specListedFilesLib    contained '/\(lib\|include\)/'me=e-1
  63 syn match specListedFilesDoc    contained '/\(man\d*\|doc\|info\)\>'
  64 syn match specListedFilesEtc    contained '/etc/'me=e-1
  65 syn match specListedFilesShare  contained '/share/'me=e-1
  66 syn cluster specListedFiles contains=specListedFilesBin,specListedFilesLib,specListedFilesDoc,specListedFilesEtc,specListedFilesShare,specListedFilesPrefix,specSpecialChar
  67
  68 " specComands
  69 syn match   specConfigure  contained '\./configure'
  70 syn match   specTarCommand contained '\<tar\s\+[cxvpzjf]\{,5}\s*'
  71
  72 " XXX don't forget to update specScriptArea when updating specMacro
  73 syn match   specMacro contained '%\(group\|user\)\(add\|remove\)'
  74 syn match   specMacro contained '%\(depmod\|banner\|service\|addusertogroup\|env_update\)'
  75 syn match   specMacro contained '%\(\(nsplugin\|apache_config\)_\(un\)\?install\)'
  76 syn match   specMacro contained '%\(\(openldap_schema\|webapp\)_\(un\)\?register\)'
  77 syn match   specMacro contained '%\(pear_package_\(setup\|install\)\)'
  78 syn match   specMacro contained '%\(py_o\?comp\|py_postclean\|py_lint\)'
  79 syn match   specMacro contained '%\(build\|install\)_kernel_modules'
  80 syn match   specMacro contained '%ant'
  81 syn match   specMacro contained '%\(php\|php4\)_webserver_restart'
  82 syn match   specMacro contained '%update_browser_plugins\|%browser_plugins_add_browser'
  83 syn match   specMacro contained '%gconf_schema_\(un\)?install'
  84 syn match   specMacro contained '%scrollkeeper_update_post\(un\)?'
  85 syn match   specMacro contained '%update_icon_cache\|%update_mime_database'
  86
  87 syn keyword specCommandSpecial contained root
  88 syn keyword specCommand         contained make xmkmf mkdir chmod find sed rm strip moc echo grep ls rm mv mkdir chown install cp pwd cat tail then else elif cd gzip rmdir ln eval export touch unzip bzip2
  89 syn cluster specCommands contains=specCommand,specTarCommand,specConfigure,specCommandSpecial,specMacro
  90
  91 " frequently used rpm env vars
  92 syn keyword specSpecialVariablesNames contained RPM_BUILD_ROOT RPM_BUILD_DIR RPM_SOURCE_DIR RPM_OPT_FLAGS LDFLAGS CC CC_FLAGS CPPNAME CFLAGS CXX CXXFLAGS CPPFLAGS
  93
  94 " valid macro names from /usr/lib/rpm/macros*
  95 syn keyword specMacroNameOther contained ix86 x8664 ppc
  96 syn keyword specMacroNameOther contained buildroot buildsubdir distribution disturl name nil optflags perl_sitearch release requires_eq vendor version
  97 syn keyword specMacroNameOther contained __kernel_ver date debugcflags debuginfocflags epoch kgcc kgcc_package packager
  98 syn keyword specMacroNameOther contained pear_package_install pear_package_setup perl_archlib perl_privlib perl_sitelib
  99 syn keyword specMacroNameOther contained perl_vendorarch perl_vendorlib php_pear_dir php_data_dir py_sitedir py_scriptdir py_sitescriptdir
 100 syn keyword specMacroNameOther contained requires_php_extension requires_php_pdo_module
 101 syn keyword specMacroNameOther contained requires_zend_extension ruby_mod_ver_requires_eq ruby_ver_requires_eq rpmcflags rpmcxxflags rpmldflags tmpdir
 102 syn keyword specMacroNameOther contained ruby_archdir ruby_rubylibdir ruby_vendorarchdir ruby_vendorlibdir ruby_ridir ruby_sitearchdir ruby_sitelibdir ruby_version ruby_rdocdir
 103 syn keyword specMacroNameOther contained apache_modules_api php_sysconfdir php_includedir php_extensiondir _browserpluginsdir _browserpluginsconfdir
 104 syn keyword specMacroNameOther contained releq_kernel releq_kernel_up releq_kernel_smp requires_releq_kernel requires_releq_kernel_up requires_releq_kernel_smp
 105
 106 syn match   specMacroNameOther contained '\<\(PATCH\|SOURCE\)\d*\>'
 107
 108 " valid _macro names from /usr/lib/rpm/macros*
 109 syn keyword specMacroNameLocal contained _aclocaldir _applnkdir _arch _binary_payload _bindir _build _build_arch _build_alias
 110 syn keyword specMacroNameLocal contained _build_cpu _builddir _build_os _buildshell _buildsubdir _build_vendor _bzip2bin _datadir
 111 syn keyword specMacroNameLocal contained _dbpath _dbpath_rebuild _defaultdocdir _desktopdir _docdir _examplesdir _excludedocs _kdedocdir
 112 syn keyword specMacroNameLocal contained _exec_prefix _fixgroup _fixowner _fixperms _fontsdir _ftpport _ftpproxy _gnu _gpg_name
 113 syn keyword specMacroNameLocal contained _gpg_path _gtkdocdir _gzipbin _host _host_alias _host_cpu _host_os _host_vendor
 114 syn keyword specMacroNameLocal contained _httpport _httpproxy _iconsdir _includedir _infodir _initrddir _install_langs
 115 syn keyword specMacroNameLocal contained _install_script_path _instchangelog _javaclasspath _javadir _javadocdir _kernelsrcdir
 116 syn keyword specMacroNameLocal contained _kernel_ver _kernel_ver_str _kernel_vermagic _langpatt _lib _libdir _libexecdir _localstatedir _mandir
 117 syn keyword specMacroNameLocal contained _netsharedpath _oldincludedir _omf_dest_dir _os _package_version _pgpbin _pgp_name
 118 syn keyword specMacroNameLocal contained _pgp_path _pixmapsdir _pkgconfigdir _prefix _preScriptEnvironment _provides _rpmdir
 119 syn keyword specMacroNameLocal contained _rpmfilename _sbindir _sharedstatedir _signature _smp_mflags _sourcedir _source_payload
 120 syn keyword specMacroNameLocal contained _specdir _srcrpmdir _sysconfdir _target _target_alias _target_cpu _target_os _target_platform
 121 syn keyword specMacroNameLocal contained _target_vendor _target_base_arch _timecheck _tmppath _topdir _usr _usrsrc _var _vendor
 122 syn keyword specMacroNameLocal contained __cxx __cc __ar __libtoolize __autopoint __aclocal __autoconf __automake __autoheader
 123 syn keyword specMacroNameLocal contained __gettextize __glib_gettextize __intltoolize
 124 syn keyword specMacroNameLocal contained __bzip2 __cat __chgrp __chmod __chown __cp   __cpio __file __gpg __grep __gzip
 125 syn keyword specMacroNameLocal contained __id  __install __ld   __make   __mkdir __mkdir_p __mv __nm  __objcopy __objdump
 126 syn keyword specMacroNameLocal contained __patch __perl __pgp __python __rm __rsh  __sed __ssh __strip  __tar __unzip
 127
 128
 129
 130 " ------------------------------------------------------------------------------
 131 " here's is all the spec sections definitions: PreAmble, Description, Package,
 132 "   Scripts, Files and Changelog
 133
 134 " One line macros - valid in all ScriptAreas
 135 " tip: remember do include new items on specScriptArea's skip section
 136 syn region specSectionMacroArea oneline matchgroup=specSectionMacro start='^%\(\(un\)\?define\|dump\|trace\|patch\d*\|setup\|configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|scons\|waf\|bcond_with\(out\)\?\|include\)\>' end='$' contains=specCommandOpts,specMacroIdentifier,specSectionMacroBcondArea
 137 syn region specSectionMacroBracketArea oneline matchgroup=specSectionMacro start='^%{\(configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|scons\|waf\)}' end='$' contains=specCommandOpts,specMacroIdentifier
 138 syn region specSectionMacroBcondArea oneline matchgroup=specBlock start='%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):' skip='\\}' end='}' contains=ALL
 139
 140 " %% Files Section %%
 141 " TODO %config valid parameters: missingok\|noreplace
 142 " TODO %verify valid parameters: \(not\)\= \(md5\|atime\|...\)
 143 syn region specFilesArea matchgroup=specSection start="^%files\>"
 144         \ skip="%\(attrib\|defattr\|attr\|dir\|config\|docdir\|doc\|lang\|verify\|ghost\|exclude\|dev\|if\|ifarch\|ifnarch\|else\|endif\)\>"
 145         \ end='^%[a-zA-Z]'me=e-2
 146         \ contains=specFilesOpts,specFilesDirective,@specListedFiles,specComment,specCommandSpecial,specMacroIdentifier,specSectionMacroBcondArea,specIf
 147
 148 " tip: remember to include new items in specFilesArea above
 149 syn match  specFilesDirective contained '%\(dir\|docdir\|doc\|ghost\|exclude\)\>'
 150 syn region specFilesDirective contained start="%\(attrib\|attr\|defattr\|config\|lang\|verify\|dev\)(" end=")" contains=specAttr transparent
 151 syn match  specAttr contained "%\(attrib\|attr\|defattr\|config\|lang\|verify\|dev\)"
 152
 153 " valid options for certain section headers
 154 syn match specDescriptionOpts contained '\s-[ln]\s\a'ms=s+1,me=e-1 contains=specDescriptionCharset
 155 "syn match specDescriptionOptLang contained '\s-l\s*[a-zA-Z0-9.-]\+'ms=s+1
 156 syn match specPackageOpts     contained    '\s-n\s*\w'ms=s+1,me=e-1
 157 syn match specFilesOpts       contained    '\s-f\s*\w'ms=s+1,me=e-1
 158
 159 " charset: et,et.UTF-8,pl.UTF-8,pt_BR, ... etc
 160 syn match specDescriptionCharset         contained '-l\s[a-z_A-Z]\+\(\.UTF-8\)\?'ms=s+2
 161 syn match specPreAmbleCharset         contained '([a-z_A-Z]\+\(\.UTF-8\)\?):'
 162
 163
 164 " %% PreAmble Section %%
 165 " Copyright and Serial were deprecated by License and Epoch
 166 " PreReq and BuildPreReq deprecated by Requires ans BuildRequires
 167 syn region specPreAmbleDeprecated oneline matchgroup=specError start='^\(Copyright\|Serial\|PreReq\|BuildPreReq\(uires\)\?\)' end='$' contains=specEmail,specURL,specURLMacro,specLicense,specColon,specVariables,specSpecialChar,specMacroIdentifier
 168 syn region specPreAmble oneline matchgroup=specPreambleField
 169         \ start='\(^\|\(^%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):\)\@<=\)\(Name\|Version\|Packager\|Requires\|Suggests\|Icon\|URL\|Source\d*\|Patch\d*\|Prefix\|Packager\|Group\|License\|Release\|BuildRoot\|Distribution\|Vendor\|Provides\|ExclusiveArch\|ExcludeArch\|ExclusiveOS\|Obsoletes\|BuildArch\|BuildArchitectures\|BuildRequires\|BuildConflicts\|Conflicts\|AutoRequires\|AutoReqProv\|AutoReq\|AutoProv\|Epoch\|NoSource\)'
 170         \ end='$\|}\@='
 171         \ contains=specEmail,specURL,specURLMacro,specLicense,specLicenseWarning,specColon,specVariables,specSpecialChar,specMacroIdentifier,specSectionMacroBcondArea
 172
 173 syn region specPreAmble oneline matchgroup=specPreambleField
 174         \ start='\(Summary\)'
 175         \ end='$\|}\@='
 176         \ contains=specPreambleCharset,specURLMacro,specMacroIdentifier,specSectionMacroBcondArea
 177
 178 " %% Description Section %%
 179 syn region specDescriptionArea matchgroup=specSection start='^%description' end='^%'me=e-1
 180         \ contains=specDescriptionOpts,specEmail,specURL,specNumber,specMacroIdentifier,specComment
 181
 182 " %% Package Section %%
 183 syn region specPackageArea matchgroup=specSection start='^%package' end='^%'me=e-1
 184         \ contains=specPackageOpts,specPreAmble,specComment,specMacroNameOther
 185
 186 " %% Scripts Section %%
 187 syn region specScriptArea matchgroup=specSection
 188         \ start='^%\(prep\|build\|install\|clean\|pre\|postun\|preun\|post\|triggerin\|triggerun\|triggerpostun\|pretrans\|posttrans\|verifyscript\|check\)\>'
 189         \ skip='^%{\|^%\(define\|patch\d*\|configure2_13\|configure\|ant\|GNUconfigure\|setup\|find_lang\|makeinstall\|cmake\|scons\|waf\|useradd\|groupadd\|addusertogroup\|banner\|service\|env_update\|py_o\?comp\|py_postclean\|py_lint\|\(openldap_schema\|webapp\)_\(un\)\?register\|depmod\|pear_package_\(setup\|install\)\|\(build\|install\)_kernel_modules\|php_webserver_restart\|php4_webserver_restart\|update_browser_plugins\|gconf_schema_\(un\)?install\|scrollkeeper_update_post\(un\)?\|update_icon_cache\|update_mime_database\)\>'
 190         \ end='^%'me=e-1
 191         \ contains=specSpecialVariables,specVariables,@specCommands,specVariables,shDo,shFor,shCaseEsac,specNoNumberHilite,specCommandOpts,shComment,shIf,specSpecialChar,specMacroIdentifier,specSectionMacroArea,specSectionMacroBracketArea,shOperator,shQuote1,shQuote2,specSectionMacroBcondArea
 192 " XXX don't forget to update specMacro when updating specScriptArea skip definition
 193
 194 " %% Changelog Section %%
 195 syn region specChangelogArea matchgroup=specSection start='^%changelog' end='^%'me=e-1
 196         \ contains=specEmail,specURL,specWeekday,specMonth,specNumber,specComment,specLicense,specRevision,specLogMessage,specLogError
 197
 198 syn match specRevision contained "^Revision [.0-9]\+  [-/0-9]\+ [:0-9]\+  [a-zA-Z0-9]\+$"
 199 syn region specLogMessage contained start="^[- ] " end="$" contains=specLogError,specURL,specEmail
 200 syn match specLogError contained "%%"
 201
 202 " ------------------------------------------------------------------------------
 203 " here's the shell syntax for all the Script Sections
 204
 205 " sh-like comment style, only valid in script part
 206 syn match shComment contained '#.*$'
 207
 208 syn region shQuote1 contained matchgroup=shQuoteDelim start=+'+ skip=+\\'+ end=+'+ contains=specMacroIdentifier
 209 syn region shQuote2 contained matchgroup=shQuoteDelim start=+"+ skip=+\\"+ end=+"+ contains=specVariables,specMacroIdentifier,specSectionMacroBcondArea
 210
 211 syn match shOperator contained '[><|!&;]\|[!=]='
 212 syn region shDo transparent matchgroup=specBlock start="\(^\|\s\)do\(\s\|$\)" end="\(^\|\s\)done\(\s\|$\)" contains=ALLBUT,shDoError,shCase,specPreAmble,@specListedFiles
 213 syn region shIf transparent matchgroup=specBlock start="\(^\|\s\)if\(\s\|$\)" end="\(^\|\s\)fi\(\s\|$\)" contains=ALLBUT,shIfError,shCase,@specListedFiles
 214
 215 syn region shFor  matchgroup=specBlock start="\(^\|\s\)for\(\s\|$\)" end="\(^\|\s\)in\(\s\|$\)" contains=ALLBUT,shInError,shCase,@specListedFiles
 216
 217 syn region shCaseEsac transparent matchgroup=specBlock start="\(^\|\s\)case\(\s\|$\)" matchgroup=NONE end="\(^\|\s\)in\(\s\|$\)"me=s-1 contains=ALLBUT,@specListedFiles nextgroup=shCaseEsac
 218 syn region shCaseEsac matchgroup=specBlock start="\(^\|\s\)in\(\s\|$\)" end="\(^\|\s\)esac\(\s\|$\)" contains=ALLBUT,@specListedFilesBin
 219 syn region shCase matchgroup=specBlock contained start=")"  end=";;" contains=ALLBUT,shCase,@specListedFiles
 220
 221 syn sync match shDoSync       grouphere  shDo       "\<do\>"
 222 syn sync match shDoSync       groupthere shDo       "\<done\>"
 223 syn sync match shIfSync       grouphere  shIf       "\<if\>"
 224 syn sync match shIfSync       groupthere shIf       "\<fi\>"
 225 syn sync match shForSync      grouphere  shFor      "\<for\>"
 226 syn sync match shForSync      groupthere shFor      "\<in\>"
 227 syn sync match shCaseEsacSync grouphere  shCaseEsac "\<case\>"
 228 syn sync match shCaseEsacSync groupthere shCaseEsac "\<esac\>"
 229
 230 syn region specIf  matchgroup=specBlock start="%ifosf\|%ifos\|%ifnos\|%ifarch\|%ifnarch\|ifdef\|ifndef\|%if\|%else"  end='%endif' contains=ALLBUT, specOutSkip, specOut2
 231
 232 " %if 0 handing
 233 if exists("spec_if0")
 234     syn region specOut start="^\s*%if\s\+0$" end="$" contains=specOut2
 235     syn region specOut2 contained start="%if\s\+0" end="^\s*%\(endif\>\|else\>\)" contains=specOutSkip
 236
 237     syn region specOutSkip contained start="^\s*%if\>" end="^\s*%endif\>" contains=specOutSkip
 238
 239     syn sync match specIfSync     grouphere  specIf     "%ifarch\|%ifos\|%ifnos"
 240     syn sync match specIfSync     groupthere specIf     "%endIf"
 241 endif
 242
 243 " Define the default highlighting.
 244 " For version 5.7 and earlier: only when not done already
 245 " For version 5.8 and later: only when an item doesn't have highlighting yet
 246 if version >= 508 || !exists("did_spec_syntax_inits")
 247   if version < 508
 248     let did_spec_syntax_inits = 1
 249     command -nargs=+ HiLink hi link <args>
 250   else
 251     command -nargs=+ HiLink hi def link <args>
 252   endif
 253
 254   "main types color definitions
 255   HiLink specSection                    Structure
 256   HiLink specSectionMacro               Macro
 257   HiLink specWWWlink                    PreProc
 258   HiLink specOpts                       Operator
 259
 260   "yes, it's ugly, but white is sooo cool
 261   if &background == "dark"
 262     hi def specGlobalMacro              ctermfg=white
 263   else
 264     HiLink specGlobalMacro              Identifier
 265   endif
 266
 267   "sh colors
 268   HiLink shComment                      Comment
 269   HiLink shIf                           Statement
 270   HiLink shOperator                     Special
 271   HiLink shQuote1                       String
 272   HiLink shQuote2                       String
 273   HiLink shQuoteDelim                   Statement
 274
 275   " spec colors
 276   HiLink specBlock                      Function
 277   HiLink specBcond                      Function
 278   HiLink specColon                      Special
 279   HiLink specCommand                    Statement
 280   HiLink specPreambleField              Statement
 281   HiLink specCommandOpts                specOpts
 282   HiLink specCommandSpecial             Special
 283   HiLink specComment                    Comment
 284   HiLink specConfigure                  specCommand
 285   HiLink specDate                       String
 286   HiLink specPreAmbleCharset            String
 287   HiLink specDescriptionCharset         String
 288   HiLink specDescriptionOpts            specOpts
 289   HiLink specEmail                      specWWWlink
 290   HiLink specError                      Error
 291   HiLink specFilesDirective             specSectionMacro
 292   HiLink specAttr                       specSectionMacro
 293   HiLink specFilesOpts                  specOpts
 294   HiLink specLicense                    String
 295   HiLink specLicenseWarning             specError
 296   HiLink specMacroNameLocal             specGlobalMacro
 297   HiLink specMacroNameOther             specGlobalMacro
 298   HiLink specManpageFile                NONE
 299   HiLink specMonth                      specDate
 300   HiLink specNoNumberHilite             NONE
 301   HiLink specNumber                     Number
 302   HiLink specPackageOpts                specOpts
 303   HiLink specPercent                    Special
 304   HiLink specSpecialChar                Special
 305   HiLink specSubstChar                  Special
 306   HiLink specSpecialVariables           specGlobalMacro
 307   HiLink specSpecialVariablesNames      specGlobalMacro
 308   HiLink specTarCommand                 specCommand
 309   HiLink specMacro                      Macro
 310   HiLink specURL                        specWWWlink
 311   HiLink specURLMacro                   specWWWlink
 312   HiLink specVariables                  Identifier
 313   HiLink specWeekday                    specDate
 314   HiLink specListedFilesBin             Statement
 315   HiLink specListedFilesDoc             Statement
 316   HiLink specListedFilesEtc             Statement
 317   HiLink specListedFilesLib             Statement
 318   HiLink specListedFilesPrefix          Statement
 319   HiLink specListedFilesShare           Statement
 320
 321   HiLink specRevision                   Number
 322   HiLink specLogMessage                 Identifier
 323   HiLink specLogError                   Error
 324
 325   HiLink specOutSkip            specOut
 326   HiLink specOut2            specOut
 327   HiLink specOut             Comment
 328
 329   delcommand HiLink
 330 endif
 331
 332 let b:current_syntax = "spec"
 333
 334 " vim: ts=8