pldnotify.awk

   1 #!/usr/bin/gawk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2010 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17 # - support debian/watch http://wiki.debian.org/debian/watch/
  18
  19
  20 function d(s) {
  21         if (!DEBUG) {
  22                 return
  23         }
  24
  25         print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  26 #       print s >> "/dev/stderr"
  27 }
  28
  29 function fixedsub(s1,s2,t,      ind) {
  30 # substitutes fixed strings (not regexps)
  31         if (ind = index(t,s1)) {
  32                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  33         }
  34         return t
  35 }
  36
  37 function ispre(s) {
  38         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  39                 d("pre-version")
  40                 return 1
  41         } else {
  42                 return 0
  43         }
  44 }
  45
  46 function compare_ver(v1,v2) {
  47 # compares version numbers
  48         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  49                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  50         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  51                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  52         sub("^0*","",v1)
  53         sub("^0*","",v2)
  54         gsub("\.0*",".",v1)
  55         gsub("\.0*",".",v2)
  56         d("v1 == " v1)
  57         d("v2 == " v2)
  58         count=split(v1,v1a,"\.")
  59         count2=split(v2,v2a,"\.")
  60
  61         if (count<count2) mincount=count
  62         else mincount=count2
  63
  64         for (i=1; i<=mincount; i++) {
  65                 if (v1a[i]=="") v1a[i]=0
  66                 if (v2a[i]=="") v2a[i]=0
  67                 d("i == " i)
  68                 d("v1[i] == " v1a[i])
  69                 d("v2[i] == " v2a[i])
  70                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  71                         if (length(v2a[i])>length(v1a[i]))
  72                                 return 1
  73                         else if (v2a[i]>v1a[i])
  74                                 return 1
  75                         else if (length(v1a[i])>length(v2a[i]))
  76                                 return 0
  77                         else if (v1a[i]>v2a[i])
  78                                 return 0
  79                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  80                         if (v2a[i]>v1a[i])
  81                                 return 1
  82                         else if (v1a[i]>v2a[i])
  83                                 return 0
  84                 } else if (ispre(v1a[i]) == 1)
  85                         return 1
  86                 else
  87                         return 0
  88         }
  89         if ((count2==mincount)&&(count!=count2)) {
  90                 for (i=count2+1; i<=count; i++)
  91                         if (ispre(v1a[i]) == 1)
  92                                 return 1
  93                 return 0
  94         } else if (count!=count2) {
  95                 for (i=count+1; i<=count2; i++)
  96                         if (ispre(v2a[i]) == 1)
  97                                 return 0
  98                 return 1
  99         }
 100         return 0
 101 }
 102
 103 function compare_ver_dec(v1,v2) {
 104 # compares version numbers as decimal floats
 105         while (match(v1,/[0-9][a-zA-Z]/))
 106                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 107         while (match(v2,/[0-9][a-zA-Z]/))
 108                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 109         sub("^0*","",v1)
 110         sub("^0*","",v2)
 111         d("v1 == " v1)
 112         d("v2 == " v2)
 113         count=split(v1,v1a,"\.")
 114         count2=split(v2,v2a,"\.")
 115
 116         if (count<count2) mincount=count
 117         else mincount=count2
 118
 119         for (i=1; i<=mincount; i++) {
 120                 if (v1a[i]=="") v1a[i]=0
 121                 if (v2a[i]=="") v2a[i]=0
 122                 d("i == " i)
 123                 d("v1[i] == " v1a[i])
 124                 d("v2[i] == " v2a[i])
 125                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 126                         if (i==2) {
 127                                 if (0+("." v2a[i])>0+("." v1a[i]))
 128                                         return 1
 129                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 130                                         return 0
 131                         } else {
 132                                 if (length(v2a[i])>length(v1a[i]))
 133                                         return 1
 134                                 else if (v2a[i]>v1a[i])
 135                                         return 1
 136                                 else if (length(v1a[i])>length(v2a[i]))
 137                                         return 0
 138                                 else if (v1a[i]>v2a[i])
 139                                         return 0
 140                         }
 141                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 142                         if (v2a[i]>v1a[i])
 143                                 return 1
 144                         else if (v1a[i]>v2a[i])
 145                                 return 0
 146                 } else if (ispre(v1a[i]) == 1)
 147                         return 1
 148                 else
 149                         return 0
 150         }
 151         if ((count2==mincount)&&(count!=count2)) {
 152                 for (i=count2+1; i<=count; i++)
 153                         if (ispre(v1a[i]) == 1)
 154                                 return 1
 155                 return 0
 156         } else if (count!=count2) {
 157                 for (i=count+1; i<=count2; i++)
 158                         if (ispre(v2a[i]) == 1)
 159                                 return 0
 160                 return 1
 161         }
 162         return 0
 163 }
 164
 165 function link_seen(link) {
 166         for (seenlink in frameseen) {
 167                 if (seenlink == link) {
 168                         d("Link: [" link "] seen already, skipping...")
 169                         return 1
 170                 }
 171         }
 172         frameseen[link]=1
 173         return 0
 174 }
 175
 176 function mktemp(   _cmd, _tmpfile) {
 177         _cmd = "mktemp /tmp/XXXXXX"
 178         _cmd | getline _tmpfile
 179         close(_cmd)
 180         return _tmpfile
 181 }
 182
 183 # fix link to artificial one that will be recognized rest of this script
 184 function postfix_link(url, link,   oldlink) {
 185         oldlink = link
 186         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 187                 gsub(".*\/tarball\/", "", link)
 188                 link = link ".tar.gz"
 189         }
 190         if (oldlink != link) {
 191                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 192         }
 193         return link
 194 }
 195
 196 # get all <A HREF=..> tags from specified URL
 197 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 198
 199         wholeerr=""
 200
 201         tmpfile = mktemp()
 202         tmpfileerr = mktemp()
 203
 204         if (url ~ /^http:\/\/(download|downloads|dl)\.(sf|sourceforge)\.net\//) {
 205                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 206                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 207                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 208                 gsub("^http://downloads\.(sf|sourceforge)\.net/project/", "", url)
 209
 210                 gsub("/.*", "", url)
 211                 url = "http://sourceforge.net/projects/" url "/files/"
 212                 d("sf url, mungled url to: " url)
 213         }
 214
 215         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 216                 gsub("^http://", "", url)
 217                 gsub("\..*", "", url)
 218                 url = "http://code.google.com/p/" url "/downloads/list"
 219                 d("googlecode url, mungled url to: " url)
 220         }
 221
 222         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 223                 gsub("-.*", "", filename)
 224                 url = "http://pecl.php.net/package/" filename
 225                 d("pecl.php.net url, mungled url to: " url)
 226         }
 227
 228         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 229                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 230                  d("mysql 5.1 url, mungled url to: " url)
 231         }
 232
 233         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 234                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 235                 gsub("\/.*/", "", url)
 236                 url = "https://code.launchpad.net/" url "/+download"
 237                 d("main launchpad url, mungled url to: " url)
 238         }
 239
 240         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 241                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 242                 gsub("\/.*/", "", url)
 243                 url = "https://edge.launchpad.net/" url "/+download"
 244                 d("edge launchpad url, mungled url to: " url)
 245         }
 246
 247         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 248                 gsub("\/tarball\/.*", "/downloads", url)
 249                 d("github tarball url, mungled url to: " url)
 250         }
 251
 252         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 253                 gsub("\/snapshot\/.*", "/", url)
 254                 d("cgit snapshot tarball url, mungled url to: " url)
 255         }
 256
 257         d("Retrieving: " url)
 258         cmd = "wget --user-agent \"Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6\" -nv -O - \"" url "\" -t 2 -T 45 --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 259         d("Execute: " cmd)
 260         errno = system(cmd)
 261         d("Execute done")
 262
 263         if (errno != 0) {
 264                 d("Reading failure response...")
 265                 wholeerr = ""
 266                 while (getline oneline < tmpfileerr)
 267                         wholeerr = (wholeerr " " oneline)
 268                 d("Error Response: " wholeerr)
 269
 270                 system("rm -f " tmpfile)
 271                 system("rm -f " tmpfileerr)
 272                 retval = ("WGET ERROR: " errno ": " wholeerr)
 273                 return retval
 274         }
 275
 276         wholeodp = ""
 277         d("Reading success response...")
 278         while (getline oneline < tmpfile) {
 279                 wholeodp = (wholeodp " " oneline)
 280 #               d("Response: " wholeodp)
 281         }
 282         d("Reponse read done...")
 283
 284         system("rm -f " tmpfile)
 285         system("rm -f " tmpfileerr)
 286
 287         urldir = url;
 288         sub(/[^\/]+$/, "", urldir)
 289
 290         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 291                 d("Processing links...")
 292                 odp = substr(wholeodp,RSTART,RLENGTH);
 293                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 294
 295                 lowerodp = tolower(odp);
 296                 if (lowerodp ~ /<frame[ \t]/) {
 297                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 298                         match(odp, /src="[^"]+"/)
 299                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 300                         d("Frame: " newurl)
 301                         if (newurl !~ /\//) {
 302                                 newurl=(urldir newurl)
 303                                 d("Frame->: " newurl)
 304                         }
 305
 306                         if (link_seen(newurl)) {
 307                                 newurl = ""
 308                                 continue
 309                         }
 310
 311                         retval = (retval " " get_links(newurl))
 312                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 313                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 314                         match(odp,/href="[^"]*"/)
 315                         link=substr(odp,RSTART,RLENGTH)
 316                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 317                         link=substr(link,7,length(link)-7)
 318                         link=postfix_link(url, link)
 319
 320                         if (link_seen(link)) {
 321                                 link=""
 322                                 continue
 323                         }
 324
 325                         retval = (retval " " link)
 326                         d("href(\"\"): " link)
 327                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 328                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 329                         match(odp,/href='[^']*'/)
 330                         link=substr(odp,RSTART,RLENGTH)
 331                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 332                         link=substr(link,7,length(link)-7)
 333                         link=postfix_link(url, link)
 334
 335                         if (link_seen(link)) {
 336                                 link=""
 337                                 continue
 338                         }
 339
 340                         retval = (retval " " link)
 341                         d("href(''): " link)
 342                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 343                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 344                         match(odp,/href=[^ \t>]*/)
 345                         link=substr(odp,RSTART,RLENGTH)
 346                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 347                         link=substr(link,6,length(link)-5)
 348
 349                         if (link_seen(link)) {
 350                                 link=""
 351                                 continue
 352                         }
 353
 354                         retval = (retval " " link)
 355                         d("href(): " link)
 356                 } else {
 357                         # <a ...> but not href - skip
 358                         d("skipping <a > without href: " odp)
 359                 }
 360         }
 361
 362         d("Returning: " retval)
 363         return retval
 364 }
 365
 366 function subst_defines(var,defs) {
 367 # substitute all possible RPM macros
 368         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 369                 oldvar=var
 370                 for (j in defs) {
 371                         gsub("%{" j "}", defs[j], var)
 372                         gsub("%" j , defs[j], var)
 373                 }
 374                 if (var==oldvar) {
 375                         if (DEBUG) {
 376                                 for (i in defs) {
 377                                         d(i " == " defs[i])
 378                                 }
 379                         }
 380                         return var
 381                 }
 382         }
 383         return var
 384 }
 385
 386 function find_mirror(url) {
 387
 388         while (succ = (getline line < "mirrors")) {
 389             if (succ==-1) { return url }
 390                 nf=split(line,fields,"|")
 391                 if (nf>1){
 392                         origin=fields[1]
 393                         mirror=fields[2]
 394                         mname=fields[3]
 395                         prefix=substr(url,1,length(origin))
 396                         if (prefix==origin){
 397                                 d("Mirror fount at " mname)
 398                                 close("mirrors")
 399                                 return mirror substr(url,length(origin)+1)
 400                         }
 401                 }
 402         }
 403
 404         return url
 405 }
 406
 407 function process_source(number,lurl,name,version) {
 408 # fetches file list, and compares version numbers
 409         d("Processing " lurl)
 410
 411         if ( index(lurl,version)==0 ) {
 412                 d("There is no version number.")
 413                 return 0
 414         }
 415
 416         sub("://",":",lurl)
 417         sub("/",":/",lurl)
 418         gsub("[^/]*$",":&",lurl)
 419         split(lurl,url,":")
 420         acc=url[1]
 421         host=url[2]
 422         dir=url[3]
 423         filename=url[4]
 424
 425         if (index(dir,version)) {
 426                 # directory name as version maching mode:
 427                 # if /something/version/name-version.tarball then check
 428                 # in /something/ looking for newer directory
 429                 dir=substr(dir,1,index(dir,version)-1)
 430                 sub("[^/]*$","",dir)
 431                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 432         }
 433
 434         d("Will check a directory: " dir)
 435         d("and a file: " filename)
 436
 437         filenameexp=filename
 438         gsub("[+]","\\+",filenameexp)
 439         sub(version,"[A-Za-z0-9.]+",filenameexp)
 440         gsub("[.]","\\.",filenameexp)
 441         d("Expression: " filenameexp)
 442         match(filename,version)
 443         prever=substr(filename,1,RSTART-1)
 444         postver=substr(filename,RSTART+RLENGTH)
 445         d("Before number: " prever)
 446         d("and after: " postver)
 447         newurl=find_mirror(acc "://" host dir)
 448         #print acc "://" host dir
 449         #newurl=url[1]"://"url[2]url[3]url[4]
 450         #newurl=acc "://" host dir filename
 451         d("Looking at " newurl)
 452
 453         references=0
 454         finished=0
 455         oldversion=version
 456         odp = get_links(newurl, filename)
 457         if( odp ~ "ERROR: ") {
 458                 print name "(" number ") " odp
 459         } else {
 460                 d("WebPage downloaded")
 461                 c=split(odp,linki)
 462                 for (nr=1; nr<=c; nr++) {
 463                         addr=linki[nr]
 464
 465                         d("Found link: " addr)
 466
 467                         # github has very different tarball links that clash with this safe check
 468                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 469                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 470                                         continue
 471                                 }
 472                         }
 473
 474                         if (addr ~ filenameexp) {
 475                                 match(addr,filenameexp)
 476                                 newfilename=substr(addr,RSTART,RLENGTH)
 477                                 d("Hypothetical new: " newfilename)
 478                                 newfilename=fixedsub(prever,"",newfilename)
 479                                 newfilename=fixedsub(postver,"",newfilename)
 480                                 d("Version: " newfilename)
 481                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 482                                 # strip ending (happens when in directiory name as version matching mode)
 483                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 484                                 if (NUMERIC) {
 485                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 486                                                 d("Yes, there is new one")
 487                                                 version=newfilename
 488                                                 finished=1
 489                                         }
 490                                 } else if ( compare_ver(version, newfilename)==1 ) {
 491                                         d("Yes, there is new one")
 492                                         version=newfilename
 493                                         finished=1
 494                                 }
 495                         }
 496                 }
 497                 if (finished==0)
 498                         print name "(" number ") seems ok: " oldversion
 499                 else
 500                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 501         }
 502 }
 503
 504 function rss_upgrade(name, ver, url, regex, cmd, nver) {
 505         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 506         cmd = "wget -q -O - " url " | sed -nre '" regex "' | head -n1"
 507
 508         d("rss_upgrade_cmd: " cmd)
 509         cmd | getline nver
 510         close(cmd)
 511
 512         if (compare_ver(ver, nver)) {
 513                 print name " [OLD] " ver " [NEW] " nver
 514         } else {
 515                 print name " seems ok: " ver
 516         }
 517 }
 518
 519 # check for ZF upgrade from rss
 520 function zf_upgrade(name, ver) {
 521         rss_upgrade(name, ver, \
 522                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 523                 "Zend Framework ([^\\s]+) Released" \
 524         );
 525 }
 526
 527 function hudson_upgrade(name, ver) {
 528         rss_upgrade(name, ver, \
 529                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 530                 "Hudson ([0-9.]+) released" \
 531         );
 532 }
 533
 534 # upgrade check for pear package using PEAR CLI
 535 function pear_upgrade(name, ver,    pname, pearcmd, nver) {
 536         pname = name;
 537         sub(/^php-pear-/, "", pname);
 538
 539         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 540         d("pearcmd: " pearcmd)
 541         pearcmd | getline nver
 542         close(pearcmd)
 543
 544         if (compare_ver(ver, nver)) {
 545                 print name " [OLD] " ver " [NEW] " nver
 546         } else {
 547                 print name " seems ok: " ver
 548         }
 549
 550         return
 551 }
 552
 553 function vim_upgrade(name, ver,     mver, nver, vimcmd) {
 554         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 555         mver = substr(ver, 0, 4)
 556         vimcmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/"mver"/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 557         d("vimcmd: " vimcmd)
 558         vimcmd | getline nver
 559         close(vimcmd)
 560
 561         if (compare_ver(ver, nver)) {
 562                 print name " [OLD] " ver " [NEW] " nver
 563         } else {
 564                 print name " seems ok: " ver
 565         }
 566 }
 567
 568 function process_data(name,ver,rel,src) {
 569         if (name ~ /^php-pear-/) {
 570                 return pear_upgrade(name, ver);
 571         }
 572         if (name == "ZendFramework") {
 573                 return zf_upgrade(name, ver);
 574         }
 575         if (name == "hudson") {
 576                 return hudson_upgrade(name, ver);
 577         }
 578         if (name == "vim") {
 579                 return vim_upgrade(name, ver);
 580         }
 581
 582 # this function checks if substitutions were valid, and if true:
 583 # processes each URL and tries to get current file list
 584         for (i in src) {
 585                 if ( src[i] ~ /%{nil}/ ) {
 586                         gsub(/\%\{nil\}/, "", src[i])
 587                 }
 588                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 589                         d("Source: " src[i])
 590                         process_source(i,src[i],name,ver)
 591                 } else {
 592                         print FNAME ":" i ": impossible substitution: " src[i]
 593                 }
 594         }
 595 }
 596
 597 BEGIN {
 598         # if U want to use DEBUG, run script with "-v DEBUG=1"
 599         # or uncomment the line below
 600         # DEBUG = 1
 601
 602         errno=system("wget --help > /dev/null 2>&1")
 603         if (errno) {
 604                 print "No wget installed!"
 605                 exit 1
 606         }
 607         if (ARGC>=3 && ARGV[2]=="-n") {
 608                 NUMERIC=1
 609                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 610                 ARGC=ARGC-1
 611         }
 612 }
 613
 614 FNR==1 {
 615         if ( ARGIND != 1 ) {
 616                 # clean frameseen for each ARG
 617                 for (i in frameseen) {
 618                         delete frameseen[i]
 619                 }
 620                 frameseen[0] = 1
 621
 622                 process_data(NAME,VER,REL,SRC)
 623                 NAME="" ; VER="" ; REL=""
 624                 for (i in DEFS) delete DEFS[i]
 625                 for (i in SRC) delete SRC[i]
 626         }
 627         FNAME=FILENAME
 628         DEFS["_alt_kernel"]=""
 629         DEFS["20"]="\\ "
 630 }
 631
 632 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 633 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 634 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 635 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 636 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 637 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 638
 639 END {
 640         process_data(NAME,VER,REL,SRC)
 641 }