pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2010 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17 # - support debian/watch http://wiki.debian.org/debian/watch/
  18
  19
  20 function d(s) {
  21         if (!DEBUG) {
  22                 return
  23         }
  24         print s >> "/dev/stderr"
  25 }
  26
  27 function fixedsub(s1,s2,t,      ind) {
  28 # substitutes fixed strings (not regexps)
  29         if (ind = index(t,s1)) {
  30                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  31         }
  32         return t
  33 }
  34
  35 function ispre(s) {
  36         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  37                 d("pre-version")
  38                 return 1
  39         } else {
  40                 return 0
  41         }
  42 }
  43
  44 function compare_ver(v1,v2) {
  45 # compares version numbers
  46         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  47                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  48         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  49                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  50         sub("^0*","",v1)
  51         sub("^0*","",v2)
  52         gsub("\.0*",".",v1)
  53         gsub("\.0*",".",v2)
  54         d("v1 == " v1)
  55         d("v2 == " v2)
  56         count=split(v1,v1a,"\.")
  57         count2=split(v2,v2a,"\.")
  58
  59         if (count<count2) mincount=count
  60         else mincount=count2
  61
  62         for (i=1; i<=mincount; i++) {
  63                 if (v1a[i]=="") v1a[i]=0
  64                 if (v2a[i]=="") v2a[i]=0
  65                 d("i == " i)
  66                 d("v1[i] == " v1a[i])
  67                 d("v2[i] == " v2a[i])
  68                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  69                         if (length(v2a[i])>length(v1a[i]))
  70                                 return 1
  71                         else if (v2a[i]>v1a[i])
  72                                 return 1
  73                         else if (length(v1a[i])>length(v2a[i]))
  74                                 return 0
  75                         else if (v1a[i]>v2a[i])
  76                                 return 0
  77                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  78                         if (v2a[i]>v1a[i])
  79                                 return 1
  80                         else if (v1a[i]>v2a[i])
  81                                 return 0
  82                 } else if (ispre(v1a[i]) == 1)
  83                         return 1
  84                 else
  85                         return 0
  86         }
  87         if ((count2==mincount)&&(count!=count2)) {
  88                 for (i=count2+1; i<=count; i++)
  89                         if (ispre(v1a[i]) == 1)
  90                                 return 1
  91                 return 0
  92         } else if (count!=count2) {
  93                 for (i=count+1; i<=count2; i++)
  94                         if (ispre(v2a[i]) == 1)
  95                                 return 0
  96                 return 1
  97         }
  98         return 0
  99 }
 100
 101 function compare_ver_dec(v1,v2) {
 102 # compares version numbers as decimal floats
 103         while (match(v1,/[0-9][a-zA-Z]/))
 104                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 105         while (match(v2,/[0-9][a-zA-Z]/))
 106                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 107         sub("^0*","",v1)
 108         sub("^0*","",v2)
 109         d("v1 == " v1)
 110         d("v2 == " v2)
 111         count=split(v1,v1a,"\.")
 112         count2=split(v2,v2a,"\.")
 113
 114         if (count<count2) mincount=count
 115         else mincount=count2
 116
 117         for (i=1; i<=mincount; i++) {
 118                 if (v1a[i]=="") v1a[i]=0
 119                 if (v2a[i]=="") v2a[i]=0
 120                 d("i == " i)
 121                 d("v1[i] == " v1a[i])
 122                 d("v2[i] == " v2a[i])
 123                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 124                         if (i==2) {
 125                                 if (0+("." v2a[i])>0+("." v1a[i]))
 126                                         return 1
 127                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 128                                         return 0
 129                         } else {
 130                                 if (length(v2a[i])>length(v1a[i]))
 131                                         return 1
 132                                 else if (v2a[i]>v1a[i])
 133                                         return 1
 134                                 else if (length(v1a[i])>length(v2a[i]))
 135                                         return 0
 136                                 else if (v1a[i]>v2a[i])
 137                                         return 0
 138                         }
 139                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 140                         if (v2a[i]>v1a[i])
 141                                 return 1
 142                         else if (v1a[i]>v2a[i])
 143                                 return 0
 144                 } else if (ispre(v1a[i]) == 1)
 145                         return 1
 146                 else
 147                         return 0
 148         }
 149         if ((count2==mincount)&&(count!=count2)) {
 150                 for (i=count2+1; i<=count; i++)
 151                         if (ispre(v1a[i]) == 1)
 152                                 return 1
 153                 return 0
 154         } else if (count!=count2) {
 155                 for (i=count+1; i<=count2; i++)
 156                         if (ispre(v2a[i]) == 1)
 157                                 return 0
 158                 return 1
 159         }
 160         return 0
 161 }
 162
 163 function link_seen(link) {
 164         for (seenlink in frameseen) {
 165                 if (seenlink == link) {
 166                         d("Link: [" link "] seen already, skipping...")
 167                         return 1
 168                 }
 169         }
 170         frameseen[link]=1
 171         return 0
 172 }
 173
 174 function mktemp(   _cmd, _tmpfile) {
 175         _cmd = "mktemp /tmp/XXXXXX"
 176         _cmd | getline _tmpfile
 177         close(_cmd)
 178         return _tmpfile
 179 }
 180
 181 # fix link to artificial one that will be recognized rest of this script
 182 function postfix_link(url, link) {
 183         oldlink = link
 184         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 185                 gsub(".*\/tarball\/", "", link)
 186                 link = link ".tar.gz"
 187         }
 188         d("POST FIXING URL [ " oldlink " ] to [ " link " ]")
 189         return link
 190 }
 191
 192 # get all <A HREF=..> tags from specified URL
 193 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 194
 195         wholeerr=""
 196
 197         tmpfile = mktemp()
 198         tmpfileerr = mktemp()
 199
 200         if (url ~ /^http:\/\/(download|downloads|dl)\.(sf|sourceforge)\.net\//) {
 201                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 202                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 203                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 204                 gsub("^http://downloads\.(sf|sourceforge)\.net/project/", "", url)
 205
 206                 gsub("/.*", "", url)
 207                 url = "http://sourceforge.net/projects/" url "/files/"
 208                 d("sf url, mungled url to: " url)
 209         }
 210
 211         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 212                 gsub("^http://", "", url)
 213                 gsub("\..*", "", url)
 214                 url = "http://code.google.com/p/" url "/downloads/list"
 215                 d("googlecode url, mungled url to: " url)
 216         }
 217
 218         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 219                 gsub("-.*", "", filename)
 220                 url = "http://pecl.php.net/package/" filename
 221                 d("pecl.php.net url, mungled url to: " url)
 222         }
 223
 224         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 225                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 226                  d("mysql 5.1 url, mungled url to: " url)
 227         }
 228
 229         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 230                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 231                 gsub("\/.*/", "", url)
 232                 url = "https://code.launchpad.net/" url "/+download"
 233                 d("main launchpad url, mungled url to: " url)
 234         }
 235
 236         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 237                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 238                 gsub("\/.*/", "", url)
 239                 url = "https://edge.launchpad.net/" url "/+download"
 240                 d("edge launchpad url, mungled url to: " url)
 241         }
 242
 243         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 244                 gsub("\/tarball\/.*", "/downloads", url)
 245                 d("github tarball url, mungled url to: " url)
 246         }
 247
 248         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 249                 gsub("\/snapshot\/.*", "/", url)
 250                 d("cgit snapshot tarball url, mungled url to: " url)
 251         }
 252
 253         d("Retrieving: " url)
 254         cmd = "wget --user-agent \"Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6\" -nv -O - \"" url "\" -t 2 -T 45 --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 255         d("Execute: " cmd)
 256         errno = system(cmd)
 257         d("Execute done")
 258
 259         if (errno==0) {
 260                 wholeodp = ""
 261                 d("Reading success response...")
 262                 while (getline oneline < tmpfile)
 263                         wholeodp = (wholeodp " " oneline)
 264 #                       d("Response: " wholeodp)
 265         } else {
 266                 d("Reading failure response...")
 267                 wholeerr = ""
 268                 while (getline oneline < tmpfileerr)
 269                         wholeerr=(wholeerr " " oneline)
 270                 d("Error Response: " wholeerr)
 271         }
 272
 273         system("rm -f " tmpfile)
 274         system("rm -f " tmpfileerr)
 275
 276         if (errno != 0) {
 277                 retval = ("WGET ERROR: " errno ": " wholeerr)
 278                 return retval
 279         }
 280
 281         urldir = url;
 282         sub(/[^\/]+$/, "", urldir)
 283
 284         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 285                 d("Processing links...")
 286                 odp = substr(wholeodp,RSTART,RLENGTH);
 287                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 288
 289                 lowerodp = tolower(odp);
 290                 if (lowerodp ~ /<frame[ \t]/) {
 291                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 292                         match(odp, /src="[^"]+"/)
 293                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 294                         d("Frame: " newurl)
 295                         if (newurl !~ /\//) {
 296                                 newurl=(urldir newurl)
 297                                 d("Frame->: " newurl)
 298                         }
 299
 300                         if (link_seen(newurl)) {
 301                                 newurl = ""
 302                                 continue
 303                         }
 304
 305                         retval = (retval " " get_links(newurl))
 306                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 307                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 308                         match(odp,/href="[^"]*"/)
 309                         link=substr(odp,RSTART,RLENGTH)
 310                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 311                         link=substr(link,7,length(link)-7)
 312                         link=postfix_link(url, link)
 313
 314                         if (link_seen(link)) {
 315                                 link=""
 316                                 continue
 317                         }
 318
 319                         retval = (retval " " link)
 320                         d("href(\"\"): " link)
 321                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 322                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 323                         match(odp,/href='[^']*'/)
 324                         link=substr(odp,RSTART,RLENGTH)
 325                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 326                         link=substr(link,7,length(link)-7)
 327                         link=postfix_link(url, link)
 328
 329                         if (link_seen(link)) {
 330                                 link=""
 331                                 continue
 332                         }
 333
 334                         retval = (retval " " link)
 335                         d("href(''): " link)
 336                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 337                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 338                         match(odp,/href=[^ \t>]*/)
 339                         link=substr(odp,RSTART,RLENGTH)
 340                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 341                         link=substr(link,6,length(link)-5)
 342
 343                         if (link_seen(link)) {
 344                                 link=""
 345                                 continue
 346                         }
 347
 348                         retval = (retval " " link)
 349                         d("href(): " link)
 350                 } else {
 351                         # <a ...> but not href - skip
 352                         d("skipping <a > without href: " odp)
 353                 }
 354         }
 355
 356         d("Returning: " retval)
 357         return retval
 358 }
 359
 360 function subst_defines(var,defs) {
 361 # substitute all possible RPM macros
 362         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 363                 oldvar=var
 364                 for (j in defs) {
 365                         gsub("%{" j "}", defs[j], var)
 366                         gsub("%" j , defs[j], var)
 367                 }
 368                 if (var==oldvar) {
 369                         if (DEBUG) {
 370                                 for (i in defs) {
 371                                         d(i " == " defs[i])
 372                                 }
 373                         }
 374                         return var
 375                 }
 376         }
 377         return var
 378 }
 379
 380 function find_mirror(url) {
 381
 382         while (succ = (getline line < "mirrors")) {
 383             if (succ==-1) { return url }
 384                 nf=split(line,fields,"|")
 385                 if (nf>1){
 386                         origin=fields[1]
 387                         mirror=fields[2]
 388                         mname=fields[3]
 389                         prefix=substr(url,1,length(origin))
 390                         if (prefix==origin){
 391                                 d("Mirror fount at " mname)
 392                                 close("mirrors")
 393                                 return mirror substr(url,length(origin)+1)
 394                         }
 395                 }
 396         }
 397
 398         return url
 399 }
 400
 401 function process_source(number,lurl,name,version) {
 402 # fetches file list, and compares version numbers
 403         d("Processing " lurl)
 404
 405         if ( index(lurl,version)==0 ) {
 406                 d("There is no version number.")
 407                 return 0
 408         }
 409
 410         sub("://",":",lurl)
 411         sub("/",":/",lurl)
 412         gsub("[^/]*$",":&",lurl)
 413         split(lurl,url,":")
 414         acc=url[1]
 415         host=url[2]
 416         dir=url[3]
 417         filename=url[4]
 418
 419         if (index(dir,version)) {
 420                 # directory name as version maching mode:
 421                 # if /something/version/name-version.tarball then check
 422                 # in /something/ looking for newer directory
 423                 dir=substr(dir,1,index(dir,version)-1)
 424                 sub("[^/]*$","",dir)
 425                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 426         }
 427
 428         d("Will check a directory: " dir)
 429         d("and a file: " filename)
 430
 431         filenameexp=filename
 432         gsub("\+","\\+",filenameexp)
 433         sub(version,"[A-Za-z0-9.]+",filenameexp)
 434         gsub("\.","\\.",filenameexp)
 435         d("Expression: " filenameexp)
 436         match(filename,version)
 437         prever=substr(filename,1,RSTART-1)
 438         postver=substr(filename,RSTART+RLENGTH)
 439         d("Before number: " prever)
 440         d("and after: " postver)
 441         newurl=find_mirror(acc "://" host dir)
 442         #print acc "://" host dir
 443         #newurl=url[1]"://"url[2]url[3]url[4]
 444         #newurl=acc "://" host dir filename
 445         d("Looking at " newurl)
 446
 447         references=0
 448         finished=0
 449         oldversion=version
 450         odp = get_links(newurl, filename)
 451         if( odp ~ "ERROR: ") {
 452                 print name "(" number ") " odp
 453         } else {
 454                 d("WebPage downloaded")
 455                 c=split(odp,linki)
 456                 for (nr=1; nr<=c; nr++) {
 457                         addr=linki[nr]
 458
 459                         d("Found link: " addr)
 460
 461                         # github has very different tarball links that clash with this safe check
 462                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 463                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 464                                         continue
 465                                 }
 466                         }
 467
 468                         if (addr ~ filenameexp) {
 469                                 match(addr,filenameexp)
 470                                 newfilename=substr(addr,RSTART,RLENGTH)
 471                                 d("Hypothetical new: " newfilename)
 472                                 newfilename=fixedsub(prever,"",newfilename)
 473                                 newfilename=fixedsub(postver,"",newfilename)
 474                                 d("Version: " newfilename)
 475                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 476                                 # strip ending (happens when in directiory name as version matching mode)
 477                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 478                                 if (NUMERIC) {
 479                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 480                                                 d("Yes, there is new one")
 481                                                 version=newfilename
 482                                                 finished=1
 483                                         }
 484                                 } else if ( compare_ver(version, newfilename)==1 ) {
 485                                         d("Yes, there is new one")
 486                                         version=newfilename
 487                                         finished=1
 488                                 }
 489                         }
 490                 }
 491                 if (finished==0)
 492                         print name "(" number ") seems ok: " oldversion
 493                 else
 494                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 495         }
 496 }
 497
 498 function rss_upgrade(name, ver, url, regex, cmd, nver) {
 499         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 500         cmd = "wget -q -O - " url " | sed -nre '" regex "' | head -n1"
 501
 502         d("rss_upgrade_cmd: " cmd)
 503         cmd | getline nver
 504         close(cmd)
 505
 506         if (compare_ver(ver, nver)) {
 507                 print name " [OLD] " ver " [NEW] " nver
 508         } else {
 509                 print name " seems ok: " ver
 510         }
 511 }
 512
 513 # check for ZF upgrade from rss
 514 function zf_upgrade(name, ver) {
 515         rss_upgrade(name, ver, \
 516                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 517                 "Zend Framework ([^\\s]+) Released" \
 518         );
 519 }
 520
 521 function hudson_upgrade(name, ver) {
 522         rss_upgrade(name, ver, \
 523                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 524                 "Hudson ([0-9.]+) released" \
 525         );
 526 }
 527
 528 # upgrade check for pear package using PEAR CLI
 529 function pear_upgrade(name, ver,    pname, pearcmd, nver) {
 530         pname = name;
 531         sub(/^php-pear-/, "", pname);
 532
 533         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 534         d("pearcmd: " pearcmd)
 535         pearcmd | getline nver
 536         close(pearcmd)
 537
 538         if (compare_ver(ver, nver)) {
 539                 print name " [OLD] " ver " [NEW] " nver
 540         } else {
 541                 print name " seems ok: " ver
 542         }
 543
 544         return
 545 }
 546
 547 function vim_upgrade(name, ver,     mver, nver, vimcmd) {
 548         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 549         mver = substr(ver, 0, 4)
 550         vimcmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/"mver"/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 551         d("vimcmd: " vimcmd)
 552         vimcmd | getline nver
 553         close(vimcmd)
 554
 555         if (compare_ver(ver, nver)) {
 556                 print name " [OLD] " ver " [NEW] " nver
 557         } else {
 558                 print name " seems ok: " ver
 559         }
 560 }
 561
 562 function process_data(name,ver,rel,src) {
 563         if (name ~ /^php-pear-/) {
 564                 return pear_upgrade(name, ver);
 565         }
 566         if (name == "ZendFramework") {
 567                 return zf_upgrade(name, ver);
 568         }
 569         if (name == "hudson") {
 570                 return hudson_upgrade(name, ver);
 571         }
 572         if (name == "vim") {
 573                 return vim_upgrade(name, ver);
 574         }
 575
 576 # this function checks if substitutions were valid, and if true:
 577 # processes each URL and tries to get current file list
 578         for (i in src) {
 579                 if ( src[i] ~ /%{nil}/ ) {
 580                         gsub(/\%\{nil\}/, "", src[i])
 581                 }
 582                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 583                         d("Source: " src[i])
 584                         process_source(i,src[i],name,ver)
 585                 } else {
 586                         print FNAME ":" i ": impossible substitution: " src[i]
 587                 }
 588         }
 589 }
 590
 591 BEGIN {
 592         # if U want to use DEBUG, run script with "-v DEBUG=1"
 593         # or uncomment the line below
 594         # DEBUG = 1
 595
 596         errno=system("wget --help > /dev/null 2>&1")
 597         if (errno) {
 598                 print "No wget installed!"
 599                 exit 1
 600         }
 601         if (ARGC>=3 && ARGV[2]=="-n") {
 602                 NUMERIC=1
 603                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 604                 ARGC=ARGC-1
 605         }
 606 }
 607
 608 FNR==1 {
 609         if ( ARGIND != 1 ) {
 610                 # clean frameseen for each ARG
 611                 for (i in frameseen) {
 612                         delete frameseen[i]
 613                 }
 614                 frameseen[0] = 1
 615
 616                 process_data(NAME,VER,REL,SRC)
 617                 NAME="" ; VER="" ; REL=""
 618                 for (i in DEFS) delete DEFS[i]
 619                 for (i in SRC) delete SRC[i]
 620         }
 621         FNAME=FILENAME
 622         DEFS["_alt_kernel"]=""
 623         DEFS["20"]="\\ "
 624 }
 625
 626 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 627 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 628 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 629 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 630 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 631 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 632
 633 END {
 634         process_data(NAME,VER,REL,SRC)
 635 }