pldnotify.awk

   1 #!/usr/bin/gawk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2010 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17 # - support debian/watch http://wiki.debian.org/debian/watch/
  18
  19
  20 function d(s) {
  21         if (!DEBUG) {
  22                 return
  23         }
  24
  25         print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  26 #       print s >> "/dev/stderr"
  27 }
  28
  29 function fixedsub(s1,s2,t,      ind) {
  30 # substitutes fixed strings (not regexps)
  31         if (ind = index(t,s1)) {
  32                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  33         }
  34         return t
  35 }
  36
  37 function ispre(s) {
  38         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  39                 d("pre-version")
  40                 return 1
  41         } else {
  42                 return 0
  43         }
  44 }
  45
  46 function compare_ver(v1,v2) {
  47 # compares version numbers
  48         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  49                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  50         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  51                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  52         sub("^0*","",v1)
  53         sub("^0*","",v2)
  54         gsub("\.0*",".",v1)
  55         gsub("\.0*",".",v2)
  56         d("v1 == " v1)
  57         d("v2 == " v2)
  58         count=split(v1,v1a,"\.")
  59         count2=split(v2,v2a,"\.")
  60
  61         if (count<count2) mincount=count
  62         else mincount=count2
  63
  64         for (i=1; i<=mincount; i++) {
  65                 if (v1a[i]=="") v1a[i]=0
  66                 if (v2a[i]=="") v2a[i]=0
  67                 d("i == " i)
  68                 d("v1[i] == " v1a[i])
  69                 d("v2[i] == " v2a[i])
  70                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  71                         if (length(v2a[i])>length(v1a[i]))
  72                                 return 1
  73                         else if (v2a[i]>v1a[i])
  74                                 return 1
  75                         else if (length(v1a[i])>length(v2a[i]))
  76                                 return 0
  77                         else if (v1a[i]>v2a[i])
  78                                 return 0
  79                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  80                         if (v2a[i]>v1a[i])
  81                                 return 1
  82                         else if (v1a[i]>v2a[i])
  83                                 return 0
  84                 } else if (ispre(v1a[i]) == 1)
  85                         return 1
  86                 else
  87                         return 0
  88         }
  89         if ((count2==mincount)&&(count!=count2)) {
  90                 for (i=count2+1; i<=count; i++)
  91                         if (ispre(v1a[i]) == 1)
  92                                 return 1
  93                 return 0
  94         } else if (count!=count2) {
  95                 for (i=count+1; i<=count2; i++)
  96                         if (ispre(v2a[i]) == 1)
  97                                 return 0
  98                 return 1
  99         }
 100         return 0
 101 }
 102
 103 function compare_ver_dec(v1,v2) {
 104 # compares version numbers as decimal floats
 105         while (match(v1,/[0-9][a-zA-Z]/))
 106                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 107         while (match(v2,/[0-9][a-zA-Z]/))
 108                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 109         sub("^0*","",v1)
 110         sub("^0*","",v2)
 111         d("v1 == " v1)
 112         d("v2 == " v2)
 113         count=split(v1,v1a,"\.")
 114         count2=split(v2,v2a,"\.")
 115
 116         if (count<count2) mincount=count
 117         else mincount=count2
 118
 119         for (i=1; i<=mincount; i++) {
 120                 if (v1a[i]=="") v1a[i]=0
 121                 if (v2a[i]=="") v2a[i]=0
 122                 d("i == " i)
 123                 d("v1[i] == " v1a[i])
 124                 d("v2[i] == " v2a[i])
 125                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 126                         if (i==2) {
 127                                 if (0+("." v2a[i])>0+("." v1a[i]))
 128                                         return 1
 129                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 130                                         return 0
 131                         } else {
 132                                 if (length(v2a[i])>length(v1a[i]))
 133                                         return 1
 134                                 else if (v2a[i]>v1a[i])
 135                                         return 1
 136                                 else if (length(v1a[i])>length(v2a[i]))
 137                                         return 0
 138                                 else if (v1a[i]>v2a[i])
 139                                         return 0
 140                         }
 141                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 142                         if (v2a[i]>v1a[i])
 143                                 return 1
 144                         else if (v1a[i]>v2a[i])
 145                                 return 0
 146                 } else if (ispre(v1a[i]) == 1)
 147                         return 1
 148                 else
 149                         return 0
 150         }
 151         if ((count2==mincount)&&(count!=count2)) {
 152                 for (i=count2+1; i<=count; i++)
 153                         if (ispre(v1a[i]) == 1)
 154                                 return 1
 155                 return 0
 156         } else if (count!=count2) {
 157                 for (i=count+1; i<=count2; i++)
 158                         if (ispre(v2a[i]) == 1)
 159                                 return 0
 160                 return 1
 161         }
 162         return 0
 163 }
 164
 165 function link_seen(link) {
 166         for (seenlink in frameseen) {
 167                 if (seenlink == link) {
 168                         d("Link: [" link "] seen already, skipping...")
 169                         return 1
 170                 }
 171         }
 172         frameseen[link]=1
 173         return 0
 174 }
 175
 176 function mktemp(   _cmd, _tmpfile) {
 177         _cmd = "mktemp /tmp/XXXXXX"
 178         _cmd | getline _tmpfile
 179         close(_cmd)
 180         return _tmpfile
 181 }
 182
 183 # fix link to artificial one that will be recognized rest of this script
 184 function postfix_link(url, link) {
 185         oldlink = link
 186         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 187                 gsub(".*\/tarball\/", "", link)
 188                 link = link ".tar.gz"
 189         }
 190         d("POST FIXING URL [ " oldlink " ] to [ " link " ]")
 191         return link
 192 }
 193
 194 # get all <A HREF=..> tags from specified URL
 195 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 196
 197         wholeerr=""
 198
 199         tmpfile = mktemp()
 200         tmpfileerr = mktemp()
 201
 202         if (url ~ /^http:\/\/(download|downloads|dl)\.(sf|sourceforge)\.net\//) {
 203                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 204                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 205                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 206                 gsub("^http://downloads\.(sf|sourceforge)\.net/project/", "", url)
 207
 208                 gsub("/.*", "", url)
 209                 url = "http://sourceforge.net/projects/" url "/files/"
 210                 d("sf url, mungled url to: " url)
 211         }
 212
 213         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 214                 gsub("^http://", "", url)
 215                 gsub("\..*", "", url)
 216                 url = "http://code.google.com/p/" url "/downloads/list"
 217                 d("googlecode url, mungled url to: " url)
 218         }
 219
 220         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 221                 gsub("-.*", "", filename)
 222                 url = "http://pecl.php.net/package/" filename
 223                 d("pecl.php.net url, mungled url to: " url)
 224         }
 225
 226         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 227                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 228                  d("mysql 5.1 url, mungled url to: " url)
 229         }
 230
 231         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 232                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 233                 gsub("\/.*/", "", url)
 234                 url = "https://code.launchpad.net/" url "/+download"
 235                 d("main launchpad url, mungled url to: " url)
 236         }
 237
 238         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 239                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 240                 gsub("\/.*/", "", url)
 241                 url = "https://edge.launchpad.net/" url "/+download"
 242                 d("edge launchpad url, mungled url to: " url)
 243         }
 244
 245         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 246                 gsub("\/tarball\/.*", "/downloads", url)
 247                 d("github tarball url, mungled url to: " url)
 248         }
 249
 250         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 251                 gsub("\/snapshot\/.*", "/", url)
 252                 d("cgit snapshot tarball url, mungled url to: " url)
 253         }
 254
 255         d("Retrieving: " url)
 256         cmd = "wget --user-agent \"Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6\" -nv -O - \"" url "\" -t 2 -T 45 --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 257         d("Execute: " cmd)
 258         errno = system(cmd)
 259         d("Execute done")
 260
 261         if (errno != 0) {
 262                 d("Reading failure response...")
 263                 wholeerr = ""
 264                 while (getline oneline < tmpfileerr)
 265                         wholeerr = (wholeerr " " oneline)
 266                 d("Error Response: " wholeerr)
 267
 268                 system("rm -f " tmpfile)
 269                 system("rm -f " tmpfileerr)
 270                 retval = ("WGET ERROR: " errno ": " wholeerr)
 271                 return retval
 272         }
 273
 274         wholeodp = ""
 275         d("Reading success response...")
 276         while (getline oneline < tmpfile) {
 277                 wholeodp = (wholeodp " " oneline)
 278 #               d("Response: " wholeodp)
 279         }
 280         d("Reponse read done...")
 281
 282         system("rm -f " tmpfile)
 283         system("rm -f " tmpfileerr)
 284
 285         urldir = url;
 286         sub(/[^\/]+$/, "", urldir)
 287
 288         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 289                 d("Processing links...")
 290                 odp = substr(wholeodp,RSTART,RLENGTH);
 291                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 292
 293                 lowerodp = tolower(odp);
 294                 if (lowerodp ~ /<frame[ \t]/) {
 295                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 296                         match(odp, /src="[^"]+"/)
 297                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 298                         d("Frame: " newurl)
 299                         if (newurl !~ /\//) {
 300                                 newurl=(urldir newurl)
 301                                 d("Frame->: " newurl)
 302                         }
 303
 304                         if (link_seen(newurl)) {
 305                                 newurl = ""
 306                                 continue
 307                         }
 308
 309                         retval = (retval " " get_links(newurl))
 310                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 311                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 312                         match(odp,/href="[^"]*"/)
 313                         link=substr(odp,RSTART,RLENGTH)
 314                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 315                         link=substr(link,7,length(link)-7)
 316                         link=postfix_link(url, link)
 317
 318                         if (link_seen(link)) {
 319                                 link=""
 320                                 continue
 321                         }
 322
 323                         retval = (retval " " link)
 324                         d("href(\"\"): " link)
 325                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 326                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 327                         match(odp,/href='[^']*'/)
 328                         link=substr(odp,RSTART,RLENGTH)
 329                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 330                         link=substr(link,7,length(link)-7)
 331                         link=postfix_link(url, link)
 332
 333                         if (link_seen(link)) {
 334                                 link=""
 335                                 continue
 336                         }
 337
 338                         retval = (retval " " link)
 339                         d("href(''): " link)
 340                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 341                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 342                         match(odp,/href=[^ \t>]*/)
 343                         link=substr(odp,RSTART,RLENGTH)
 344                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 345                         link=substr(link,6,length(link)-5)
 346
 347                         if (link_seen(link)) {
 348                                 link=""
 349                                 continue
 350                         }
 351
 352                         retval = (retval " " link)
 353                         d("href(): " link)
 354                 } else {
 355                         # <a ...> but not href - skip
 356                         d("skipping <a > without href: " odp)
 357                 }
 358         }
 359
 360         d("Returning: " retval)
 361         return retval
 362 }
 363
 364 function subst_defines(var,defs) {
 365 # substitute all possible RPM macros
 366         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 367                 oldvar=var
 368                 for (j in defs) {
 369                         gsub("%{" j "}", defs[j], var)
 370                         gsub("%" j , defs[j], var)
 371                 }
 372                 if (var==oldvar) {
 373                         if (DEBUG) {
 374                                 for (i in defs) {
 375                                         d(i " == " defs[i])
 376                                 }
 377                         }
 378                         return var
 379                 }
 380         }
 381         return var
 382 }
 383
 384 function find_mirror(url) {
 385
 386         while (succ = (getline line < "mirrors")) {
 387             if (succ==-1) { return url }
 388                 nf=split(line,fields,"|")
 389                 if (nf>1){
 390                         origin=fields[1]
 391                         mirror=fields[2]
 392                         mname=fields[3]
 393                         prefix=substr(url,1,length(origin))
 394                         if (prefix==origin){
 395                                 d("Mirror fount at " mname)
 396                                 close("mirrors")
 397                                 return mirror substr(url,length(origin)+1)
 398                         }
 399                 }
 400         }
 401
 402         return url
 403 }
 404
 405 function process_source(number,lurl,name,version) {
 406 # fetches file list, and compares version numbers
 407         d("Processing " lurl)
 408
 409         if ( index(lurl,version)==0 ) {
 410                 d("There is no version number.")
 411                 return 0
 412         }
 413
 414         sub("://",":",lurl)
 415         sub("/",":/",lurl)
 416         gsub("[^/]*$",":&",lurl)
 417         split(lurl,url,":")
 418         acc=url[1]
 419         host=url[2]
 420         dir=url[3]
 421         filename=url[4]
 422
 423         if (index(dir,version)) {
 424                 # directory name as version maching mode:
 425                 # if /something/version/name-version.tarball then check
 426                 # in /something/ looking for newer directory
 427                 dir=substr(dir,1,index(dir,version)-1)
 428                 sub("[^/]*$","",dir)
 429                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 430         }
 431
 432         d("Will check a directory: " dir)
 433         d("and a file: " filename)
 434
 435         filenameexp=filename
 436         gsub("[+]","\\+",filenameexp)
 437         sub(version,"[A-Za-z0-9.]+",filenameexp)
 438         gsub("[.]","\\.",filenameexp)
 439         d("Expression: " filenameexp)
 440         match(filename,version)
 441         prever=substr(filename,1,RSTART-1)
 442         postver=substr(filename,RSTART+RLENGTH)
 443         d("Before number: " prever)
 444         d("and after: " postver)
 445         newurl=find_mirror(acc "://" host dir)
 446         #print acc "://" host dir
 447         #newurl=url[1]"://"url[2]url[3]url[4]
 448         #newurl=acc "://" host dir filename
 449         d("Looking at " newurl)
 450
 451         references=0
 452         finished=0
 453         oldversion=version
 454         odp = get_links(newurl, filename)
 455         if( odp ~ "ERROR: ") {
 456                 print name "(" number ") " odp
 457         } else {
 458                 d("WebPage downloaded")
 459                 c=split(odp,linki)
 460                 for (nr=1; nr<=c; nr++) {
 461                         addr=linki[nr]
 462
 463                         d("Found link: " addr)
 464
 465                         # github has very different tarball links that clash with this safe check
 466                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 467                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 468                                         continue
 469                                 }
 470                         }
 471
 472                         if (addr ~ filenameexp) {
 473                                 match(addr,filenameexp)
 474                                 newfilename=substr(addr,RSTART,RLENGTH)
 475                                 d("Hypothetical new: " newfilename)
 476                                 newfilename=fixedsub(prever,"",newfilename)
 477                                 newfilename=fixedsub(postver,"",newfilename)
 478                                 d("Version: " newfilename)
 479                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 480                                 # strip ending (happens when in directiory name as version matching mode)
 481                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 482                                 if (NUMERIC) {
 483                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 484                                                 d("Yes, there is new one")
 485                                                 version=newfilename
 486                                                 finished=1
 487                                         }
 488                                 } else if ( compare_ver(version, newfilename)==1 ) {
 489                                         d("Yes, there is new one")
 490                                         version=newfilename
 491                                         finished=1
 492                                 }
 493                         }
 494                 }
 495                 if (finished==0)
 496                         print name "(" number ") seems ok: " oldversion
 497                 else
 498                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 499         }
 500 }
 501
 502 function rss_upgrade(name, ver, url, regex, cmd, nver) {
 503         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 504         cmd = "wget -q -O - " url " | sed -nre '" regex "' | head -n1"
 505
 506         d("rss_upgrade_cmd: " cmd)
 507         cmd | getline nver
 508         close(cmd)
 509
 510         if (compare_ver(ver, nver)) {
 511                 print name " [OLD] " ver " [NEW] " nver
 512         } else {
 513                 print name " seems ok: " ver
 514         }
 515 }
 516
 517 # check for ZF upgrade from rss
 518 function zf_upgrade(name, ver) {
 519         rss_upgrade(name, ver, \
 520                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 521                 "Zend Framework ([^\\s]+) Released" \
 522         );
 523 }
 524
 525 function hudson_upgrade(name, ver) {
 526         rss_upgrade(name, ver, \
 527                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 528                 "Hudson ([0-9.]+) released" \
 529         );
 530 }
 531
 532 # upgrade check for pear package using PEAR CLI
 533 function pear_upgrade(name, ver,    pname, pearcmd, nver) {
 534         pname = name;
 535         sub(/^php-pear-/, "", pname);
 536
 537         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 538         d("pearcmd: " pearcmd)
 539         pearcmd | getline nver
 540         close(pearcmd)
 541
 542         if (compare_ver(ver, nver)) {
 543                 print name " [OLD] " ver " [NEW] " nver
 544         } else {
 545                 print name " seems ok: " ver
 546         }
 547
 548         return
 549 }
 550
 551 function vim_upgrade(name, ver,     mver, nver, vimcmd) {
 552         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 553         mver = substr(ver, 0, 4)
 554         vimcmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/"mver"/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 555         d("vimcmd: " vimcmd)
 556         vimcmd | getline nver
 557         close(vimcmd)
 558
 559         if (compare_ver(ver, nver)) {
 560                 print name " [OLD] " ver " [NEW] " nver
 561         } else {
 562                 print name " seems ok: " ver
 563         }
 564 }
 565
 566 function process_data(name,ver,rel,src) {
 567         if (name ~ /^php-pear-/) {
 568                 return pear_upgrade(name, ver);
 569         }
 570         if (name == "ZendFramework") {
 571                 return zf_upgrade(name, ver);
 572         }
 573         if (name == "hudson") {
 574                 return hudson_upgrade(name, ver);
 575         }
 576         if (name == "vim") {
 577                 return vim_upgrade(name, ver);
 578         }
 579
 580 # this function checks if substitutions were valid, and if true:
 581 # processes each URL and tries to get current file list
 582         for (i in src) {
 583                 if ( src[i] ~ /%{nil}/ ) {
 584                         gsub(/\%\{nil\}/, "", src[i])
 585                 }
 586                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 587                         d("Source: " src[i])
 588                         process_source(i,src[i],name,ver)
 589                 } else {
 590                         print FNAME ":" i ": impossible substitution: " src[i]
 591                 }
 592         }
 593 }
 594
 595 BEGIN {
 596         # if U want to use DEBUG, run script with "-v DEBUG=1"
 597         # or uncomment the line below
 598         # DEBUG = 1
 599
 600         errno=system("wget --help > /dev/null 2>&1")
 601         if (errno) {
 602                 print "No wget installed!"
 603                 exit 1
 604         }
 605         if (ARGC>=3 && ARGV[2]=="-n") {
 606                 NUMERIC=1
 607                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 608                 ARGC=ARGC-1
 609         }
 610 }
 611
 612 FNR==1 {
 613         if ( ARGIND != 1 ) {
 614                 # clean frameseen for each ARG
 615                 for (i in frameseen) {
 616                         delete frameseen[i]
 617                 }
 618                 frameseen[0] = 1
 619
 620                 process_data(NAME,VER,REL,SRC)
 621                 NAME="" ; VER="" ; REL=""
 622                 for (i in DEFS) delete DEFS[i]
 623                 for (i in SRC) delete SRC[i]
 624         }
 625         FNAME=FILENAME
 626         DEFS["_alt_kernel"]=""
 627         DEFS["20"]="\\ "
 628 }
 629
 630 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 631 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 632 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 633 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 634 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 635 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 636
 637 END {
 638         process_data(NAME,VER,REL,SRC)
 639 }