pldnotify.awk

   1 #!/usr/bin/gawk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2010 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17 # - support debian/watch http://wiki.debian.org/debian/watch/
  18
  19
  20 function d(s) {
  21         if (!DEBUG) {
  22                 return
  23         }
  24
  25         print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  26 #       print s >> "/dev/stderr"
  27 }
  28
  29 function fixedsub(s1,s2,t,      ind) {
  30 # substitutes fixed strings (not regexps)
  31         if (ind = index(t,s1)) {
  32                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  33         }
  34         return t
  35 }
  36
  37 function ispre(s) {
  38         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  39                 d("pre-version")
  40                 return 1
  41         } else {
  42                 return 0
  43         }
  44 }
  45
  46 function compare_ver(v1,v2) {
  47 # compares version numbers
  48         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  49                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  50         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  51                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  52         sub("^0*","",v1)
  53         sub("^0*","",v2)
  54         gsub("\.0*",".",v1)
  55         gsub("\.0*",".",v2)
  56         d("v1 == " v1)
  57         d("v2 == " v2)
  58         count=split(v1,v1a,"\.")
  59         count2=split(v2,v2a,"\.")
  60
  61         if (count<count2) mincount=count
  62         else mincount=count2
  63
  64         for (i=1; i<=mincount; i++) {
  65                 if (v1a[i]=="") v1a[i]=0
  66                 if (v2a[i]=="") v2a[i]=0
  67                 d("i == " i)
  68                 d("v1[i] == " v1a[i])
  69                 d("v2[i] == " v2a[i])
  70                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  71                         if (length(v2a[i])>length(v1a[i]))
  72                                 return 1
  73                         else if (v2a[i]>v1a[i])
  74                                 return 1
  75                         else if (length(v1a[i])>length(v2a[i]))
  76                                 return 0
  77                         else if (v1a[i]>v2a[i])
  78                                 return 0
  79                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  80                         if (v2a[i]>v1a[i])
  81                                 return 1
  82                         else if (v1a[i]>v2a[i])
  83                                 return 0
  84                 } else if (ispre(v1a[i]) == 1)
  85                         return 1
  86                 else
  87                         return 0
  88         }
  89         if ((count2==mincount)&&(count!=count2)) {
  90                 for (i=count2+1; i<=count; i++)
  91                         if (ispre(v1a[i]) == 1)
  92                                 return 1
  93                 return 0
  94         } else if (count!=count2) {
  95                 for (i=count+1; i<=count2; i++)
  96                         if (ispre(v2a[i]) == 1)
  97                                 return 0
  98                 return 1
  99         }
 100         return 0
 101 }
 102
 103 function compare_ver_dec(v1,v2) {
 104 # compares version numbers as decimal floats
 105         while (match(v1,/[0-9][a-zA-Z]/))
 106                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 107         while (match(v2,/[0-9][a-zA-Z]/))
 108                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 109         sub("^0*","",v1)
 110         sub("^0*","",v2)
 111         d("v1 == " v1)
 112         d("v2 == " v2)
 113         count=split(v1,v1a,"\.")
 114         count2=split(v2,v2a,"\.")
 115
 116         if (count<count2) mincount=count
 117         else mincount=count2
 118
 119         for (i=1; i<=mincount; i++) {
 120                 if (v1a[i]=="") v1a[i]=0
 121                 if (v2a[i]=="") v2a[i]=0
 122                 d("i == " i)
 123                 d("v1[i] == " v1a[i])
 124                 d("v2[i] == " v2a[i])
 125                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 126                         if (i==2) {
 127                                 if (0+("." v2a[i])>0+("." v1a[i]))
 128                                         return 1
 129                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 130                                         return 0
 131                         } else {
 132                                 if (length(v2a[i])>length(v1a[i]))
 133                                         return 1
 134                                 else if (v2a[i]>v1a[i])
 135                                         return 1
 136                                 else if (length(v1a[i])>length(v2a[i]))
 137                                         return 0
 138                                 else if (v1a[i]>v2a[i])
 139                                         return 0
 140                         }
 141                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 142                         if (v2a[i]>v1a[i])
 143                                 return 1
 144                         else if (v1a[i]>v2a[i])
 145                                 return 0
 146                 } else if (ispre(v1a[i]) == 1)
 147                         return 1
 148                 else
 149                         return 0
 150         }
 151         if ((count2==mincount)&&(count!=count2)) {
 152                 for (i=count2+1; i<=count; i++)
 153                         if (ispre(v1a[i]) == 1)
 154                                 return 1
 155                 return 0
 156         } else if (count!=count2) {
 157                 for (i=count+1; i<=count2; i++)
 158                         if (ispre(v2a[i]) == 1)
 159                                 return 0
 160                 return 1
 161         }
 162         return 0
 163 }
 164
 165 function link_seen(link) {
 166         for (seenlink in frameseen) {
 167                 if (seenlink == link) {
 168                         d("Link: [" link "] seen already, skipping...")
 169                         return 1
 170                 }
 171         }
 172         frameseen[link]=1
 173         return 0
 174 }
 175
 176 function mktemp(   _cmd, _tmpfile) {
 177         _cmd = "mktemp /tmp/XXXXXX"
 178         _cmd | getline _tmpfile
 179         close(_cmd)
 180         return _tmpfile
 181 }
 182
 183 # fix link to artificial one that will be recognized rest of this script
 184 function postfix_link(url, link,   oldlink) {
 185         oldlink = link
 186         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 187                 gsub(".*\/tarball\/", "", link)
 188                 link = link ".tar.gz"
 189         }
 190         if (oldlink != link) {
 191                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 192         }
 193         return link
 194 }
 195
 196 # use perl HTML::TreeBuilder module to extract links from html
 197 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 198 function extract_links_cmd(tmpfile) {
 199         return "perl -MHTML::TreeBuilder -e ' \
 200         my $content = join q//, <>; \
 201         my $root = new HTML::TreeBuilder; \
 202         $root->parse($content); \
 203         my $links_r = $root->extract_links(); \
 204         \
 205         for (@{$root->extract_links(qw(a iframe))}) { \
 206                 my($link, $element, $attr, $tag) = @$_; \
 207                 print $tag, q/ /, $link, $/; \
 208         } \
 209         ' " tmpfile
 210 }
 211
 212 # get all <A HREF=..> tags from specified URL
 213 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 214
 215         wholeerr=""
 216
 217         tmpfile = mktemp()
 218         tmpfileerr = mktemp()
 219
 220         if (url ~ /^http:\/\/(download|downloads|dl)\.(sf|sourceforge)\.net\//) {
 221                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 222                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 223                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 224                 gsub("^http://downloads\.(sf|sourceforge)\.net/project/", "", url)
 225
 226                 gsub("/.*", "", url)
 227                 url = "http://sourceforge.net/projects/" url "/files/"
 228                 d("sf url, mungled url to: " url)
 229         }
 230
 231         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 232                 gsub("^http://", "", url)
 233                 gsub("\..*", "", url)
 234                 url = "http://code.google.com/p/" url "/downloads/list"
 235                 d("googlecode url, mungled url to: " url)
 236         }
 237
 238         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 239                 gsub("-.*", "", filename)
 240                 url = "http://pecl.php.net/package/" filename
 241                 d("pecl.php.net url, mungled url to: " url)
 242         }
 243
 244         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 245                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 246                  d("mysql 5.1 url, mungled url to: " url)
 247         }
 248
 249         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 250                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 251                 gsub("\/.*/", "", url)
 252                 url = "https://code.launchpad.net/" url "/+download"
 253                 d("main launchpad url, mungled url to: " url)
 254         }
 255
 256         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 257                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 258                 gsub("\/.*/", "", url)
 259                 url = "https://edge.launchpad.net/" url "/+download"
 260                 d("edge launchpad url, mungled url to: " url)
 261         }
 262
 263         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 264                 gsub("\/tarball\/.*", "/downloads", url)
 265                 d("github tarball url, mungled url to: " url)
 266         }
 267
 268         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 269                 gsub("\/snapshot\/.*", "/", url)
 270                 d("cgit snapshot tarball url, mungled url to: " url)
 271         }
 272
 273         d("Retrieving: " url)
 274         cmd = "wget --user-agent \"Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6\" -nv -O - \"" url "\" -t 2 -T 45 --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 275         d("Execute: " cmd)
 276         errno = system(cmd)
 277         d("Execute done")
 278
 279         if (errno != 0) {
 280                 d("Reading failure response...")
 281                 wholeerr = ""
 282                 while (getline oneline < tmpfileerr)
 283                         wholeerr = (wholeerr " " oneline)
 284                 d("Error Response: " wholeerr)
 285
 286                 system("rm -f " tmpfile)
 287                 system("rm -f " tmpfileerr)
 288                 retval = ("WGET ERROR: " errno ": " wholeerr)
 289                 return retval
 290         }
 291         system("rm -f " tmpfileerr)
 292
 293         urldir = url;
 294         sub(/[^\/]+$/, "", urldir)
 295
 296 if (USE_PERL) {
 297         cmd = extract_links_cmd(tmpfile)
 298         while (cmd | getline) {
 299                 tag = $1
 300                 link = substr($0, length(tag) + 2)
 301
 302                 if (tag == "iframe") {
 303                         d("Frame: " link)
 304                         if (url !~ /\//) {
 305                                 link = (urldir link)
 306                                 d("Frame->: " link)
 307                         }
 308
 309                         if (link_seen(link)) {
 310                                 continue
 311                         }
 312                         retval = (retval " " get_links(link))
 313                 }
 314
 315                 if (link_seen(link)) {
 316                         continue
 317                 }
 318
 319                 retval = (retval " " link)
 320                 d("href(): " link)
 321         }
 322         close(cmd)
 323         system("rm -f " tmpfile)
 324
 325         d("Returning: [" retval "]")
 326         return retval
 327 }
 328
 329         wholeodp = ""
 330         d("Reading success response...")
 331         while (getline oneline < tmpfile) {
 332                 wholeodp = (wholeodp " " oneline)
 333 #               d("Response: " wholeodp)
 334         }
 335         d("Reponse read done...")
 336         system("rm -f " tmpfile)
 337
 338         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 339                 d("Processing links...")
 340                 odp = substr(wholeodp,RSTART,RLENGTH);
 341                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 342
 343                 lowerodp = tolower(odp);
 344                 if (lowerodp ~ /<frame[ \t]/) {
 345                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 346                         match(odp, /src="[^"]+"/)
 347                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 348                         d("Frame: " newurl)
 349                         if (newurl !~ /\//) {
 350                                 newurl=(urldir newurl)
 351                                 d("Frame->: " newurl)
 352                         }
 353
 354                         if (link_seen(newurl)) {
 355                                 newurl = ""
 356                                 continue
 357                         }
 358
 359                         retval = (retval " " get_links(newurl))
 360                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 361                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 362                         match(odp,/href="[^"]*"/)
 363                         link=substr(odp,RSTART,RLENGTH)
 364                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 365                         link=substr(link,7,length(link)-7)
 366                         link=postfix_link(url, link)
 367
 368                         if (link_seen(link)) {
 369                                 link=""
 370                                 continue
 371                         }
 372
 373                         retval = (retval " " link)
 374                         d("href(\"\"): " link)
 375                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 376                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 377                         match(odp,/href='[^']*'/)
 378                         link=substr(odp,RSTART,RLENGTH)
 379                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 380                         link=substr(link,7,length(link)-7)
 381                         link=postfix_link(url, link)
 382
 383                         if (link_seen(link)) {
 384                                 link=""
 385                                 continue
 386                         }
 387
 388                         retval = (retval " " link)
 389                         d("href(''): " link)
 390                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 391                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 392                         match(odp,/href=[^ \t>]*/)
 393                         link=substr(odp,RSTART,RLENGTH)
 394                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 395                         link=substr(link,6,length(link)-5)
 396
 397                         if (link_seen(link)) {
 398                                 link=""
 399                                 continue
 400                         }
 401
 402                         retval = (retval " " link)
 403                         d("href(): " link)
 404                 } else {
 405                         # <a ...> but not href - skip
 406                         d("skipping <a > without href: " odp)
 407                 }
 408         }
 409
 410         d("Returning: [" retval "]")
 411         return retval
 412 }
 413
 414 function subst_defines(var,defs) {
 415 # substitute all possible RPM macros
 416         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 417                 oldvar=var
 418                 for (j in defs) {
 419                         gsub("%{" j "}", defs[j], var)
 420                         gsub("%" j , defs[j], var)
 421                 }
 422                 if (var==oldvar) {
 423                         if (DEBUG) {
 424                                 for (i in defs) {
 425                                         d(i " == " defs[i])
 426                                 }
 427                         }
 428                         return var
 429                 }
 430         }
 431         return var
 432 }
 433
 434 function find_mirror(url) {
 435
 436         while (succ = (getline line < "mirrors")) {
 437             if (succ==-1) { return url }
 438                 nf=split(line,fields,"|")
 439                 if (nf>1){
 440                         origin=fields[1]
 441                         mirror=fields[2]
 442                         mname=fields[3]
 443                         prefix=substr(url,1,length(origin))
 444                         if (prefix==origin){
 445                                 d("Mirror fount at " mname)
 446                                 close("mirrors")
 447                                 return mirror substr(url,length(origin)+1)
 448                         }
 449                 }
 450         }
 451
 452         return url
 453 }
 454
 455 function process_source(number,lurl,name,version) {
 456 # fetches file list, and compares version numbers
 457         d("Processing " lurl)
 458
 459         if ( index(lurl,version)==0 ) {
 460                 d("There is no version number.")
 461                 return 0
 462         }
 463
 464         sub("://",":",lurl)
 465         sub("/",":/",lurl)
 466         gsub("[^/]*$",":&",lurl)
 467         split(lurl,url,":")
 468         acc=url[1]
 469         host=url[2]
 470         dir=url[3]
 471         filename=url[4]
 472
 473         if (index(dir,version)) {
 474                 # directory name as version maching mode:
 475                 # if /something/version/name-version.tarball then check
 476                 # in /something/ looking for newer directory
 477                 dir=substr(dir,1,index(dir,version)-1)
 478                 sub("[^/]*$","",dir)
 479                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 480         }
 481
 482         d("Will check a directory: " dir)
 483         d("and a file: " filename)
 484
 485         filenameexp=filename
 486         gsub("[+]","\\+",filenameexp)
 487         sub(version,"[A-Za-z0-9.]+",filenameexp)
 488         gsub("[.]","\\.",filenameexp)
 489         d("Expression: " filenameexp)
 490         match(filename,version)
 491         prever=substr(filename,1,RSTART-1)
 492         postver=substr(filename,RSTART+RLENGTH)
 493         d("Before number: " prever)
 494         d("and after: " postver)
 495         newurl=find_mirror(acc "://" host dir)
 496         #print acc "://" host dir
 497         #newurl=url[1]"://"url[2]url[3]url[4]
 498         #newurl=acc "://" host dir filename
 499         d("Looking at " newurl)
 500
 501         references=0
 502         finished=0
 503         oldversion=version
 504         odp = get_links(newurl, filename)
 505         if( odp ~ "ERROR: ") {
 506                 print name "(" number ") " odp
 507         } else {
 508                 d("WebPage downloaded")
 509                 c=split(odp,linki)
 510                 for (nr=1; nr<=c; nr++) {
 511                         addr=linki[nr]
 512
 513                         d("Found link: " addr)
 514
 515                         # github has very different tarball links that clash with this safe check
 516                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 517                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 518                                         continue
 519                                 }
 520                         }
 521
 522                         if (addr ~ filenameexp) {
 523                                 match(addr,filenameexp)
 524                                 newfilename=substr(addr,RSTART,RLENGTH)
 525                                 d("Hypothetical new: " newfilename)
 526                                 newfilename=fixedsub(prever,"",newfilename)
 527                                 newfilename=fixedsub(postver,"",newfilename)
 528                                 d("Version: " newfilename)
 529                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 530                                 # strip ending (happens when in directiory name as version matching mode)
 531                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 532                                 if (NUMERIC) {
 533                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 534                                                 d("Yes, there is new one")
 535                                                 version=newfilename
 536                                                 finished=1
 537                                         }
 538                                 } else if ( compare_ver(version, newfilename)==1 ) {
 539                                         d("Yes, there is new one")
 540                                         version=newfilename
 541                                         finished=1
 542                                 }
 543                         }
 544                 }
 545                 if (finished==0)
 546                         print name "(" number ") seems ok: " oldversion
 547                 else
 548                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 549         }
 550 }
 551
 552 function rss_upgrade(name, ver, url, regex, cmd, nver) {
 553         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 554         cmd = "wget -q -O - " url " | sed -nre '" regex "' | head -n1"
 555
 556         d("rss_upgrade_cmd: " cmd)
 557         cmd | getline nver
 558         close(cmd)
 559
 560         if (compare_ver(ver, nver)) {
 561                 print name " [OLD] " ver " [NEW] " nver
 562         } else {
 563                 print name " seems ok: " ver
 564         }
 565 }
 566
 567 # check for ZF upgrade from rss
 568 function zf_upgrade(name, ver) {
 569         rss_upgrade(name, ver, \
 570                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 571                 "Zend Framework ([^\\s]+) Released" \
 572         );
 573 }
 574
 575 function hudson_upgrade(name, ver) {
 576         rss_upgrade(name, ver, \
 577                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 578                 "Hudson ([0-9.]+) released" \
 579         );
 580 }
 581
 582 # upgrade check for pear package using PEAR CLI
 583 function pear_upgrade(name, ver,    pname, pearcmd, nver) {
 584         pname = name;
 585         sub(/^php-pear-/, "", pname);
 586
 587         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 588         d("pearcmd: " pearcmd)
 589         pearcmd | getline nver
 590         close(pearcmd)
 591
 592         if (compare_ver(ver, nver)) {
 593                 print name " [OLD] " ver " [NEW] " nver
 594         } else {
 595                 print name " seems ok: " ver
 596         }
 597
 598         return
 599 }
 600
 601 function vim_upgrade(name, ver,     mver, nver, vimcmd) {
 602         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 603         mver = substr(ver, 0, 4)
 604         vimcmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/"mver"/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 605         d("vimcmd: " vimcmd)
 606         vimcmd | getline nver
 607         close(vimcmd)
 608
 609         if (compare_ver(ver, nver)) {
 610                 print name " [OLD] " ver " [NEW] " nver
 611         } else {
 612                 print name " seems ok: " ver
 613         }
 614 }
 615
 616 function process_data(name,ver,rel,src) {
 617         if (name ~ /^php-pear-/) {
 618                 return pear_upgrade(name, ver);
 619         }
 620         if (name == "ZendFramework") {
 621                 return zf_upgrade(name, ver);
 622         }
 623         if (name == "hudson") {
 624                 return hudson_upgrade(name, ver);
 625         }
 626         if (name == "vim") {
 627                 return vim_upgrade(name, ver);
 628         }
 629
 630 # this function checks if substitutions were valid, and if true:
 631 # processes each URL and tries to get current file list
 632         for (i in src) {
 633                 if ( src[i] ~ /%{nil}/ ) {
 634                         gsub(/\%\{nil\}/, "", src[i])
 635                 }
 636                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 637                         d("Source: " src[i])
 638                         process_source(i,src[i],name,ver)
 639                 } else {
 640                         print FNAME ":" i ": impossible substitution: " src[i]
 641                 }
 642         }
 643 }
 644
 645 BEGIN {
 646         # if U want to use DEBUG, run script with "-v DEBUG=1"
 647         # or uncomment the line below
 648         # DEBUG = 1
 649
 650         errno=system("wget --help > /dev/null 2>&1")
 651         if (errno) {
 652                 print "No wget installed!"
 653                 exit 1
 654         }
 655         if (ARGC>=3 && ARGV[2]=="-n") {
 656                 NUMERIC=1
 657                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 658                 ARGC=ARGC-1
 659         }
 660 }
 661
 662 FNR==1 {
 663         if ( ARGIND != 1 ) {
 664                 # clean frameseen for each ARG
 665                 for (i in frameseen) {
 666                         delete frameseen[i]
 667                 }
 668                 frameseen[0] = 1
 669
 670                 process_data(NAME,VER,REL,SRC)
 671                 NAME="" ; VER="" ; REL=""
 672                 for (i in DEFS) delete DEFS[i]
 673                 for (i in SRC) delete SRC[i]
 674         }
 675         FNAME=FILENAME
 676         DEFS["_alt_kernel"]=""
 677         DEFS["20"]="\\ "
 678 }
 679
 680 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 681 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 682 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 683 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 684 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 685 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 686
 687 END {
 688         process_data(NAME,VER,REL,SRC)
 689 }