pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|dl)\.(sf|sourceforge)\.net\//) {
 236                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 237                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 238
 239                 gsub("/.*", "", url)
 240                 url = "http://sourceforge.net/projects/" url "/files/"
 241                 d("sf url, mungled url to: " url)
 242         }
 243
 244         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 245                 gsub("^http://", "", url)
 246                 gsub("\..*", "", url)
 247                 url = "http://code.google.com/p/" url "/downloads/list"
 248                 d("googlecode url, mungled url to: " url)
 249         }
 250
 251         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 252                 gsub("-.*", "", filename)
 253                 url = "http://pecl.php.net/package/" filename
 254                 d("pecl.php.net url, mungled url to: " url)
 255         }
 256
 257         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 258                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 259                  d("mysql 5.1 url, mungled url to: " url)
 260         }
 261
 262         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 263                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 264                 gsub("\/.*/", "", url)
 265                 url = "https://code.launchpad.net/" url "/+download"
 266                 d("main launchpad url, mungled url to: " url)
 267         }
 268
 269         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 270                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 271                 gsub("\/.*/", "", url)
 272                 url = "https://edge.launchpad.net/" url "/+download"
 273                 d("edge launchpad url, mungled url to: " url)
 274         }
 275
 276         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 277                 gsub("\/tarball\/.*", "/downloads", url)
 278                 d("github tarball url, mungled url to: " url)
 279         }
 280
 281         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 282                 gsub("\/archive\/.*", "/tags", url)
 283                 d("github archive url, mungled url to: " url)
 284         }
 285
 286         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 287                 gsub("\/snapshot\/.*", "/", url)
 288                 d("cgit snapshot tarball url, mungled url to: " url)
 289         }
 290
 291         if (url ~/^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 292                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 293                 d("aquamaniac.de tarball url, mungled url to: " url)
 294         }
 295
 296         if (url ~/^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 297                 url = "http://www.process-one.net/en/ejabberd/archive/"
 298                 d("ejabberd tarball url, mungled url to: " url)
 299         }
 300
 301         d("Retrieving: " url)
 302         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 303         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 304         d("Execute: " cmd)
 305         errno = system(cmd)
 306         d("Execute done")
 307
 308         if (errno != 0) {
 309                 d("Reading failure response...")
 310                 wholeerr = ""
 311                 while (getline oneline < tmpfileerr)
 312                         wholeerr = (wholeerr " " oneline)
 313                 d("Error Response: " wholeerr)
 314
 315                 system("rm -f " tmpfile)
 316                 system("rm -f " tmpfileerr)
 317                 retval = ("WGET ERROR: " errno ": " wholeerr)
 318                 return retval
 319         }
 320         system("rm -f " tmpfileerr)
 321
 322         urldir = url;
 323         sub(/[^\/]+$/, "", urldir)
 324
 325 if (USE_PERL) {
 326         cmd = extract_links_cmd(tmpfile)
 327         while (cmd | getline) {
 328                 tag = $1
 329                 link = substr($0, length(tag) + 2)
 330
 331                 if (tag == "iframe") {
 332                         d("Frame: " link)
 333                         if (url !~ /\//) {
 334                                 link = (urldir link)
 335                                 d("Frame->: " link)
 336                         }
 337
 338                         if (link_seen(link)) {
 339                                 continue
 340                         }
 341                         retval = (retval " " get_links(link))
 342                 }
 343
 344                 if (link_seen(link)) {
 345                         continue
 346                 }
 347
 348                 retval = (retval " " link)
 349                 d("href(): " link)
 350         }
 351         close(cmd)
 352         system("rm -f " tmpfile)
 353
 354         d("Returning: [" retval "]")
 355         return retval
 356 }
 357
 358         wholeodp = ""
 359         d("Reading success response...")
 360         while (getline oneline < tmpfile) {
 361                 wholeodp = (wholeodp " " oneline)
 362 #               d("Response: " wholeodp)
 363         }
 364         d("Reponse read done...")
 365         system("rm -f " tmpfile)
 366
 367         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 368                 d("Processing links...")
 369                 odp = substr(wholeodp,RSTART,RLENGTH);
 370                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 371
 372                 lowerodp = tolower(odp);
 373                 if (lowerodp ~ /<frame[ \t]/) {
 374                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 375                         match(odp, /src="[^"]+"/)
 376                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 377                         d("Frame: " newurl)
 378                         if (newurl !~ /\//) {
 379                                 newurl=(urldir newurl)
 380                                 d("Frame->: " newurl)
 381                         }
 382
 383                         if (link_seen(newurl)) {
 384                                 newurl = ""
 385                                 continue
 386                         }
 387
 388                         retval = (retval " " get_links(newurl))
 389                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 390                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 391                         match(odp,/href="[^"]*"/)
 392                         link=substr(odp,RSTART,RLENGTH)
 393                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 394                         link=substr(link,7,length(link)-7)
 395                         link=postfix_link(url, link)
 396
 397                         if (link_seen(link)) {
 398                                 link=""
 399                                 continue
 400                         }
 401
 402                         # link ends with at least 2 digit version
 403                         mlink = ""
 404                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 405                                 mlink = get_links(link)
 406
 407                         retval = (retval " " link " " mlink)
 408                         d("href(\"\"): " link)
 409                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 410                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 411                         match(odp,/href='[^']*'/)
 412                         link=substr(odp,RSTART,RLENGTH)
 413                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 414                         link=substr(link,7,length(link)-7)
 415                         link=postfix_link(url, link)
 416
 417                         if (link_seen(link)) {
 418                                 link=""
 419                                 continue
 420                         }
 421
 422                         retval = (retval " " link)
 423                         d("href(''): " link)
 424                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 425                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 426                         match(odp,/href=[^ \t>]*/)
 427                         link=substr(odp,RSTART,RLENGTH)
 428                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 429                         link=substr(link,6,length(link)-5)
 430
 431                         if (link_seen(link)) {
 432                                 link=""
 433                                 continue
 434                         }
 435
 436                         retval = (retval " " link)
 437                         d("href(): " link)
 438                 } else {
 439                         # <a ...> but not href - skip
 440                         d("skipping <a > without href: " odp)
 441                 }
 442         }
 443
 444         d("Returning: [" retval "]")
 445         return retval
 446 }
 447
 448 function subst_defines(var,defs) {
 449 # substitute all possible RPM macros
 450         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 451                 oldvar=var
 452                 for (j in defs) {
 453                         gsub("%{" j "}", defs[j], var)
 454                         gsub("%" j , defs[j], var)
 455                 }
 456                 if (var==oldvar) {
 457                         if (DEBUG) {
 458                                 for (i in defs) {
 459                                         d(i " == " defs[i])
 460                                 }
 461                         }
 462                         return var
 463                 }
 464         }
 465         return var
 466 }
 467
 468 function find_mirror(url) {
 469
 470         while (succ = (getline line < "mirrors")) {
 471             if (succ==-1) { return url }
 472                 nf=split(line,fields,"|")
 473                 if (nf>1){
 474                         origin=fields[1]
 475                         mirror=fields[2]
 476                         mname=fields[3]
 477                         prefix=substr(url,1,length(origin))
 478                         if (prefix==origin){
 479                                 d("Mirror found at " mname)
 480                                 close("mirrors")
 481                                 return mirror substr(url,length(origin)+1)
 482                         }
 483                 }
 484         }
 485
 486         return url
 487 }
 488
 489 # fetches file list, and compares version numbers
 490 function process_source(number, lurl, name, version) {
 491         d("Processing " lurl)
 492
 493         if (index(lurl, version) == 0) {
 494                 d("There is no version number ["version"] in ["lurl"]")
 495                 return 0
 496         }
 497
 498         sub("://",":",lurl)
 499         sub("/",":/",lurl)
 500         gsub("[^/]*$",":&",lurl)
 501         split(lurl,url,":")
 502         acc=url[1]
 503         host=url[2]
 504         dir=url[3]
 505         filename=url[4]
 506
 507         if (index(dir,version)) {
 508                 # directory name as version maching mode:
 509                 # if /something/version/name-version.tarball then check
 510                 # in /something/ looking for newer directory
 511                 dir=substr(dir,1,index(dir,version)-1)
 512                 sub("[^/]*$","",dir)
 513                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 514         }
 515
 516         d("Will check a directory: " dir)
 517         d("and a file: " filename)
 518
 519         filenameexp=filename
 520         gsub("[+]","\\+",filenameexp)
 521         sub(version,"[A-Za-z0-9.]+",filenameexp)
 522         gsub("[.]","\\.",filenameexp)
 523         d("Expression: " filenameexp)
 524         match(filename,version)
 525         prever=substr(filename,1,RSTART-1)
 526         postver=substr(filename,RSTART+RLENGTH)
 527         d("Before number: " prever)
 528         d("and after: " postver)
 529         newurl=find_mirror(acc "://" host dir)
 530         #print acc "://" host dir
 531         #newurl=url[1]"://"url[2]url[3]url[4]
 532         #newurl=acc "://" host dir filename
 533         d("Looking at " newurl)
 534
 535         references=0
 536         finished=0
 537         oldversion=version
 538         odp = get_links(newurl, filename)
 539         if( odp ~ "ERROR: ") {
 540                 print name "(" number ") " odp
 541         } else {
 542                 d("WebPage downloaded")
 543                 c=split(odp,linki)
 544                 for (nr=1; nr<=c; nr++) {
 545                         addr=linki[nr]
 546
 547                         d("Found link: " addr)
 548
 549                         # github has very different tarball links that clash with this safe check
 550                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 551                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 552                                         continue
 553                                 }
 554                         }
 555
 556                         if (addr ~ filenameexp) {
 557                                 match(addr,filenameexp)
 558                                 newfilename=substr(addr,RSTART,RLENGTH)
 559                                 d("Hypothetical new: " newfilename)
 560                                 newfilename=fixedsub(prever,"",newfilename)
 561                                 newfilename=fixedsub(postver,"",newfilename)
 562                                 d("Version: " newfilename)
 563                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 564                                 # strip ending (happens when in directiory name as version matching mode)
 565                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 566                                 if (NUMERIC) {
 567                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 568                                                 d("Yes, there is new one")
 569                                                 version=newfilename
 570                                                 finished=1
 571                                         }
 572                                 } else if ( compare_ver(version, newfilename)==1 ) {
 573                                         d("Yes, there is new one")
 574                                         version=newfilename
 575                                         finished=1
 576                                 }
 577                         }
 578                 }
 579                 if (finished == 0)
 580                         print name "(" number ") seems ok: " oldversion
 581                 else
 582                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 583         }
 584 }
 585
 586 function rss_upgrade(name, ver, url, regex, cmd) {
 587         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 588         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 589
 590         d("rss_upgrade_cmd: " cmd)
 591         cmd | getline ver
 592         close(cmd)
 593
 594         return ver
 595 }
 596
 597 # check for ZF upgrade from rss
 598 function zf_upgrade(name, ver) {
 599         return rss_upgrade(name, ver, \
 600                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 601                 "Zend Framework ([^\\s]+) Released" \
 602         );
 603 }
 604
 605 function hudson_upgrade(name, ver) {
 606         return rss_upgrade(name, ver, \
 607                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 608                 "Hudson ([0-9.]+) released" \
 609         );
 610 }
 611
 612 # upgrade check for pear package using PEAR CLI
 613 function pear_upgrade(name, ver,    cmd) {
 614         sub(/^php-pear-/, "", name);
 615
 616         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 617         d("PEAR: " cmd)
 618         cmd | getline ver
 619         close(cmd)
 620
 621         return ver
 622 }
 623
 624 function vim_upgrade(name, ver,     cmd) {
 625         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 626         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 627         d("VIM: " cmd)
 628         cmd | getline ver
 629         close(cmd)
 630         return ver
 631 }
 632
 633 function nodejs_upgrade(name, ver,   cmd) {
 634         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 635         if (DEFS["pkg"]) {
 636                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 637         } else {
 638                 cmd = "npm info " name " dist-tags.latest"
 639         }
 640         cmd | getline ver
 641         close(cmd)
 642
 643         return ver
 644 }
 645
 646 function rubygem_upgrade(name, ver,   cmd, pkg) {
 647         if (DEFS["gem_name"]) {
 648                 pkg = DEFS["gem_name"];
 649
 650         } else if (DEFS["gemname"]) {
 651                 pkg = DEFS["gemname"];
 652
 653         } else if (DEFS["pkgname"]) {
 654                 pkg = DEFS["pkgname"];
 655
 656         } else {
 657                 pkg = name;
 658                 gsub(/^ruby-/, "", pkg);
 659         }
 660
 661         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); print v}'"
 662         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 663         cmd | getline ver
 664
 665         close(cmd)
 666
 667         return ver
 668 }
 669
 670 function chrome_upgrade(name, ver,   cmd, sourceurl) {
 671         sourceurl = "http://dl.google.com/linux/chrome/rpm/stable/x86_64/repodata/primary.xml.gz"
 672         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>google-chrome-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 673         d("CHROME " cmd);
 674         cmd | getline ver
 675         close(cmd)
 676
 677         return ver
 678 }
 679
 680 function process_data(name, ver, rel, src,   nver) {
 681         if (name ~ /^php-pear-/) {
 682                 nver = pear_upgrade(name, ver);
 683         } else if (name == "ZendFramework") {
 684                 nver = zf_upgrade(name, ver);
 685         } else if (name == "hudson") {
 686                 nver = hudson_upgrade(name, ver);
 687         } else if (name == "vim") {
 688                 nver = vim_upgrade(name, ver);
 689         } else if (name == "google-chrome") {
 690                 nver = chrome_upgrade(name, ver);
 691         } else if (name ~ "^nodejs-") {
 692                 nver = nodejs_upgrade(name, ver);
 693         } else if (name ~ "^ruby-") {
 694                 nver = rubygem_upgrade(name, ver);
 695         }
 696
 697         if (nver) {
 698                 if (compare_ver(ver, nver)) {
 699                         print name " [OLD] " ver " [NEW] " nver
 700                 } else {
 701                         print name " seems ok: " ver
 702                 }
 703                 return;
 704         }
 705
 706         if (name == "xulrunner") {
 707                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 708                 d("package xulrunner, change version to firefox ["ver"]")
 709         }
 710
 711 # this function checks if substitutions were valid, and if true:
 712 # processes each URL and tries to get current file list
 713         for (i in src) {
 714                 if (src[i] ~ /%{nil}/) {
 715                         gsub(/\%\{nil\}/, "", src[i])
 716                 }
 717                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 718                         d("Source: " src[i])
 719                         process_source(i, src[i], name, ver)
 720                 } else {
 721                         print FNAME ":" i ": impossible substitution: " src[i]
 722                 }
 723         }
 724 }
 725
 726 BEGIN {
 727         # if you want to use DEBUG, run script with "-v DEBUG=1"
 728         # or uncomment the line below
 729         # DEBUG = 1
 730
 731         errno=system("wget --help > /dev/null 2>&1")
 732         if (errno && errno != 3) {
 733                 print "No wget installed!"
 734                 exit 1
 735         }
 736         if (ARGC>=3 && ARGV[2]=="-n") {
 737                 NUMERIC=1
 738                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 739                 ARGC=ARGC-1
 740         }
 741 }
 742
 743 FNR==1 {
 744         if ( ARGIND != 1 ) {
 745                 # clean frameseen for each ARG
 746                 for (i in frameseen) {
 747                         delete frameseen[i]
 748                 }
 749                 frameseen[0] = 1
 750
 751                 process_data(NAME,VER,REL,SRC)
 752                 NAME="" ; VER="" ; REL=""
 753                 for (i in DEFS) delete DEFS[i]
 754                 for (i in SRC) delete SRC[i]
 755         }
 756         FNAME=FILENAME
 757         DEFS["_alt_kernel"]=""
 758         DEFS["20"]="\\ "
 759         DEFS["nil"]=""
 760 }
 761
 762 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 763 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 764 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 765 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 766 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 767 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 768
 769 END {
 770         process_data(NAME,VER,REL,SRC)
 771 }