pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|dl)\.(sf|sourceforge)\.net\//) {
 236                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 237                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 238
 239                 gsub("/.*", "", url)
 240                 url = "http://sourceforge.net/projects/" url "/files/"
 241                 d("sf url, mungled url to: " url)
 242         }
 243
 244         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 245                 gsub("^http://", "", url)
 246                 gsub("\..*", "", url)
 247                 url = "http://code.google.com/p/" url "/downloads/list"
 248                 d("googlecode url, mungled url to: " url)
 249         }
 250
 251         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 252                 gsub("-.*", "", filename)
 253                 url = "http://pecl.php.net/package/" filename
 254                 d("pecl.php.net url, mungled url to: " url)
 255         }
 256
 257         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 258                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 259                  d("mysql 5.1 url, mungled url to: " url)
 260         }
 261
 262         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 263                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 264                 gsub("\/.*/", "", url)
 265                 url = "https://code.launchpad.net/" url "/+download"
 266                 d("main launchpad url, mungled url to: " url)
 267         }
 268
 269         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 270                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 271                 gsub("\/.*/", "", url)
 272                 url = "https://edge.launchpad.net/" url "/+download"
 273                 d("edge launchpad url, mungled url to: " url)
 274         }
 275
 276         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 277                 gsub("\/tarball\/.*", "/downloads", url)
 278                 d("github tarball url, mungled url to: " url)
 279         }
 280
 281         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 282                 gsub("\/archive\/.*", "/tags", url)
 283                 d("github archive url, mungled url to: " url)
 284         }
 285
 286         # https://bitbucket.org/logilab/pylint/get/tip.tar.bz2 -> https://bitbucket.org/logilab/pylint/downloads
 287         if (url ~/^(http|https):\/\/bitbucket.org\/.*\/get\/.*/) {
 288                 gsub("\/get\/.*", "/downloads", url)
 289                 d("github bitbucket url, mungled url to: " url)
 290         }
 291
 292         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 293                 gsub("\/snapshot\/.*", "/", url)
 294                 d("cgit snapshot tarball url, mungled url to: " url)
 295         }
 296
 297         if (url ~/^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 298                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 299                 d("aquamaniac.de tarball url, mungled url to: " url)
 300         }
 301
 302         if (url ~/^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 303                 url = "http://www.process-one.net/en/ejabberd/archive/"
 304                 d("ejabberd tarball url, mungled url to: " url)
 305         }
 306
 307         d("Retrieving: " url)
 308         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 309         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 310         d("Execute: " cmd)
 311         errno = system(cmd)
 312         d("Execute done")
 313
 314         if (errno != 0) {
 315                 d("Reading failure response...")
 316                 wholeerr = ""
 317                 while (getline oneline < tmpfileerr)
 318                         wholeerr = (wholeerr " " oneline)
 319                 d("Error Response: " wholeerr)
 320
 321                 system("rm -f " tmpfile)
 322                 system("rm -f " tmpfileerr)
 323                 retval = ("WGET ERROR: " errno ": " wholeerr)
 324                 return retval
 325         }
 326         system("rm -f " tmpfileerr)
 327
 328         urldir = url;
 329         sub(/[^\/]+$/, "", urldir)
 330
 331 if (USE_PERL) {
 332         cmd = extract_links_cmd(tmpfile)
 333         while (cmd | getline) {
 334                 tag = $1
 335                 link = substr($0, length(tag) + 2)
 336
 337                 if (tag == "iframe") {
 338                         d("Frame: " link)
 339                         if (url !~ /\//) {
 340                                 link = (urldir link)
 341                                 d("Frame->: " link)
 342                         }
 343
 344                         if (link_seen(link)) {
 345                                 continue
 346                         }
 347                         retval = (retval " " get_links(link))
 348                 }
 349
 350                 if (link_seen(link)) {
 351                         continue
 352                 }
 353
 354                 retval = (retval " " link)
 355                 d("href(): " link)
 356         }
 357         close(cmd)
 358         system("rm -f " tmpfile)
 359
 360         d("Returning: [" retval "]")
 361         return retval
 362 }
 363
 364         wholeodp = ""
 365         d("Reading success response...")
 366         while (getline oneline < tmpfile) {
 367                 wholeodp = (wholeodp " " oneline)
 368 #               d("Response: " wholeodp)
 369         }
 370         d("Reponse read done...")
 371         system("rm -f " tmpfile)
 372
 373         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 374                 d("Processing links...")
 375                 odp = substr(wholeodp,RSTART,RLENGTH);
 376                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 377
 378                 lowerodp = tolower(odp);
 379                 if (lowerodp ~ /<frame[ \t]/) {
 380                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 381                         match(odp, /src="[^"]+"/)
 382                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 383                         d("Frame: " newurl)
 384                         if (newurl !~ /\//) {
 385                                 newurl=(urldir newurl)
 386                                 d("Frame->: " newurl)
 387                         }
 388
 389                         if (link_seen(newurl)) {
 390                                 newurl = ""
 391                                 continue
 392                         }
 393
 394                         retval = (retval " " get_links(newurl))
 395                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 396                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 397                         match(odp,/href="[^"]*"/)
 398                         link=substr(odp,RSTART,RLENGTH)
 399                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 400                         link=substr(link,7,length(link)-7)
 401                         link=postfix_link(url, link)
 402
 403                         if (link_seen(link)) {
 404                                 link=""
 405                                 continue
 406                         }
 407
 408                         # link ends with at least 2 digit version
 409                         mlink = ""
 410                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 411                                 mlink = get_links(link)
 412
 413                         retval = (retval " " link " " mlink)
 414                         d("href(\"\"): " link)
 415                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 416                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 417                         match(odp,/href='[^']*'/)
 418                         link=substr(odp,RSTART,RLENGTH)
 419                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 420                         link=substr(link,7,length(link)-7)
 421                         link=postfix_link(url, link)
 422
 423                         if (link_seen(link)) {
 424                                 link=""
 425                                 continue
 426                         }
 427
 428                         retval = (retval " " link)
 429                         d("href(''): " link)
 430                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 431                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 432                         match(odp,/href=[^ \t>]*/)
 433                         link=substr(odp,RSTART,RLENGTH)
 434                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 435                         link=substr(link,6,length(link)-5)
 436
 437                         if (link_seen(link)) {
 438                                 link=""
 439                                 continue
 440                         }
 441
 442                         retval = (retval " " link)
 443                         d("href(): " link)
 444                 } else {
 445                         # <a ...> but not href - skip
 446                         d("skipping <a > without href: " odp)
 447                 }
 448         }
 449
 450         d("Returning: [" retval "]")
 451         return retval
 452 }
 453
 454 function subst_defines(var,defs) {
 455 # substitute all possible RPM macros
 456         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 457                 oldvar=var
 458                 for (j in defs) {
 459                         gsub("%{" j "}", defs[j], var)
 460                         gsub("%" j , defs[j], var)
 461                 }
 462                 if (var==oldvar) {
 463                         if (DEBUG) {
 464                                 for (i in defs) {
 465                                         d(i " == " defs[i])
 466                                 }
 467                         }
 468                         return var
 469                 }
 470         }
 471         return var
 472 }
 473
 474 function find_mirror(url) {
 475
 476         while (succ = (getline line < "mirrors")) {
 477             if (succ==-1) { return url }
 478                 nf=split(line,fields,"|")
 479                 if (nf>1){
 480                         origin=fields[1]
 481                         mirror=fields[2]
 482                         mname=fields[3]
 483                         prefix=substr(url,1,length(origin))
 484                         if (prefix==origin){
 485                                 d("Mirror found at " mname)
 486                                 close("mirrors")
 487                                 return mirror substr(url,length(origin)+1)
 488                         }
 489                 }
 490         }
 491
 492         return url
 493 }
 494
 495 # fetches file list, and compares version numbers
 496 function process_source(number, lurl, name, version) {
 497         d("Processing " lurl)
 498
 499         if (index(lurl, version) == 0) {
 500                 d("There is no version number ["version"] in ["lurl"]")
 501                 return 0
 502         }
 503
 504         sub("://",":",lurl)
 505         sub("/",":/",lurl)
 506         gsub("[^/]*$",":&",lurl)
 507         split(lurl,url,":")
 508         acc=url[1]
 509         host=url[2]
 510         dir=url[3]
 511         filename=url[4]
 512
 513         if (index(dir,version)) {
 514                 # directory name as version maching mode:
 515                 # if /something/version/name-version.tarball then check
 516                 # in /something/ looking for newer directory
 517                 dir=substr(dir,1,index(dir,version)-1)
 518                 sub("[^/]*$","",dir)
 519                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 520         }
 521
 522         d("Will check a directory: " dir)
 523         d("and a file: " filename)
 524
 525         filenameexp=filename
 526         gsub("[+]","\\+",filenameexp)
 527         sub(version,"[A-Za-z0-9.]+",filenameexp)
 528         gsub("[.]","\\.",filenameexp)
 529         d("Expression: " filenameexp)
 530         match(filename,version)
 531         prever=substr(filename,1,RSTART-1)
 532         postver=substr(filename,RSTART+RLENGTH)
 533         d("Before number: " prever)
 534         d("and after: " postver)
 535         newurl=find_mirror(acc "://" host dir)
 536         #print acc "://" host dir
 537         #newurl=url[1]"://"url[2]url[3]url[4]
 538         #newurl=acc "://" host dir filename
 539         d("Looking at " newurl)
 540
 541         references=0
 542         finished=0
 543         oldversion=version
 544         odp = get_links(newurl, filename)
 545         if( odp ~ "ERROR: ") {
 546                 print name "(" number ") " odp
 547         } else {
 548                 d("WebPage downloaded")
 549                 c=split(odp,linki)
 550                 for (nr=1; nr<=c; nr++) {
 551                         addr=linki[nr]
 552
 553                         d("Found link: " addr)
 554
 555                         # github has very different tarball links that clash with this safe check
 556                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 557                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 558                                         continue
 559                                 }
 560                         }
 561
 562                         if (addr ~ filenameexp) {
 563                                 match(addr,filenameexp)
 564                                 newfilename=substr(addr,RSTART,RLENGTH)
 565                                 d("Hypothetical new: " newfilename)
 566                                 newfilename=fixedsub(prever,"",newfilename)
 567                                 newfilename=fixedsub(postver,"",newfilename)
 568                                 d("Version: " newfilename)
 569                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 570                                 # strip ending (happens when in directiory name as version matching mode)
 571                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 572                                 if (NUMERIC) {
 573                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 574                                                 d("Yes, there is new one")
 575                                                 version=newfilename
 576                                                 finished=1
 577                                         }
 578                                 } else if ( compare_ver(version, newfilename)==1 ) {
 579                                         d("Yes, there is new one")
 580                                         version=newfilename
 581                                         finished=1
 582                                 }
 583                         }
 584                 }
 585                 if (finished == 0)
 586                         print name "(" number ") seems ok: " oldversion
 587                 else
 588                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 589         }
 590 }
 591
 592 function rss_upgrade(name, ver, url, regex, cmd) {
 593         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 594         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 595
 596         d("rss_upgrade_cmd: " cmd)
 597         cmd | getline ver
 598         close(cmd)
 599
 600         return ver
 601 }
 602
 603 # check for ZF upgrade from rss
 604 function zf_upgrade(name, ver) {
 605         return rss_upgrade(name, ver, \
 606                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 607                 "Zend Framework ([^\\s]+) Released" \
 608         );
 609 }
 610
 611 function hudson_upgrade(name, ver) {
 612         return rss_upgrade(name, ver, \
 613                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 614                 "Hudson ([0-9.]+) released" \
 615         );
 616 }
 617
 618 # upgrade check for pear package using PEAR CLI
 619 function pear_upgrade(name, ver,    cmd) {
 620         sub(/^php-pear-/, "", name);
 621
 622         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 623         d("PEAR: " cmd)
 624         cmd | getline ver
 625         close(cmd)
 626
 627         return ver
 628 }
 629
 630 function vim_upgrade(name, ver,     cmd) {
 631         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 632         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 633         d("VIM: " cmd)
 634         cmd | getline ver
 635         close(cmd)
 636         return ver
 637 }
 638
 639 function nodejs_upgrade(name, ver,   cmd) {
 640         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 641         if (DEFS["pkg"]) {
 642                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 643         } else {
 644                 cmd = "npm info " name " dist-tags.latest"
 645         }
 646         cmd | getline ver
 647         close(cmd)
 648
 649         return ver
 650 }
 651
 652 function rubygem_upgrade(name, ver,   cmd, pkg) {
 653         if (DEFS["gem_name"]) {
 654                 pkg = DEFS["gem_name"];
 655
 656         } else if (DEFS["gemname"]) {
 657                 pkg = DEFS["gemname"];
 658
 659         } else if (DEFS["pkgname"]) {
 660                 pkg = DEFS["pkgname"];
 661
 662         } else {
 663                 pkg = name;
 664                 gsub(/^ruby-/, "", pkg);
 665         }
 666
 667         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); print v}'"
 668         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 669         cmd | getline ver
 670
 671         close(cmd)
 672
 673         return ver
 674 }
 675
 676 function chrome_upgrade(name, ver,   cmd, sourceurl) {
 677         sourceurl = "http://dl.google.com/linux/chrome/rpm/stable/x86_64/repodata/primary.xml.gz"
 678         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>google-chrome-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 679         d("CHROME " cmd);
 680         cmd | getline ver
 681         close(cmd)
 682
 683         return ver
 684 }
 685
 686 function process_data(name, ver, rel, src,   nver) {
 687         if (name ~ /^php-pear-/) {
 688                 nver = pear_upgrade(name, ver);
 689         } else if (name == "ZendFramework") {
 690                 nver = zf_upgrade(name, ver);
 691         } else if (name == "hudson") {
 692                 nver = hudson_upgrade(name, ver);
 693         } else if (name == "vim") {
 694                 nver = vim_upgrade(name, ver);
 695         } else if (name == "google-chrome") {
 696                 nver = chrome_upgrade(name, ver);
 697         } else if (name ~ "^nodejs-") {
 698                 nver = nodejs_upgrade(name, ver);
 699         } else if (name ~ "^ruby-") {
 700                 nver = rubygem_upgrade(name, ver);
 701         }
 702
 703         if (nver) {
 704                 if (compare_ver(ver, nver)) {
 705                         print name " [OLD] " ver " [NEW] " nver
 706                 } else {
 707                         print name " seems ok: " ver
 708                 }
 709                 return;
 710         }
 711
 712         if (name == "xulrunner") {
 713                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 714                 d("package xulrunner, change version to firefox ["ver"]")
 715         }
 716
 717 # this function checks if substitutions were valid, and if true:
 718 # processes each URL and tries to get current file list
 719         for (i in src) {
 720                 if (src[i] ~ /%{nil}/) {
 721                         gsub(/\%\{nil\}/, "", src[i])
 722                 }
 723                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 724                         d("Source: " src[i])
 725                         process_source(i, src[i], name, ver)
 726                 } else {
 727                         print FNAME ":" i ": impossible substitution: " src[i]
 728                 }
 729         }
 730 }
 731
 732 BEGIN {
 733         # if you want to use DEBUG, run script with "-v DEBUG=1"
 734         # or uncomment the line below
 735         # DEBUG = 1
 736
 737         errno=system("wget --help > /dev/null 2>&1")
 738         if (errno && errno != 3) {
 739                 print "No wget installed!"
 740                 exit 1
 741         }
 742         if (ARGC>=3 && ARGV[2]=="-n") {
 743                 NUMERIC=1
 744                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 745                 ARGC=ARGC-1
 746         }
 747 }
 748
 749 FNR==1 {
 750         if ( ARGIND != 1 ) {
 751                 # clean frameseen for each ARG
 752                 for (i in frameseen) {
 753                         delete frameseen[i]
 754                 }
 755                 frameseen[0] = 1
 756
 757                 process_data(NAME,VER,REL,SRC)
 758                 NAME="" ; VER="" ; REL=""
 759                 for (i in DEFS) delete DEFS[i]
 760                 for (i in SRC) delete SRC[i]
 761         }
 762         FNAME=FILENAME
 763         DEFS["_alt_kernel"]=""
 764         DEFS["20"]="\\ "
 765         DEFS["nil"]=""
 766 }
 767
 768 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 769 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 770 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 771 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 772 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 773 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 774
 775 END {
 776         process_data(NAME,VER,REL,SRC)
 777 }