findbr

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use IPC::Open2;
   6 use Cwd;
   7
   8 my $pwd = getcwd();
   9 # how to run poldek
  10 my @ignore = qw(vserver-packages python-devel-src);
  11 my @poldek = (qw(sudo poldek -n th-x86_64-ready), "--cachedir=$pwd/poldekcache",
  12         "--skip-installed", "--conf=$pwd/poldekconf/poldek.conf",
  13         "-O", "ignore=" . (join " ", @ignore)
  14 );
  15
  16 # if multiple packages provide some funcionality those will be selected:
  17 my %preferred = (
  18         "automake" => +1,
  19         "autoconf" => +1,
  20         "pkgconfig" => +1,
  21
  22         "python" => +1,
  23         "python-modules" => +1,
  24         "python-setuptools" => +1,
  25
  26         "perl-modules" => +1,
  27         "perl-Encode" => +2,
  28
  29         "zlib-devel" => +1,
  30         "libstdc++-devel" => +1,
  31         "libusb-compat-devel" => +1,
  32         "libjpeg-devel" => +1,
  33         "libpng-devel" => +1,
  34         "libsamplerate-devel" => +1,
  35         "pulseaudio-devel" => +1,
  36         "xorg-lib-libXrandr-devel" => +1,
  37         "sqlite-devel" => +1,
  38
  39         "ice-devel" => -1,
  40 );
  41
  42 # translate package name to provides name
  43 my %translate = (
  44         "gcc-c++" => "libstdc++-devel",
  45         "rarian-compat" => "scrollkeeper",
  46         "Mesa-libGL" => "OpenGL",
  47         "Mesa-libGL-devel" => "OpenGL-devel",
  48         "Mesa-libGLU-devel" => "OpenGL-GLU-devel",
  49 );
  50
  51 my @skip = qw(hostname git svn svnversion mt gawk);
  52 my %skip;
  53 @skip{ @skip } = (1) x scalar @skip;
  54
  55 # for m4 in *.m4; do R=$(rpm -qf $m4); R=${R%-*-*}; \
  56 #   awk -vr=$R '/^\s*(AC_DEFUN|AU_ALIAS)/ { gsub(/\].*/,""); gsub(/.*\[/,""); print r " " $0}' $m4; \
  57 # done | sort | awk '{print "\t\"" $2 "\" => \"" $1 "\","}'
  58 my %ac2br = do "findbr-ac2br";
  59
  60 my %cmake2br = (
  61         "findkde4:44" => "kde4-kdelibs",
  62         "findmsgfmt" => "gettext-tools",
  63         "findpythoninterp" => "python",
  64 );
  65
  66 BEGIN {
  67         $SIG{__WARN__} = sub
  68         {
  69                 local $_ = shift;
  70                 chomp;
  71                 print STDERR "\033[31;1m" . $_ . "\033[0m\n"
  72         };
  73 }
  74
  75 my $builddir = shift @ARGV;
  76 my @lines = <ARGV>;
  77
  78 my $reason;
  79
  80 my %out;
  81 sub add_br
  82 {
  83         my $pkg = shift;
  84         my $msg = shift || $reason;
  85         if ( ref $pkg ) {
  86                 foreach my $p ( @$pkg ) {
  87                         add_br( $p, $msg );
  88                 }
  89                 return;
  90         }
  91
  92         $msg =~ s/\n/ # /sg;
  93
  94         $pkg = $translate{ $pkg } || $pkg;
  95
  96         return if exists $out{ $pkg };
  97         $out{ $pkg } = $msg;
  98         print STDERR "\033[33;1madding: $pkg => $msg\033[0m\n";
  99 }
 100
 101 sub poldek_cmd
 102 {
 103         my $cmd = shift;
 104         warn "Poldek: $cmd\n";
 105         my $pid = open( READ, "-|", @poldek, "--shcmd=".$cmd );
 106
 107         my @read = <READ>;
 108         close READ;
 109
 110         return @read if wantarray;
 111         return \@read;
 112 }
 113
 114 my $check_ac = 0;
 115 my $check_config_log = undef;
 116
 117 my %checked_files;
 118 sub poldek_file
 119 {
 120         my @files;
 121         foreach ( @_ ) {
 122                 next if $checked_files{ $_ };
 123                 $checked_files{ $_ } = 1;
 124                 push @files, $_;
 125         }
 126         return unless @files;
 127
 128         my $search = join "; ", map "search -f $_", @files;
 129         warn "Reason: $reason\n";
 130         my @read = poldek_cmd( $search );
 131
 132         local $_;
 133         my @found;
 134         while ( $_ = shift @read ) {
 135                 if ( /(\d+) package\(s\) found:$/ ) {
 136                         foreach my $i ( 1..$1 ) {
 137                                 $_ = shift @read;
 138                                 chomp;
 139                                 $_ =~ /^(.*)-.*?-.*?$/;
 140                                 push @found, $1;
 141                         }
 142                 }
 143         }
 144
 145         return unless @found;
 146
 147         my $found = $found[0];
 148         if ( @found > 1 ) {
 149                 my $i = 0.0;
 150                 my %pts = map { ( $_ => ( ($i += 0.001) + ( $preferred{ $_ } || 0 ) ) ) }
 151                         reverse @found;
 152                 my @pref = sort { $pts{$b} <=> $pts{$a} } @found;
 153                 my $pref = join ", ", map "$_ => $pts{$_}", @pref;
 154                 warn "Multiple found: $pref\n";
 155                 $found = $pref[0];
 156         }
 157
 158         $found = $translate{ $found } if $translate{ $found };
 159
 160         add_br( $found );
 161 }
 162
 163 my $pkglist;
 164 sub get_pkglist
 165 {
 166         my %pkglist;
 167         my $read = poldek_cmd( "ls" );
 168         foreach ( @$read ) {
 169                 chomp;
 170                 next unless /(\S+)-.*?-.*?\.[a-z0-9_]+$/;
 171                 my $pkg = $1;
 172                 $pkglist{ lc $pkg } = $pkg;
 173         }
 174         $pkglist = \%pkglist;
 175 }
 176
 177 sub guess_package
 178 {
 179         my $origname = shift;
 180         get_pkglist() unless $pkglist;
 181         return unless defined $origname;
 182         my $name = lc $origname;
 183         my @try = (
 184                 "lib$name-devel",
 185                 "$name-devel",
 186                 "$name",
 187                 "lib$name-.*-devel",
 188                 "$name-.*-devel",
 189                 ".*-lib$name-devel",
 190                 ".*-$name-devel",
 191                 ".*-lib$name-.*-devel",
 192                 ".*-$name-.*-devel",
 193         );
 194         my @select;
 195         for my $k ( keys %$pkglist ) {
 196                 if ( $k =~ /$name/ ) {
 197                         push @select, $k;
 198                 }
 199         }
 200         @select = sort @select;
 201
 202         foreach my $try ( @try ) {
 203                 foreach my $pkg ( @select ) {
 204                         if ( $pkg =~ /^$try$/ ) {
 205                                 warn "guessed: $origname => $pkglist->{ $pkg }\n";
 206                                 return $pkglist->{ $pkg };
 207                         }
 208                 }
 209         }
 210         warn "$origname not guessed\n";
 211         return undef;
 212 }
 213
 214 start_check:
 215
 216 my %checked;
 217 my $cmake_get_call = 0;
 218 my $cmake_pkg_list = 0;
 219 while ( $_ = shift @lines ) {
 220         chomp;
 221         #next if $checked{ $_ };
 222         #$checked{ $_ } = 1;
 223
 224         $reason = $_;
 225         if ( /^\S+: (\S+): (?:Command )?not found$/ or /.*configure\[\d+\]: (\S+): not found$/
 226                         or m{which: no (\S+) in \(.*/bin.*\)}
 227                         or m{\S+: (\S+): command not found$}
 228                         or m{(?:/usr/bin/)?env: (\S+): No such file or directory}
 229                         or m{flock: (\S+): No such file or directory}
 230                         or m{Can't exec "(\S+)": No such file or directory} ) {
 231                 my $exec = $1;
 232                 $exec = $1 if $exec =~ m{^"(.*)"$};
 233                 next if $skip{ $exec };
 234                 warn "Looking for executable $exec\n";
 235                 if ( $exec =~ m#^/# ) {
 236                         poldek_file( $exec );
 237                 }
 238                 poldek_file( "/usr/bin/$exec", "/bin/$exec" );
 239         }
 240
 241         if ( /\S+\.[ch](?:pp|xx|c)?:\d+:\d+: error: (\S+): No such file or directory$/ or
 242                 /\S+\.[ch](?:pp|xx|c)?:\d+:\d+: fatal error: (\S+): No such file or directory$/ ) {
 243                 my $h = $1;
 244                 warn "Looking for C(++) header $h\n";
 245                 poldek_file( "/usr/include*/$h" );
 246         }
 247
 248         if (m{^ImportError: No module named (\S+)$}
 249                 or m{^ERROR: Cannot find .+: No module named (\S+)$}
 250                 or m{^ERROR: Failed to import the ".+" module: No module named (\S+)$}
 251                 or m{^distutils.errors.DistutilsError: Could not find suitable distribution for Requirement.parse\('([^'>=]+).*'\)}
 252                 or m{^Couldn't find index page for '(\S+)'}
 253                 ) {
 254                 my $mod = $1;
 255                 $mod =~ s#\.#/#g;
 256                 warn "Looking for python module $mod\n";
 257                 poldek_file(
 258                                 "/usr/share/python2*/$mod/__init__.py*",
 259                                 "/usr/share/python2*/$mod.py*",
 260                                 "/usr/lib*/python2*/$mod/__init__.py*",
 261                                 "/usr/lib*/python2*/$mod.py*",
 262                                 "/usr/lib*/python2*/_$mod.so",
 263                                 "/usr/lib*/python2*/$mod.so" );
 264         }
 265
 266         if (
 267                 m{^-- Could NOT find Sphinx \(missing:  SPHINX_EXECUTABLE\)}
 268         ) {
 269                 add_br("sphinx-pdg");
 270                 next;
 271         }
 272
 273         if (
 274                 m{^cannot load such file -- (\S+)} or
 275                 m{in `require': cannot load such file -- (\S+) \(LoadError\)}
 276         ) {
 277                 my $mod = $1;
 278                 warn "Looking for ruby module $mod\n";
 279                 poldek_file(
 280                         "/usr/share/ruby/*/$mod.rb",
 281                         "/usr/share/ruby/vendor_ruby/*/$mod.rb",
 282                         "/usr/lib64/ruby/vendor_ruby/*/$mod.so",
 283                 );
 284         }
 285
 286         if ( /configure(?:\.in|\.ac)?:\d+: error: possibly undefined macro: (\S+)/
 287                         or m{configure(?:\.in|\.ac)?:\d+: error: m4 macro `(\S+)' is not defined}
 288                         or m{warning: macro `(\S+)' not found in library} ) {
 289                 my $macro = $1;
 290                 warn "Looking for autotools macro $macro\n";
 291                 if ( my $br = $ac2br{ $macro } ) {
 292                         add_br( $br );
 293                         next;
 294                 } else {
 295                         $check_ac = 1;
 296                 }
 297         }
 298         if ( /^No package '(\S+)' found$/ or
 299                         /Package (\S+) was not found in the pkg-config search path/
 300                                 or m{None of the required '(\S+?)(?:[<>=].*)?' found}
 301                                 or m{--\s+package '(\S+?)(?:[<>=].*)?' not found}
 302                                 or m{ERROR: cannot find a valid pkg-config package for \['(\S+?)(?:[<>=].*)?'\]}
 303                 ) {
 304                 my $pkg = $1;
 305                 warn "Looking for package $pkg\n";
 306                 poldek_file( "/usr/lib*/pkgconfig/$pkg.pc", "/usr/share/pkgconfig/$pkg.pc" );
 307         }
 308
 309         if (/^ocamlfind: Package `(\S+)' not found - required by/
 310                 or m{Camlp4: Uncaught exception: DynLoader.Error \("(\S+)", "file not found in path"\)}
 311                 ) {
 312                 my $pkg = $1;
 313                 warn "Looking for ocaml package $pkg\n";
 314                 poldek_file( "/usr/lib*/ocaml/*/$pkg.a", "/usr/lib*/ocaml/*/$pkg");
 315         }
 316
 317         if ( m{^cp: cannot stat `(/.*)': No such file or directory$} ) {
 318                 my $f = $1;
 319                 warn "Looking for file $f\n";
 320                 poldek_file( $f );
 321         }
 322
 323         if ( m{ERROR: Could not find KDE4 (kde4-config)}) {
 324                 my $f = "/usr/bin/$1";
 325                 warn "Looking for file $f\n";
 326                 poldek_file( $f );
 327         }
 328
 329         if (m{Ragel State Machine Compiler not found}) {
 330                 add_br( "ragel" );
 331                 next;
 332         }
 333
 334         if ( m{^find-lang.sh: Error: international files not found for '}
 335                         or m{ gettext tools not found}
 336                         ) {
 337                 add_br( "gettext-tools" );
 338                 next;
 339         }
 340
 341         if ( m{ pkg-config .*not .*found}
 342                 or m{^checking for pkg-config\.\.\. no}
 343                 or m{^pkg-config unavailable, build terminated}
 344                 or m{^\*\*\*Error\*\*\*: You must have pkg-config >= .* installed}
 345                 or m{^-- Could NOT find PkgConfig \(missing:  PKG_CONFIG_EXECUTABLE\)}
 346         ) {
 347                 add_br( "pkgconfig" );
 348                 next;
 349         }
 350
 351         if ( m{Can't locate (.*?\.pm) in \@INC} ) {
 352                 my $mod = $1;
 353                 warn "Looking for perl module $mod\n";
 354                 poldek_file( "/usr/lib*/perl*/$mod", "/usr/share/perl*/$mod" );
 355         }
 356
 357         if (
 358                 m{^(?:/usr/bin/ld: )?cannot find -l(.*?)$}
 359         ) {
 360                 my $lib = $1;
 361                 warn "Looking for library $lib\n";
 362                 poldek_file( "/usr/lib64/lib$lib.so", "/usr/lib/lib$lib.so",
 363                         "/usr/lib*/lib$lib.so" );
 364         }
 365
 366         # full path to ldd files
 367         if (
 368                 m{^WARNING; can.*t resolve .* dependency: (.*?)$}
 369         ) {
 370                 my $lib = $1;
 371                 warn "Looking for library '$lib'\n";
 372                 poldek_file( "/usr/lib64/$lib", "/usr/lib/$lib", "/lib64/$lib", "/lib/$lib");
 373         }
 374
 375         if ( m{^error: Couldn't exec (/\S+): No such file or directory$}
 376                         or m{^Can't open perl script "(/\S+)": No such file or directory$}
 377                         or m{unable to open (/\S+) \(No such file or directory\)$}
 378                         or m{GConf-CRITICAL \*\*: No such file `(/.\S+?)'$}
 379                         or m{make.*: \*\*\* No rule to make target `(/\S+)'}
 380                         or m{g(?:cc|\+\+): (/\S+): No such file or directory$}
 381                         or m{env: (/\S+): No such file or directory$}
 382                         ) {
 383                 my $file = $1;
 384                 warn "Looking for file $file\n";
 385                 poldek_file( $file );
 386         }
 387
 388         if ( m{^ValueError: Couldn't find include '(.*\.gir)'} ) {
 389                 my $file = $1;
 390                 warn "Looking for gir file $file\n";
 391                 poldek_file( "/usr/share/gir-1.0/" . $file );
 392         }
 393
 394         if ( m{^error: Package `(\S+)' not found in specified Vala API directories or GObject-Introspection GIR directories}
 395         ) {
 396                 my $file = $1;
 397                 warn "Looking for gir file $file\n";
 398                 poldek_file( "/usr/share/vala/vapi/$file.vapi");
 399         }
 400
 401         if ( m{failed.*http://www\.oasis-open\.org/docbook/xml/([\d\.]+/\S+\.dtd)} ) {
 402                 my $dtd = $1;
 403                 warn "Looking for docbook file $dtd\n";
 404                 poldek_file( "/usr/share/sgml/docbook/xml-dtd-$dtd" );
 405         }
 406         if ( m{http://docbook.sourceforge.net/release/xsl/current/(\S+\.xsl)} ) {
 407                 my $db = $1;
 408                 next if m{^\s*(/usr/bin/)?xsltproc };
 409                 warn "Looking for docbook file $db\n";
 410                 poldek_file( "/usr/share/sgml/*/$db" );
 411         }
 412
 413         if ( m{LaTeX Error: File `(\S+)' not found} ) {
 414                 my $tex = $1;
 415                 warn "Looking for tex file $tex\n";
 416                 poldek_file( "/usr/share/tex*/$tex" );
 417         }
 418         if ( m{mv: cannot move `\S+' to `(/var/lib/texmf.*?)':} ) {
 419                 my $tex = $1;
 420                 warn "Looking for tex file $tex\n";
 421                 poldek_file( $tex );
 422         }
 423
 424         if ( m{configure: error: C\+\+ preprocessor "/lib/cpp" fails sanity check} ) {
 425                 add_br( "gcc-c++", "try: %undefine\t__cxx" );
 426         }
 427         if ( m{configure: error: C\+\+ compiler cannot create executables} ) {
 428                 add_br( "libstdc++-devel", "maybe try: %undefine\t__cxx" );
 429         }
 430         if ( m{configure: error: XML::Parser perl module is required for intltool} ) {
 431                 add_br( "perl-XML-Parser" );
 432         }
 433         if ( m{iconv: conversion from `\S+' is not supported} ) {
 434                 add_br( "iconv" );
 435         }
 436
 437         if (m{rst2man \(python-docutils\) is required to build man pages}) {
 438                 add_br("docutils");
 439         }
 440
 441         if ( m{ (\S+) does not appear in AM_CONDITIONAL$} ) {
 442                 my $macro = $1;
 443                 warn "Looking for autotools macro $macro\n";
 444                 if ( my $br = $ac2br{ $macro } ) {
 445                         add_br( $br );
 446                         next;
 447                 } else {
 448                         $check_ac = 1;
 449                 }
 450         }
 451
 452         if ( m{configure\[\d+\]: syntax error: }
 453                         or m{\./configure\[\d+\]: \S+_\S+: not found}
 454                         or m{./configure\[\d+\]: .*unexpected}
 455                         or m{does not appear in AM_CONDITIONAL$}
 456                         ) {
 457                 warn "Need to check configure source: $reason\n";
 458                 $check_ac = 1;
 459         }
 460         if ( m{^configure: error:} ) {
 461                 $check_config_log = 1 unless defined $check_config_log;
 462         }
 463
 464         if ( m{^CMake (?:Error|Warning) at (?:\S+/)?(\S+?)\.cmake:(\d+) } ) {
 465                 my ( $module, $line ) = ( lc $1, $2 );
 466                 my $br;
 467                 if ( $module eq "findqt4" ) {
 468                         my $l = $lines[0];
 469                         chomp $l;
 470                         if ( $l =~ /qmake/ ) {
 471                                 add_br( "qt4-qmake", $l );
 472                         } elsif ( $l =~ /rcc/ ) {
 473                                 add_br( "qt4-build", $l );
 474                         } elsif ( $l =~ /Could NOT find (Qt\S+) header/ ) {
 475                                 add_br( "$1-devel", $l );
 476                         } else {
 477                                 warn "unrecognized Qt requirement: $l\n";
 478                         }
 479                 } elsif ( $module eq "cmakedeterminecxxcompiler" ) {
 480                         add_br( "libstdc++-devel",
 481                                 '"try: -DCMAKE_CXX_COMPILER_WORKS=1 -DCMAKE_CXX_COMPILER="%{__cc}"' );
 482                 } elsif ( $br = $cmake2br{ $module . ":" . $line } ) {
 483                         add_br( $br );
 484                 } elsif ( $br = $cmake2br{ $module } ) {
 485                         add_br( $br );
 486                 } elsif ( $br = guess_package( $module =~ /find(.+)/ ) ) {
 487                         add_br( $br );
 488                 } else {
 489                         $cmake_get_call = 1;
 490                         warn "Unrecognized cmake error: $reason\n";
 491                 }
 492         }
 493         if ( m{^\s*ERROR: (?:\S+/)?(\S+?\.cmake) not found} ) {
 494                 my $cmake = $1;
 495                 warn "Looking for cmake file: $cmake\n";
 496                 poldek_file( "/usr/*/cmake/*/$cmake" )
 497         }
 498         if ( $cmake_get_call ) {
 499                 if ( m{^\s*/\S+/(\S+)\.cmake:(\d+) } ) {
 500                         my ( $module, $line ) = ( lc $1, $2 );
 501                         my $br;
 502                         if ( $br = $cmake2br{ $module . ":" . $line } ) {
 503                                 add_br( $br );
 504                                 $cmake_get_call = 0;
 505                         } elsif ( $br = $cmake2br{ $module } ) {
 506                                 add_br( $br );
 507                                 $cmake_get_call = 0;
 508                         } elsif ( $br = guess_package( $module =~ /find(.+)/ ) ) {
 509                                 add_br( $br );
 510                                 $cmake_get_call = 0;
 511                         }
 512                 } elsif (m{Can not use "(.+)" module which has not yet been found}
 513                         or m{Could not find a package configuration file provided by "(.+)"}) {
 514                         my $cmake = $1;
 515
 516                         warn "Looking for cmake file: $cmake\n";
 517                         poldek_file(
 518                                 "/usr/*/cmake/*/$cmake.cmake",
 519                                 "/usr/*/cmake/*/${cmake}Config.cmake",
 520                                 "/usr/*/cmake/*/${cmake}-config.cmake",
 521                         );
 522                         $cmake_get_call = 0;
 523                 }
 524         }
 525         if ( m{^-- WARNING: you are using the obsolete 'PKGCONFIG' macro} ) {
 526                 add_br( "pkgconfig" );
 527         }
 528         if ( m{QT_(QT\S+)_LIBRARY \(ADVANCED\)}
 529                         or m{X11_(\S+)_LIB \(ADVANCED\)}
 530                         or m{Qt (\S+) library not found} ) {
 531                 my $find = $1;
 532                 my $pkg = guess_package( $find );
 533                 if ( $pkg ) {
 534                         add_br( $pkg );
 535                 } else {
 536                         warn "Cannot quess qt package: $find\n";
 537                 }
 538         }
 539
 540         if ( m{Unable to find a javac compiler;$} ) {
 541                 add_br( "jdk" );
 542         }
 543         if ( m{Could not find (\S+) Java extension for this JVM$} ) {
 544                 my $jar = $1;
 545                 warn "Looking for jar file: $jar\n";
 546                 poldek_file( "/usr/share/java/$jar.jar", "*/$jar.jar" )
 547         }
 548
 549
 550         if ( m{^-- The following OPTIONAL packages could NOT be located on your system} ) {
 551                 $cmake_pkg_list = 1;
 552         }
 553         if ( $cmake_pkg_list ) {
 554                 if ( /\s+\* (\S+) / ) {
 555                         my $find = $1;
 556                         my $pkg = guess_package( $find );
 557                         if ( $pkg ) {
 558                                 add_br( $pkg );
 559                         } else {
 560                                 warn "Cannot quess optional package: $find\n";
 561                         }
 562                 } elsif ( /^\s*$/ ) {
 563                         $cmake_pkg_list = 0;
 564                 }
 565         }
 566
 567         # CMake Error at CMakeLists.txt:86 (find_package):
 568         #  By not providing "FindQt5LinguistTools.cmake" in CMAKE_MODULE_PATH this
 569         #  project has asked CMake to find a package configuration file provided by
 570         #  "Qt5LinguistTools", but CMake did not find one.
 571         #
 572         #  Could not find a package configuration file provided by "Qt5LinguistTools"
 573         #  with any of the following names:
 574         #
 575         #    Qt5LinguistToolsConfig.cmake
 576         #    qt5linguisttools-config.cmake
 577         #
 578         #  Add the installation prefix of "Qt5LinguistTools" to CMAKE_PREFIX_PATH or
 579         #  set "Qt5LinguistTools_DIR" to a directory containing one of the above
 580         #  files.  If "Qt5LinguistTools" provides a separate development package or
 581         #  SDK, be sure it has been installed.
 582         # ---
 583         #CMake Warning at /usr/lib64/cmake/Qt5Core/Qt5CoreMacros.cmake:273 (find_package):
 584         #  Could not find a package configuration file provided by "Qt5Network" with
 585         #  any of the following names:
 586         #
 587         #    Qt5NetworkConfig.cmake
 588         #    qt5network-config.cmake
 589         #
 590         #  Add the installation prefix of "Qt5Network" to CMAKE_PREFIX_PATH or set
 591         #  "Qt5Network_DIR" to a directory containing one of the above files.  If
 592         #  "Qt5Network" provides a separate development package or SDK, be sure it has
 593         #  been installed.
 594         #   Can not use "Network" module which has not yet been found.
 595
 596         if (m{By not providing "Find(.+)\.cmake" in CMAKE_MODULE_PATH}
 597                 or m{Could not find a package configuration file provided by "(.+)"
 598                 }) {
 599                 my $cmake = $1;
 600                 my $lcmake = lc $cmake;
 601
 602                 warn "Looking for cmake file: $cmake\n";
 603                 poldek_file(
 604                         "/usr/*/cmake/*/$cmake.cmake",
 605                         "/usr/*/cmake/*/${cmake}Config.cmake",
 606                         "/usr/*/cmake/*/${cmake}-config.cmake",
 607                         "/usr/*/cmake/*/${lcmake}Config.cmake",
 608                         "/usr/*/cmake/*/${lcmake}-config.cmake",
 609                 )
 610         }
 611
 612         if ( m{^configure:\d+: checking for (?:"(\S+)"|(\S+))$} ) {
 613                 my $exec = $1 || $2;
 614                 if ( @lines and $lines[0] =~ m{^configure:\d+: result: no$} ) {
 615                         next if $skip{ $exec };
 616                         warn "Looking for executable $exec\n";
 617                         poldek_file( $exec ) if $exec =~ m#^/#;
 618                         poldek_file( "/usr/bin/$exec", "/bin/$exec" );
 619                 }
 620         }
 621 }
 622
 623
 624
 625 sub wanted
 626 {
 627         return unless /^configure(\.(?:ac|in|in\.in))?$/;
 628         return unless -r;
 629
 630         warn "$File::Find::name\n";
 631         open F_IN, "<", $_;
 632         my $file = $_;
 633         while ( <F_IN> ) {
 634                 chomp;
 635                 if ( m{^\s*([A-Za-z0-9_]+)\s*(\(.*)?$} ) {
 636                         my $def = $1;
 637                         if ( my $br = $ac2br{ $def } ) {
 638                                 add_br( $br, "$file: $_" );
 639                         } elsif ( $def !~ /^A[CM]_/ and $def =~ /^_?[A-Z]+_[A-Z_0-9a-z]+$/ ) {
 640                                 #warn "Possible macro unrecognized: $def [[[$_]]]\n";
 641                         }
 642                 }
 643         }
 644         close F_IN;
 645 }
 646
 647 use File::Find;
 648 if ( $check_ac ) {
 649         find( \&wanted, $builddir );
 650 }
 651
 652 sub wanted2
 653 {
 654         return unless /^config\.log$/;
 655         return unless -r;
 656
 657         warn "$File::Find::name\n";
 658         open F_IN, "<", $_;
 659         push @lines, <F_IN>;
 660         close F_IN;
 661 }
 662
 663 if ( $check_config_log ) {
 664         $check_config_log = 0;
 665         find( \&wanted2, $builddir );
 666         goto start_check if @lines;
 667 }
 668
 669 foreach my $pkg ( sort keys %out ) {
 670         print "$pkg -- $out{$pkg}\n";
 671 }
 672 # vim: ts=4 sw=4