pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 function fixedsub(s1,s2,t,      ind) {
   4 # substitutes fixed strings (not regexps)
   5         if (ind = index(t,s1)) {
   6                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
   7         }
   8         return t
   9 }
  10
  11 function compare_ver(v1,v2) {
  12 # compares version numbers
  13         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  14                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  15         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  16                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  17         sub("^0*","",v1)
  18         sub("^0*","",v2)
  19         if (DEBUG) print "v1 == " v1
  20         if (DEBUG) print "v2 == " v2
  21         count=split(v1,v1a,"\.")
  22         count2=split(v2,v2a,"\.")
  23
  24         if (count<count2) mincount=count
  25         else mincount=count2
  26
  27         for (i=1; i<=mincount; i++) {
  28                 if (v1a[i]=="") v1a[i]=0
  29                 if (v2a[i]=="") v2a[i]=0
  30                 if (DEBUG) print "i == " i
  31                 if (DEBUG) print "v1[i] == " v1a[i]
  32                 if (DEBUG) print "v2[i] == " v2a[i]
  33                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  34                         if (length(v2a[i])>length(v1a[i]))
  35                                 return 1
  36                         else if (v2a[i]>v1a[i])
  37                                 return 1
  38                         else if (length(v1a[i])>length(v2a[i]))
  39                                 return 0
  40                         else if (v1a[i]>v2a[i])
  41                                 return 0
  42                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  43                         if (v2a[i]>v1a[i])
  44                                 return 1
  45                         else if (v1a[i]>v2a[i])
  46                                 return 0
  47                 } else if ((v1a[i]~"pre")||(v1a[i]~"beta")||(v1a[i]~"alpha"))
  48                         return 1
  49                 else
  50                         return 0
  51         }
  52         if ((count2==mincount)&&(count!=count2)) {
  53                 for (i=count2+1; i<=count; i++)
  54                         if ((v1a[i]~"pre")||(v1a[i]~"beta")||(v1a[i]~"alpha"))
  55                                 return 1
  56                 return 0
  57         } else if (count!=count2) {
  58                 for (i=count+1; i<=count2; i++)
  59                         if ((v2a[i]~"pre")||(v2a[i]~"beta")||(v2a[i]~"alpha"))
  60                                 return 0
  61                 return 1
  62         }
  63         return 0
  64 }
  65
  66 function get_links(url, errno,link,oneline,retval,odp,tmpfile) {
  67 # get all <A HREF=..> tags from specified URL
  68         "mktemp /tmp/XXXXXX" | getline tmpfile
  69         close("mktemp /tmp/XXXXXX")
  70
  71         if (DEBUG) print "Retrieving: " url
  72         errno=system("wget -O - \"" url "\" -t 1 -T 300 --passive-ftp > " tmpfile " 2>/dev/null" )
  73
  74         if (errno==0) {
  75                 while (getline oneline < tmpfile)
  76                         odp=(odp " " oneline)
  77                 if ( DEBUG ) print "Odpowiedz: " odp
  78         }
  79
  80         close(tmpfile)
  81         system("rm -f " tmpfile)
  82         if ( errno==0) {
  83                 while ((tolower(odp) ~ /<frame[ \t]/)||(tolower(odp) ~ /href=/)) {
  84                         if (tolower(odp) ~ /<frame[ \t]/) {
  85                                 match(tolower(odp),/<frame[ \t][^>]*>/)
  86                                 ramka=substr(odp,RSTART,RLENGTH)
  87                                 odp=substr(odp,RSTART+RLENGTH)
  88                                 match(tolower(ramka),/src="[^"]+"/)
  89                                 newurl=substr(ramka,RSTART+5,RLENGTH-6)
  90                                 if (DEBUG) print "Ramka: " newurl
  91                                 retval=(retval " " get_links(newurl))
  92                         } else if (tolower(odp) ~ /href="[^"]+"/) {
  93                                 match(tolower(odp),/href="[^"]+"/)
  94                                 link=substr(odp,RSTART,RLENGTH)
  95                                 odp=substr(odp,RSTART+RLENGTH)
  96                                 link=substr(link,7,length(link)-7)
  97                                 retval=(retval " " link)
  98                         } else {
  99                                 match(tolower(odp),/href=[^ \t>]+/)
 100                                 link=substr(odp,RSTART,RLENGTH)
 101                                 odp=substr(odp,RSTART+RLENGTH)
 102                                 link=substr(link,6,length(link)-5)
 103                                 retval=(retval " " link)
 104                         }
 105                 }
 106         } else {
 107                 retval=("WGET ERROR: " errno)
 108         }
 109
 110
 111         if (DEBUG) print "Zwracane: " retval
 112         return retval
 113 }
 114
 115 function subst_defines(var,defs) {
 116 # substitute all possible RPM macros
 117         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 118                 oldvar=var
 119                 for (j in defs) {
 120                         gsub("%{" j "}", defs[j], var)
 121                         gsub("%" j , defs[j], var)
 122                 }
 123                 if (var==oldvar) {
 124                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 125                         return var
 126                 }
 127         }
 128         return var
 129 }
 130
 131 function find_mirror(url) {
 132
 133         while (getline line < "mirrors") {
 134                 nf=split(line,fields,"|")
 135                 if (nf>0){
 136                         origin=fields[1]
 137                         mirror=fields[2]
 138                         mname=fields[3]
 139                         prefix=substr(url,1,length(origin))
 140                         if (prefix==origin){
 141                                 if ( DEBUG ) print "Mirror znaleziony na " mname
 142                                 close("mirrors")
 143                                 return mirror substr(url,length(origin))
 144                         }
 145                 }
 146         }
 147
 148         return url
 149 }
 150
 151 function process_source(number,lurl,name,version) {
 152 # fetches file list, and compares version numbers
 153         if ( DEBUG ) print "Przetwarzam " lurl
 154
 155         if ( index(lurl,version)==0 ) {
 156                 if (DEBUG) print "Nie ma numeru wersji."
 157                 return 0
 158         }
 159
 160         sub("://",":",lurl)
 161         sub("/",":/",lurl)
 162         gsub("[^/]*$",":&",lurl)
 163         split(lurl,url,":")
 164         acc=url[1]
 165         host=url[2]
 166         dir=url[3]
 167         filename=url[4]
 168
 169         if (index(dir,version)) {
 170                 dir=substr(dir,1,index(dir,version)-1)
 171                 sub("[^/]*$","",dir)
 172                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 173                 if ( DEBUG ) print "Sprawdze katalog: " dir
 174                 if ( DEBUG ) print "i plik: " filename
 175         }
 176
 177         filenameexp=filename
 178         gsub("\+","\\+",filenameexp)
 179         sub(version,"[A-Za-z0-9\\.]+",filenameexp)
 180         if ( DEBUG ) print "Wzorzec: " filenameexp
 181         match(filename,version)
 182         prever=substr(filename,1,RSTART-1)
 183         postver=substr(filename,RSTART+RLENGTH)
 184         if ( DEBUG ) print "Przed numerkiem: " prever
 185         if ( DEBUG ) print "i po: " postver
 186         newurl=find_mirror(acc "://" host dir)
 187         if ( DEBUG ) print "Zagl±dam na " newurl
 188
 189         references=0
 190         finished=0
 191         oldversion=version
 192         odp=get_links(newurl)
 193         if( odp ~ "ERROR: ") {
 194                 print name "(" number ") " odp
 195         } else {
 196                 if (DEBUG) print "Sciagnieta strona"
 197                 c=split(odp,linki)
 198                 for (nr=1; nr<=c; nr++) {
 199                         addr=linki[nr]
 200                         if (DEBUG) print "Znaleziony link: " addr
 201                         if (addr ~ filenameexp) {
 202                                 match(addr,filenameexp)
 203                                 newfilename=substr(addr,RSTART,RLENGTH)
 204                                 if (DEBUG) print "Hipotetyczny nowy: " newfilename
 205                                 newfilename=fixedsub(prever,"",newfilename)
 206                                 newfilename=fixedsub(postver,"",newfilename)
 207                                 if (DEBUG) print "Wersja: " newfilename
 208                                 if ( compare_ver(version, newfilename)==1 ) {
 209                                         if (DEBUG) print "Tak, jest nowa"
 210                                         version=newfilename
 211                                         finished=1
 212                                 }
 213                         }
 214                 }
 215                 if (finished==0)
 216                         print name "(" number ") seems ok: " oldversion
 217                 else
 218                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 219         }
 220 }
 221
 222 function process_data(name,ver,rel,src) {
 223 # this function checks if substitutions were valid, and if true:
 224 # processes each URL and tries to get current file list
 225         for (i in src) {
 226                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 227                         if ( DEBUG ) print "Zrodlo: " src[i]
 228                         process_source(i,src[i],name,ver)
 229                 } else {
 230                         print FNAME ":" i ": niemozliwe podstawienie: " src[i]
 231                 }
 232         }
 233 }
 234
 235 BEGIN {
 236         # if U want to use DEBUG, run script with "-v DEBUG=1"
 237         # or uncomment the line below
 238         # DEBUG = 1
 239
 240         errno=system("wget --help > /dev/null 2>&1")
 241         if (errno) {
 242                 print "No wget installed!"
 243                 exit 1
 244         }
 245 }
 246
 247 FNR==1 {
 248         if ( ARGIND != 1 ) {
 249                 process_data(NAME,VER,REL,SRC)
 250                 NAME="" ; VER="" ; REL=""
 251                 for (i in DEFS) delete DEFS[i]
 252                 for (i in SRC) delete SRC[i]
 253         }
 254         FNAME=FILENAME
 255 }
 256
 257 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 258 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 259 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 260 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 261 /^[Ss]ource[0-9]*:/ { if (/(ftp|http):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 262 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 263
 264 END {
 265         process_data(NAME,VER,REL,SRC)
 266 }