pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2009 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17
  18 function fixedsub(s1,s2,t,      ind) {
  19 # substitutes fixed strings (not regexps)
  20         if (ind = index(t,s1)) {
  21                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  22         }
  23         return t
  24 }
  25
  26 function ispre(s) {
  27         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  28                 if (DEBUG) print "pre-version"
  29                 return 1
  30         } else {
  31                 return 0
  32         }
  33 }
  34
  35 function compare_ver(v1,v2) {
  36 # compares version numbers
  37         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  38                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  39         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  40                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  41         sub("^0*","",v1)
  42         sub("^0*","",v2)
  43         gsub("\.0*",".",v1)
  44         gsub("\.0*",".",v2)
  45         if (DEBUG) print "v1 == " v1
  46         if (DEBUG) print "v2 == " v2
  47         count=split(v1,v1a,"\.")
  48         count2=split(v2,v2a,"\.")
  49
  50         if (count<count2) mincount=count
  51         else mincount=count2
  52
  53         for (i=1; i<=mincount; i++) {
  54                 if (v1a[i]=="") v1a[i]=0
  55                 if (v2a[i]=="") v2a[i]=0
  56                 if (DEBUG) print "i == " i
  57                 if (DEBUG) print "v1[i] == " v1a[i]
  58                 if (DEBUG) print "v2[i] == " v2a[i]
  59                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  60                         if (length(v2a[i])>length(v1a[i]))
  61                                 return 1
  62                         else if (v2a[i]>v1a[i])
  63                                 return 1
  64                         else if (length(v1a[i])>length(v2a[i]))
  65                                 return 0
  66                         else if (v1a[i]>v2a[i])
  67                                 return 0
  68                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  69                         if (v2a[i]>v1a[i])
  70                                 return 1
  71                         else if (v1a[i]>v2a[i])
  72                                 return 0
  73                 } else if (ispre(v1a[i]) == 1)
  74                         return 1
  75                 else
  76                         return 0
  77         }
  78         if ((count2==mincount)&&(count!=count2)) {
  79                 for (i=count2+1; i<=count; i++)
  80                         if (ispre(v1a[i]) == 1)
  81                                 return 1
  82                 return 0
  83         } else if (count!=count2) {
  84                 for (i=count+1; i<=count2; i++)
  85                         if (ispre(v2a[i]) == 1)
  86                                 return 0
  87                 return 1
  88         }
  89         return 0
  90 }
  91
  92 function compare_ver_dec(v1,v2) {
  93 # compares version numbers as decimal floats
  94         while (match(v1,/[0-9][a-zA-Z]/))
  95                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  96         while (match(v2,/[0-9][a-zA-Z]/))
  97                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  98         sub("^0*","",v1)
  99         sub("^0*","",v2)
 100         if (DEBUG) print "v1 == " v1
 101         if (DEBUG) print "v2 == " v2
 102         count=split(v1,v1a,"\.")
 103         count2=split(v2,v2a,"\.")
 104
 105         if (count<count2) mincount=count
 106         else mincount=count2
 107
 108         for (i=1; i<=mincount; i++) {
 109                 if (v1a[i]=="") v1a[i]=0
 110                 if (v2a[i]=="") v2a[i]=0
 111                 if (DEBUG) print "i == " i
 112                 if (DEBUG) print "v1[i] == " v1a[i]
 113                 if (DEBUG) print "v2[i] == " v2a[i]
 114                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 115                         if (i==2) {
 116                                 if (0+("." v2a[i])>0+("." v1a[i]))
 117                                         return 1
 118                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 119                                         return 0
 120                         } else {
 121                                 if (length(v2a[i])>length(v1a[i]))
 122                                         return 1
 123                                 else if (v2a[i]>v1a[i])
 124                                         return 1
 125                                 else if (length(v1a[i])>length(v2a[i]))
 126                                         return 0
 127                                 else if (v1a[i]>v2a[i])
 128                                         return 0
 129                         }
 130                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 131                         if (v2a[i]>v1a[i])
 132                                 return 1
 133                         else if (v1a[i]>v2a[i])
 134                                 return 0
 135                 } else if (ispre(v1a[i]) == 1)
 136                         return 1
 137                 else
 138                         return 0
 139         }
 140         if ((count2==mincount)&&(count!=count2)) {
 141                 for (i=count2+1; i<=count; i++)
 142                         if (ispre(v1a[i]) == 1)
 143                                 return 1
 144                 return 0
 145         } else if (count!=count2) {
 146                 for (i=count+1; i<=count2; i++)
 147                         if (ispre(v2a[i]) == 1)
 148                                 return 0
 149                 return 1
 150         }
 151         return 0
 152 }
 153
 154 function link_seen(link) {
 155         for (seenlink in frameseen) {
 156                 if (seenlink == link) {
 157                         if (DEBUG) print "Link: [" link "] seen already, skipping..."
 158                         return 1
 159                 }
 160         }
 161         frameseen[link]=1
 162         return 0
 163 }
 164
 165 function mktemp(   _cmd, _tmpfile) {
 166         _cmd = "mktemp /tmp/XXXXXX"
 167         _cmd | getline _tmpfile
 168         close(_cmd)
 169         return _tmpfile
 170 }
 171
 172 # get all <A HREF=..> tags from specified URL
 173 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 174
 175         wholeerr=""
 176
 177         tmpfile = mktemp()
 178         tmpfileerr = mktemp()
 179
 180         if (url ~ /^http:\/\/(download|dl).(sf|sourceforge).net\//) {
 181                 gsub("^http://(download|dl).(sf|sourceforge).net/", "", url)
 182                 url = "http://prdownloads.sourceforge.net/" substr(url, 1, 1) "/" substr(url, 1, 2) "/" url
 183                 if (DEBUG) print "sf url, mungled url to: " url
 184         }
 185
 186         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 187                 gsub("^http://", "", url)
 188                 gsub("\..*", "", url)
 189                 url = "http://code.google.com/p/" url "/downloads/list"
 190                 if (DEBUG) print "googlecode url, mungled url to: " url
 191         }
 192
 193         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 194                 gsub("-.*", "", filename)
 195                 url = "http://pecl.php.net/package/" filename
 196                 if (DEBUG) print "pecl.php.net url, mungled url to: " url
 197         }
 198
 199         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 200                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 201                  if (DEBUG) print "mysql 5.1 url, mungled url to: " url
 202         }
 203
 204         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 205                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 206                 gsub("\/.*/", "", url)
 207                 url = "https://code.launchpad.net/" url "/+download"
 208                 if (DEBUG) print "main launchpad url, mungled url to: " url
 209         }
 210
 211         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 212                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 213                 gsub("\/.*/", "", url)
 214                 url = "https://edge.launchpad.net/" url "/+download"
 215                 if (DEBUG) print "edge launchpad url, mungled url to: " url
 216         }
 217
 218
 219         if (DEBUG) print "Retrieving: " url
 220         cmd = "wget -nv -O - \"" url "\" -t 2 -T 45 --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 221         if (DEBUG) print "Execute: " cmd
 222         errno = system(cmd)
 223
 224         if (errno==0) {
 225                 while (getline oneline < tmpfile)
 226                         wholeodp=(wholeodp " " oneline)
 227                 if ( DEBUG ) print "Response: " wholeodp
 228         } else {
 229                 wholeerr = ""
 230                 while (getline oneline < tmpfileerr)
 231                         wholeerr=(wholeerr " " oneline)
 232                 if ( DEBUG ) print "Error Response: " wholeerr
 233         }
 234
 235         system("rm -f " tmpfile)
 236         system("rm -f " tmpfileerr)
 237
 238         urldir=url;
 239         sub(/[^\/]+$/,"",urldir)
 240
 241         if ( errno==0) {
 242                 while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 243                         odp=substr(wholeodp,RSTART,RLENGTH);
 244                         wholeodp=substr(wholeodp,RSTART+RLENGTH);
 245
 246                         lowerodp=tolower(odp);
 247                         if (lowerodp ~ /<frame[ \t]/) {
 248                                 sub(/[sS][rR][cC]=[ \t]*/,"src=",odp);
 249                                 match(odp,/src="[^"]+"/)
 250                                 newurl=substr(odp,RSTART+5,RLENGTH-6)
 251                                 if (DEBUG) print "Frame: " newurl
 252                                 if (newurl !~ /\//) {
 253                                         newurl=(urldir newurl)
 254                                         if (DEBUG) print "Frame->: " newurl
 255                                 }
 256
 257                                 if (link_seen(newurl)) {
 258                                         newurl=""
 259                                         continue
 260                                 }
 261
 262                                 retval=(retval " " get_links(newurl))
 263                         } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 264                                 sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 265                                 match(odp,/href="[^"]*"/)
 266                                 link=substr(odp,RSTART,RLENGTH)
 267                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 268                                 link=substr(link,7,length(link)-7)
 269
 270                                 if (link_seen(link)) {
 271                                         link=""
 272                                         continue
 273                                 }
 274
 275                                 retval=(retval " " link)
 276                                 if (DEBUG) print "href(\"\"): " link
 277                         } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 278                                 sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 279                                 match(odp,/href='[^']*'/)
 280                                 link=substr(odp,RSTART,RLENGTH)
 281                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 282                                 link=substr(link,7,length(link)-7)
 283
 284                                 if (link_seen(link)) {
 285                                         link=""
 286                                         continue
 287                                 }
 288
 289                                 retval=(retval " " link)
 290                                 if (DEBUG) print "href(''): " link
 291                         } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 292                                 sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 293                                 match(odp,/href=[^ \t>]*/)
 294                                 link=substr(odp,RSTART,RLENGTH)
 295                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 296                                 link=substr(link,6,length(link)-5)
 297
 298                                 if (link_seen(link)) {
 299                                         link=""
 300                                         continue
 301                                 }
 302
 303                                 retval=(retval " " link)
 304                                 if (DEBUG) print "href(): " link
 305                         } else {
 306                                 # <a ...> but not href - skip
 307                                 if (DEBUG) print "skipping <a > without href: " odp
 308                         }
 309                 }
 310         } else {
 311                 retval=("WGET ERROR: " errno ": " wholeerr)
 312         }
 313
 314
 315         if (DEBUG) print "Returning: " retval
 316         return retval
 317 }
 318
 319 function subst_defines(var,defs) {
 320 # substitute all possible RPM macros
 321         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 322                 oldvar=var
 323                 for (j in defs) {
 324                         gsub("%{" j "}", defs[j], var)
 325                         gsub("%" j , defs[j], var)
 326                 }
 327                 if (var==oldvar) {
 328                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 329                         return var
 330                 }
 331         }
 332         return var
 333 }
 334
 335 function find_mirror(url) {
 336
 337         while (succ = (getline line < "mirrors")) {
 338             if (succ==-1) { return url }
 339                 nf=split(line,fields,"|")
 340                 if (nf>1){
 341                         origin=fields[1]
 342                         mirror=fields[2]
 343                         mname=fields[3]
 344                         prefix=substr(url,1,length(origin))
 345                         if (prefix==origin){
 346                                 if ( DEBUG ) print "Mirror fount at " mname
 347                                 close("mirrors")
 348                                 return mirror substr(url,length(origin)+1)
 349                         }
 350                 }
 351         }
 352
 353         return url
 354 }
 355
 356 function process_source(number,lurl,name,version) {
 357 # fetches file list, and compares version numbers
 358         if ( DEBUG ) print "Processing " lurl
 359
 360         if ( index(lurl,version)==0 ) {
 361                 if (DEBUG) print "There is no version number."
 362                 return 0
 363         }
 364
 365         sub("://",":",lurl)
 366         sub("/",":/",lurl)
 367         gsub("[^/]*$",":&",lurl)
 368         split(lurl,url,":")
 369         acc=url[1]
 370         host=url[2]
 371         dir=url[3]
 372         filename=url[4]
 373
 374         if (index(dir,version)) {
 375                 dir=substr(dir,1,index(dir,version)-1)
 376                 sub("[^/]*$","",dir)
 377                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 378                 if ( DEBUG ) print "Will check a directory: " dir
 379                 if ( DEBUG ) print "and a file: " filename
 380         }
 381
 382         filenameexp=filename
 383         gsub("\+","\\+",filenameexp)
 384         sub(version,"[A-Za-z0-9.]+",filenameexp)
 385         gsub("\.","\\.",filenameexp)
 386         if ( DEBUG ) print "Expression: " filenameexp
 387         match(filename,version)
 388         prever=substr(filename,1,RSTART-1)
 389         postver=substr(filename,RSTART+RLENGTH)
 390         if ( DEBUG ) print "Before number: " prever
 391         if ( DEBUG ) print "and after: " postver
 392         newurl=find_mirror(acc "://" host dir)
 393         #print acc "://" host dir
 394         #newurl=url[1]"://"url[2]url[3]url[4]
 395         #newurl=acc "://" host dir filename
 396         if ( DEBUG ) print "Looking at " newurl
 397
 398         references=0
 399         finished=0
 400         oldversion=version
 401         odp=get_links(newurl,filename)
 402         if( odp ~ "ERROR: ") {
 403                 print name "(" number ") " odp
 404         } else {
 405                 if (DEBUG) print "WebPage downloaded"
 406                 c=split(odp,linki)
 407                 for (nr=1; nr<=c; nr++) {
 408                         addr=linki[nr]
 409                         if (DEBUG) print "Found link: " addr
 410                         if ((addr ~ filenameexp) && !(addr ~ "[-_.0-9A-Za-z~]" filenameexp)) {
 411                                 match(addr,filenameexp)
 412                                 newfilename=substr(addr,RSTART,RLENGTH)
 413                                 if (DEBUG) print "Hypothetical new: " newfilename
 414                                 newfilename=fixedsub(prever,"",newfilename)
 415                                 newfilename=fixedsub(postver,"",newfilename)
 416                                 if (DEBUG) print "Version: " newfilename
 417                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 418                                 if (NUMERIC) {
 419                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 420                                                 if (DEBUG) print "Yes, there is new one"
 421                                                 version=newfilename
 422                                                 finished=1
 423                                         }
 424                                 } else if ( compare_ver(version, newfilename)==1 ) {
 425                                         if (DEBUG) print "Yes, there is new one"
 426                                         version=newfilename
 427                                         finished=1
 428                                 }
 429                         }
 430                 }
 431                 if (finished==0)
 432                         print name "(" number ") seems ok: " oldversion
 433                 else
 434                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 435         }
 436 }
 437
 438 # upgrade check for pear package using PEAR CLI
 439 function pear_upgrade(name, ver) {
 440         pname = name;
 441         sub(/^php-pear-/, "", pname);
 442
 443         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 444         if (DEBUG) {
 445                 print "pearcmd: " pearcmd
 446         }
 447         pearcmd | getline nver
 448         close(pearcmd)
 449
 450         if (compare_ver(ver, nver)) {
 451                 print name " [OLD] " ver " [NEW] " nver
 452         } else {
 453                 print name " seems ok: " ver
 454         }
 455
 456         return
 457 }
 458
 459 function process_data(name,ver,rel,src) {
 460         if (name ~ /^php-pear-/) {
 461                 return pear_upgrade(name, ver);
 462         }
 463
 464 # this function checks if substitutions were valid, and if true:
 465 # processes each URL and tries to get current file list
 466         for (i in src) {
 467                 if ( src[i] ~ /%{nil}/ ) {
 468                         gsub(/\%\{nil\}/, "", src[i])
 469                 }
 470                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 471                         if ( DEBUG ) print "Source: " src[i]
 472                         process_source(i,src[i],name,ver)
 473                 } else {
 474                         print FNAME ":" i ": impossible substitution: " src[i]
 475                 }
 476         }
 477 }
 478
 479 BEGIN {
 480         # if U want to use DEBUG, run script with "-v DEBUG=1"
 481         # or uncomment the line below
 482         # DEBUG = 1
 483
 484         errno=system("wget --help > /dev/null 2>&1")
 485         if (errno) {
 486                 print "No wget installed!"
 487                 exit 1
 488         }
 489         if (ARGC>=3 && ARGV[2]=="-n") {
 490                 NUMERIC=1
 491                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 492                 ARGC=ARGC-1
 493         }
 494 }
 495
 496 FNR==1 {
 497         if ( ARGIND != 1 ) {
 498                 # clean frameseen for each ARG
 499                 for (i in frameseen) {
 500                         delete frameseen[i]
 501                 }
 502                 frameseen[0] = 1
 503
 504                 process_data(NAME,VER,REL,SRC)
 505                 NAME="" ; VER="" ; REL=""
 506                 for (i in DEFS) delete DEFS[i]
 507                 for (i in SRC) delete SRC[i]
 508         }
 509         FNAME=FILENAME
 510         DEFS["_alt_kernel"]=""
 511         DEFS["20"]="\\ "
 512 }
 513
 514 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 515 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 516 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 517 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 518 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 519 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 520
 521 END {
 522         process_data(NAME,VER,REL,SRC)
 523 }