spec.vim

   1 " Filename:    spec.vim
   2 " Purpose:     Vim syntax file
   3 " Language:    SPEC: Build/install scripts for PLD Linux RPM packages
   4 " Maintainer:  PLD Linux <feedback@pld-linux.org>
   5 " URL:         http://www.pld-linux.org/
   6 " Last Change: $Date$ (UTC)
   7 " Version:     $Revision$
   8
   9 " For version 5.x: Clear all syntax items
  10 " For version 6.x: Quit when a syntax file was already loaded
  11 if version < 600
  12   syntax clear
  13 elseif exists("b:current_syntax")
  14   finish
  15 endif
  16
  17 syn sync minlines=1000
  18
  19 syn match specSpecialChar contained '[][!$()\\|>^;:]'
  20 syn match specColon       contained ':'
  21 syn match specPercent     contained '%'
  22 syn match specSubstChar   contained '[#%]'
  23
  24 syn match specVariables   contained '\$\h\w*' contains=specSpecialVariablesNames,specSpecialChar
  25 syn match specVariables   contained '\${\w*}' contains=specSpecialVariablesNames,specSpecialChar
  26 syn match specVariables   contained '\${\w*[#%][^}]*}' contains=specSubstChar
  27
  28 syn match specMacroIdentifier contained '%\h\w*' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  29 syn region specMacroIdentifier oneline matchgroup=Special start='%{' skip='\\}' end='}' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  30 syn match specBcond contained '%{with\(out\)\?\s\+[a-zA-Z0-9_-]\+}'
  31
  32 syn match specSpecialVariables contained '\$[0-9]\|\${[0-9]}'
  33 syn match specCommandOpts      contained '\s\(-\w\+\|--\w[a-zA-Z0-9_-]\+\)'ms=s+1
  34 syn match specComment '^\s*#.*$'
  35
  36 syn case match
  37
  38 " matches with no highlight
  39 syn match specNoNumberHilite 'X11\|X11R6\|[a-zA-Z]*\.\d\|[a-zA-Z][-/]\d'
  40 syn match specManpageFile '[a-zA-Z]\.1'
  41
  42 " Day, Month and most used license acronyms
  43 syn keyword specLicense contained GPL LGPL BSD MIT GNU Apache PHP
  44 syn keyword specLicenseWarning contained unknown
  45 syn match specLicenseWarning contained /same as perl/
  46 syn match specLicenseWarning contained "(enter GPL/LGPL/BSD/BSD-like/Artistic/other license name here)"
  47 syn keyword specWeekday contained Mon Tue Wed Thu Fri Sat Sun
  48 syn keyword specMonth   contained Jan Feb Mar Apr Jun Jul Aug Sep Oct Nov Dec
  49 syn keyword specMonth   contained January February March April May June July August September October November December
  50
  51 " #, @, www
  52 syn match specNumber '\(^-\=\|[ \t]-\=\|-\)[0-9.-]*[0-9]'
  53 syn match specEmail contained "<\=\<[A-Za-z0-9_.-]\+@\([A-Za-z0-9_-]\+\.\)\+[A-Za-z]\+\>>\="
  54 syn match specURL      contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#?=-]\+\>'
  55 syn match specURLMacro contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#%{}-]\+\>' contains=specMacroIdentifier
  56
  57 " TODO take specSpecialVariables out of the cluster for the sh* contains (ALLBUT)
  58 " Special system directories
  59 syn match specListedFilesPrefix contained '/\(usr\|local\|opt\|X11R6\|X11\)/'me=e-1
  60 syn match specListedFilesBin    contained '/s\=bin/'me=e-1
  61 syn match specListedFilesLib    contained '/\(lib\|include\)/'me=e-1
  62 syn match specListedFilesDoc    contained '/\(man\d*\|doc\|info\)\>'
  63 syn match specListedFilesEtc    contained '/etc/'me=e-1
  64 syn match specListedFilesShare  contained '/share/'me=e-1
  65 syn cluster specListedFiles contains=specListedFilesBin,specListedFilesLib,specListedFilesDoc,specListedFilesEtc,specListedFilesShare,specListedFilesPrefix,specSpecialChar
  66
  67 " specComands
  68 syn match   specConfigure  contained '\./configure'
  69 syn match   specTarCommand contained '\<tar\s\+[cxvpzjf]\{,5}\s*'
  70
  71 " XXX don't forget to update specScriptArea when updating specMacro
  72 syn match   specMacro contained '%\(group\|user\)\(add\|remove\)'
  73 syn match   specMacro contained '%\(depmod\|banner\|service\|addusertogroup\|env_update\)'
  74 syn match   specMacro contained '%\(\(nsplugin\|apache_config\)_\(un\)\?install\)'
  75 syn match   specMacro contained '%\(\(openldap_schema\|webapp\)_\(un\)\?register\)'
  76 syn match   specMacro contained '%\(pear_package_\(setup\|install\)\)'
  77 syn match   specMacro contained '%\(py_o\?comp\|py_postclean\)'
  78 syn match   specMacro contained '%\(build\|install\)_kernel_modules'
  79 syn match   specMacro contained '%ant'
  80 syn match   specMacro contained '%\(php\|php4\)_webserver_restart'
  81 syn match   specMacro contained '%update_browser_plugins\|%browser_plugins_add_browser'
  82
  83 syn keyword specCommandSpecial contained root
  84 syn keyword specCommand         contained make xmkmf mkdir chmod find sed rm strip moc echo grep ls rm mv mkdir chown install cp pwd cat tail then else elif cd gzip rmdir ln eval export touch unzip bzip2
  85 syn cluster specCommands contains=specCommand,specTarCommand,specConfigure,specCommandSpecial,specMacro
  86
  87 " frequently used rpm env vars
  88 syn keyword specSpecialVariablesNames contained RPM_BUILD_ROOT RPM_BUILD_DIR RPM_SOURCE_DIR RPM_OPT_FLAGS LDFLAGS CC CC_FLAGS CPPNAME CFLAGS CXX CXXFLAGS CPPFLAGS
  89
  90 " valid macro names from /usr/lib/rpm/macros*
  91 syn keyword specMacroNameOther contained ix86 x8664 ppc
  92 syn keyword specMacroNameOther contained buildroot buildsubdir distribution disturl name nil optflags perl_sitearch release requires_eq vendor version
  93 syn keyword specMacroNameOther contained __kernel_ver date debugcflags debuginfocflags epoch kgcc kgcc_package packager
  94 syn keyword specMacroNameOther contained pear_package_install pear_package_setup perl_archlib perl_privlib perl_sitelib
  95 syn keyword specMacroNameOther contained perl_vendorarch perl_vendorlib php_pear_dir php_data_dir py_sitedir py_scriptdir py_sitescriptdir
  96 syn keyword specMacroNameOther contained requires_php_extension requires_php_pdo_module
  97 syn keyword specMacroNameOther contained requires_zend_extension ruby_mod_ver_requires_eq ruby_ver_requires_eq rpmcflags rpmcxxflags rpmldflags tmpdir
  98 syn keyword specMacroNameOther contained ruby_archdir ruby_rubylibdir ruby_vendorarchdir ruby_vendorlibdir ruby_ridir ruby_sitearchdir ruby_sitelibdir ruby_version
  99 syn keyword specMacroNameOther contained apache_modules_api php_sysconfdir php_includedir php_extensiondir _browserpluginsdir _browserpluginsconfdir
 100 syn keyword specMacroNameOther contained releq_kernel releq_kernel_up releq_kernel_smp requires_releq_kernel requires_releq_kernel_up requires_releq_kernel_smp
 101
 102 syn match   specMacroNameOther contained '\<\(PATCH\|SOURCE\)\d*\>'
 103
 104 " valid _macro names from /usr/lib/rpm/macros*
 105 syn keyword specMacroNameLocal contained _aclocaldir _applnkdir _arch _binary_payload _bindir _build _build_arch _build_alias
 106 syn keyword specMacroNameLocal contained _build_cpu _builddir _build_os _buildshell _buildsubdir _build_vendor _bzip2bin _datadir
 107 syn keyword specMacroNameLocal contained _dbpath _dbpath_rebuild _defaultdocdir _desktopdir _docdir _examplesdir _excludedocs _kdedocdir
 108 syn keyword specMacroNameLocal contained _exec_prefix _fixgroup _fixowner _fixperms _fontsdir _ftpport _ftpproxy _gnu _gpg_name
 109 syn keyword specMacroNameLocal contained _gpg_path _gtkdocdir _gzipbin _host _host_alias _host_cpu _host_os _host_vendor
 110 syn keyword specMacroNameLocal contained _httpport _httpproxy _iconsdir _includedir _infodir _initrddir _install_langs
 111 syn keyword specMacroNameLocal contained _install_script_path _instchangelog _javaclasspath _javadir _javadocdir _kernelsrcdir
 112 syn keyword specMacroNameLocal contained _kernel_ver _kernel_ver_str _langpatt _lib _libdir _libexecdir _localstatedir _mandir
 113 syn keyword specMacroNameLocal contained _netsharedpath _oldincludedir _omf_dest_dir _os _package_version _pgpbin _pgp_name
 114 syn keyword specMacroNameLocal contained _pgp_path _pixmapsdir _pkgconfigdir _prefix _preScriptEnvironment _provides _rpmdir
 115 syn keyword specMacroNameLocal contained _rpmfilename _sbindir _sharedstatedir _signature _smp_mflags _sourcedir _source_payload
 116 syn keyword specMacroNameLocal contained _specdir _srcrpmdir _sysconfdir _target _target_alias _target_cpu _target_os _target_platform
 117 syn keyword specMacroNameLocal contained _target_vendor _target_base_arch _timecheck _tmppath _topdir _usr _usrsrc _var _vendor
 118 syn keyword specMacroNameLocal contained __cxx __cc __libtoolize __autopoint __aclocal __autoconf __automake __autoheader
 119 syn keyword specMacroNameLocal contained __gettextize __glib_gettextize __intltoolize
 120 syn keyword specMacroNameLocal contained __bzip2 __cat __chgrp __chmod __chown __cp   __cpio __file __gpg __grep __gzip
 121 syn keyword specMacroNameLocal contained __id  __install __ld   __make   __mkdir __mkdir_p __mv __nm  __objcopy __objdump
 122 syn keyword specMacroNameLocal contained __patch __perl __pgp __python __rm __rsh  __sed __ssh __strip  __tar __unzip
 123
 124
 125
 126 " ------------------------------------------------------------------------------
 127 " here's is all the spec sections definitions: PreAmble, Description, Package,
 128 "   Scripts, Files and Changelog
 129
 130 " One line macros - valid in all ScriptAreas
 131 " tip: remember do include new items on specScriptArea's skip section
 132 syn region specSectionMacroArea oneline matchgroup=specSectionMacro start='^%\(\(un\)\?define\|dump\|trace\|patch\d*\|setup\|configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|scons\|waf\|bcond_with\(out\)\?\|include\)\>' end='$' contains=specCommandOpts,specMacroIdentifier,specSectionMacroBcondArea
 133 syn region specSectionMacroBracketArea oneline matchgroup=specSectionMacro start='^%{\(configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|scons\|waf\)}' end='$' contains=specCommandOpts,specMacroIdentifier
 134 syn region specSectionMacroBcondArea oneline matchgroup=specBlock start='%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):' skip='\\}' end='}' contains=ALL
 135
 136 " %% Files Section %%
 137 " TODO %config valid parameters: missingok\|noreplace
 138 " TODO %verify valid parameters: \(not\)\= \(md5\|atime\|...\)
 139 syn region specFilesArea matchgroup=specSection start="^%files\>"
 140         \ skip="%\(attrib\|defattr\|attr\|dir\|config\|docdir\|doc\|lang\|verify\|ghost\|exclude\|dev\|if\|ifarch\|ifnarch\|else\|endif\)\>"
 141         \ end='^%[a-zA-Z]'me=e-2
 142         \ contains=specFilesOpts,specFilesDirective,@specListedFiles,specComment,specCommandSpecial,specMacroIdentifier,specSectionMacroBcondArea,specIf
 143
 144 " tip: remember to include new items in specFilesArea above
 145 syn match  specFilesDirective contained '%\(dir\|docdir\|doc\|ghost\|exclude\)\>'
 146 syn region specFilesDirective contained start="%\(attrib\|attr\|defattr\|config\|lang\|verify\|dev\)(" end=")" contains=specAttr transparent
 147 syn match  specAttr contained "%\(attrib\|attr\|defattr\|config\|lang\|verify\|dev\)"
 148
 149 " valid options for certain section headers
 150 syn match specDescriptionOpts contained '\s-[ln]\s*\a'ms=s+1,me=e-1
 151 syn match specPackageOpts     contained    '\s-n\s*\w'ms=s+1,me=e-1
 152 syn match specFilesOpts       contained    '\s-f\s*\w'ms=s+1,me=e-1
 153
 154
 155 syn case ignore
 156
 157
 158 " %% PreAmble Section %%
 159 " Copyright and Serial were deprecated by License and Epoch
 160 " PreReq and BuildPreReq deprecated by Requires ans BuildRequires
 161 syn region specPreAmbleDeprecated oneline matchgroup=specError start='^\(Copyright\|Serial\|PreReq\|BuildPreReq\(uires\)\?\)' end='$' contains=specEmail,specURL,specURLMacro,specLicense,specColon,specVariables,specSpecialChar,specMacroIdentifier
 162 syn region specPreAmble oneline matchgroup=specCommand
 163         \ start='\(^\|\(^%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):\)\@<=\)\(Summary\|Name\|Version\|Packager\|Requires\|Suggests\|Icon\|URL\|Source\d*\|Patch\d*\|Prefix\|Packager\|Group\|License\|Release\|BuildRoot\|Distribution\|Vendor\|Provides\|ExclusiveArch\|ExcludeArch\|ExclusiveOS\|Obsoletes\|BuildArch\|BuildArchitectures\|BuildRequires\|BuildConflicts\|Conflicts\|AutoRequires\|AutoReqProv\|AutoReq\|AutoProv\|Epoch\|NoSource\)'
 164         \ end='$\|}\@='
 165         \ contains=specEmail,specURL,specURLMacro,specLicense,specLicenseWarning,specColon,specVariables,specSpecialChar,specMacroIdentifier,specSectionMacroBcondArea
 166
 167 " %% Description Section %%
 168 syn region specDescriptionArea matchgroup=specSection start='^%description' end='^%'me=e-1
 169         \ contains=specDescriptionOpts,specEmail,specURL,specNumber,specMacroIdentifier,specComment
 170
 171 " %% Package Section %%
 172 syn region specPackageArea matchgroup=specSection start='^%package' end='^%'me=e-1
 173         \ contains=specPackageOpts,specPreAmble,specComment,specMacroNameOther
 174
 175 " %% Scripts Section %%
 176 syn region specScriptArea matchgroup=specSection
 177         \ start='^%\(prep\|build\|install\|clean\|pre\|postun\|preun\|post\|triggerin\|triggerun\|triggerpostun\|pretrans\|posttrans\|verifyscript\|check\)\>'
 178         \ skip='^%{\|^%\(define\|patch\d*\|configure2_13\|configure\|ant\|GNUconfigure\|setup\|find_lang\|makeinstall\|cmake\|scons\|waf\|useradd\|groupadd\|addusertogroup\|banner\|service\|env_update\|py_o\?comp\|py_postclean\|\(openldap_schema\|webapp\)_\(un\)\?register\|depmod\|pear_package_\(setup\|install\)\|\(build\|install\)_kernel_modules\|php_webserver_restart\|php4_webserver_restart\|update_browser_plugins\)\>'
 179         \ end='^%'me=e-1
 180         \ contains=specSpecialVariables,specVariables,@specCommands,specVariables,shDo,shFor,shCaseEsac,specNoNumberHilite,specCommandOpts,shComment,shIf,specSpecialChar,specMacroIdentifier,specSectionMacroArea,specSectionMacroBracketArea,shOperator,shQuote1,shQuote2,specSectionMacroBcondArea
 181 " XXX don't forget to update specMacro when updating specScriptArea skip definition
 182
 183 " %% Changelog Section %%
 184 syn region specChangelogArea matchgroup=specSection start='^%changelog' end='^%'me=e-1
 185         \ contains=specEmail,specURL,specWeekday,specMonth,specNumber,specComment,specLicense,specRevision,specLogMessage,specLogError
 186
 187 syn match specRevision contained "^Revision [.0-9]\+  [-/0-9]\+ [:0-9]\+  [a-zA-Z0-9]\+$"
 188 syn region specLogMessage contained start="^[- ] " end="$" contains=specLogError,specURL,specEmail
 189 syn match specLogError contained "%%"
 190
 191 " ------------------------------------------------------------------------------
 192 " here's the shell syntax for all the Script Sections
 193
 194
 195 syn case match
 196
 197
 198 " sh-like comment style, only valid in script part
 199 syn match shComment contained '#.*$'
 200
 201 syn region shQuote1 contained matchgroup=shQuoteDelim start=+'+ skip=+\\'+ end=+'+ contains=specMacroIdentifier
 202 syn region shQuote2 contained matchgroup=shQuoteDelim start=+"+ skip=+\\"+ end=+"+ contains=specVariables,specMacroIdentifier,specSectionMacroBcondArea
 203
 204 syn match shOperator contained '[><|!&;]\|[!=]='
 205 syn region shDo transparent matchgroup=specBlock start="\(^\|\s\)do\(\s\|$\)" end="\(^\|\s\)done\(\s\|$\)" contains=ALLBUT,shDoError,shCase,specPreAmble,@specListedFiles
 206 syn region shIf transparent matchgroup=specBlock start="\(^\|\s\)if\(\s\|$\)" end="\(^\|\s\)fi\(\s\|$\)" contains=ALLBUT,shIfError,shCase,@specListedFiles
 207
 208 syn region shFor  matchgroup=specBlock start="\(^\|\s\)for\(\s\|$\)" end="\(^\|\s\)in\(\s\|$\)" contains=ALLBUT,shInError,shCase,@specListedFiles
 209
 210 syn region shCaseEsac transparent matchgroup=specBlock start="\(^\|\s\)case\(\s\|$\)" matchgroup=NONE end="\(^\|\s\)in\(\s\|$\)"me=s-1 contains=ALLBUT,@specListedFiles nextgroup=shCaseEsac
 211 syn region shCaseEsac matchgroup=specBlock start="\(^\|\s\)in\(\s\|$\)" end="\(^\|\s\)esac\(\s\|$\)" contains=ALLBUT,@specListedFilesBin
 212 syn region shCase matchgroup=specBlock contained start=")"  end=";;" contains=ALLBUT,shCase,@specListedFiles
 213
 214 syn sync match shDoSync       grouphere  shDo       "\<do\>"
 215 syn sync match shDoSync       groupthere shDo       "\<done\>"
 216 syn sync match shIfSync       grouphere  shIf       "\<if\>"
 217 syn sync match shIfSync       groupthere shIf       "\<fi\>"
 218 syn sync match shForSync      grouphere  shFor      "\<for\>"
 219 syn sync match shForSync      groupthere shFor      "\<in\>"
 220 syn sync match shCaseEsacSync grouphere  shCaseEsac "\<case\>"
 221 syn sync match shCaseEsacSync groupthere shCaseEsac "\<esac\>"
 222
 223 syn region specIf  matchgroup=specBlock start="%ifosf\|%ifos\|%ifnos\|%ifarch\|%ifnarch\|ifdef\|ifndef\|%if\|%else"  end='%endif' contains=ALLBUT, specOutSkip, specOut2
 224
 225 " %if 0 handing
 226 if exists("spec_if0")
 227     syn region specOut start="^\s*%if\s\+0$" end="$" contains=specOut2
 228     syn region specOut2 contained start="%if\s\+0" end="^\s*%\(endif\>\|else\>\)" contains=specOutSkip
 229
 230     syn region specOutSkip contained start="^\s*%if\>" end="^\s*%endif\>" contains=specOutSkip
 231
 232     syn sync match specIfSync     grouphere  specIf     "%ifarch\|%ifos\|%ifnos"
 233     syn sync match specIfSync     groupthere specIf     "%endIf"
 234 endif
 235
 236 " Define the default highlighting.
 237 " For version 5.7 and earlier: only when not done already
 238 " For version 5.8 and later: only when an item doesn't have highlighting yet
 239 if version >= 508 || !exists("did_spec_syntax_inits")
 240   if version < 508
 241     let did_spec_syntax_inits = 1
 242     command -nargs=+ HiLink hi link <args>
 243   else
 244     command -nargs=+ HiLink hi def link <args>
 245   endif
 246
 247   "main types color definitions
 248   HiLink specSection                    Structure
 249   HiLink specSectionMacro               Macro
 250   HiLink specWWWlink                    PreProc
 251   HiLink specOpts                       Operator
 252
 253   "yes, it's ugly, but white is sooo cool
 254   if &background == "dark"
 255     hi def specGlobalMacro              ctermfg=white
 256   else
 257     HiLink specGlobalMacro              Identifier
 258   endif
 259
 260   "sh colors
 261   HiLink shComment                      Comment
 262   HiLink shIf                           Statement
 263   HiLink shOperator                     Special
 264   HiLink shQuote1                       String
 265   HiLink shQuote2                       String
 266   HiLink shQuoteDelim                   Statement
 267
 268   " spec colors
 269   HiLink specBlock                      Function
 270   HiLink specBcond                      Function
 271   HiLink specColon                      Special
 272   HiLink specCommand                    Statement
 273   HiLink specCommandOpts                specOpts
 274   HiLink specCommandSpecial             Special
 275   HiLink specComment                    Comment
 276   HiLink specConfigure                  specCommand
 277   HiLink specDate                       String
 278   HiLink specDescriptionOpts            specOpts
 279   HiLink specEmail                      specWWWlink
 280   HiLink specError                      Error
 281   HiLink specFilesDirective             specSectionMacro
 282   HiLink specAttr                       specSectionMacro
 283   HiLink specFilesOpts                  specOpts
 284   HiLink specLicense                    String
 285   HiLink specLicenseWarning             specError
 286   HiLink specMacroNameLocal             specGlobalMacro
 287   HiLink specMacroNameOther             specGlobalMacro
 288   HiLink specManpageFile                NONE
 289   HiLink specMonth                      specDate
 290   HiLink specNoNumberHilite             NONE
 291   HiLink specNumber                     Number
 292   HiLink specPackageOpts                specOpts
 293   HiLink specPercent                    Special
 294   HiLink specSpecialChar                Special
 295   HiLink specSubstChar                  Special
 296   HiLink specSpecialVariables           specGlobalMacro
 297   HiLink specSpecialVariablesNames      specGlobalMacro
 298   HiLink specTarCommand                 specCommand
 299   HiLink specMacro                      Macro
 300   HiLink specURL                        specWWWlink
 301   HiLink specURLMacro                   specWWWlink
 302   HiLink specVariables                  Identifier
 303   HiLink specWeekday                    specDate
 304   HiLink specListedFilesBin             Statement
 305   HiLink specListedFilesDoc             Statement
 306   HiLink specListedFilesEtc             Statement
 307   HiLink specListedFilesLib             Statement
 308   HiLink specListedFilesPrefix          Statement
 309   HiLink specListedFilesShare           Statement
 310
 311   HiLink specRevision                   Number
 312   HiLink specLogMessage                 Identifier
 313   HiLink specLogError                   Error
 314
 315   HiLink specOutSkip            specOut
 316   HiLink specOut2            specOut
 317   HiLink specOut             Comment
 318
 319   delcommand HiLink
 320 endif
 321
 322 let b:current_syntax = "spec"
 323
 324 " vim: ts=8