adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2006 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Micha³ Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Elan Ruusamä¤e <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  21 # - add "-nc" option to skip CVS interaction
  22 # - sort Summary(XX)
  23 # - sort Requires, BuildRequires
  24 # - check if %description (lang=C) contains 8bit
  25 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  26
  27 BEGIN {
  28         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  29         SECTIONS = "^%(" RPM_SECTIONS ")"
  30
  31         PREAMBLE_TAGS = "(Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires)"
  32
  33         preamble = 1    # Is it part of preamble? Default - yes
  34         boc = 4                 # Beginning of %changelog
  35         bod = 0                 # Beginning of %description
  36         tw = 70                 # Descriptions width
  37
  38         b_idx = 0               # index of BR/R arrays
  39     BR_count = 0   # number of additional BuildRequires
  40
  41         # If variable removed, then 1 (for removing it from export)
  42         removed["LDFLAGS"] = 0
  43         removed["CFLAGS"] = 0
  44         removed["CXXFLAGS"] = 0
  45
  46         # get cvsaddress for changelog section
  47         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  48         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  49         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  50
  51         # If 1, we are inside of comment block (started with /^#%/)
  52         comment_block = 0
  53
  54         # File with rpm groups
  55         "rpm --eval %_sourcedir" | getline groups_file
  56         groups_file = groups_file "/rpm.groups"
  57         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  58         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  59
  60         # Temporary file for changelog section
  61         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  62
  63         # Load rpm macros
  64         "rpm --eval %_prefix"   | getline prefix
  65         "rpm --eval %_bindir"   | getline bindir
  66         "rpm --eval %_sbindir"  | getline sbindir
  67         "rpm --eval %_libdir"   | getline libdir
  68         "rpm --eval %_sysconfdir" | getline sysconfdir
  69         "rpm --eval %_datadir"  | getline datadir
  70         "rpm --eval %_includedir" | getline includedir
  71         "rpm --eval %_mandir"   | getline mandir
  72         "rpm --eval %_infodir"  | getline infodir
  73         "rpm --eval %_examplesdir"      | getline examplesdir
  74         "rpm --eval %_defaultdocdir"    | getline docdir
  75         "rpm --eval %_desktopdir" | getline desktopdir
  76         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  77
  78         "rpm --eval %perl_sitearch" | getline perl_sitearch
  79         "rpm --eval %perl_archlib" | getline perl_archlib
  80         "rpm --eval %perl_privlib" | getline perl_privlib
  81         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  82         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  83         "rpm --eval %perl_sitelib" | getline perl_sitelib
  84
  85         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  86         "rpm --eval %py_sitedir" | getline py_sitedir
  87         "rpm --eval %py_scriptdir " | getline py_scriptdir
  88
  89         "rpm --eval %ruby_archdir" | getline ruby_archdir
  90         "rpm --eval %ruby_ridir" | getline ruby_ridir
  91         "rpm --eval %ruby_rubylibdir" | getline ruby_rubylibdir
  92         "rpm --eval %ruby_sitearchdir" | getline ruby_sitearchdir
  93         "rpm --eval %ruby_sitelibdir" | getline ruby_sitelibdir
  94
  95         "rpm --eval %php_pear_dir" | getline php_pear_dir
  96         "rpm --eval %tmpdir" | getline tmpdir
  97 }
  98
  99 # There should be a comment with CVS keywords on the first line of file.
 100 FNR == 1 {
 101         if (!/# \$Revision:/)   # If this line is already OK?
 102                 print "# $" "Revision:$, " "$" "Date:$" # No
 103         else {
 104                 print $0                                # Yes
 105                 next            # It is enough for first line
 106         }
 107 }
 108
 109 # If the latest line matched /%files/
 110 defattr == 1 {
 111         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 112                 if ($0 !~ /defattr/) {  # If no %defattr
 113                         print "%defattr(644,root,root,755)"     # Add it
 114                 } else {
 115                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 116                 }
 117         }
 118         defattr = 0
 119 }
 120
 121 function b_makekey(a, b,        s) {
 122         s = a "" b;
 123         # kill bcond
 124     gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 125
 126         # kill commented out items
 127     gsub(/^#[ \t]*/, "", s);
 128
 129         # force order
 130     gsub(/^Summary\(/, "11Summary(", s);
 131     gsub(/^Summary/, "10Summary", s);
 132     gsub(/^Name/, "2Name", s);
 133     gsub(/^Version/, "3Version", s);
 134     gsub(/^Release/, "4Release", s);
 135     gsub(/^Epoch/, "5Epoch", s);
 136     gsub(/^License/, "5License", s);
 137     gsub(/^Group/, "6Group", s);
 138     gsub(/^URL/, "7URL", s);
 139
 140     gsub(/^BuildRequires/, "B1BuildRequires", s);
 141     gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 142     gsub(/^Provides/, "X1Provides", s);
 143     gsub(/^Obsoletes/, "X2Obsoletes", s);
 144     gsub(/^Conflicts/, "X3Conflicts", s);
 145     gsub(/^BuildArch/, "X4BuildArch", s);
 146     gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 147     gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 148     gsub(/^BuildRoot/, "X9BuildRoot", s);
 149
 150 #       printf("%s -> %s\n", a""b, s);
 151         return s;
 152 }
 153
 154 # Comments
 155 /^#/ && (description == 0) {
 156         if (/This file does not like to be adapterized!/) {
 157                 print                   # print this message
 158                 while (getline)         # print the rest of spec as it is
 159                         print
 160                 do_not_touch_anything = 1 # do not touch anything in END()
 161                 exit 0
 162         }
 163
 164         # Generally, comments are printed without touching
 165         sub(/[ \t]+$/, "")
 166
 167         if (/Source.*md5/) {
 168                 print $0
 169                 next
 170         }
 171 }
 172
 173 /^%define/ {
 174         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 175         if ($2 == "_applnkdir") {
 176                 next
 177         }
 178         if ($2 == "date") {
 179                 date = 1
 180                 if (did_files == 0) {
 181                         print "%files"
 182                         print ""
 183                         did_files = 1
 184                 }
 185         }
 186
 187         # Do not add %define of _prefix if it already is.
 188         if ($2 ~ /^_prefix/) {
 189                 sub("^"prefix, $3, bindir)
 190                 sub("^"prefix, $3, sbindir)
 191                 sub("^"prefix, $3, libdir)
 192                 sub("^"prefix, $3, datadir)
 193                 sub("^"prefix, $3, includedir)
 194                 prefix = $3
 195         }
 196
 197         if ($2 ~ /_bindir/ && !/_sbindir/)
 198                 bindir = $3
 199         if ($2 ~ /_sbindir/)
 200                 sbindir = $3
 201         if ($2 ~ /_libdir/) {
 202                 if ($3 ~ /^%\(/) {
 203                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 204                         libdir = "%%%%%%%%%%%%%%"
 205                 } else {
 206                         libdir = $3
 207                 }
 208         }
 209         if ($2 ~ /_sysconfdir/) {
 210                 if ($3 ~ /^%\(/) {
 211                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 212                         sysconfdir = "%%%%%%%%%%%%%%"
 213                 } else {
 214                         sysconfdir = $3
 215                 }
 216         }
 217         if ($2 ~ /_datadir/) {
 218                 if ($3 ~ /^%\(/) {
 219                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 220                         datadir = "%%%%%%%%%%%%%%"
 221                 } else {
 222                         datadir = $3
 223                 }
 224         }
 225         if ($2 ~ /_includedir/)
 226                 includedir = $3
 227         if ($2 ~ /_mandir/)
 228                 mandir = $3
 229         if ($2 ~ /_infodir/)
 230                 infodir = $3
 231         if ($2 ~ /_docdir/)
 232                 docdir = $3
 233
 234         # version related macros
 235         if ($2 ~ /^_beta$/)
 236                 _beta = $3
 237         if ($2 ~ /^_rc$/)
 238                 _rc = $3
 239         if ($2 ~ /^_pre$/)
 240                 _pre = $3
 241         if ($2 ~ /^_snap$/)
 242                 _snap = $3
 243
 244         # these are used usually when adapterizing external spec
 245         if ($2 ~ /^name$/)
 246                 name = $3
 247         if ($2 ~ /^version$/)
 248                 version = $3
 249         if ($2 ~ /^release$/)
 250                 release = $3
 251
 252         if ($2 ~ /^mod_name$/)
 253                 mod_name = $3
 254
 255         sub(/[ \t]+$/, "");
 256         # do nothing further, otherwise adapter thinks we're at preamble
 257         print
 258         next
 259 }
 260
 261 # Obsolete
 262 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 263         next
 264 }
 265
 266 ################
 267 # %description #
 268 ################
 269 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 270         preamble = 0
 271
 272         if (/^%description/) {
 273                 bod++
 274                 format_line = ""
 275                 format_indent = -1
 276         }
 277
 278         # Format description
 279         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 280                 if (/^[ \t]*$/) {
 281                         format_flush(format_line, format_indent)
 282                         print ""
 283                         format_line = ""
 284                         format_indent = -1
 285                 } else if (/^[ \t]*[-\*][ \t]*/) {
 286                         format_flush(format_line, format_indent)
 287                         match($0, /^[ \t]*/)
 288                         format_indent = RLENGTH
 289                         match($0, /^[ \t]*[-\*][ \t]/)
 290                         format_line = substr($0, RLENGTH)
 291                 } else
 292                         format_line = format_line " " $0
 293                 next
 294         }
 295
 296         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 297                 if (NF > 3 && $2 == "-l") {
 298                         ll = $1
 299                         for (i = 4; i <= NF; i++)
 300                                 ll = ll " " $i
 301                         $0 = ll " -l " $3
 302                 }
 303                 format_flush(format_line, format_indent)
 304                 if (bod == 2) {
 305                         bod = 1
 306                         description = 1
 307                 } else {
 308                         bod = 0
 309                         description = 0
 310                 }
 311         } else
 312                 description = 1
 313 }
 314
 315 #########
 316 # %prep #
 317 #########
 318 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 319         preamble = 0
 320         did_prep = 1
 321
 322         use_macros()
 323
 324         # Add '-q' to %setup
 325         if (/^%setup/ && !/-q/) {
 326                 sub(/^%setup/, "%setup -q")
 327         }
 328
 329         if (/^%setup/ && name != "setup") {
 330                 $0 = fixedsub(name, "%{name}", $0);
 331                 $0 = fixedsub(version, "%{version}", $0);
 332                 if (_beta) {
 333                         $0 = fixedsub(_beta, "%{_beta}", $0);
 334                 }
 335                 if (_rc) {
 336                         $0 = fixedsub(_rc, "%{_rc}", $0);
 337                 }
 338                 if (_pre) {
 339                         $0 = fixedsub(_pre, "%{_pre}", $0);
 340                 }
 341                 if (_snap) {
 342                         $0 = fixedsub(_snap, "%{_snap}", $0);
 343                 }
 344         }
 345
 346         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 347                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 348         }
 349     sub("^%patch ", "%patch0 ");
 350
 351         # invalid in %prep
 352         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 353 }
 354
 355 ##########
 356 # %build #
 357 ##########
 358 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 359         preamble = 0
 360
 361         if (did_prep == 0) {
 362                 print "%prep"
 363                 print ""
 364                 did_prep = 1
 365         }
 366
 367         use_macros()
 368         use_tabs()
 369
 370         if (/^automake$/)
 371                 sub(/$/, " -a -c")
 372
 373         if (/LDFLAGS/) {
 374                 if (/LDFLAGS="-s"/) {
 375                         removed["LDFLAGS"] = 1
 376                         next
 377                 } else {
 378                         split($0, tmp, "LDFLAGS=")
 379                         count = split(tmp[2], flags, "\"")
 380                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 381                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 382                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 383                                 for (i = 2; i < count; i++)
 384                                         $0 = $0 flags[i] "\""
 385                         }
 386                 }
 387         }
 388
 389         if (/CFLAGS=/)
 390                 if (cflags("CFLAGS") == 0)
 391                         next
 392
 393         if (/CXXFLAGS=/)
 394                 if (cflags("CXXFLAGS") == 0)
 395                         next
 396
 397         if (/^export /) {
 398                 if (removed["LDFLAGS"])
 399                         sub(" LDFLAGS", "")
 400                 if (removed["CFLAGS"])
 401                         sub(" CFLAGS", "")
 402                 if (removed["CXXFLAGS"])
 403                         sub(" CXXFLAGS", "")
 404                 # Is there still something?
 405                 if (/^export[ ]*$/)
 406                         next
 407         }
 408
 409         # quote CC
 410         if (/CC=%{__cc} /) {
 411                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 412         }
 413
 414         # use PLD Linux macros
 415         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 416         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 417         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 418         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 419         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 420         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 421         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 422
 423         sub(/^aclocal$/, "%{__aclocal}");
 424         sub(/^autoheader$/, "%{__autoheader}");
 425         sub(/^autoconf$/, "%{__autoconf}");
 426         sub(/^automake$/, "%{__automake}");
 427
 428         # atrpms
 429         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 430         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 431 }
 432
 433 ##########
 434 # %clean #
 435 ##########
 436 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 437         did_clean = 1
 438
 439         # prevent next section header like "%post -p /sbin/ldconfig" being adapterized
 440         if (!/^%post/) {
 441                 use_macros()
 442         }
 443 }
 444
 445 ############
 446 # %install #
 447 ############
 448 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 449
 450         preamble = 0
 451
 452         # foreign rpms
 453         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 454     sub("%buildroot", "$RPM_BUILD_ROOT");
 455     sub("%{buildroot}", "$RPM_BUILD_ROOT");
 456
 457         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 458                 did_rmroot=1
 459                 print "rm -rf $RPM_BUILD_ROOT"
 460                 next
 461         }
 462
 463         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 464                 print "rm -rf $RPM_BUILD_ROOT"
 465                 did_rmroot=1
 466         }
 467
 468     if (tmpdir) {
 469         buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 470                 gsub(buildroot, "$RPM_BUILD_ROOT")
 471     }
 472
 473     if (!/%{_lib}/) {
 474         sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 475     }
 476
 477         use_macros()
 478
 479         # 'install -d' instead 'mkdir -p'
 480         if (/mkdir -p/)
 481                 sub(/mkdir -p/, "install -d")
 482
 483         # cp -a already implies cp -r
 484     sub(/^cp -ar/, "cp -a")
 485
 486         # No '-u root' or '-g root' for 'install'
 487         if (/^install/ && /-[ug][ \t]*root/)
 488                 gsub(/-[ug][ \t]*root /, "")
 489
 490         if (/^install/ && /-m[ \t]*[0-9]+/)
 491                 gsub(/-m[ \t]*[0-9]+ /, "")
 492
 493         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 494         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 495                 next
 496
 497         # No lines contain 'chmod' if it sets the modes to '644'
 498         if ($1 ~ /chmod/ && $2 ~ /644/)
 499                 next
 500
 501         # atrpms
 502         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 503 }
 504
 505 ##########
 506 # %files #
 507 ##########
 508 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 509         preamble = 0
 510         did_files = 1
 511
 512         if ($0 ~ /^%files/)
 513                 defattr = 1
 514
 515         use_files_macros()
 516 }
 517
 518 ##############
 519 # %changelog #
 520 ##############
 521 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 522         preamble = 0
 523         has_changelog = 1
 524         skip = 0
 525         # There should be some CVS keywords on the first line of %changelog.
 526         if (boc == 3) {
 527                 if ($0 !~ _cvsmailfeedback)
 528                         print "* %{date} " _cvsmailfeedback > changelog_file
 529                 else
 530                         skip = 1
 531                 boc = 2
 532         }
 533         if (boc == 2 && !skip) {
 534                 if (!/All persons listed below/) {
 535                         printf "All persons listed below can be reached at " > changelog_file
 536                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 537                 } else
 538                         skip = 1
 539                 boc = 1
 540         }
 541         if (boc == 1 && !skip) {
 542                 if (!/^$/) {
 543                         if (!/\$.*Log:.*\$/)
 544                                 print "$" "Log:$" > changelog_file
 545                         boc = 0
 546                 }
 547         }
 548         # Define date macro.
 549         if (boc == 4) {
 550                 if (date == 0) {
 551                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 552                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 553                         date = 1
 554                 }
 555                 boc = 3
 556         }
 557
 558         sub(/[ \t]+$/, "")
 559         if (!/^%[a-z]+$/ || /changelog/)
 560                 print > changelog_file
 561         else
 562                 print
 563         next
 564 }
 565
 566 ###########
 567 # SCRIPTS #
 568 ###########
 569 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 570         preamble = 0
 571
 572         if (gsub("/usr/sbin/useradd", "%useradd")) {
 573                 sub(" 2> /dev/null \|\| :", "");
 574                 sub(" >/dev/null 2>&1 \|\|:", "");
 575         }
 576
 577         # %useradd and %groupadd may not be wrapped
 578         if (/%(useradd|groupadd).*\\$/) {
 579                 a = $0; getline;
 580                 sub(/^[\s\t]*/, "");
 581                 $0 = substr(a, 1, length(a) - 1) $0;
 582         }
 583         use_script_macros()
 584 }
 585
 586 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 587         preamble = 0
 588         use_macros()
 589 }
 590 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 591         preamble = 0
 592         use_script_macros()
 593 }
 594 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 595         preamble = 0
 596         use_script_macros()
 597 }
 598 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 599         preamble = 0
 600         use_script_macros()
 601 }
 602 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 603         preamble = 0
 604         use_script_macros()
 605 }
 606 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 607         preamble = 0
 608         use_script_macros()
 609 }
 610 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 611         preamble = 0
 612         use_script_macros()
 613 }
 614 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 615         preamble = 0
 616         use_script_macros()
 617 }
 618 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 619         preamble = 0
 620         use_script_macros()
 621 }
 622 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 623         preamble = 0
 624         use_script_macros()
 625 }
 626
 627 #############
 628 # PREAMBLES #
 629 #############
 630 preamble == 1 {
 631         # There should not be a space after the name of field
 632         # and before the colon.
 633         sub(/[ \t]*:/, ":")
 634
 635         if (/^%perl_module_wo_prefix/) {
 636                 name = $2
 637                 version = $3
 638                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 639         }
 640
 641         field = tolower($1)
 642         fieldnlower = $1
 643         if (field ~ /summary:/ && !/etc\.$/) {
 644                 sub(/\.$/, "", $0);
 645         }
 646         if (field ~ /group(\([^)]+\)):/)
 647                 next
 648         if (field ~ /group:/) {
 649                 format_preamble()
 650                 group = $0;
 651                 sub(/^[^ \t]*[ \t]*/, "", group);
 652
 653                 sub(/^Utilities\//,"Applications/", group)
 654                 sub(/^Games/,"Applications/Games", group)
 655                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 656                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 657                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 658                 sub(/^X11\/GNOME/,"X11/Applications", group)
 659                 sub(/^X11\/Utilities/,"X11/Applications", group)
 660                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 661                 sub(/^X11\/Library/,"X11/Libraries", group)
 662                 sub(/^Shells/,"Applications/Shells", group)
 663                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 664                 sub(/^Library\/Development$/, "Development/Libraries", group)
 665                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 666                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 667                 sub(/^Applications\/Daemons$/, "Daemons", group)
 668                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 669                 sub(/^System\/Servers$/, "Daemons", group)
 670                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 671                 sub(/^X11\/XFree86/, "X11", group)
 672                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 673                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 674                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 675                 sub(/^Development\/Docs$/, "Documentation", group)
 676                 sub(/^Development\/Documentation$/, "Documentation", group)
 677                 sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
 678                 sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
 679                 sub(/^Development\/Java/, "Development/Languages/Java", group)
 680                 sub(/^Development\/Testing$/, "Development", group)
 681                 sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
 682                 sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
 683                 sub(/^Web\/Database$/, "Applications/WWW", group)
 684                 sub(/^System Environment\/Base$/, "Base", group)
 685
 686                 $0 = "Group:\t\t" group
 687
 688                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 689                         x11 = 1
 690
 691                 byl_plik_z_groupmi = 0
 692                 byl_opis_grupy = 0
 693                 while ((getline linia_grup < groups_file) > 0) {
 694                         byl_plik_z_groupmi = 1
 695                         if (linia_grup == group) {
 696                                 byl_opis_grupy = 1
 697                                 break
 698                         }
 699                 }
 700
 701                 if (!byl_plik_z_groupmi)
 702                         print "######\t\t" groups_file ": no such file"
 703                 else if (!byl_opis_grupy)
 704                         print "######\t\t" "Unknown group!"
 705
 706                 close(groups_file)
 707                 did_groups = 1
 708         }
 709
 710         if (field ~ /prereq:/) {
 711                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 712         }
 713
 714         # split (build)requires, obsoletes on commas
 715         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 716                 value = substr($0, index($0, $2));
 717                 $0 = format_requires($1, value);
 718         }
 719
 720         # BR: tar (and others) is to common (rpm-build requires it)
 721         if (field ~ /^buildrequires:/) {
 722                 l = substr($0, index($0, $2));
 723                 if (l == "awk" ||
 724                         l == "binutils" ||
 725                         l == "bzip2" ||
 726                         l == "cpio" ||
 727                         l == "diffutils" ||
 728                         l == "elfutils" ||
 729                         l == "fileutils" ||
 730                         l == "findutils" ||
 731                         l == "glibc-devel" ||
 732                         l == "grep" ||
 733                         l == "gzip" ||
 734                         l == "make" ||
 735                         l == "patch" ||
 736                         l == "sed" ||
 737                         l == "sh-utils" ||
 738                         l == "tar" ||
 739                         l == "textutils") {
 740                         next
 741                 }
 742
 743         # perhaps we have common known name?
 744
 745         # jpackages
 746                 sub(/^java-devel$/, "jdk", $2);
 747                 sub(/^log4j$/, "jakarta-log4j", $2);
 748                 sub(/^oro$/, "jakarta-oro", $2);
 749                 sub(/^xerces-j2$/, "xerces-j", $2);
 750                 sub(/^ant-junit$/, "jakarta-ant", $2);
 751                 sub(/^ldapjdk$/, "ldapsdk", $2);
 752                 sub(/^saxon-scripts$/, "saxon", $2);
 753         }
 754
 755         # obsolete/unwanted tags
 756         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 757                 next
 758         }
 759
 760         if (field ~ /buildroot:/) {
 761                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 762                 did_build_root = 1
 763         }
 764
 765         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 766         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 767                 $1 = "License:"
 768         }
 769
 770         if (field ~ /license:/) {
 771                 l = substr($0, index($0, $2));
 772                 if (l == "Python Software Foundation License") {
 773                         l = "PSF"
 774                 }
 775                 $0 = "License:\t" l;
 776         }
 777
 778
 779         if (field ~ /name:/) {
 780                 if ($2 == "%{name}" && name) {
 781                         $2 = name
 782                 }
 783                 name = $2
 784                 name_seen = 1;
 785         }
 786
 787         if (field ~ /version:/) {
 788                 if ($2 == "%{version}" && version) {
 789                         $2 = version
 790                 }
 791                 version = $2
 792                 version_seen = 1;
 793         }
 794
 795         if (field ~ /release:/) {
 796                 if ($2 == "%{release}" && release) {
 797                         $2 = release
 798                 }
 799                 sub(/%atrelease /, "0.", $0)
 800                 release = $2
 801                 release_seen = 1;
 802         }
 803
 804
 805         if (field ~ /serial:/)
 806                 $1 = "Epoch:"
 807
 808         if (field ~ /home-page:/)
 809                 $1 = "URL:"
 810
 811         # proper caps
 812         if (field ~ /^url:$/)
 813                 $1 = "URL:"
 814
 815         if (field ~ /^description:$/)
 816                 $1 = "\n%description\n"
 817
 818         # Use %{name} and %{version} in the filenames in "Source:"
 819         if (field ~ /^source/ || field ~ /patch/) {
 820                 n = split($2, url, /\//)
 821                 if (url[n] ~ /\.gz$/) {
 822                         url[n+1] = ".gz" url[n+1]
 823                         sub(/\.gz$/,"",url[n])
 824                 }
 825                 if (url[n] ~ /\.zip$/) {
 826                         url[n+1] = ".zip" url[n+1]
 827                         sub(/\.zip$/,"",url[n])
 828                 }
 829                 if (url[n] ~ /\.tar$/) {
 830                         url[n+1] = ".tar" url[n+1]
 831                         sub(/\.tar$/,"",url[n])
 832                 }
 833                 if (url[n] ~ /\.patch$/) {
 834                         url[n+1] = ".patch" url[n+1]
 835                         sub(/\.patch$/,"",url[n])
 836                 }
 837                 if (url[n] ~ /\.bz2$/) {
 838                         url[n+1] = ".bz2" url[n+1]
 839                         sub(/\.bz2$/,"",url[n])
 840                 }
 841                 if (url[n] ~ /\.logrotate$/) {
 842                         url[n+1] = ".logrotate" url[n+1]
 843                         sub(/\.logrotate$/,"",url[n])
 844                 }
 845                 if (url[n] ~ /\.pamd$/) {
 846                         url[n+1] = ".pamd" url[n+1]
 847                         sub(/\.pamd$/,"",url[n])
 848                 }
 849
 850                 # allow %{name} only in last url component
 851                 s = ""
 852                 for (i = 1; i <= n; i++) {
 853                         url[i] = fixedsub("%{name}", name, url[i])
 854                         if (s) {
 855                                 s = s "/" url[i]
 856                         } else {
 857                                 s = url[i]
 858                         }
 859                 }
 860                 $2 = s url[n+1]
 861
 862                 filename = url[n]
 863                 if (name) {
 864                         url[n] = fixedsub(name, "%{name}", url[n])
 865                 }
 866                 if (field ~ /source/) {
 867                         if (version) {
 868                                 url[n] = fixedsub(version, "%{version}", url[n])
 869                         }
 870                         if (_beta) {
 871                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 872                         }
 873                         if (_rc) {
 874                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 875                         }
 876                         if (_pre) {
 877                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 878                         }
 879                         if (_snap) {
 880                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 881                         }
 882                 }
 883                 # assigning to $2 kills preamble formatting
 884                 $2 = fixedsub(filename, url[n], $2)
 885
 886                 # sourceforge urls
 887                 sub("[?]use_mirror=.*$", "", $2);
 888                 sub("[?]download$", "", $2);
 889                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 890                 sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", $2)
 891
 892                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 893                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 894                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 895         }
 896
 897
 898         if (field ~ /^source:/)
 899                 $1 = "Source0:"
 900
 901         if (field ~ /^patch:/)
 902                 $1 = "Patch0:"
 903
 904         kill_preamble_macros();
 905         format_preamble()
 906
 907         if (field ~ /requires/) {
 908                 # atrpms
 909                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 910         }
 911 }
 912
 913 /^%bcond_/ {
 914         # do nothing
 915         print
 916         next
 917 }
 918
 919 # sort BR/R!
 920 #
 921 # NOTES:
 922 # - mixing BR/R and anything else confuses this (all will be sorted together)
 923 #   so don't do that.
 924 # - comments leading the BR/R can not be associated,
 925 #   so don't adapterize when the BR/R are mixed with comments
 926 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 927         if ($1 ~ /Pre[Rr]eq:/) {
 928                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 929         }
 930         format_preamble()
 931 #       kill_preamble_macros(); # breaks tabbing
 932
 933         b_idx++;
 934         l = substr($0, index($0, $2));
 935         b_ktmp = b_makekey($1, l);
 936         b_key[b_idx] = b_ktmp;
 937         b_val[b_ktmp] = $0;
 938
 939         next;
 940 }
 941
 942 preamble == 1 {
 943         if (b_idx > 0) {
 944                 isort(b_key, b_idx);
 945                 for (i = 1; i <= b_idx; i++) {
 946                         v = b_val[b_key[i]];
 947                         sub(/[ \t]+$/, "", v);
 948                         print "" v;
 949                 }
 950                 b_idx = 0
 951         }
 952 }
 953
 954 # main() ;-)
 955 {
 956         preamble = 1
 957
 958         sub(/[ \t]+$/, "")
 959         print
 960
 961         if (name_seen == 0 && name) {
 962                 print "Name:\t\t" name
 963                 name_seen = 1
 964         }
 965
 966         if (version_seen == 0 && version) {
 967                 print "Version:\t" version
 968                 version_seen = 1
 969         }
 970
 971         if (release_seen == 0 && release) {
 972                 print "Release:\t" release
 973                 release_seen = 1
 974         }
 975
 976         if (did_build_root == 0) {
 977 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 978                 did_build_root = 1
 979         }
 980         if (did_groups == 0) {
 981 #               print "Group:\t\tunknown"
 982                 did_groups = 1
 983         }
 984 }
 985
 986
 987 END {
 988         if (do_not_touch_anything)
 989                 exit 0
 990
 991     # TODO: need to output these in proper place
 992     if (BR_count > 0) {
 993         for (i = 0; i <= BR_count; i++) {
 994             print BR[i];
 995         }
 996     }
 997
 998         close(changelog_file)
 999         while ((getline < changelog_file) > 0)
1000                 print
1001         system("rm -f " changelog_file)
1002
1003         if (did_clean == 0) {
1004                 print ""
1005                 print "%clean"
1006                 print "rm -rf $RPM_BUILD_ROOT"
1007         }
1008
1009         if (date == 0) {
1010                 print ""
1011                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1012         }
1013
1014         if (has_changelog == 0) {
1015                 print "%changelog"
1016     }
1017
1018         if (boc > 2) {
1019                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1020     }
1021         if (boc > 1) {
1022                 printf "All persons listed below can be reached at "
1023                 print "<cvs_login>@pld-linux.org\n"
1024         }
1025         if (boc > 0) {
1026                 print "$" "Log:$"
1027     }
1028 }
1029
1030 function fixedsub(s1,s2,t, ind) {
1031 # substitutes fixed strings (not regexps)
1032         if (ind = index(t,s1))
1033                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1034         return t
1035 }
1036
1037 # There should be one or two tabs after the colon.
1038 function format_preamble()
1039 {
1040         if (/^#/ || /^%bcond_with/) {
1041                 return;
1042         }
1043         sub(/:[ \t]*/, ":")
1044         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
1045                 if (RLENGTH < 8)
1046                         sub(/:/, ":\t\t")
1047                 else
1048                         sub(/:/, ":\t")
1049         }
1050 }
1051
1052 # Replace directly specified directories with macros
1053 function use_macros()
1054 {
1055         # -m, --skip-macros, --no-macros -- skip macros subst
1056         if (ENVIRON["SKIP_MACROS"]) {
1057                 return
1058         }
1059
1060         # leave inline sed lines alone
1061         if (/(%{__sed}|sed) -i -e/) {
1062                 return;
1063         }
1064
1065     sub("%{_defaultdocdir}", "%{_docdir}");
1066     sub("%{_bindir}/perl", "%{__perl}");
1067     sub("%{_bindir}/python", "%{__python}");
1068
1069         gsub(perl_sitearch, "%{perl_sitearch}")
1070         gsub(perl_archlib, "%{perl_archlib}")
1071         gsub(perl_privlib, "%{perl_privlib}")
1072         gsub(perl_vendorlib, "%{perl_vendorlib}")
1073         gsub(perl_vendorarch, "%{perl_vendorarch}")
1074         gsub(perl_sitelib, "%{perl_sitelib}")
1075
1076         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1077         gsub(py_sitedir, "%{py_sitedir}")
1078         gsub(py_scriptdir, "%{py_scriptdir}")
1079         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1080         gsub("%{python_sitelib}", "%{py_sitedir}")
1081
1082         gsub(ruby_archdir, "%{ruby_archdir}")
1083         gsub(ruby_ridir, "%{ruby_ridir}")
1084         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1085         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1086         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1087
1088         gsub("%{_datadir}/applications", "%{_desktopdir}")
1089         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1090
1091         gsub(bindir, "%{_bindir}")
1092         gsub("%{prefix}/bin", "%{_bindir}")
1093         if (prefix"/bin" == bindir)
1094                 gsub("%{_prefix}/bin", "%{_bindir}")
1095
1096         for (c = 1; c <= NF; c++) {
1097                 if ($c ~ sbindir "/fix-info-dir")
1098                         continue;
1099                 if ($c ~ sbindir "/webapp")
1100                         continue;
1101                 if ($c ~ sbindir "/chsh")
1102                         continue;
1103                 if ($c ~ sbindir "/usermod")
1104                         continue;
1105                 if ($c ~ sbindir "/chkconfig")
1106                         continue;
1107                 if ($c ~ sbindir "/installzope(product|3package)")
1108                         continue;
1109                 gsub(sbindir, "%{_sbindir}", $c)
1110         }
1111
1112         gsub("%{prefix}/sbin", "%{_sbindir}")
1113         if (prefix"/sbin" == sbindir) {
1114                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1115         }
1116
1117         for (c = 1; c <= NF; c++) {
1118                 if ($c ~ sysconfdir "/{?cron.")
1119                         continue;
1120                 if ($c ~ sysconfdir "/{?crontab.d")
1121                         continue;
1122                 if ($c ~ sysconfdir "/{?env.d")
1123                         continue;
1124                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1125                         continue;
1126                 if ($c ~ sysconfdir "/{?udev/rules.d")
1127                         continue;
1128                 if ($c ~ sysconfdir "/{?logrotate.d")
1129                         continue;
1130                 if ($c ~ sysconfdir "/{?pam.d")
1131                         continue;
1132                 if ($c ~ sysconfdir "/{?profile.d")
1133                         continue;
1134                 if ($c ~ sysconfdir "/{?rc.d")
1135                         continue;
1136                 if ($c ~ sysconfdir "/{?security")
1137                         continue;
1138                 if ($c ~ sysconfdir "/{?skel")
1139                         continue;
1140                 if ($c ~ sysconfdir "/{?sysconfig")
1141                         continue;
1142                 if ($c ~ sysconfdir "/{?shrc.d")
1143                         continue;
1144                 if ($c ~ sysconfdir "/{?certs")
1145                         continue;
1146                 if ($c ~ sysconfdir "/{?X11")
1147                         continue;
1148                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1149                         continue;
1150                 if ($c ~ sysconfdir "/{?rpm")
1151                         continue;
1152                 if ($c ~ sysconfdir "/{?bash_completion.d")
1153                         continue;
1154                 if ($c ~ sysconfdir "/{?samba")
1155                         continue;
1156                 if ($c ~ sysconfdir "/shells")
1157                         continue;
1158                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1159         }
1160
1161         gsub(docdir, "%{_docdir}")
1162         gsub(php_pear_dir, "%{php_pear_dir}")
1163
1164         for (c = 1; c <= NF; c++) {
1165                 if ($c ~ datadir "/automake")
1166                         continue;
1167                 if ($c ~ datadir "/unsermake")
1168                         continue;
1169                 if ($c ~ datadir "/file/magic.mime")
1170                         continue;
1171                 gsub(datadir, "%{_datadir}", $c)
1172         }
1173
1174         gsub("%{prefix}/share", "%{_datadir}")
1175         if (prefix"/share" == datadir)
1176                 gsub("%{_prefix}/share", "%{_datadir}")
1177
1178         # CFLAGS="-I/usr/include/ncurses is usually correct.
1179         if (!/-I\/usr\/include/) {
1180                 gsub(includedir, "%{_includedir}")
1181         }
1182
1183         gsub("%{prefix}/include", "%{_includedir}")
1184         if (prefix"/include" == includedir) {
1185                 gsub("%{_prefix}/include", "%{_includedir}")
1186         }
1187
1188         gsub(mandir, "%{_mandir}")
1189         if ($0 !~ "%{_datadir}/manual") {
1190                 gsub("%{_datadir}/man", "%{_mandir}")
1191         }
1192         gsub("%{_prefix}/share/man", "%{_mandir}")
1193         gsub("%{prefix}/share/man", "%{_mandir}")
1194         gsub("%{prefix}/man", "%{_mandir}")
1195         gsub("%{_prefix}/man", "%{_mandir}")
1196
1197         gsub(infodir, "%{_infodir}")
1198         gsub("%{prefix}/info", "%{_infodir}")
1199         gsub("%{_prefix}/info", "%{_infodir}")
1200
1201         if (prefix !~ "/X11R6") {
1202                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1203         }
1204
1205         gsub(examplesdir, "%{_examplesdir}")
1206
1207         if (prefix != "/") {
1208                 # leave --with-foo=/usr alone
1209                 if ($0 !~ "--with.*=.*" prefix) {
1210                         for (c = 1; c <= NF; c++) {
1211                                 if ($c ~ prefix "/sbin/fix-info-dir")
1212                                         continue;
1213                                 if ($c ~ prefix "/sbin/webapp")
1214                                         continue;
1215                                 if ($c ~ prefix "/sbin/chsh")
1216                                         continue;
1217                                 if ($c ~ prefix "/sbin/usermod")
1218                                         continue;
1219                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1220                                         continue;
1221                                 if ($c ~ prefix "/share/automake")
1222                                         continue;
1223                                 if ($c ~ prefix "/share/unsermake")
1224                                         continue;
1225                                 if ($c ~ prefix "/lib/sendmail")
1226                                         continue;
1227                                 if ($c ~ prefix "/lib/pkgconfig")
1228                                         continue;
1229
1230                                 # CFLAGS="-I/usr..." is usually correct.
1231                                 if (/-I\/usr/)
1232                                         continue;
1233                                 # same for LDFLAGS="-L/usr..."
1234                                 if (/-L\/usr/)
1235                                         continue;
1236
1237                                 gsub(prefix, "%{_prefix}", $c)
1238                         }
1239                 }
1240                 gsub("%{prefix}", "%{_prefix}")
1241         }
1242
1243         # replace back
1244         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1245         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1246
1247         gsub("%{PACKAGE_VERSION}", "%{version}")
1248         gsub("%{PACKAGE_NAME}", "%{name}")
1249
1250         gsub("^make$", "%{__make}")
1251         gsub("^make ", "%{__make} ")
1252         gsub("^gcc ", "%{__cc} ")
1253
1254         # mandrake specs
1255         gsub("^%make$", "%{__make}")
1256         gsub("^%make ", "%{__make} ")
1257         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1258         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1259         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1260         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1261         gsub("^%{__install}", "install")
1262         gsub("^%{__rm}", "rm")
1263         gsub("%optflags", "%{rpmcflags}")
1264         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1265
1266         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1267         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
1268         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1269         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1270         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1271
1272         # split configure line to multiple lines
1273         if (/%configure / && !/\\$/) {
1274                 $0 = format_configure($0);
1275         }
1276
1277         gsub("%_bindir", "%{_bindir}")
1278         gsub("%_datadir", "%{_datadir}")
1279         gsub("%_iconsdir", "%{_iconsdir}")
1280         gsub("%_sbindir", "%{_sbindir}")
1281         gsub("%_mandir", "%{_mandir}")
1282         gsub("%name", "%{name}")
1283     gsub(/%__rm/, "rm");
1284     gsub(/%__mkdir_p/, "install -d");
1285     gsub(/%__cp/, "cp");
1286     gsub(/%__ln_s/, "ln -s");
1287     gsub(/%__sed/, "%{__sed}");
1288     gsub(/%__cat/, "cat");
1289     gsub(/%__chmod/, "chmod");
1290
1291         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1292         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1293
1294         if (/^ant /) {
1295                 sub(/^ant/, "%ant")
1296         add_br("BuildRequires:  jpackage-utils");
1297         add_br("BuildRequires:  rpmbuild(macros) >= 1.294");
1298     }
1299
1300 }
1301
1302 function format_configure(line,         n, a, s) {
1303         n = split(line, a, / /);
1304         s = a[1] " \\\n";
1305         for (i = 2; i <= n; i++) {
1306                 s = s "\t" a[i] " \\\n"
1307         }
1308         return s
1309 }
1310
1311
1312 # insertion sort of A[1..n]
1313 # copied from mawk manual
1314 function isort(A,n,             i,j,hold) {
1315         for (i = 2; i <= n; i++) {
1316                 hold = A[j = i]
1317                 while (A[j-1] > hold) {
1318                         j-- ; A[j+1] = A[j]
1319                 }
1320                 A[j] = hold
1321         }
1322         # sentinel A[0] = "" will be created if needed
1323 }
1324
1325
1326 function use_files_macros(      i, n, t, a)
1327 {
1328         use_macros()
1329
1330         # skip comments
1331         if (/^#/) {
1332                 return;
1333         }
1334
1335         sub("^%doc %{_mandir}", "%{_mandir}")
1336
1337         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1338         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1339
1340         # uid/gid nobody is not valid in %files
1341         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1342                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1343         }
1344
1345         # s[gu]id programs with globs are evil
1346         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1347                 $0 = $0 " # FIXME no globs for suid/sgid files"
1348         }
1349
1350         # replace back
1351         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1352         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1353         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1354         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1355         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1356         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1357         gsub("%{_sysconfdir}/security", "/etc/security")
1358         gsub("%{_sysconfdir}/skel", "/etc/skel")
1359         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1360         gsub("%{_sysconfdir}/certs", "/etc/certs")
1361         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1362
1363         # /etc/init.d -> /etc/rc.d/init.d
1364         if (!/^\/etc\/init\.d$/) {
1365                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1366         }
1367
1368         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1369                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1370                         $0 = "%attr(754,root,root) " $0
1371                 }
1372                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1373                         gsub("^%attr\\(... *,", "%attr(754,");
1374                 }
1375         }
1376
1377         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1378                 $0 = "%attr(755,root,root) " $0
1379         }
1380
1381         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1382                 $0 = "%attr(755,root,root) " $0
1383         }
1384
1385         # /etc/sysconfig files
1386         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1387         # attr not required, allow default 644 attr
1388         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1389                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1390                         gsub("%config", "%config(noreplace)")
1391                 }
1392
1393                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1394                         $NF = "%config(noreplace) " $NF
1395                 }
1396
1397                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1398                         gsub("^%attr\\(... *,", "%attr(640,");
1399                 }
1400
1401                 if (/\/etc\/sysconfig\// && !/%verify/) {
1402                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1403                 }
1404         }
1405
1406         # kill leading zeros
1407         if (/%attr\(0[1-9]/) {
1408                 gsub("%attr\\(0", "%attr(")
1409         }
1410
1411     # kill default attrs
1412     gsub(/%dir %attr\(755,root,root\)/, "%dir");
1413     if (!/%dir/) {
1414         gsub(/%attr\(644,root,root\) /, "");
1415     }
1416
1417         # sort %verify attrs
1418         if (match($0, /%verify\(not([^)]+)\)/)) {
1419                 t = substr($0, RSTART, RLENGTH)
1420                 # kill commas: %verify(not,md5,size,mtime)
1421                 gsub(/,/, " ", t);
1422
1423                 gsub(/^%verify\(not |\)$/, "", t)
1424                 n = split(t, a, / /)
1425                 isort(a, n)
1426
1427                 s = "%verify(not"
1428                 for (i = 1 ; i <= n; i++) {
1429                         s = s " " a[i]
1430                 }
1431                 s = s ")"
1432
1433                 gsub(/%verify\(not[^)]+\)/, s)
1434         }
1435
1436         if (/%{_mandir}/) {
1437                 gsub("\.gz$", "*")
1438         }
1439
1440         # locale dir and no %lang -> bad
1441         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1442                 $(NF + 1) = "# FIXME consider using %find_lang"
1443         }
1444
1445         # atrpms
1446         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1447         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1448         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1449
1450         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1451         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1452         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1453
1454         gsub("%{_datadir}/applications", "%{_desktopdir}");
1455         gsub("%{_datadir}/icons", "%{_iconsdir}");
1456         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1457 }
1458
1459 function use_script_macros()
1460 {
1461         if (gsub("/sbin/service", "%service")) {
1462                 sub(" >/dev/null 2>&1 \|\|:", "");
1463                 sub(" 2> /dev/null \|\| :", "");
1464         }
1465 }
1466
1467 function fill(ch, n, i) {
1468         for (i = 0; i < n; i++)
1469                 printf("%c", ch)
1470 }
1471
1472 function format_flush(line, indent, newline, word, first_word) {
1473         first_word = 1
1474         if (format_indent == -1)
1475                 newline = ""
1476         else
1477                 newline = fill(" ", format_indent) "- "
1478
1479         while (match(line, /[^\t ]+/)) {
1480                 word = substr(line, RSTART, RLENGTH)
1481                 if (length(newline) + length(word) + 1 > tw) {
1482                         print newline
1483
1484                         if (format_indent == -1)
1485                                 newline = ""
1486                         else
1487                                 newline = fill(" ", format_indent + 2)
1488                         first_word = 1
1489                 }
1490
1491                 if (first_word) {
1492                         newline = newline word
1493                         first_word = 0
1494                 } else
1495                         newline = newline " " word
1496
1497                 line = substr(line, RSTART + RLENGTH)
1498         }
1499         if (newline ~ /[^\t ]/) {
1500                 print newline
1501         }
1502 }
1503
1504 function cflags(var)
1505 {
1506         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1507                 removed[var] = 1
1508                 return 0
1509         }
1510
1511         if (!/!\?debug/)
1512                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1513         return 1
1514 }
1515
1516 function demacroize(str)
1517 {
1518         if (mod_name) {
1519                 sub("%{mod_name}", mod_name, str);
1520         }
1521         if (name) {
1522                 sub("%{name}", name, str);
1523         }
1524         if (version) {
1525                 sub("%{version}", version, str);
1526         }
1527         if (_beta) {
1528                 sub("%{_beta}", _beta, str);
1529         }
1530         if (_rc) {
1531                 sub("%{_rc}", _rc, str);
1532         }
1533         if (_pre) {
1534                 sub("%{_pre}", _pre, str);
1535         }
1536         if (_snap) {
1537                 sub("%{_snap}", _snap, str);
1538         }
1539         return str;
1540 }
1541
1542 function kill_preamble_macros()
1543 {
1544         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1545                 # NB! assigning $2 a value breaks tabbing
1546                 $2 = demacroize($2);
1547                 # unify sourceforge url
1548                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1549         }
1550 }
1551
1552 function get_epoch(pkg, ver,    epoch)
1553 {
1554         return
1555 # should parse the BR lines more adequately:
1556 #       freetype = 2.0.0 -> correct
1557 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1558
1559         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1560         shell | getline epoch;
1561         return epoch;
1562 }
1563
1564 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1565         # skip any formatting for commented out items or some weird macros
1566         if (/^#/ || /%\(/) {
1567                 return tag "\t" value
1568         }
1569         n = split(value, p, / *,? */);
1570         for (i = 1; i <= n; i++) {
1571                 if (p[i+1] ~ /[<=>]/) {
1572                         # add epoch if the version doesn't have it but BuildRequires.txt has
1573                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1574                                 epoch = get_epoch(p[i], p[i+2])
1575                                 if (epoch) {
1576                                         p[i+2] = epoch ":" p[i+2];
1577                                 }
1578                         }
1579                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1580                         i += 2;
1581                 } else {
1582                         deps[ndeps++] = p[i];
1583                 }
1584         }
1585         s = ""
1586         for (i in deps) {
1587                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1588         }
1589         return substr(s, 1, length(s)-1);
1590 }
1591
1592 function use_tabs()
1593 {
1594         # reverse vim: ts=4 sw=4 et
1595         gsub(/    /, "\t");
1596 }
1597
1598 function add_br(br)
1599 {
1600     BR[BR_count++] = br
1601 }
1602
1603 # vim:ts=4:sw=4:et