pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|dl)\.(sf|sourceforge)\.net\//) {
 236                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 237                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 238
 239                 gsub("/.*", "", url)
 240                 url = "http://sourceforge.net/projects/" url "/files/"
 241                 d("sf url, mungled url to: " url)
 242         }
 243
 244         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 245                 gsub("^http://", "", url)
 246                 gsub("\..*", "", url)
 247                 url = "http://code.google.com/p/" url "/downloads/list"
 248                 d("googlecode url, mungled url to: " url)
 249         }
 250
 251         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 252                 gsub("-.*", "", filename)
 253                 url = "http://pecl.php.net/package/" filename
 254                 d("pecl.php.net url, mungled url to: " url)
 255         }
 256
 257         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 258                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 259                  d("mysql 5.1 url, mungled url to: " url)
 260         }
 261
 262         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 263                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 264                 gsub("\/.*/", "", url)
 265                 url = "https://code.launchpad.net/" url "/+download"
 266                 d("main launchpad url, mungled url to: " url)
 267         }
 268
 269         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 270                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 271                 gsub("\/.*/", "", url)
 272                 url = "https://edge.launchpad.net/" url "/+download"
 273                 d("edge launchpad url, mungled url to: " url)
 274         }
 275
 276         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 277                 gsub("\/tarball\/.*", "/downloads", url)
 278                 d("github tarball url, mungled url to: " url)
 279         }
 280
 281         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 282                 gsub("\/archive\/.*", "/tags", url)
 283                 d("github archive url, mungled url to: " url)
 284         }
 285
 286         # https://bitbucket.org/logilab/pylint/get/tip.tar.bz2 -> https://bitbucket.org/logilab/pylint/downloads
 287         if (url ~/^(http|https):\/\/bitbucket.org\/.*\/get\/.*/) {
 288                 gsub("\/get\/.*", "/downloads", url)
 289                 d("github bitbucket url, mungled url to: " url)
 290         }
 291
 292         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 293                 gsub("\/snapshot\/.*", "/", url)
 294                 d("cgit snapshot tarball url, mungled url to: " url)
 295         }
 296
 297         if (url ~/^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 298                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 299                 d("aquamaniac.de tarball url, mungled url to: " url)
 300         }
 301
 302         if (url ~/^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 303                 url = "http://www.process-one.net/en/ejabberd/archive/"
 304                 d("ejabberd tarball url, mungled url to: " url)
 305         }
 306
 307         if (url ~/^(http|https):\/\/llvm.org\/releases\//) {
 308                 url = "http://llvm.org/releases/download.html"
 309                 d("llvm tarball url, mungled url to: " url)
 310         }
 311
 312         if (url ~/^(http|https):\/\/download\.owncloud\.org\/community\//) {
 313                 url = "http://owncloud.org/changelog/"
 314                 d("owncloud tarball url, mungled url to: " url)
 315         }
 316
 317         if (url ~/^(http|https):\/\/hackage\.haskell\.org\/packages\/archive\//) {
 318                 gsub("\/packages\/archive","/package",url)
 319                 d("hackage haskell tarball url, mungled url to: " url)
 320         }
 321
 322         d("Retrieving: " url)
 323         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 324         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 325         d("Execute: " cmd)
 326         errno = system(cmd)
 327         d("Execute done")
 328
 329         if (errno != 0) {
 330                 d("Reading failure response...")
 331                 wholeerr = ""
 332                 while (getline oneline < tmpfileerr)
 333                         wholeerr = (wholeerr " " oneline)
 334                 d("Error Response: " wholeerr)
 335
 336                 system("rm -f " tmpfile)
 337                 system("rm -f " tmpfileerr)
 338                 retval = ("WGET ERROR: " errno ": " wholeerr)
 339                 return retval
 340         }
 341         system("rm -f " tmpfileerr)
 342
 343         urldir = url;
 344         sub(/[^\/]+$/, "", urldir)
 345
 346 if (USE_PERL) {
 347         cmd = extract_links_cmd(tmpfile)
 348         while (cmd | getline) {
 349                 tag = $1
 350                 link = substr($0, length(tag) + 2)
 351
 352                 if (tag == "iframe") {
 353                         d("Frame: " link)
 354                         if (url !~ /\//) {
 355                                 link = (urldir link)
 356                                 d("Frame->: " link)
 357                         }
 358
 359                         if (link_seen(link)) {
 360                                 continue
 361                         }
 362                         retval = (retval " " get_links(link))
 363                 }
 364
 365                 if (link_seen(link)) {
 366                         continue
 367                 }
 368
 369                 retval = (retval " " link)
 370                 d("href(): " link)
 371         }
 372         close(cmd)
 373         system("rm -f " tmpfile)
 374
 375         d("Returning: [" retval "]")
 376         return retval
 377 }
 378
 379         wholeodp = ""
 380         d("Reading success response...")
 381         while (getline oneline < tmpfile) {
 382                 wholeodp = (wholeodp " " oneline)
 383 #               d("Response: " wholeodp)
 384         }
 385         d("Reponse read done...")
 386         system("rm -f " tmpfile)
 387
 388         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 389                 d("Processing links...")
 390                 odp = substr(wholeodp,RSTART,RLENGTH);
 391                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 392
 393                 lowerodp = tolower(odp);
 394                 if (lowerodp ~ /<frame[ \t]/) {
 395                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 396                         match(odp, /src="[^"]+"/)
 397                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 398                         d("Frame: " newurl)
 399                         if (newurl !~ /\//) {
 400                                 newurl=(urldir newurl)
 401                                 d("Frame->: " newurl)
 402                         }
 403
 404                         if (link_seen(newurl)) {
 405                                 newurl = ""
 406                                 continue
 407                         }
 408
 409                         retval = (retval " " get_links(newurl))
 410                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 411                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 412                         match(odp,/href="[^"]*"/)
 413                         link=substr(odp,RSTART,RLENGTH)
 414                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 415                         link=substr(link,7,length(link)-7)
 416                         link=postfix_link(url, link)
 417
 418                         if (link_seen(link)) {
 419                                 link=""
 420                                 continue
 421                         }
 422
 423                         # link ends with at least 2 digit version
 424                         mlink = ""
 425                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 426                                 mlink = get_links(link)
 427
 428                         retval = (retval " " link " " mlink)
 429                         d("href(\"\"): " link)
 430                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 431                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 432                         match(odp,/href='[^']*'/)
 433                         link=substr(odp,RSTART,RLENGTH)
 434                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 435                         link=substr(link,7,length(link)-7)
 436                         link=postfix_link(url, link)
 437
 438                         if (link_seen(link)) {
 439                                 link=""
 440                                 continue
 441                         }
 442
 443                         retval = (retval " " link)
 444                         d("href(''): " link)
 445                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 446                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 447                         match(odp,/href=[^ \t>]*/)
 448                         link=substr(odp,RSTART,RLENGTH)
 449                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 450                         link=substr(link,6,length(link)-5)
 451
 452                         if (link_seen(link)) {
 453                                 link=""
 454                                 continue
 455                         }
 456
 457                         retval = (retval " " link)
 458                         d("href(): " link)
 459                 } else {
 460                         # <a ...> but not href - skip
 461                         d("skipping <a > without href: " odp)
 462                 }
 463         }
 464
 465         d("Returning: [" retval "]")
 466         return retval
 467 }
 468
 469 function subst_defines(var,defs) {
 470 # substitute all possible RPM macros
 471         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 472                 oldvar=var
 473                 for (j in defs) {
 474                         gsub("%{" j "}", defs[j], var)
 475                         gsub("%" j , defs[j], var)
 476                 }
 477                 if (var==oldvar) {
 478                         if (DEBUG) {
 479                                 for (i in defs) {
 480                                         d(i " == " defs[i])
 481                                 }
 482                         }
 483                         return var
 484                 }
 485         }
 486         return var
 487 }
 488
 489 function find_mirror(url) {
 490
 491         while (succ = (getline line < "mirrors")) {
 492             if (succ==-1) { return url }
 493                 nf=split(line,fields,"|")
 494                 if (nf>1){
 495                         origin=fields[1]
 496                         mirror=fields[2]
 497                         mname=fields[3]
 498                         prefix=substr(url,1,length(origin))
 499                         if (prefix==origin){
 500                                 d("Mirror found at " mname)
 501                                 close("mirrors")
 502                                 return mirror substr(url,length(origin)+1)
 503                         }
 504                 }
 505         }
 506
 507         return url
 508 }
 509
 510 # fetches file list, and compares version numbers
 511 function process_source(number, lurl, name, version) {
 512         d("Processing " lurl)
 513
 514         if (index(lurl, version) == 0) {
 515                 d("There is no version number ["version"] in ["lurl"]")
 516                 return 0
 517         }
 518
 519         sub("://",":",lurl)
 520         sub("/",":/",lurl)
 521         gsub("[^/]*$",":&",lurl)
 522         split(lurl,url,":")
 523         acc=url[1]
 524         host=url[2]
 525         dir=url[3]
 526         filename=url[4]
 527
 528         if (index(dir,version)) {
 529                 # directory name as version maching mode:
 530                 # if /something/version/name-version.tarball then check
 531                 # in /something/ looking for newer directory
 532                 dir=substr(dir,1,index(dir,version)-1)
 533                 sub("[^/]*$","",dir)
 534                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 535         }
 536
 537         d("Will check a directory: " dir)
 538         d("and a file: " filename)
 539
 540         filenameexp=filename
 541         gsub("[+]","\\+",filenameexp)
 542         sub(version,"[A-Za-z0-9.]+",filenameexp)
 543         gsub("[.]","\\.",filenameexp)
 544         sub("\.(bz|bz2|gz|lzma|xz|zip)$",".(bz|bz2|gz|lzma|xz|zip)",filenameexp)
 545         d("Expression: " filenameexp)
 546         match(filename,version)
 547         prever=substr(filename,1,RSTART-1)
 548         postver=substr(filename,RSTART+RLENGTH)
 549         d("Before number: " prever)
 550         d("and after: " postver)
 551         newurl=find_mirror(acc "://" host dir)
 552         #print acc "://" host dir
 553         #newurl=url[1]"://"url[2]url[3]url[4]
 554         #newurl=acc "://" host dir filename
 555         d("Looking at " newurl)
 556
 557         references=0
 558         finished=0
 559         oldversion=version
 560         odp = get_links(newurl, filename)
 561         if( odp ~ "ERROR: ") {
 562                 print name "(" number ") " odp
 563         } else {
 564                 d("WebPage downloaded")
 565                 c=split(odp,linki)
 566                 for (nr=1; nr<=c; nr++) {
 567                         addr=linki[nr]
 568
 569                         d("Found link: " addr)
 570
 571                         # github has very different tarball links that clash with this safe check
 572                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 573                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 574                                         continue
 575                                 }
 576                         }
 577
 578                         if (addr ~ filenameexp) {
 579                                 match(addr,filenameexp)
 580                                 newfilename=substr(addr,RSTART,RLENGTH)
 581                                 d("Hypothetical new: " newfilename)
 582                                 newfilename=fixedsub(prever,"",newfilename)
 583                                 newfilename=fixedsub(postver,"",newfilename)
 584                                 d("Version: " newfilename)
 585                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 586                                 # strip ending (happens when in directiory name as version matching mode)
 587                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 588                                 if (NUMERIC) {
 589                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 590                                                 d("Yes, there is new one")
 591                                                 version=newfilename
 592                                                 finished=1
 593                                         }
 594                                 } else if ( compare_ver(version, newfilename)==1 ) {
 595                                         d("Yes, there is new one")
 596                                         version=newfilename
 597                                         finished=1
 598                                 }
 599                         }
 600                 }
 601                 if (finished == 0)
 602                         print name "(" number ") seems ok: " oldversion
 603                 else
 604                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 605         }
 606 }
 607
 608 function rss_upgrade(name, ver, url, regex, cmd) {
 609         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 610         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 611
 612         d("rss_upgrade_cmd: " cmd)
 613         cmd | getline ver
 614         close(cmd)
 615
 616         return ver
 617 }
 618
 619 # check for ZF upgrade from rss
 620 function zf_upgrade(name, ver) {
 621         return rss_upgrade(name, ver, \
 622                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 623                 "Zend Framework ([^\\s]+) Released" \
 624         );
 625 }
 626
 627 function hudson_upgrade(name, ver) {
 628         return rss_upgrade(name, ver, \
 629                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 630                 "Hudson ([0-9.]+) released" \
 631         );
 632 }
 633
 634 # upgrade check for pear package using PEAR CLI
 635 function pear_upgrade(name, ver,    cmd) {
 636         sub(/^php-pear-/, "", name);
 637
 638         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 639         d("PEAR: " cmd)
 640         cmd | getline ver
 641         close(cmd)
 642
 643         return ver
 644 }
 645
 646 function vim_upgrade(name, ver,     cmd) {
 647         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 648         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 649         d("VIM: " cmd)
 650         cmd | getline ver
 651         close(cmd)
 652         return ver
 653 }
 654
 655 function nodejs_upgrade(name, ver,   cmd) {
 656         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 657         if (DEFS["pkg"]) {
 658                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 659         } else {
 660                 cmd = "npm info " name " dist-tags.latest"
 661         }
 662         cmd | getline ver
 663         close(cmd)
 664
 665         return ver
 666 }
 667
 668 function rubygem_upgrade(name, ver,   cmd, pkg) {
 669         if (DEFS["gem_name"]) {
 670                 pkg = DEFS["gem_name"];
 671
 672         } else if (DEFS["gemname"]) {
 673                 pkg = DEFS["gemname"];
 674
 675         } else if (DEFS["pkgname"]) {
 676                 pkg = DEFS["pkgname"];
 677
 678         } else {
 679                 pkg = name;
 680                 gsub(/^ruby-/, "", pkg);
 681         }
 682
 683         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); print v}'"
 684         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 685         cmd | getline ver
 686
 687         close(cmd)
 688
 689         return ver
 690 }
 691
 692 function chrome_upgrade(name, ver,   cmd, sourceurl) {
 693         sourceurl = "http://dl.google.com/linux/chrome/rpm/stable/x86_64/repodata/primary.xml.gz"
 694         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>google-chrome-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 695         d("CHROME " cmd);
 696         cmd | getline ver
 697         close(cmd)
 698
 699         return ver
 700 }
 701
 702 function process_data(name, ver, rel, src,   nver) {
 703         if (name ~ /^php-pear-/) {
 704                 nver = pear_upgrade(name, ver);
 705         } else if (name == "ZendFramework") {
 706                 nver = zf_upgrade(name, ver);
 707         } else if (name == "hudson") {
 708                 nver = hudson_upgrade(name, ver);
 709         } else if (name == "vim") {
 710                 nver = vim_upgrade(name, ver);
 711         } else if (name == "google-chrome") {
 712                 nver = chrome_upgrade(name, ver);
 713         } else if (name ~ "^nodejs-") {
 714                 nver = nodejs_upgrade(name, ver);
 715         } else if (name ~ "^ruby-") {
 716                 nver = rubygem_upgrade(name, ver);
 717         }
 718
 719         if (nver) {
 720                 if (compare_ver(ver, nver)) {
 721                         print name " [OLD] " ver " [NEW] " nver
 722                 } else {
 723                         print name " seems ok: " ver
 724                 }
 725                 return;
 726         }
 727
 728         if (name == "xulrunner") {
 729                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 730                 d("package xulrunner, change version to firefox ["ver"]")
 731         }
 732
 733 # this function checks if substitutions were valid, and if true:
 734 # processes each URL and tries to get current file list
 735         for (i in src) {
 736                 if (src[i] ~ /%{nil}/) {
 737                         gsub(/\%\{nil\}/, "", src[i])
 738                 }
 739                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 740                         d("Source: " src[i])
 741                         process_source(i, src[i], name, ver)
 742                 } else {
 743                         print FNAME ":" i ": impossible substitution: " src[i]
 744                 }
 745         }
 746 }
 747
 748 BEGIN {
 749         # if you want to use DEBUG, run script with "-v DEBUG=1"
 750         # or uncomment the line below
 751         # DEBUG = 1
 752
 753         errno=system("wget --help > /dev/null 2>&1")
 754         if (errno && errno != 3) {
 755                 print "No wget installed!"
 756                 exit 1
 757         }
 758         if (ARGC>=3 && ARGV[2]=="-n") {
 759                 NUMERIC=1
 760                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 761                 ARGC=ARGC-1
 762         }
 763 }
 764
 765 FNR==1 {
 766         if ( ARGIND != 1 ) {
 767                 # clean frameseen for each ARG
 768                 for (i in frameseen) {
 769                         delete frameseen[i]
 770                 }
 771                 frameseen[0] = 1
 772
 773                 process_data(NAME,VER,REL,SRC)
 774                 NAME="" ; VER="" ; REL=""
 775                 for (i in DEFS) delete DEFS[i]
 776                 for (i in SRC) delete SRC[i]
 777         }
 778         FNAME=FILENAME
 779         DEFS["_alt_kernel"]=""
 780         DEFS["20"]="\\ "
 781         DEFS["nil"]=""
 782 }
 783
 784 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 785 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 786 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 787 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 788 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 789 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 790
 791 END {
 792         process_data(NAME,VER,REL,SRC)
 793 }