adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2006 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Micha³ Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Elan Ruusamä¤e <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  21 # - add "-nc" option to skip CVS interaction
  22 # - sort Summary(XX)
  23 # - sort Requires, BuildRequires
  24 # - check if %description (lang=C) contains 8bit
  25 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  26
  27 BEGIN {
  28         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  29         SECTIONS = "^%(" RPM_SECTIONS ")"
  30
  31         PREAMBLE_TAGS = "(Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires)"
  32
  33         preamble = 1            # Is it part of preamble? Default - yes
  34         boc = 4                 # Beginning of %changelog
  35         bod = 0                 # Beginning of %description
  36         tw = 70                 # Descriptions width
  37
  38         b_idx = 0               # index of BR/R arrays
  39
  40         # If variable removed, then 1 (for removing it from export)
  41         removed["LDFLAGS"] = 0
  42         removed["CFLAGS"] = 0
  43         removed["CXXFLAGS"] = 0
  44
  45         # get cvsaddress for changelog section
  46         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  47         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  48         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  49
  50         # If 1, we are inside of comment block (started with /^#%/)
  51         comment_block = 0
  52
  53         # File with rpm groups
  54         "rpm --eval %_sourcedir" | getline groups_file
  55         groups_file = groups_file "/rpm.groups"
  56         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  57         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  58
  59         # Temporary file for changelog section
  60         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  61
  62         # Load rpm macros
  63         "rpm --eval %_prefix"   | getline prefix
  64         "rpm --eval %_bindir"   | getline bindir
  65         "rpm --eval %_sbindir"  | getline sbindir
  66         "rpm --eval %_libdir"   | getline libdir
  67         "rpm --eval %_sysconfdir" | getline sysconfdir
  68         "rpm --eval %_datadir"  | getline datadir
  69         "rpm --eval %_includedir" | getline includedir
  70         "rpm --eval %_mandir"   | getline mandir
  71         "rpm --eval %_infodir"  | getline infodir
  72         "rpm --eval %_examplesdir"      | getline examplesdir
  73         "rpm --eval %_defaultdocdir"    | getline docdir
  74         "rpm --eval %_desktopdir" | getline desktopdir
  75         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  76
  77         "rpm --eval %perl_sitearch" | getline perl_sitearch
  78         "rpm --eval %perl_archlib" | getline perl_archlib
  79         "rpm --eval %perl_privlib" | getline perl_privlib
  80         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  81         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  82         "rpm --eval %perl_sitelib" | getline perl_sitelib
  83
  84         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  85         "rpm --eval %py_sitedir" | getline py_sitedir
  86         "rpm --eval %py_scriptdir " | getline py_scriptdir
  87         "rpm --eval %php_pear_dir" | getline php_pear_dir
  88         "rpm --eval %tmpdir" | getline tmpdir
  89 }
  90
  91 # There should be a comment with CVS keywords on the first line of file.
  92 FNR == 1 {
  93         if (!/# \$Revision:/)   # If this line is already OK?
  94                 print "# $" "Revision:$, " "$" "Date:$" # No
  95         else {
  96                 print $0                                # Yes
  97                 next            # It is enough for first line
  98         }
  99 }
 100
 101 # If the latest line matched /%files/
 102 defattr == 1 {
 103         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 104                 if ($0 !~ /defattr/) {  # If no %defattr
 105                         print "%defattr(644,root,root,755)"     # Add it
 106                 } else {
 107                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 108                 }
 109         }
 110         defattr = 0
 111 }
 112
 113 function b_makekey(a, b,        s) {
 114         s = a "" b;
 115         # kill bcond
 116     gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 117
 118         # kill commented out items
 119     gsub(/^#[ \t]*/, "", s);
 120
 121         # force order
 122     gsub(/^Summary\(/, "11Summary(", s);
 123     gsub(/^Summary/, "10Summary", s);
 124     gsub(/^Name/, "2Name", s);
 125     gsub(/^Version/, "3Version", s);
 126     gsub(/^Release/, "4Release", s);
 127     gsub(/^Epoch/, "5Epoch", s);
 128     gsub(/^License/, "5License", s);
 129     gsub(/^Group/, "6Group", s);
 130     gsub(/^URL/, "7URL", s);
 131
 132     gsub(/^BuildRequires/, "B1BuildRequires", s);
 133     gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 134     gsub(/^Provides/, "X1Provides", s);
 135     gsub(/^Obsoletes/, "X2Obsoletes", s);
 136     gsub(/^Conflicts/, "X3Conflicts", s);
 137     gsub(/^BuildArch/, "X4BuildArch", s);
 138     gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 139     gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 140     gsub(/^BuildRoot/, "X9BuildRoot", s);
 141
 142 #       printf("%s -> %s\n", a""b, s);
 143         return s;
 144 }
 145
 146 # Comments
 147 /^#/ && (description == 0) {
 148         if (/This file does not like to be adapterized!/) {
 149                 print                   # print this message
 150                 while (getline)         # print the rest of spec as it is
 151                         print
 152                 do_not_touch_anything = 1 # do not touch anything in END()
 153                 exit 0
 154         }
 155
 156         # Generally, comments are printed without touching
 157         sub(/[ \t]+$/, "")
 158
 159         if (/Source.*md5/) {
 160                 print $0
 161                 next
 162         }
 163 }
 164
 165 /^%define/ {
 166         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 167         if ($2 == "_applnkdir") {
 168                 next
 169         }
 170         if ($2 == "date") {
 171                 date = 1
 172                 if (did_files == 0) {
 173                         print "%files"
 174                         print ""
 175                         did_files = 1
 176                 }
 177         }
 178
 179         # Do not add %define of _prefix if it already is.
 180         if ($2 ~ /^_prefix/) {
 181                 sub("^"prefix, $3, bindir)
 182                 sub("^"prefix, $3, sbindir)
 183                 sub("^"prefix, $3, libdir)
 184                 sub("^"prefix, $3, datadir)
 185                 sub("^"prefix, $3, includedir)
 186                 prefix = $3
 187         }
 188
 189         if ($2 ~ /_bindir/ && !/_sbindir/)
 190                 bindir = $3
 191         if ($2 ~ /_sbindir/)
 192                 sbindir = $3
 193         if ($2 ~ /_libdir/) {
 194                 if ($3 ~ /^%\(/) {
 195                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 196                         libdir = "%%%%%%%%%%%%%%"
 197                 } else {
 198                         libdir = $3
 199                 }
 200         }
 201         if ($2 ~ /_sysconfdir/) {
 202                 if ($3 ~ /^%\(/) {
 203                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 204                         sysconfdir = "%%%%%%%%%%%%%%"
 205                 } else {
 206                         sysconfdir = $3
 207                 }
 208         }
 209         if ($2 ~ /_datadir/) {
 210                 if ($3 ~ /^%\(/) {
 211                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 212                         datadir = "%%%%%%%%%%%%%%"
 213                 } else {
 214                         datadir = $3
 215                 }
 216         }
 217         if ($2 ~ /_includedir/)
 218                 includedir = $3
 219         if ($2 ~ /_mandir/)
 220                 mandir = $3
 221         if ($2 ~ /_infodir/)
 222                 infodir = $3
 223         if ($2 ~ /_docdir/)
 224                 docdir = $3
 225
 226         # version related macros
 227         if ($2 ~ /^_beta$/)
 228                 _beta = $3
 229         if ($2 ~ /^_rc$/)
 230                 _rc = $3
 231         if ($2 ~ /^_pre$/)
 232                 _pre = $3
 233         if ($2 ~ /^_snap$/)
 234                 _snap = $3
 235
 236         # these are used usually when adapterizing external spec
 237         if ($2 ~ /^name$/)
 238                 name = $3
 239         if ($2 ~ /^version$/)
 240                 version = $3
 241         if ($2 ~ /^release$/)
 242                 release = $3
 243
 244         if ($2 ~ /^mod_name$/)
 245                 mod_name = $3
 246
 247         sub(/[ \t]+$/, "");
 248         # do nothing further, otherwise adapter thinks we're at preamble
 249         print
 250         next
 251 }
 252
 253 # Obsolete
 254 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 255         next
 256 }
 257
 258 ################
 259 # %description #
 260 ################
 261 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 262         preamble = 0
 263
 264         if (/^%description/) {
 265                 bod++
 266                 format_line = ""
 267                 format_indent = -1
 268         }
 269
 270         # Format description
 271         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 272                 if (/^[ \t]*$/) {
 273                         format_flush(format_line, format_indent)
 274                         print ""
 275                         format_line = ""
 276                         format_indent = -1
 277                 } else if (/^[ \t]*[-\*][ \t]*/) {
 278                         format_flush(format_line, format_indent)
 279                         match($0, /^[ \t]*/)
 280                         format_indent = RLENGTH
 281                         match($0, /^[ \t]*[-\*][ \t]/)
 282                         format_line = substr($0, RLENGTH)
 283                 } else
 284                         format_line = format_line " " $0
 285                 next
 286         }
 287
 288         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 289                 if (NF > 3 && $2 == "-l") {
 290                         ll = $1
 291                         for (i = 4; i <= NF; i++)
 292                                 ll = ll " " $i
 293                         $0 = ll " -l " $3
 294                 }
 295                 format_flush(format_line, format_indent)
 296                 if (bod == 2) {
 297                         bod = 1
 298                         description = 1
 299                 } else {
 300                         bod = 0
 301                         description = 0
 302                 }
 303         } else
 304                 description = 1
 305 }
 306
 307 #########
 308 # %prep #
 309 #########
 310 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 311         preamble = 0
 312         did_prep = 1
 313
 314         use_macros()
 315
 316         # Add '-q' to %setup
 317         if (/^%setup/ && !/-q/) {
 318                 sub(/^%setup/, "%setup -q")
 319         }
 320
 321         if (/^%setup/) {
 322                 $0 = fixedsub(name, "%{name}", $0);
 323                 $0 = fixedsub(version, "%{version}", $0);
 324                 if (_beta) {
 325                         $0 = fixedsub(_beta, "%{_beta}", $0);
 326                 }
 327                 if (_rc) {
 328                         $0 = fixedsub(_rc, "%{_rc}", $0);
 329                 }
 330                 if (_pre) {
 331                         $0 = fixedsub(_pre, "%{_pre}", $0);
 332                 }
 333                 if (_snap) {
 334                         $0 = fixedsub(_snap, "%{_snap}", $0);
 335                 }
 336         }
 337
 338         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 339                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 340         }
 341
 342         # invalid in %prep
 343         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 344 }
 345
 346 ##########
 347 # %build #
 348 ##########
 349 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 350         preamble = 0
 351
 352         if (did_prep == 0) {
 353                 print "%prep"
 354                 print ""
 355                 did_prep = 1
 356         }
 357
 358         use_macros()
 359         use_tabs()
 360
 361         if (/^automake$/)
 362                 sub(/$/, " -a -c")
 363
 364         if (/LDFLAGS/) {
 365                 if (/LDFLAGS="-s"/) {
 366                         removed["LDFLAGS"] = 1
 367                         next
 368                 } else {
 369                         split($0, tmp, "LDFLAGS=")
 370                         count = split(tmp[2], flags, "\"")
 371                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 372                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 373                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 374                                 for (i = 2; i < count; i++)
 375                                         $0 = $0 flags[i] "\""
 376                         }
 377                 }
 378         }
 379
 380         if (/CFLAGS=/)
 381                 if (cflags("CFLAGS") == 0)
 382                         next
 383
 384         if (/CXXFLAGS=/)
 385                 if (cflags("CXXFLAGS") == 0)
 386                         next
 387
 388         if (/^export /) {
 389                 if (removed["LDFLAGS"])
 390                         sub(" LDFLAGS", "")
 391                 if (removed["CFLAGS"])
 392                         sub(" CFLAGS", "")
 393                 if (removed["CXXFLAGS"])
 394                         sub(" CXXFLAGS", "")
 395                 # Is there still something?
 396                 if (/^export[ ]*$/)
 397                         next
 398         }
 399
 400         # quote CC
 401         if (/CC=%{__cc} /) {
 402                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 403         }
 404
 405         # use PLD Linux macros
 406         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 407         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 408         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 409         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 410         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 411         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 412         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 413
 414         sub(/^aclocal$/, "%{__aclocal}");
 415         sub(/^autoheader$/, "%{__autoheader}");
 416         sub(/^autoconf$/, "%{__autoconf}");
 417         sub(/^automake$/, "%{__automake}");
 418
 419         # atrpms
 420         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 421         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 422 }
 423
 424 ##########
 425 # %clean #
 426 ##########
 427 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 428         did_clean = 1
 429
 430         # prevent next section header like "%post -p /sbin/ldconfig" being adapterized
 431         if (!/^%post/) {
 432                 use_macros()
 433         }
 434 }
 435
 436 ############
 437 # %install #
 438 ############
 439 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 440
 441         preamble = 0
 442
 443         # foreign rpms
 444         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 445     sub("%buildroot", "$RPM_BUILD_ROOT");
 446     sub("%{buildroot}", "$RPM_BUILD_ROOT");
 447
 448         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 449                 did_rmroot=1
 450                 print "rm -rf $RPM_BUILD_ROOT"
 451                 next
 452         }
 453
 454         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 455                 print "rm -rf $RPM_BUILD_ROOT"
 456                 did_rmroot=1
 457         }
 458
 459     if (tmpdir) {
 460         buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 461                 gsub(buildroot, "$RPM_BUILD_ROOT")
 462     }
 463
 464     if (!/%{_lib}/) {
 465         sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 466     }
 467
 468         use_macros()
 469
 470         # 'install -d' instead 'mkdir -p'
 471         if (/mkdir -p/)
 472                 sub(/mkdir -p/, "install -d")
 473
 474         # 'install' instead 'cp -p'
 475         if (/cp -p\b/)
 476                 sub(/cp -p/, "install")
 477
 478         # No '-u root' or '-g root' for 'install'
 479         if (/^install/ && /-[ug][ \t]*root/)
 480                 gsub(/-[ug][ \t]*root /, "")
 481
 482         if (/^install/ && /-m[ \t]*[0-9]+/)
 483                 gsub(/-m[ \t]*[0-9]+ /, "")
 484
 485         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 486         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 487                 next
 488
 489         # No lines contain 'chmod' if it sets the modes to '644'
 490         if ($1 ~ /chmod/ && $2 ~ /644/)
 491                 next
 492
 493         # atrpms
 494         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 495 }
 496
 497 ##########
 498 # %files #
 499 ##########
 500 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 501         preamble = 0
 502         did_files = 1
 503
 504         if ($0 ~ /^%files/)
 505                 defattr = 1
 506
 507         use_files_macros()
 508 }
 509
 510 ##############
 511 # %changelog #
 512 ##############
 513 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 514         preamble = 0
 515         has_changelog = 1
 516         skip = 0
 517         # There should be some CVS keywords on the first line of %changelog.
 518         if (boc == 3) {
 519                 if ($0 !~ _cvsmailfeedback)
 520                         print "* %{date} " _cvsmailfeedback > changelog_file
 521                 else
 522                         skip = 1
 523                 boc = 2
 524         }
 525         if (boc == 2 && !skip) {
 526                 if (!/All persons listed below/) {
 527                         printf "All persons listed below can be reached at " > changelog_file
 528                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 529                 } else
 530                         skip = 1
 531                 boc = 1
 532         }
 533         if (boc == 1 && !skip) {
 534                 if (!/^$/) {
 535                         if (!/\$.*Log:.*\$/)
 536                                 print "$" "Log:$" > changelog_file
 537                         boc = 0
 538                 }
 539         }
 540         # Define date macro.
 541         if (boc == 4) {
 542                 if (date == 0) {
 543                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 544                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 545                         date = 1
 546                 }
 547                 boc = 3
 548         }
 549
 550         sub(/[ \t]+$/, "")
 551         if (!/^%[a-z]+$/ || /changelog/)
 552                 print > changelog_file
 553         else
 554                 print
 555         next
 556 }
 557
 558 ###########
 559 # SCRIPTS #
 560 ###########
 561 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 562         preamble = 0
 563
 564         if (gsub("/usr/sbin/useradd", "%useradd")) {
 565                 sub(" 2> /dev/null \|\| :", "");
 566                 sub(" >/dev/null 2>&1 \|\|:", "");
 567         }
 568
 569         # %useradd and %groupadd may not be wrapped
 570         if (/%(useradd|groupadd).*\\$/) {
 571                 a = $0; getline;
 572                 sub(/^[\s\t]*/, "");
 573                 $0 = substr(a, 1, length(a) - 1) $0;
 574         }
 575         use_script_macros()
 576 }
 577
 578 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 579         preamble = 0
 580         use_macros()
 581 }
 582 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 583         preamble = 0
 584         use_script_macros()
 585 }
 586 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 587         preamble = 0
 588         use_script_macros()
 589 }
 590 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 591         preamble = 0
 592         use_script_macros()
 593 }
 594 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 595         preamble = 0
 596         use_script_macros()
 597 }
 598 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 599         preamble = 0
 600         use_script_macros()
 601 }
 602 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 603         preamble = 0
 604         use_script_macros()
 605 }
 606 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 607         preamble = 0
 608         use_script_macros()
 609 }
 610 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 611         preamble = 0
 612         use_script_macros()
 613 }
 614 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 615         preamble = 0
 616         use_script_macros()
 617 }
 618
 619 #############
 620 # PREAMBLES #
 621 #############
 622 preamble == 1 {
 623         # There should not be a space after the name of field
 624         # and before the colon.
 625         sub(/[ \t]*:/, ":")
 626
 627         if (/^%perl_module_wo_prefix/) {
 628                 name = $2
 629                 version = $3
 630                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 631         }
 632
 633         field = tolower($1)
 634         fieldnlower = $1
 635         if (field ~ /summary:/ && !/etc\.$/) {
 636                 sub(/\.$/, "", $0);
 637         }
 638         if (field ~ /group(\([^)]+\)):/)
 639                 next
 640         if (field ~ /group:/) {
 641                 format_preamble()
 642                 group = $0;
 643                 sub(/^[^ \t]*[ \t]*/, "", group);
 644
 645                 sub(/^Utilities\//,"Applications/", group)
 646                 sub(/^Games/,"Applications/Games", group)
 647                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 648                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 649                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 650                 sub(/^X11\/GNOME/,"X11/Applications", group)
 651                 sub(/^X11\/Utilities/,"X11/Applications", group)
 652                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 653                 sub(/^X11\/Library/,"X11/Libraries", group)
 654                 sub(/^Shells/,"Applications/Shells", group)
 655                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 656                 sub(/^Library\/Development$/, "Development/Libraries", group)
 657                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 658                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 659                 sub(/^Applications\/Daemons$/, "Daemons", group)
 660                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 661                 sub(/^System\/Servers$/, "Daemons", group)
 662                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 663                 sub(/^X11\/XFree86/, "X11", group)
 664                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 665                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 666                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 667                 sub(/^Development\/Docs$/, "Documentation", group)
 668                 sub(/^Development\/Documentation$/, "Documentation", group)
 669                 sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
 670                 sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
 671                 sub(/^Development\/Java/, "Development/Languages/Java", group)
 672                 sub(/^Development\/Testing$/, "Development", group)
 673                 sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
 674                 sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
 675                 sub(/^Web\/Database$/, "Applications/WWW", group)
 676                 sub(/^System Environment\/Base$/, "Base", group)
 677
 678                 $0 = "Group:\t\t" group
 679
 680                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 681                         x11 = 1
 682
 683                 byl_plik_z_groupmi = 0
 684                 byl_opis_grupy = 0
 685                 while ((getline linia_grup < groups_file) > 0) {
 686                         byl_plik_z_groupmi = 1
 687                         if (linia_grup == group) {
 688                                 byl_opis_grupy = 1
 689                                 break
 690                         }
 691                 }
 692
 693                 if (!byl_plik_z_groupmi)
 694                         print "######\t\t" groups_file ": no such file"
 695                 else if (!byl_opis_grupy)
 696                         print "######\t\t" "Unknown group!"
 697
 698                 close(groups_file)
 699                 did_groups = 1
 700         }
 701
 702         if (field ~ /prereq:/) {
 703                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 704         }
 705
 706         # split (build)requires, obsoletes on commas
 707         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 708                 value = substr($0, index($0, $2));
 709                 $0 = format_requires($1, value);
 710         }
 711
 712         # BR: tar (and others) is to common (rpm-build requires it)
 713         if (field ~ /^buildrequires:/) {
 714                 l = substr($0, index($0, $2));
 715                 if (l == "awk" ||
 716                         l == "binutils" ||
 717                         l == "bzip2" ||
 718                         l == "cpio" ||
 719                         l == "diffutils" ||
 720                         l == "elfutils" ||
 721                         l == "fileutils" ||
 722                         l == "findutils" ||
 723                         l == "glibc-devel" ||
 724                         l == "grep" ||
 725                         l == "gzip" ||
 726                         l == "make" ||
 727                         l == "patch" ||
 728                         l == "sed" ||
 729                         l == "sh-utils" ||
 730                         l == "tar" ||
 731                         l == "textutils") {
 732                         next
 733                 }
 734
 735         # perhaps we have common known name?
 736
 737         # jpackages
 738                 sub(/^java-devel$/, "jdk", $2);
 739                 sub(/^log4j$/, "jakarta-log4j", $2);
 740                 sub(/^oro$/, "jakarta-oro", $2);
 741                 sub(/^xerces-j2$/, "xerces-j", $2);
 742                 sub(/^ant-junit$/, "jakarta-ant", $2);
 743                 sub(/^ldapjdk$/, "ldapsdk", $2);
 744                 sub(/^saxon-scripts$/, "saxon", $2);
 745         }
 746
 747         # obsolete/unwanted tags
 748         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 749                 next
 750         }
 751
 752         if (field ~ /buildroot:/) {
 753                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 754                 did_build_root = 1
 755         }
 756
 757         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 758         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 759                 $1 = "License:"
 760         }
 761
 762         if (field ~ /license:/) {
 763                 l = substr($0, index($0, $2));
 764                 if (l == "Python Software Foundation License") {
 765                         l = "PSF"
 766                 }
 767                 $0 = "License:\t" l;
 768         }
 769
 770
 771         if (field ~ /name:/) {
 772                 if ($2 == "%{name}" && name) {
 773                         $2 = name
 774                 }
 775                 name = $2
 776                 name_seen = 1;
 777         }
 778
 779         if (field ~ /version:/) {
 780                 if ($2 == "%{version}" && version) {
 781                         $2 = version
 782                 }
 783                 version = $2
 784                 version_seen = 1;
 785         }
 786
 787         if (field ~ /release:/) {
 788                 if ($2 == "%{release}" && release) {
 789                         $2 = release
 790                 }
 791                 sub(/%atrelease /, "0.", $0)
 792                 release = $2
 793                 release_seen = 1;
 794         }
 795
 796
 797         if (field ~ /serial:/)
 798                 $1 = "Epoch:"
 799
 800         if (field ~ /home-page:/)
 801                 $1 = "URL:"
 802
 803         # proper caps
 804         if (field ~ /^url:$/)
 805                 $1 = "URL:"
 806
 807         if (field ~ /^description:$/)
 808                 $1 = "\n%description\n"
 809
 810         # Use %{name} and %{version} in the filenames in "Source:"
 811         if (field ~ /^source/ || field ~ /patch/) {
 812                 n = split($2, url, /\//)
 813                 if (url[n] ~ /\.gz$/) {
 814                         url[n+1] = ".gz" url[n+1]
 815                         sub(/\.gz$/,"",url[n])
 816                 }
 817                 if (url[n] ~ /\.zip$/) {
 818                         url[n+1] = ".zip" url[n+1]
 819                         sub(/\.zip$/,"",url[n])
 820                 }
 821                 if (url[n] ~ /\.tar$/) {
 822                         url[n+1] = ".tar" url[n+1]
 823                         sub(/\.tar$/,"",url[n])
 824                 }
 825                 if (url[n] ~ /\.patch$/) {
 826                         url[n+1] = ".patch" url[n+1]
 827                         sub(/\.patch$/,"",url[n])
 828                 }
 829                 if (url[n] ~ /\.bz2$/) {
 830                         url[n+1] = ".bz2" url[n+1]
 831                         sub(/\.bz2$/,"",url[n])
 832                 }
 833                 if (url[n] ~ /\.logrotate$/) {
 834                         url[n+1] = ".logrotate" url[n+1]
 835                         sub(/\.logrotate$/,"",url[n])
 836                 }
 837                 if (url[n] ~ /\.pamd$/) {
 838                         url[n+1] = ".pamd" url[n+1]
 839                         sub(/\.pamd$/,"",url[n])
 840                 }
 841
 842                 # allow %{name} only in last url component
 843                 s = ""
 844                 for (i = 1; i <= n; i++) {
 845                         url[i] = fixedsub("%{name}", name, url[i])
 846                         if (s) {
 847                                 s = s "/" url[i]
 848                         } else {
 849                                 s = url[i]
 850                         }
 851                 }
 852                 $2 = s url[n+1]
 853
 854                 filename = url[n]
 855                 if (name) {
 856                         url[n] = fixedsub(name, "%{name}", url[n])
 857                 }
 858                 if (field ~ /source/) {
 859                         if (version) {
 860                                 url[n] = fixedsub(version, "%{version}", url[n])
 861                         }
 862                         if (_beta) {
 863                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 864                         }
 865                         if (_rc) {
 866                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 867                         }
 868                         if (_pre) {
 869                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 870                         }
 871                         if (_snap) {
 872                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 873                         }
 874                 }
 875                 # assigning to $2 kills preamble formatting
 876                 $2 = fixedsub(filename, url[n], $2)
 877
 878                 # sourceforge urls
 879                 sub("[?]use_mirror=.*$", "", $2);
 880                 sub("[?]download$", "", $2);
 881                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 882                 sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", $2)
 883
 884                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 885                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 886                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 887         }
 888
 889
 890         if (field ~ /^source:/)
 891                 $1 = "Source0:"
 892
 893         if (field ~ /^patch:/)
 894                 $1 = "Patch0:"
 895
 896         kill_preamble_macros();
 897         format_preamble()
 898
 899         if (field ~ /requires/) {
 900                 # atrpms
 901                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 902         }
 903 }
 904
 905 /^%bcond_/ {
 906         # do nothing
 907         print
 908         next
 909 }
 910
 911 # sort BR/R!
 912 #
 913 # NOTES:
 914 # - mixing BR/R and anything else confuses this (all will be sorted together)
 915 #   so don't do that.
 916 # - comments leading the BR/R can not be associated,
 917 #   so don't adapterize when the BR/R are mixed with comments
 918 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 919         if ($1 ~ /Pre[Rr]eq:/) {
 920                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 921         }
 922         format_preamble()
 923 #       kill_preamble_macros(); # breaks tabbing
 924
 925         b_idx++;
 926         l = substr($0, index($0, $2));
 927         b_ktmp = b_makekey($1, l);
 928         b_key[b_idx] = b_ktmp;
 929         b_val[b_ktmp] = $0;
 930
 931         next;
 932 }
 933
 934 preamble == 1 {
 935         if (b_idx > 0) {
 936                 isort(b_key, b_idx);
 937                 for (i = 1; i <= b_idx; i++) {
 938                         v = b_val[b_key[i]];
 939                         sub(/[ \t]+$/, "", v);
 940                         print "" v;
 941                 }
 942                 b_idx = 0
 943         }
 944 }
 945
 946 # main() ;-)
 947 {
 948         preamble = 1
 949
 950         sub(/[ \t]+$/, "")
 951         print
 952
 953         if (name_seen == 0 && name) {
 954                 print "Name:\t\t" name
 955                 name_seen = 1
 956         }
 957
 958         if (version_seen == 0 && version) {
 959                 print "Version:\t" version
 960                 version_seen = 1
 961         }
 962
 963         if (release_seen == 0 && release) {
 964                 print "Release:\t" release
 965                 release_seen = 1
 966         }
 967
 968         if (did_build_root == 0) {
 969 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 970                 did_build_root = 1
 971         }
 972         if (did_groups == 0) {
 973 #               print "Group:\t\tunknown"
 974                 did_groups = 1
 975         }
 976 }
 977
 978
 979 END {
 980         if (do_not_touch_anything)
 981                 exit 0
 982
 983         close(changelog_file)
 984         while ((getline < changelog_file) > 0)
 985                 print
 986         system("rm -f " changelog_file)
 987
 988         if (did_clean == 0) {
 989                 print ""
 990                 print "%clean"
 991                 print "rm -rf $RPM_BUILD_ROOT"
 992         }
 993
 994         if (date == 0) {
 995                 print ""
 996                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 997         }
 998
 999         if (has_changelog == 0)
1000                 print "%changelog"
1001
1002         if (boc > 2)
1003                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1004         if (boc > 1) {
1005                 printf "All persons listed below can be reached at "
1006                 print "<cvs_login>@pld-linux.org\n"
1007         }
1008         if (boc > 0)
1009                 print "$" "Log:$"
1010 }
1011
1012 function fixedsub(s1,s2,t, ind) {
1013 # substitutes fixed strings (not regexps)
1014         if (ind = index(t,s1))
1015                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1016         return t
1017 }
1018
1019 # There should be one or two tabs after the colon.
1020 function format_preamble()
1021 {
1022         if (/^#/ || /^%bcond_with/) {
1023                 return;
1024         }
1025         sub(/:[ \t]*/, ":")
1026         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
1027                 if (RLENGTH < 8)
1028                         sub(/:/, ":\t\t")
1029                 else
1030                         sub(/:/, ":\t")
1031         }
1032 }
1033
1034 # Replace directly specified directories with macros
1035 function use_macros()
1036 {
1037         # -m, --skip-macros, --no-macros -- skip macros subst
1038         if (ENVIRON["SKIP_MACROS"]) {
1039                 return
1040         }
1041
1042         # leave inline sed lines alone
1043         if (/(%{__sed}|sed) -i -e/) {
1044                 return;
1045         }
1046
1047         gsub(perl_sitearch, "%{perl_sitearch}")
1048         gsub(perl_archlib, "%{perl_archlib}")
1049         gsub(perl_privlib, "%{perl_privlib}")
1050         gsub(perl_vendorlib, "%{perl_vendorlib}")
1051         gsub(perl_vendorarch, "%{perl_vendorarch}")
1052         gsub(perl_sitelib, "%{perl_sitelib}")
1053
1054         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1055         gsub(py_sitedir, "%{py_sitedir}")
1056         gsub(py_scriptdir, "%{py_scriptdir}")
1057         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1058         gsub("%{python_sitelib}", "%{py_sitedir}")
1059         gsub("%{_datadir}/applications", "%{_desktopdir}")
1060         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1061
1062         gsub(bindir, "%{_bindir}")
1063         gsub("%{prefix}/bin", "%{_bindir}")
1064         if (prefix"/bin" == bindir)
1065                 gsub("%{_prefix}/bin", "%{_bindir}")
1066
1067         for (c = 1; c <= NF; c++) {
1068                 if ($c ~ sbindir "/fix-info-dir")
1069                         continue;
1070                 if ($c ~ sbindir "/webapp")
1071                         continue;
1072                 if ($c ~ sbindir "/chsh")
1073                         continue;
1074                 if ($c ~ sbindir "/usermod")
1075                         continue;
1076                 if ($c ~ sbindir "/chkconfig")
1077                         continue;
1078                 if ($c ~ sbindir "/installzope(product|3package)")
1079                         continue;
1080                 gsub(sbindir, "%{_sbindir}", $c)
1081         }
1082
1083         gsub("%{prefix}/sbin", "%{_sbindir}")
1084         if (prefix"/sbin" == sbindir) {
1085                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1086         }
1087
1088         for (c = 1; c <= NF; c++) {
1089                 if ($c ~ sysconfdir "/{?cron.")
1090                         continue;
1091                 if ($c ~ sysconfdir "/{?crontab.d")
1092                         continue;
1093                 if ($c ~ sysconfdir "/{?env.d")
1094                         continue;
1095                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1096                         continue;
1097                 if ($c ~ sysconfdir "/{?udev/rules.d")
1098                         continue;
1099                 if ($c ~ sysconfdir "/{?logrotate.d")
1100                         continue;
1101                 if ($c ~ sysconfdir "/{?pam.d")
1102                         continue;
1103                 if ($c ~ sysconfdir "/{?profile.d")
1104                         continue;
1105                 if ($c ~ sysconfdir "/{?rc.d")
1106                         continue;
1107                 if ($c ~ sysconfdir "/{?security")
1108                         continue;
1109                 if ($c ~ sysconfdir "/{?skel")
1110                         continue;
1111                 if ($c ~ sysconfdir "/{?sysconfig")
1112                         continue;
1113                 if ($c ~ sysconfdir "/{?shrc.d")
1114                         continue;
1115                 if ($c ~ sysconfdir "/{?certs")
1116                         continue;
1117                 if ($c ~ sysconfdir "/{?X11")
1118                         continue;
1119                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1120                         continue;
1121                 if ($c ~ sysconfdir "/{?rpm")
1122                         continue;
1123                 if ($c ~ sysconfdir "/{?bash_completion.d")
1124                         continue;
1125                 if ($c ~ sysconfdir "/{?samba")
1126                         continue;
1127                 if ($c ~ sysconfdir "/shells")
1128                         continue;
1129                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1130         }
1131
1132         gsub(docdir, "%{_docdir}")
1133         gsub(php_pear_dir, "%{php_pear_dir}")
1134
1135         for (c = 1; c <= NF; c++) {
1136                 if ($c ~ datadir "/automake")
1137                         continue;
1138                 if ($c ~ datadir "/unsermake")
1139                         continue;
1140                 if ($c ~ datadir "/file/magic.mime")
1141                         continue;
1142                 gsub(datadir, "%{_datadir}", $c)
1143         }
1144
1145         gsub("%{prefix}/share", "%{_datadir}")
1146         if (prefix"/share" == datadir)
1147                 gsub("%{_prefix}/share", "%{_datadir}")
1148
1149         # CFLAGS="-I/usr/include/ncurses is usually correct.
1150         if (!/-I\/usr\/include/) {
1151                 gsub(includedir, "%{_includedir}")
1152         }
1153
1154         gsub("%{prefix}/include", "%{_includedir}")
1155         if (prefix"/include" == includedir) {
1156                 gsub("%{_prefix}/include", "%{_includedir}")
1157         }
1158
1159         gsub(mandir, "%{_mandir}")
1160         if ($0 !~ "%{_datadir}/manual") {
1161                 gsub("%{_datadir}/man", "%{_mandir}")
1162         }
1163         gsub("%{_prefix}/share/man", "%{_mandir}")
1164         gsub("%{prefix}/share/man", "%{_mandir}")
1165         gsub("%{prefix}/man", "%{_mandir}")
1166         gsub("%{_prefix}/man", "%{_mandir}")
1167
1168         gsub(infodir, "%{_infodir}")
1169         gsub("%{prefix}/info", "%{_infodir}")
1170         gsub("%{_prefix}/info", "%{_infodir}")
1171
1172         if (prefix !~ "/X11R6") {
1173                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1174         }
1175
1176         gsub(examplesdir, "%{_examplesdir}")
1177
1178         if (prefix != "/") {
1179                 # leave --with-foo=/usr alone
1180                 if ($0 !~ "--with.*=.*" prefix) {
1181                         for (c = 1; c <= NF; c++) {
1182                                 if ($c ~ prefix "/sbin/fix-info-dir")
1183                                         continue;
1184                                 if ($c ~ prefix "/sbin/webapp")
1185                                         continue;
1186                                 if ($c ~ prefix "/sbin/chsh")
1187                                         continue;
1188                                 if ($c ~ prefix "/sbin/usermod")
1189                                         continue;
1190                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1191                                         continue;
1192                                 if ($c ~ prefix "/share/automake")
1193                                         continue;
1194                                 if ($c ~ prefix "/share/unsermake")
1195                                         continue;
1196                                 if ($c ~ prefix "/lib/sendmail")
1197                                         continue;
1198                                 if ($c ~ prefix "/lib/pkgconfig")
1199                                         continue;
1200
1201                                 # CFLAGS="-I/usr..." is usually correct.
1202                                 if (/-I\/usr/)
1203                                         continue;
1204                                 # same for LDFLAGS="-L/usr..."
1205                                 if (/-L\/usr/)
1206                                         continue;
1207
1208                                 gsub(prefix, "%{_prefix}", $c)
1209                         }
1210                 }
1211                 gsub("%{prefix}", "%{_prefix}")
1212         }
1213
1214         # replace back
1215         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1216         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1217
1218         gsub("%{PACKAGE_VERSION}", "%{version}")
1219         gsub("%{PACKAGE_NAME}", "%{name}")
1220
1221         gsub("^make$", "%{__make}")
1222         gsub("^make ", "%{__make} ")
1223         gsub("^gcc ", "%{__cc} ")
1224
1225         # mandrake specs
1226         gsub("^%make$", "%{__make}")
1227         gsub("^%make ", "%{__make} ")
1228         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1229         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1230         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1231         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1232         gsub("^%{__install}", "install")
1233         gsub("^%{__rm}", "rm")
1234         gsub("%optflags", "%{rpmcflags}")
1235         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1236
1237         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1238         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
1239         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1240         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1241         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1242
1243         # split configure line to multiple lines
1244         if (/%configure / && !/\\$/) {
1245                 $0 = format_configure($0);
1246         }
1247
1248         gsub("%_bindir", "%{_bindir}")
1249         gsub("%_datadir", "%{_datadir}")
1250         gsub("%_iconsdir", "%{_iconsdir}")
1251         gsub("%_sbindir", "%{_sbindir}")
1252         gsub("%_mandir", "%{_mandir}")
1253         gsub("%name", "%{name}")
1254     gsub(/%ant/, "ant")
1255     gsub(/%__rm/, "rm");
1256     gsub(/%__mkdir_p/, "install -d");
1257     gsub(/%__cp/, "cp");
1258     gsub(/%__ln_s/, "ln -s");
1259     gsub(/%__sed/, "%{__sed}");
1260     gsub(/%__cat/, "cat");
1261     gsub(/%__chmod/, "chmod");
1262
1263         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1264         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1265 }
1266
1267 function format_configure(line,         n, a, s) {
1268         n = split(line, a, / /);
1269         s = a[1] " \\\n";
1270         for (i = 2; i <= n; i++) {
1271                 s = s "\t" a[i] " \\\n"
1272         }
1273         return s
1274 }
1275
1276
1277 # insertion sort of A[1..n]
1278 # copied from mawk manual
1279 function isort(A,n,             i,j,hold) {
1280         for (i = 2; i <= n; i++) {
1281                 hold = A[j = i]
1282                 while (A[j-1] > hold) {
1283                         j-- ; A[j+1] = A[j]
1284                 }
1285                 A[j] = hold
1286         }
1287         # sentinel A[0] = "" will be created if needed
1288 }
1289
1290
1291 function use_files_macros(      i, n, t, a)
1292 {
1293         use_macros()
1294
1295         # skip comments
1296         if (/^#/) {
1297                 return;
1298         }
1299
1300         sub("^%doc %{_mandir}", "%{_mandir}")
1301
1302         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1303         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1304
1305         # uid/gid nobody is not valid in %files
1306         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1307                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1308         }
1309
1310         # s[gu]id programs with globs are evil
1311         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1312                 $0 = $0 " # FIXME no globs for suid/sgid files"
1313         }
1314
1315         # replace back
1316         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1317         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1318         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1319         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1320         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1321         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1322         gsub("%{_sysconfdir}/security", "/etc/security")
1323         gsub("%{_sysconfdir}/skel", "/etc/skel")
1324         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1325         gsub("%{_sysconfdir}/certs", "/etc/certs")
1326         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1327
1328         # /etc/init.d -> /etc/rc.d/init.d
1329         if (!/^\/etc\/init\.d$/) {
1330                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1331         }
1332
1333         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1334                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1335                         $0 = "%attr(754,root,root) " $0
1336                 }
1337                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1338                         gsub("^%attr\\(... *,", "%attr(754,");
1339                 }
1340         }
1341
1342         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1343                 $0 = "%attr(755,root,root) " $0
1344         }
1345
1346         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1347                 $0 = "%attr(755,root,root) " $0
1348         }
1349
1350         # /etc/sysconfig files
1351         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1352         # attr not required, allow default 644 attr
1353         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1354                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace\)/) {
1355                         gsub("%config", "%config(noreplace)")
1356                 }
1357
1358                 if (/\/etc\/sysconfig\// && !/%config\(noreplace\)/) {
1359                         $NF = "%config(noreplace) " $NF
1360                 }
1361
1362                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1363                         gsub("^%attr\\(... *,", "%attr(640,");
1364                 }
1365
1366                 if (/\/etc\/sysconfig\// && !/%verify/) {
1367                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1368                 }
1369         }
1370
1371         # kill leading zeros
1372         if (/%attr\(0[1-9]/) {
1373                 gsub("%attr\\(0", "%attr(")
1374         }
1375
1376     # kill default attrs
1377     gsub(/%dir %attr\(755,root,root\)/, "%dir");
1378     if (!/%dir/) {
1379         gsub(/%attr\(644,root,root\) /, "");
1380     }
1381
1382         # sort %verify attrs
1383         if (match($0, /%verify\(not([^)]+)\)/)) {
1384                 t = substr($0, RSTART, RLENGTH)
1385                 # kill commas: %verify(not,md5,size,mtime)
1386                 gsub(/,/, " ", t);
1387
1388                 gsub(/^%verify\(not |\)$/, "", t)
1389                 n = split(t, a, / /)
1390                 isort(a, n)
1391
1392                 s = "%verify(not"
1393                 for (i = 1 ; i <= n; i++) {
1394                         s = s " " a[i]
1395                 }
1396                 s = s ")"
1397
1398                 gsub(/%verify\(not[^)]+\)/, s)
1399         }
1400
1401         if (/%{_mandir}/) {
1402                 gsub("\.gz$", "*")
1403         }
1404
1405         # locale dir and no %lang -> bad
1406         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1407                 $(NF + 1) = "# FIXME consider using %find_lang"
1408         }
1409
1410         # atrpms
1411         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1412         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1413         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1414
1415         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1416         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1417         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1418
1419         gsub("%{_datadir}/applications", "%{_desktopdir}");
1420         gsub("%{_datadir}/icons", "%{_iconsdir}");
1421         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1422 }
1423
1424 function use_script_macros()
1425 {
1426         if (gsub("/sbin/service", "%service")) {
1427                 sub(" >/dev/null 2>&1 \|\|:", "");
1428                 sub(" 2> /dev/null \|\| :", "");
1429         }
1430 }
1431
1432 function fill(ch, n, i) {
1433         for (i = 0; i < n; i++)
1434                 printf("%c", ch)
1435 }
1436
1437 function format_flush(line, indent, newline, word, first_word) {
1438         first_word = 1
1439         if (format_indent == -1)
1440                 newline = ""
1441         else
1442                 newline = fill(" ", format_indent) "- "
1443
1444         while (match(line, /[^\t ]+/)) {
1445                 word = substr(line, RSTART, RLENGTH)
1446                 if (length(newline) + length(word) + 1 > tw) {
1447                         print newline
1448
1449                         if (format_indent == -1)
1450                                 newline = ""
1451                         else
1452                                 newline = fill(" ", format_indent + 2)
1453                         first_word = 1
1454                 }
1455
1456                 if (first_word) {
1457                         newline = newline word
1458                         first_word = 0
1459                 } else
1460                         newline = newline " " word
1461
1462                 line = substr(line, RSTART + RLENGTH)
1463         }
1464         if (newline ~ /[^\t ]/) {
1465                 print newline
1466         }
1467 }
1468
1469 function cflags(var)
1470 {
1471         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1472                 removed[var] = 1
1473                 return 0
1474         }
1475
1476         if (!/!\?debug/)
1477                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1478         return 1
1479 }
1480
1481 function demacroize(str)
1482 {
1483         if (mod_name) {
1484                 sub("%{mod_name}", mod_name, str);
1485         }
1486         if (name) {
1487                 sub("%{name}", name, str);
1488         }
1489         if (version) {
1490                 sub("%{version}", version, str);
1491         }
1492         if (_beta) {
1493                 sub("%{_beta}", _beta, str);
1494         }
1495         if (_rc) {
1496                 sub("%{_rc}", _rc, str);
1497         }
1498         if (_pre) {
1499                 sub("%{_pre}", _pre, str);
1500         }
1501         if (_snap) {
1502                 sub("%{_snap}", _snap, str);
1503         }
1504         return str;
1505 }
1506
1507 function kill_preamble_macros()
1508 {
1509         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1510                 # NB! assigning $2 a value breaks tabbing
1511                 $2 = demacroize($2);
1512                 # unify sourceforge url
1513                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1514         }
1515 }
1516
1517 function get_epoch(pkg, ver,    epoch)
1518 {
1519         return
1520 # should parse the BR lines more adequately:
1521 #       freetype = 2.0.0 -> correct
1522 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1523
1524         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1525         shell | getline epoch;
1526         return epoch;
1527 }
1528
1529 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1530         # skip any formatting for commented out items or some weird macros
1531         if (/^#/ || /%\(/) {
1532                 return tag "\t" value
1533         }
1534         n = split(value, p, / *,? */);
1535         for (i = 1; i <= n; i++) {
1536                 if (p[i+1] ~ /[<=>]/) {
1537                         # add epoch if the version doesn't have it but BuildRequires.txt has
1538                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1539                                 epoch = get_epoch(p[i], p[i+2])
1540                                 if (epoch) {
1541                                         p[i+2] = epoch ":" p[i+2];
1542                                 }
1543                         }
1544                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1545                         i += 2;
1546                 } else {
1547                         deps[ndeps++] = p[i];
1548                 }
1549         }
1550         s = ""
1551         for (i in deps) {
1552                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1553         }
1554         return substr(s, 1, length(s)-1);
1555 }
1556
1557 function use_tabs()
1558 {
1559         # reverse vim: ts=4 sw=4 et
1560         gsub(/    /, "\t");
1561 }