pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|dl)\.(sf|sourceforge)\.net\//) {
 236                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 237                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 238
 239                 gsub("/.*", "", url)
 240                 url = "http://sourceforge.net/projects/" url "/files/"
 241                 d("sf url, mungled url to: " url)
 242         }
 243
 244         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 245                 gsub("^http://", "", url)
 246                 gsub("\..*", "", url)
 247                 url = "http://code.google.com/p/" url "/downloads/list"
 248                 d("googlecode url, mungled url to: " url)
 249         }
 250
 251         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 252                 gsub("-.*", "", filename)
 253                 url = "http://pecl.php.net/package/" filename
 254                 d("pecl.php.net url, mungled url to: " url)
 255         }
 256
 257         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 258                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 259                  d("mysql 5.1 url, mungled url to: " url)
 260         }
 261
 262         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 263                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 264                 gsub("\/.*/", "", url)
 265                 url = "https://code.launchpad.net/" url "/+download"
 266                 d("main launchpad url, mungled url to: " url)
 267         }
 268
 269         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 270                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 271                 gsub("\/.*/", "", url)
 272                 url = "https://edge.launchpad.net/" url "/+download"
 273                 d("edge launchpad url, mungled url to: " url)
 274         }
 275
 276         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 277                 gsub("\/tarball\/.*", "/downloads", url)
 278                 d("github tarball url, mungled url to: " url)
 279         }
 280
 281         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 282                 gsub("\/archive\/.*", "/tags", url)
 283                 d("github archive url, mungled url to: " url)
 284         }
 285
 286         # https://bitbucket.org/logilab/pylint/get/tip.tar.bz2 -> https://bitbucket.org/logilab/pylint/downloads
 287         if (url ~/^(http|https):\/\/bitbucket.org\/.*\/get\/.*/) {
 288                 gsub("\/get\/.*", "/downloads", url)
 289                 d("github bitbucket url, mungled url to: " url)
 290         }
 291
 292         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 293                 gsub("\/snapshot\/.*", "/", url)
 294                 d("cgit snapshot tarball url, mungled url to: " url)
 295         }
 296
 297         if (url ~/^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 298                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 299                 d("aquamaniac.de tarball url, mungled url to: " url)
 300         }
 301
 302         if (url ~/^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 303                 url = "http://www.process-one.net/en/ejabberd/archive/"
 304                 d("ejabberd tarball url, mungled url to: " url)
 305         }
 306
 307         if (url ~/^(http|https):\/\/llvm.org\/releases\//) {
 308                 url = "http://llvm.org/releases/download.html"
 309                 d("llvm tarball url, mungled url to: " url)
 310         }
 311
 312         if (url ~/^(http|https):\/\/download\.owncloud\.org\/community\//) {
 313                 url = "http://owncloud.org/changelog/"
 314                 d("owncloud tarball url, mungled url to: " url)
 315         }
 316
 317         if (url ~/^(http|https):\/\/hackage\.haskell\.org\/packages\/archive\//) {
 318                 gsub("\/packages\/archive","/package",url)
 319                 d("hackage haskell tarball url, mungled url to: " url)
 320         }
 321
 322         if (url ~/^http:\/\/www.taskwarrior.org\/download\//) {
 323                 url = "http://taskwarrior.org/projects/taskwarrior/wiki/Download"
 324                 d("taskwarrior tarball url, mungled url to: " url)
 325         }
 326
 327         d("Retrieving: " url)
 328         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 329         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 330         d("Execute: " cmd)
 331         errno = system(cmd)
 332         d("Execute done")
 333
 334         if (errno != 0) {
 335                 d("Reading failure response...")
 336                 wholeerr = ""
 337                 while (getline oneline < tmpfileerr)
 338                         wholeerr = (wholeerr " " oneline)
 339                 d("Error Response: " wholeerr)
 340
 341                 system("rm -f " tmpfile)
 342                 system("rm -f " tmpfileerr)
 343                 retval = ("WGET ERROR: " errno ": " wholeerr)
 344                 return retval
 345         }
 346         system("rm -f " tmpfileerr)
 347
 348         urldir = url;
 349         sub(/[^\/]+$/, "", urldir)
 350
 351 if (USE_PERL) {
 352         cmd = extract_links_cmd(tmpfile)
 353         while (cmd | getline) {
 354                 tag = $1
 355                 link = substr($0, length(tag) + 2)
 356
 357                 if (tag == "iframe") {
 358                         d("Frame: " link)
 359                         if (url !~ /\//) {
 360                                 link = (urldir link)
 361                                 d("Frame->: " link)
 362                         }
 363
 364                         if (link_seen(link)) {
 365                                 continue
 366                         }
 367                         retval = (retval " " get_links(link))
 368                 }
 369
 370                 if (link_seen(link)) {
 371                         continue
 372                 }
 373
 374                 retval = (retval " " link)
 375                 d("href(): " link)
 376         }
 377         close(cmd)
 378         system("rm -f " tmpfile)
 379
 380         d("Returning: [" retval "]")
 381         return retval
 382 }
 383
 384         wholeodp = ""
 385         d("Reading success response...")
 386         while (getline oneline < tmpfile) {
 387                 wholeodp = (wholeodp " " oneline)
 388 #               d("Response: " wholeodp)
 389         }
 390         d("Reponse read done...")
 391         system("rm -f " tmpfile)
 392
 393         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 394                 d("Processing links...")
 395                 odp = substr(wholeodp,RSTART,RLENGTH);
 396                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 397
 398                 lowerodp = tolower(odp);
 399                 if (lowerodp ~ /<frame[ \t]/) {
 400                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 401                         match(odp, /src="[^"]+"/)
 402                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 403                         d("Frame: " newurl)
 404                         if (newurl !~ /\//) {
 405                                 newurl=(urldir newurl)
 406                                 d("Frame->: " newurl)
 407                         }
 408
 409                         if (link_seen(newurl)) {
 410                                 newurl = ""
 411                                 continue
 412                         }
 413
 414                         retval = (retval " " get_links(newurl))
 415                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 416                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 417                         match(odp,/href="[^"]*"/)
 418                         link=substr(odp,RSTART,RLENGTH)
 419                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 420                         link=substr(link,7,length(link)-7)
 421                         link=postfix_link(url, link)
 422
 423                         if (link_seen(link)) {
 424                                 link=""
 425                                 continue
 426                         }
 427
 428                         # link ends with at least 2 digit version
 429                         mlink = ""
 430                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 431                                 mlink = get_links(link)
 432
 433                         retval = (retval " " link " " mlink)
 434                         d("href(\"\"): " link)
 435                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 436                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 437                         match(odp,/href='[^']*'/)
 438                         link=substr(odp,RSTART,RLENGTH)
 439                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 440                         link=substr(link,7,length(link)-7)
 441                         link=postfix_link(url, link)
 442
 443                         if (link_seen(link)) {
 444                                 link=""
 445                                 continue
 446                         }
 447
 448                         retval = (retval " " link)
 449                         d("href(''): " link)
 450                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 451                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 452                         match(odp,/href=[^ \t>]*/)
 453                         link=substr(odp,RSTART,RLENGTH)
 454                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 455                         link=substr(link,6,length(link)-5)
 456
 457                         if (link_seen(link)) {
 458                                 link=""
 459                                 continue
 460                         }
 461
 462                         retval = (retval " " link)
 463                         d("href(): " link)
 464                 } else {
 465                         # <a ...> but not href - skip
 466                         d("skipping <a > without href: " odp)
 467                 }
 468         }
 469
 470         d("Returning: [" retval "]")
 471         return retval
 472 }
 473
 474 function subst_defines(var,defs) {
 475 # substitute all possible RPM macros
 476         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 477                 oldvar=var
 478                 for (j in defs) {
 479                         gsub("%{" j "}", defs[j], var)
 480                         gsub("%" j , defs[j], var)
 481                 }
 482                 if (var==oldvar) {
 483                         if (DEBUG) {
 484                                 for (i in defs) {
 485                                         d(i " == " defs[i])
 486                                 }
 487                         }
 488                         return var
 489                 }
 490         }
 491         return var
 492 }
 493
 494 function find_mirror(url) {
 495
 496         while (succ = (getline line < "mirrors")) {
 497             if (succ==-1) { return url }
 498                 nf=split(line,fields,"|")
 499                 if (nf>1){
 500                         origin=fields[1]
 501                         mirror=fields[2]
 502                         mname=fields[3]
 503                         prefix=substr(url,1,length(origin))
 504                         if (prefix==origin){
 505                                 d("Mirror found at " mname)
 506                                 close("mirrors")
 507                                 return mirror substr(url,length(origin)+1)
 508                         }
 509                 }
 510         }
 511
 512         return url
 513 }
 514
 515 # fetches file list, and compares version numbers
 516 function process_source(number, lurl, name, version) {
 517         d("Processing " lurl)
 518
 519         if (index(lurl, version) == 0) {
 520                 d("There is no version number ["version"] in ["lurl"]")
 521                 return 0
 522         }
 523
 524         sub("://",":",lurl)
 525         sub("/",":/",lurl)
 526         gsub("[^/]*$",":&",lurl)
 527         split(lurl,url,":")
 528         acc=url[1]
 529         host=url[2]
 530         dir=url[3]
 531         filename=url[4]
 532
 533         if (index(dir,version)) {
 534                 # directory name as version maching mode:
 535                 # if /something/version/name-version.tarball then check
 536                 # in /something/ looking for newer directory
 537                 dir=substr(dir,1,index(dir,version)-1)
 538                 sub("[^/]*$","",dir)
 539                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 540         }
 541
 542         d("Will check a directory: " dir)
 543         d("and a file: " filename)
 544
 545         filenameexp=filename
 546         gsub("[+]","\\+",filenameexp)
 547         sub(version,"[A-Za-z0-9.]+",filenameexp)
 548         gsub("[.]","\\.",filenameexp)
 549         sub("\.(bz|bz2|gz|lzma|xz|zip)$",".(bz|bz2|gz|lzma|xz|zip)",filenameexp)
 550         d("Expression: " filenameexp)
 551         match(filename,version)
 552         prever=substr(filename,1,RSTART-1)
 553         postver=substr(filename,RSTART+RLENGTH)
 554         d("Before number: " prever)
 555         d("and after: " postver)
 556         newurl=find_mirror(acc "://" host dir)
 557         #print acc "://" host dir
 558         #newurl=url[1]"://"url[2]url[3]url[4]
 559         #newurl=acc "://" host dir filename
 560         d("Looking at " newurl)
 561
 562         references=0
 563         finished=0
 564         oldversion=version
 565         odp = get_links(newurl, filename)
 566         if( odp ~ "ERROR: ") {
 567                 print name "(" number ") " odp
 568         } else {
 569                 d("WebPage downloaded")
 570                 c=split(odp,linki)
 571                 for (nr=1; nr<=c; nr++) {
 572                         addr=linki[nr]
 573
 574                         d("Found link: " addr)
 575
 576                         # github has very different tarball links that clash with this safe check
 577                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 578                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 579                                         continue
 580                                 }
 581                         }
 582
 583                         if (addr ~ filenameexp) {
 584                                 match(addr,filenameexp)
 585                                 newfilename=substr(addr,RSTART,RLENGTH)
 586                                 d("Hypothetical new: " newfilename)
 587                                 newfilename=fixedsub(prever,"",newfilename)
 588                                 newfilename=fixedsub(postver,"",newfilename)
 589                                 d("Version: " newfilename)
 590                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 591                                 # strip ending (happens when in directiory name as version matching mode)
 592                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 593                                 if (NUMERIC) {
 594                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 595                                                 d("Yes, there is new one")
 596                                                 version=newfilename
 597                                                 finished=1
 598                                         }
 599                                 } else if ( compare_ver(version, newfilename)==1 ) {
 600                                         d("Yes, there is new one")
 601                                         version=newfilename
 602                                         finished=1
 603                                 }
 604                         }
 605                 }
 606                 if (finished == 0)
 607                         print name "(" number ") seems ok: " oldversion
 608                 else
 609                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 610         }
 611 }
 612
 613 function rss_upgrade(name, ver, url, regex, cmd) {
 614         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 615         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 616
 617         d("rss_upgrade_cmd: " cmd)
 618         cmd | getline ver
 619         close(cmd)
 620
 621         return ver
 622 }
 623
 624 # check for ZF upgrade from rss
 625 function zf_upgrade(name, ver) {
 626         return rss_upgrade(name, ver, \
 627                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 628                 "Zend Framework ([^\\s]+) Released" \
 629         );
 630 }
 631
 632 function hudson_upgrade(name, ver) {
 633         return rss_upgrade(name, ver, \
 634                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 635                 "Hudson ([0-9.]+) released" \
 636         );
 637 }
 638
 639 # upgrade check for pear package using PEAR CLI
 640 function pear_upgrade(name, ver,    cmd) {
 641         sub(/^php-pear-/, "", name);
 642
 643         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 644         d("PEAR: " cmd)
 645         cmd | getline ver
 646         close(cmd)
 647
 648         return ver
 649 }
 650
 651 function vim_upgrade(name, ver,     cmd) {
 652         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 653         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 654         d("VIM: " cmd)
 655         cmd | getline ver
 656         close(cmd)
 657         return ver
 658 }
 659
 660 function nodejs_upgrade(name, ver,   cmd) {
 661         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 662         if (DEFS["pkg"]) {
 663                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 664         } else {
 665                 cmd = "npm info " name " dist-tags.latest"
 666         }
 667         cmd | getline ver
 668         close(cmd)
 669
 670         return ver
 671 }
 672
 673 function rubygem_upgrade(name, ver,   cmd, pkg) {
 674         if (DEFS["gem_name"]) {
 675                 pkg = DEFS["gem_name"];
 676
 677         } else if (DEFS["gemname"]) {
 678                 pkg = DEFS["gemname"];
 679
 680         } else if (DEFS["pkgname"]) {
 681                 pkg = DEFS["pkgname"];
 682
 683         } else {
 684                 pkg = name;
 685                 gsub(/^ruby-/, "", pkg);
 686         }
 687
 688         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); print v}'"
 689         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 690         cmd | getline ver
 691
 692         close(cmd)
 693
 694         return ver
 695 }
 696
 697 function chrome_upgrade(name, ver,   cmd, sourceurl) {
 698         sourceurl = "http://dl.google.com/linux/chrome/rpm/stable/x86_64/repodata/primary.xml.gz"
 699         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>google-chrome-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 700         d("CHROME " cmd);
 701         cmd | getline ver
 702         close(cmd)
 703
 704         return ver
 705 }
 706
 707 function process_data(name, ver, rel, src,   nver) {
 708         if (name ~ /^php-pear-/) {
 709                 nver = pear_upgrade(name, ver);
 710         } else if (name == "ZendFramework") {
 711                 nver = zf_upgrade(name, ver);
 712         } else if (name == "hudson") {
 713                 nver = hudson_upgrade(name, ver);
 714         } else if (name == "vim") {
 715                 nver = vim_upgrade(name, ver);
 716         } else if (name == "google-chrome") {
 717                 nver = chrome_upgrade(name, ver);
 718         } else if (name ~ "^nodejs-") {
 719                 nver = nodejs_upgrade(name, ver);
 720         } else if (name ~ "^ruby-") {
 721                 nver = rubygem_upgrade(name, ver);
 722         }
 723
 724         if (nver) {
 725                 if (compare_ver(ver, nver)) {
 726                         print name " [OLD] " ver " [NEW] " nver
 727                 } else {
 728                         print name " seems ok: " ver
 729                 }
 730                 return;
 731         }
 732
 733         if (name == "xulrunner") {
 734                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 735                 d("package xulrunner, change version to firefox ["ver"]")
 736         }
 737
 738 # this function checks if substitutions were valid, and if true:
 739 # processes each URL and tries to get current file list
 740         for (i in src) {
 741                 if (src[i] ~ /%{nil}/) {
 742                         gsub(/\%\{nil\}/, "", src[i])
 743                 }
 744                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 745                         d("Source: " src[i])
 746                         process_source(i, src[i], name, ver)
 747                 } else {
 748                         print FNAME ":" i ": impossible substitution: " src[i]
 749                 }
 750         }
 751 }
 752
 753 BEGIN {
 754         # if you want to use DEBUG, run script with "-v DEBUG=1"
 755         # or uncomment the line below
 756         # DEBUG = 1
 757
 758         errno=system("wget --help > /dev/null 2>&1")
 759         if (errno && errno != 3) {
 760                 print "No wget installed!"
 761                 exit 1
 762         }
 763         if (ARGC>=3 && ARGV[2]=="-n") {
 764                 NUMERIC=1
 765                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 766                 ARGC=ARGC-1
 767         }
 768 }
 769
 770 FNR==1 {
 771         if ( ARGIND != 1 ) {
 772                 # clean frameseen for each ARG
 773                 for (i in frameseen) {
 774                         delete frameseen[i]
 775                 }
 776                 frameseen[0] = 1
 777
 778                 process_data(NAME,VER,REL,SRC)
 779                 NAME="" ; VER="" ; REL=""
 780                 for (i in DEFS) delete DEFS[i]
 781                 for (i in SRC) delete SRC[i]
 782         }
 783         FNAME=FILENAME
 784         DEFS["_alt_kernel"]=""
 785         DEFS["20"]="\\ "
 786         DEFS["nil"]=""
 787 }
 788
 789 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 790 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 791 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 792 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 793 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 794 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 795
 796 END {
 797         process_data(NAME,VER,REL,SRC)
 798 }