]>
Commit | Line | Data |
---|---|---|
1 | # $Id$ | |
2 | # A script for building kernel config from multiarch config file. | |
3 | # It also has some file merging facilities. | |
4 | # | |
5 | # usage: | |
6 | # awk -v basearch=%{_target_base_arch} -v arch=%{_target_cpu} -f path/to/kernel-config.awk \ | |
7 | # kernel-important.config kernel-multiarch.config \ | |
8 | # kernel-%{arch}.config kernel-%{some_feature}.config \ | |
9 | # > .config | |
10 | # | |
11 | # Authors: | |
12 | # - Przemysław Iskra <sparky@pld-linux.org> | |
13 | # parts based on kernel-config.py, by: | |
14 | # - arekm@pld-linux.org | |
15 | # - glen@pld-linux.org | |
16 | # | |
17 | # TODO: | |
18 | # - use as many warnings as possible, we want our configs to be clean | |
19 | ||
20 | # no: | |
21 | # CONFIG_SOMETHING=n | |
22 | # SOMETHING=n | |
23 | # CONFIG_SOMETHING all=n | |
24 | # SOMETHING all=n | |
25 | # # CONFIG_SOMETHING is not set -- special case | |
26 | ||
27 | # yes/module/other | |
28 | # CONFIG_SOMETHING=y | |
29 | # SOMETHING=y | |
30 | # CONFIG_SOMETHING all=y | |
31 | # SOMETHING all=y | |
32 | ||
33 | ||
34 | # return actual file name (without path) and line number | |
35 | function fileLine() { | |
36 | f = FILENAME | |
37 | sub( /^.*\//, "", f ) # strip path | |
38 | ||
39 | return f " (" FNR ")" | |
40 | } | |
41 | ||
42 | function warn( msg ) { | |
43 | print fileLine() ": " msg > "/dev/stderr" | |
44 | } | |
45 | ||
46 | BEGIN { | |
47 | if ( ! arch ) { | |
48 | print "arch= must be specified" > "/dev/stderr" | |
49 | exit 1 | |
50 | } | |
51 | if ( ! basearch ) | |
52 | basearch = arch | |
53 | ||
54 | targetLevel[ "all" ] = 1 | |
55 | targetLevel[ basearch ] = 2 | |
56 | targetLevel[ arch ] = 3 | |
57 | ||
58 | shouldDie = 0 | |
59 | } | |
60 | ||
61 | function dieLater( code ) { | |
62 | if ( shouldDie < code ) | |
63 | shouldDie = code | |
64 | } | |
65 | ||
66 | # convert special case: | |
67 | # # CONFIG_SOMETHING it not set | |
68 | # to: | |
69 | # SOMETHING all=n | |
70 | /^# CONFIG_[A-Za-z0-9_]+ is not set$/ { | |
71 | match( $0, /CONFIG_[A-Za-z0-9_]+/ ) | |
72 | option = substr( $0, RSTART, RLENGTH) | |
73 | $0 = option " all=n" | |
74 | } | |
75 | ||
76 | # ignore all the comments and empty lines | |
77 | /^#/ || /^\s*$/ { | |
78 | next | |
79 | } | |
80 | ||
81 | !/^CONFIG_/ { | |
82 | $0 = "CONFIG_" $0 | |
83 | } | |
84 | ||
85 | { | |
86 | option = $1 | |
87 | line = $0 | |
88 | value = "" | |
89 | if ( option ~ /=/ ) { | |
90 | sub( /=.*$/, "", option ) | |
91 | sub( /^[^=]*=/, "", line ) | |
92 | value = line | |
93 | } else { | |
94 | sub( "^" option, "", line ) | |
95 | sub( /^[ \t]*/, "", line ) | |
96 | ||
97 | if ( line ~ /"/ ) { | |
98 | # there can be white spaces | |
99 | i = 0 | |
100 | while ( match( line, /^[^=]+="([^"]|\\")*"/ ) ) { | |
101 | archs[ (++i) ] = substr( line, RSTART, RLENGTH ) | |
102 | line = substr( line, RSTART + RLENGTH ) | |
103 | sub( /^[ \t]*/, "", line ) | |
104 | } | |
105 | } else { | |
106 | split( line, archs ) | |
107 | } | |
108 | ||
109 | level = 0 | |
110 | for ( i in archs ) { | |
111 | arch = val = archs[ i ] | |
112 | sub( /=.*$/, "", arch ) | |
113 | sub( /^[^=]*=/, "", val ) | |
114 | tl = targetLevel[ arch ] | |
115 | if ( tl > level ) { | |
116 | value = val | |
117 | level = tl | |
118 | } | |
119 | } | |
120 | } | |
121 | ||
122 | # completely ignore lines with no value | |
123 | if ( length( value ) == 0 ) | |
124 | next | |
125 | ||
126 | fileOption = FILENAME "/" option | |
127 | if ( fileOption in outputByFile ) { | |
128 | warn( "ERROR: " option " already defined in this file at line " outputByFile[ fileOption ] ) | |
129 | dieLater( 2 ) | |
130 | next | |
131 | } else | |
132 | outputByFile[ fileOption ] = FNR | |
133 | ||
134 | if ( option in outputArray ) { | |
135 | warn( "Warning: " option " already defined in: " outputArray[ option ] ) | |
136 | next | |
137 | } else | |
138 | outputArray[ option ] = fileLine() | |
139 | ||
140 | if ( value == "n" ) | |
141 | out = "# " option " is not set" | |
142 | else { | |
143 | out = option "=" value | |
144 | ||
145 | if ( value == "y" || value == "m" ) | |
146 | ; # OK | |
147 | else if ( value ~ /^"([^"]|\\")*"$/ ) | |
148 | ; # OK | |
149 | else if ( value ~ /^-?[0-9]+$/ || value ~ /^0x[0-9A-Fa-f]+$/ ) | |
150 | ; # OK | |
151 | else { | |
152 | warn( "ERROR: Incorrect value: " $0 ) | |
153 | dieLater( 1 ) | |
154 | } | |
155 | } | |
156 | ||
157 | print out | |
158 | } | |
159 | ||
160 | END { | |
161 | exit shouldDie | |
162 | } |