adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2001 PLD-Team <feedback@pld.org.pl>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld.org.pl>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  13
  14 BEGIN {
  15         preamble = 1            # Is it part of preamble? Default - yes
  16         boc = 2                 # Beggining of %changelog
  17         bod = 0                 # Beggining of %description
  18         tw = 70                 # Descriptions width
  19
  20         # If variable removed, then 1 (for removing it from export)
  21         removed["LDFLAGS"] = 0
  22         removed["CFLAGS"] = 0
  23         removed["CXXFLAGS"] = 0
  24
  25         # If 1, we are inside of comment block (started with /^#%/)
  26         comment_block = 0
  27
  28         # File with rpm groups
  29         "rpm --eval %_sourcedir" | getline groups_file
  30         groups_file = groups_file "/rpm.groups"
  31         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups >/dev/null")
  32
  33         # Temporary file for changelog section
  34         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  35
  36         # Load rpm macros
  37         "rpm --eval %_prefix"   | getline prefix
  38         "rpm --eval %_bindir"   | getline bindir
  39         "rpm --eval %_sbindir"  | getline sbindir
  40         "rpm --eval %_libdir"   | getline libdir
  41         "rpm --eval %_sysconfdir" | getline sysconfdir
  42         "rpm --eval %_datadir"  | getline datadir
  43         "rpm --eval %_includedir" | getline includedir
  44         "rpm --eval %_mandir"   | getline mandir
  45         "rpm --eval %_infodir"  | getline infodir
  46 }
  47
  48 # There should be a comment with CVS keywords on the first line of file.
  49 FNR == 1 {
  50         if (!/# \$Revision:/)   # If this line is already OK?
  51                 print "# $" "Revision:$, " "$" "Date:$" # No
  52         else {
  53                 print $0                                # Yes
  54                 next            # It is enough for first line
  55         }
  56 }
  57
  58 # If the latest line matched /%files/
  59 defattr == 1 {
  60         if ($0 !~ /defattr/)    # If no %defattr
  61                 print "%defattr(644,root,root,755)"     # Add it
  62         else
  63                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  64         defattr = 0
  65 }
  66
  67 # Comments
  68 /^#/ && (description == 0) {
  69         if (/This file does not like to be adapterized!/) {
  70                 print                   # print this message
  71                 while (getline)         # print the rest of spec as it is
  72                         print
  73                 do_not_touch_anything = 1 # do not touch anything in END()
  74                 exit 0
  75         }
  76
  77         # Generally, comments are printed without touching
  78         sub(/[ \t]+$/, "")
  79         print $0
  80         next
  81 }
  82
  83 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
  84 /^%define/ {
  85         if ($2 == "_applnkdir")
  86                 next
  87         if ($2 == "date")
  88                 date = 1
  89 }
  90
  91 ################
  92 # %description #
  93 ################
  94 /^%description/, (/^%[a-z]+/ && !/^%description/) {
  95         preamble = 0
  96
  97         if (/^%description/) {
  98                 bod++
  99                 format_line = ""
 100                 format_indent = -1
 101         }
 102
 103         # Define _prefix and _mandir if it is X11 application
 104         if (/^%description$/ && x11 == 1) {
 105                 print "%define\t\t_prefix\t\t/usr/X11R6"
 106                 print "%define\t\t_mandir\t\t%{_prefix}/man\n"
 107                 prefix = "/usr/X11R6"
 108                 x11 = 2
 109         }
 110
 111         # Format description
 112         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 113                 if (/^[ \t]*$/) {
 114                         format_flush(format_line, format_indent)
 115                         print ""
 116                         format_line = ""
 117                         format_indent = -1
 118                 } else if (/^[ \t]*[-\*][ \t]*/) {
 119                         format_flush(format_line, format_indent)
 120                         match($0, /^[ \t]*/)
 121                         format_indent = RLENGTH
 122                         match($0, /^[ \t]*[-\*][ \t]/)
 123                         format_line = substr($0, RLENGTH)
 124                 } else
 125                         format_line = format_line " " $0
 126                 next
 127         }
 128
 129         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 130                 if (NF > 3 && $2 == "-l") {
 131                         ll = $1
 132                         for (i = 4; i <= NF; i++)
 133                                 ll = ll " " $i
 134                         $0 = ll " -l " $3
 135                 }
 136                 format_flush(format_line, format_indent)
 137                 if (bod == 2) {
 138                         bod = 1
 139                         description = 1
 140                 } else {
 141                         bod = 0
 142                         description = 0
 143                 }
 144         } else
 145                 description = 1
 146 }
 147
 148 #########
 149 # %prep #
 150 #########
 151 /^%prep/, (/^%[a-z]+$/ && !/^%prep/) {
 152         preamble = 0
 153
 154         # Add '-q' to %setup
 155         if (/^%setup/ && !/-q/)
 156                 sub(/^%setup/, "%setup -q")
 157 }
 158
 159 ##########
 160 # %build #
 161 ##########
 162 /^%build/, (/^%[a-z]+$/ && !/^%build/) {
 163         preamble = 0
 164
 165         use_macros()
 166
 167         if (/^automake$/)
 168                 sub(/$/, " -a -c")
 169
 170         if (/LDFLAGS/) {
 171                 if (/LDFLAGS="-s"/) {
 172                         removed["LDFLAGS"] = 1
 173                         next
 174                 } else {
 175                         split($0, tmp, "LDFLAGS=")
 176                         count = split(tmp[2], flags, "\"")
 177                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 178                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 179                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 180                                 for (i = 2; i < count; i++)
 181                                         $0 = $0 flags[i] "\""
 182                         }
 183                 }
 184         }
 185
 186         if (/CFLAGS=/)
 187                 if (cflags("CFLAGS") == 0)
 188                         next
 189
 190         if (/CXXFLAGS=/)
 191                 if (cflags("CXXFLAGS") == 0)
 192                         next
 193
 194         if (/^export /) {
 195                 if (removed["LDFLAGS"])
 196                         sub(" LDFLAGS", "")
 197                 if (removed["CFLAGS"])
 198                         sub(" CFLAGS", "")
 199                 if (removed["CXXFLAGS"])
 200                         sub(" CXXFLAGS", "")
 201                 # Is there still something?
 202                 if (/^export[ ]*$/)
 203                         next
 204         }
 205
 206 }
 207
 208 ##########
 209 # %clean #
 210 ##########
 211 /^%clean/, (/^%[a-z]+$/ && !/^%clean/) {
 212         did_clean = 1
 213 }
 214
 215 ############
 216 # %install #
 217 ############
 218 /^%install/, (/^%[a-z]+$/ && !/^%install/) {
 219
 220         preamble = 0
 221
 222         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 223                 did_rmroot=1
 224                 print "rm -rf $RPM_BUILD_ROOT"
 225                 next
 226         }
 227
 228         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 229                 print "rm -rf $RPM_BUILD_ROOT"
 230                 did_rmroot=1
 231         }
 232
 233         use_macros()
 234
 235         # 'install -d' instead 'mkdir -p'
 236         if (/mkdir -p/)
 237                 sub(/mkdir -p/, "install -d")
 238
 239         # No '-u root' or '-g root' for 'install'
 240         if (/^install/ && /-[ug][ \t]*root/)
 241                 gsub(/-[ug][ \t]*root /, "")
 242
 243         if (/^install/ && /-m[ \t]*644/)
 244                 gsub(/-m[ \t]*644 /, "")
 245
 246         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 247         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 248                 next
 249
 250         # No lines contain 'chmod' if it sets the modes to '644'
 251         if ($1 ~ /chmod/ && $2 ~ /644/)
 252                 next
 253 }
 254
 255 ##########
 256 # %files #
 257 ##########
 258 /^%files/, (/^%[a-z \-]+$/ && !/^%files/) {
 259         preamble = 0
 260
 261         if ($0 ~ /^%files/)
 262                 defattr = 1
 263
 264         use_macros()
 265         use_files_macros()
 266 }
 267
 268 ##############
 269 # %changelog #
 270 ##############
 271 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 272         preamble = 0
 273         has_changelog = 1
 274         # There should be some CVS keywords on the first line of %changelog.
 275         if (boc == 1) {
 276                 if (!/PLD Team/) {
 277                         print "* %{date} PLD Team <feedback@pld.org.pl>" > changelog_file
 278                         printf "All persons listed below can be reached at " > changelog_file
 279                         print "<cvs_login>@pld.org.pl\n" > changelog_file
 280                         print "$" "Log:$" > changelog_file
 281                 }
 282                 boc = 0
 283         }
 284
 285         # Define date macro.
 286         if (boc == 2) {
 287                 if (date == 0) {
 288                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 289                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 290                         date = 1
 291                 }
 292                 boc = 1
 293         }
 294
 295         sub(/[ \t]+$/, "")
 296         if (!/^%[a-z]+$/ || /changelog/)
 297                 print > changelog_file
 298         else
 299                 print
 300         next
 301 }
 302
 303 ###########
 304 # SCRIPTS #
 305 ###########
 306 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 307         preamble = 0
 308 }
 309 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 310         preamble = 0
 311 }
 312 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 313         preamble = 0
 314 }
 315 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 316         preamble = 0
 317 }
 318
 319 #############
 320 # PREAMBLES #
 321 #############
 322 preamble == 1 {
 323         # There should not be a space after the name of field
 324         # and before the colon.
 325         sub(/[ \t]*:/, ":")
 326
 327         field = tolower($1)
 328         fieldnlower = $1
 329         if (field ~ /group(\([^)]+\)):/)
 330                 next
 331         if (field ~ /group:/) {
 332                 format_preamble()
 333                 sub(/^Utilities\//,"Applications/",$2)
 334                 sub(/^Games/,"Applications/Games",$2)
 335                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 336                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 337                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 338                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 339                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 340                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 341                 sub(/^Shells/,"Applications/Shells",$2)
 342
 343                 sub(/^[^ \t]*[ \t]*/,"")
 344                 Grupa = $0
 345
 346                 print "Group:\t\t" Grupa
 347                 if (Grupa ~ /^X11/ && x11 == 0) # Is it X11 application?
 348                        x11 = 1
 349
 350                 byl_plik_z_grupami = 0
 351                 byl_opis_grupy = 0
 352                 while ((getline linia_grup < groups_file) > 0) {
 353                         byl_plik_z_grupami = 1
 354                         if (linia_grup == Grupa) {
 355                                 byl_opis_grupy = 1
 356                                 break
 357                         }
 358                 }
 359
 360                 if (!byl_plik_z_grupami)
 361                         print "######\t\t" groups_file ": no such file"
 362                 else if (!byl_opis_grupy)
 363                         print "######\t\t" "Unknown group!"
 364
 365                 close(groups_file)
 366                 next
 367         }
 368
 369         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 370                 next
 371
 372         if (field ~ /buildroot:/)
 373                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 374
 375         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 376         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 377                 $1 = "License:"
 378
 379         if (field ~ /name:/)
 380                 name = $2
 381
 382         if (field ~ /version:/)
 383                 version = $2
 384
 385         if (field ~ /serial:/)
 386                 $1 = "Epoch:"
 387
 388         # Use %{name} and %{version} in the filenames in "Source:"
 389         if (field ~ /^source/ || field ~ /patch/) {
 390                 n = split($2, url, /\//)
 391                 if (url[n] ~ /\.gz$/) {
 392                         url[n+1] = ".gz" url[n+1]
 393                         sub(/\.gz$/,"",url[n])
 394                 }
 395                 if (url[n] ~ /\.zip$/) {
 396                         url[n+1] = ".zip" url[n+1]
 397                         sub(/\.zip$/,"",url[n])
 398                 }
 399                 if (url[n] ~ /\.tar$/) {
 400                         url[n+1] = ".tar" url[n+1]
 401                         sub(/\.tar$/,"",url[n])
 402                 }
 403                 if (url[n] ~ /\.patch$/) {
 404                         url[n+1] = ".patch" url[n+1]
 405                         sub(/\.patch$/,"",url[n])
 406                 }
 407                 if (url[n] ~ /\.bz2$/) {
 408                         url[n+1] = ".bz2" url[n+1]
 409                         sub(/\.bz2$/,"",url[n])
 410                 }
 411                 if (url[n] ~ /\.logrotate$/) {
 412                         url[n+1] = ".logrotate" url[n+1]
 413                         sub(/\.logrotate$/,"",url[n])
 414                 }
 415                 if (url[n] ~ /\.pamd$/) {
 416                         url[n+1] = ".pamd" url[n+1]
 417                         sub(/\.pamd$/,"",url[n])
 418                 }
 419
 420                 filename = url[n]
 421                 url[n] = fixedsub(name, "%{name}", url[n])
 422                 if (field ~ /source/)
 423                         url[n] = fixedsub(version, "%{version}", url[n])
 424                 $2 = fixedsub(filename, url[n], $2)
 425         }
 426
 427         if (field ~ /^source:/)
 428                 $1 = "Source0:"
 429
 430         if (field ~ /patch:/)
 431                 $1 = "Patch0:"
 432
 433         format_preamble()
 434
 435         if ($1 ~ /%define/) {
 436                 # Do not add %define of _prefix if it already is.
 437                 if ($2 ~ /^_prefix/) {
 438                         sub("^"prefix, $3, bindir)
 439                         sub("^"prefix, $3, sbindir)
 440                         sub("^"prefix, $3, libdir)
 441                         sub("^"prefix, $3, datadir)
 442                         sub("^"prefix, $3, includedir)
 443                         prefix = $3
 444                         x11 = 2
 445                 }
 446                 if ($2 ~ /_bindir/ && !/_sbindir/)
 447                         bindir = $3
 448                 if ($2 ~ /_sbindir/)
 449                         sbindir = $3
 450                 if ($2 ~ /_libdir/)
 451                         libdir = $3
 452                 if ($2 ~ /_sysconfdir/)
 453                         sysconfdir = $3
 454                 if ($2 ~ /_datadir/)
 455                         datadir = $3
 456                 if ($2 ~ /_includedir/)
 457                         includedir = $3
 458                 if ($2 ~ /_mandir/)
 459                         mandir = $3
 460                 if ($2 ~ /_infodir/)
 461                         infodir = $3
 462         }
 463 }
 464
 465
 466 # main()  ;-)
 467 {
 468         preamble = 1
 469
 470         sub(/[ \t]+$/, "")
 471         print
 472 }
 473
 474
 475 END {
 476         if (do_not_touch_anything)
 477                 exit 0
 478
 479         close(changelog_file)
 480         while ((getline < changelog_file) > 0)
 481                 print
 482         system("rm -f " changelog_file)
 483
 484         if (did_clean == 0) {
 485                 print ""
 486                 print "%clean"
 487                 print "rm -rf $RPM_BUILD_ROOT"
 488         }
 489
 490         if (date == 0) {
 491                 print ""
 492                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 493         }
 494
 495         if (has_changelog == 0)
 496                 print "%changelog"
 497
 498         if (boc > 0) {
 499                 print "* %{date} PLD Team <feedback@pld.org.pl>"
 500                 printf "All persons listed below can be reached at "
 501                 print "<cvs_login>@pld.org.pl\n"
 502                 print "$" "Log:$"
 503         }
 504 }
 505
 506 function fixedsub(s1,s2,t,      ind) {
 507 # substitutes fixed strings (not regexps)
 508         if (ind = index(t,s1))
 509                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 510         return t
 511 }
 512
 513 # There should be one or two tabs after the colon.
 514 function format_preamble()
 515 {
 516         sub(/:[ \t]*/, ":")
 517         if (match($0, /[A-Za-z0-9()#_ \t]+[ \t]*:[ \t]*/) == 1) {
 518                 if (RLENGTH < 8)
 519                         sub(/:/, ":\t\t")
 520                 else
 521                         sub(/:/, ":\t")
 522         }
 523 }
 524
 525 # Replace directly specified directories with macros
 526 function use_macros()
 527 {
 528         gsub(bindir, "%{_bindir}")
 529         gsub("%{prefix}/bin", "%{_bindir}")
 530         if(prefix"/bin" == bindir)
 531                 gsub("%{_prefix}/bin", "%{_bindir}")
 532
 533         for (c = 1; c <= NF; c++) {
 534                 if ($c ~ sbindir "/fix-info-dir")
 535                         continue;
 536                 gsub(sbindir, "%{_sbindir}", $c)
 537         }
 538
 539         gsub("%{prefix}/sbin", "%{_sbindir}")
 540         if(prefix"/sbin" == sbindir)
 541                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 542
 543         gsub(libdir, "%{_libdir}")
 544         gsub("%{prefix}/lib", "%{_libdir}")
 545         if(prefix"/lib" == libdir)
 546                 gsub("%{_prefix}/lib", "%{_libdir}")
 547
 548         for (c = 1; c <= NF; c++) {
 549                 if ($c ~ sysconfdir "/{?cron.d")
 550                         continue;
 551                 if ($c ~ sysconfdir "/{?crontab.d")
 552                         continue;
 553                 if ($c ~ sysconfdir "/{?logrotate.d")
 554                         continue;
 555                 if ($c ~ sysconfdir "/{?pam.d")
 556                         continue;
 557                 if ($c ~ sysconfdir "/{?profile.d")
 558                         continue;
 559                 if ($c ~ sysconfdir "/{?rc.d")
 560                         continue;
 561                 if ($c ~ sysconfdir "/{?security")
 562                         continue;
 563                 if ($c ~ sysconfdir "/{?skel")
 564                         continue;
 565                 if ($c ~ sysconfdir "/{?sysconfig")
 566                         continue;
 567                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 568         }
 569
 570         gsub(datadir, "%{_datadir}")
 571         gsub("%{prefix}/share", "%{_datadir}")
 572         if(prefix"/share" == datadir)
 573                 gsub("%{_prefix}/share", "%{_datadir}")
 574
 575         gsub(includedir, "%{_includedir}")
 576         gsub("%{prefix}/include", "%{_includedir}")
 577         if(prefix"/include" == includedir)
 578                 gsub("%{_prefix}/include", "%{_includedir}")
 579
 580         gsub(mandir, "%{_mandir}")
 581         if ($0 !~ "%{_datadir}/manual")
 582                 gsub("%{_datadir}/man", "%{_mandir}")
 583         gsub("%{_prefix}/share/man", "%{_mandir}")
 584         gsub("%{prefix}/share/man", "%{_mandir}")
 585         gsub("%{prefix}/man", "%{_mandir}")
 586         gsub("%{_prefix}/man", "%{_mandir}")
 587
 588         gsub(infodir, "%{_infodir}")
 589         gsub("%{prefix}/info", "%{_infodir}")
 590         gsub("%{_prefix}/info", "%{_infodir}")
 591
 592         gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 593
 594         if (prefix != "/") {
 595                 for (c = 1; c <= NF; c++) {
 596                         if ($c ~ prefix "/sbin/fix-info-dir")
 597                                 continue;
 598                         gsub(prefix, "%{_prefix}", $c)
 599                 }
 600                 gsub("%{prefix}", "%{_prefix}")
 601         }
 602
 603         gsub("%{PACKAGE_VERSION}", "%{version}")
 604         gsub("%{PACKAGE_NAME}", "%{name}")
 605
 606         gsub("%{_datadir}/gnome/apps", "%{_applnkdir}")
 607         gsub("%{_datadir}/applnk", "%{_applnkdir}")
 608
 609         gsub("^make$", "%{__make}")
 610         gsub("^make ", "%{__make} ")
 611
 612         gsub("/usr/src/linux", "%{_kernelsrcdir}")
 613         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
 614 }
 615
 616 function use_files_macros()
 617 {
 618         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 619         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 620 }
 621
 622 function fill(ch, n, i) {
 623         for (i = 0; i < n; i++)
 624                 printf("%c", ch)
 625 }
 626
 627 function format_flush(line, indent, newline, word, first_word) {
 628         first_word = 1
 629         if (format_indent == -1)
 630                 newline = ""
 631         else
 632                 newline = fill(" ", format_indent) "- "
 633
 634         while (match(line, /[^\t ]+/)) {
 635                 word = substr(line, RSTART, RLENGTH)
 636                 if (length(newline) + length(word) + 1 > tw) {
 637                         print newline
 638
 639                         if (format_indent == -1)
 640                                 newline = ""
 641                         else
 642                                 newline = fill(" ", format_indent + 2)
 643                         first_word = 1
 644                 }
 645
 646                 if (first_word) {
 647                         newline = newline word
 648                         first_word = 0
 649                 } else
 650                         newline = newline " " word
 651
 652                 line = substr(line, RSTART + RLENGTH)
 653         }
 654         if (newline ~ /[^\t ]/) {
 655                 print newline
 656         }
 657 }
 658
 659 function cflags(var)
 660 {
 661         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
 662                 removed[var] = 1
 663                 return 0
 664         }
 665
 666         if (!/!\?debug/)
 667                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
 668         return 1
 669 }
 670