]> git.pld-linux.org Git - packages/rpm-build-tools.git/blob - pldnotify.awk
pecl.php.net support
[packages/rpm-build-tools.git] / pldnotify.awk
1 #!/bin/awk -f
2 # $Revision$, $Date$
3 #
4 # Copyright (C) 2000-2008 PLD-Team <feedback@pld-linux.org>
5 # Authors:
6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
7 #       Jacek Konieczny <jajcus@pld-linux.org>
8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
9 #       Jakub Bogusz <qboosh@pld-linux.org>
10 #       Elan Ruusamäe <glen@pld-linux.org>
11 #
12 # See cvs log pldnotify.awk for list of contributors
13 #
14 # TODO:
15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
16 # - "SourceXActiveFTP" support
17
18 function fixedsub(s1,s2,t,      ind) {
19 # substitutes fixed strings (not regexps)
20         if (ind = index(t,s1)) {
21                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
22         }
23         return t
24 }
25
26 function ispre(s) {
27         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
28                 if (DEBUG) print "pre-version"
29                 return 1
30         } else {
31                 return 0
32         }
33 }
34
35 function compare_ver(v1,v2) {
36 # compares version numbers
37         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
38                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
39         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
40                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
41         sub("^0*","",v1)
42         sub("^0*","",v2)
43         gsub("\.0*",".",v1)
44         gsub("\.0*",".",v2)
45         if (DEBUG) print "v1 == " v1
46         if (DEBUG) print "v2 == " v2
47         count=split(v1,v1a,"\.")
48         count2=split(v2,v2a,"\.")
49
50         if (count<count2) mincount=count
51         else mincount=count2
52
53         for (i=1; i<=mincount; i++) {
54                 if (v1a[i]=="") v1a[i]=0
55                 if (v2a[i]=="") v2a[i]=0
56                 if (DEBUG) print "i == " i
57                 if (DEBUG) print "v1[i] == " v1a[i]
58                 if (DEBUG) print "v2[i] == " v2a[i]
59                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
60                         if (length(v2a[i])>length(v1a[i]))
61                                 return 1
62                         else if (v2a[i]>v1a[i])
63                                 return 1
64                         else if (length(v1a[i])>length(v2a[i]))
65                                 return 0
66                         else if (v1a[i]>v2a[i])
67                                 return 0
68                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
69                         if (v2a[i]>v1a[i])
70                                 return 1
71                         else if (v1a[i]>v2a[i])
72                                 return 0
73                 } else if (ispre(v1a[i]) == 1)
74                         return 1
75                 else
76                         return 0
77         }
78         if ((count2==mincount)&&(count!=count2)) {
79                 for (i=count2+1; i<=count; i++)
80                         if (ispre(v1a[i]) == 1)
81                                 return 1
82                 return 0
83         } else if (count!=count2) {
84                 for (i=count+1; i<=count2; i++)
85                         if (ispre(v2a[i]) == 1)
86                                 return 0
87                 return 1
88         }
89         return 0
90 }
91
92 function compare_ver_dec(v1,v2) {
93 # compares version numbers as decimal floats
94         while (match(v1,/[0-9][a-zA-Z]/))
95                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
96         while (match(v2,/[0-9][a-zA-Z]/))
97                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
98         sub("^0*","",v1)
99         sub("^0*","",v2)
100         if (DEBUG) print "v1 == " v1
101         if (DEBUG) print "v2 == " v2
102         count=split(v1,v1a,"\.")
103         count2=split(v2,v2a,"\.")
104
105         if (count<count2) mincount=count
106         else mincount=count2
107
108         for (i=1; i<=mincount; i++) {
109                 if (v1a[i]=="") v1a[i]=0
110                 if (v2a[i]=="") v2a[i]=0
111                 if (DEBUG) print "i == " i
112                 if (DEBUG) print "v1[i] == " v1a[i]
113                 if (DEBUG) print "v2[i] == " v2a[i]
114                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
115                         if (i==2) {
116                                 if (0+("." v2a[i])>0+("." v1a[i]))
117                                         return 1
118                                 else if (0+("." v1a[i])>0+("." v2a[i]))
119                                         return 0
120                         } else {
121                                 if (length(v2a[i])>length(v1a[i]))
122                                         return 1
123                                 else if (v2a[i]>v1a[i])
124                                         return 1
125                                 else if (length(v1a[i])>length(v2a[i]))
126                                         return 0
127                                 else if (v1a[i]>v2a[i])
128                                         return 0
129                         }
130                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
131                         if (v2a[i]>v1a[i])
132                                 return 1
133                         else if (v1a[i]>v2a[i])
134                                 return 0
135                 } else if (ispre(v1a[i]) == 1)
136                         return 1
137                 else
138                         return 0
139         }
140         if ((count2==mincount)&&(count!=count2)) {
141                 for (i=count2+1; i<=count; i++)
142                         if (ispre(v1a[i]) == 1)
143                                 return 1
144                 return 0
145         } else if (count!=count2) {
146                 for (i=count+1; i<=count2; i++)
147                         if (ispre(v2a[i]) == 1)
148                                 return 0
149                 return 1
150         }
151         return 0
152 }
153
154 function get_links(url,filename,errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile) {
155 # get all <A HREF=..> tags from specified URL
156         "mktemp /tmp/XXXXXX" | getline tmpfile
157         close("mktemp /tmp/XXXXXX")
158
159         if (url ~ /^http:\/\/(download|dl).(sf|sourceforge).net\//) {
160                 gsub("^http://(download|dl).(sf|sourceforge).net/", "", url)
161                 url = "http://prdownloads.sourceforge.net/" substr(url, 1, 1) "/" substr(url, 1, 2) "/" url
162                 if (DEBUG) print "sf url, mungled url to: " url
163         }
164
165         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
166                 gsub("^http://", "", url)
167                 gsub("\..*", "", url)
168                 url = "http://code.google.com/p/" url "/"
169                 if (DEBUG) print "googlecode url, mungled url to: " url
170         }
171
172         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
173                 gsub("-.*", "", filename)
174                 url = "http://pecl.php.net/package/" filename
175                 if (DEBUG) print "pecl.php.net url, mungled url to: " url
176         }
177
178         if (DEBUG) print "Retrieving: " url
179         errno=system("wget -O - \"" url "\" -t 3 -T 300 --passive-ftp > " tmpfile " 2>/dev/null" )
180
181         if (errno==0) {
182                 while (getline oneline < tmpfile)
183                         wholeodp=(wholeodp " " oneline)
184                 if ( DEBUG ) print "Response: " wholeodp
185         }
186
187         close(tmpfile)
188         system("rm -f " tmpfile)
189         urldir=url;
190         sub(/[^\/]+$/,"",urldir)
191
192         if ( errno==0) {
193                 while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
194                         odp=substr(wholeodp,RSTART,RLENGTH);
195                         wholeodp=substr(wholeodp,RSTART+RLENGTH);
196
197                         lowerodp=tolower(odp);
198                         if (lowerodp ~ /<frame[ \t]/) {
199                                 sub(/[sS][rR][cC]=[ \t]*/,"src=",odp);
200                                 match(odp,/src="[^"]+"/)
201                                 newurl=substr(odp,RSTART+5,RLENGTH-6)
202                                 if (DEBUG) print "Frame: " newurl
203                                 if (newurl !~ /\//) {
204                                         newurl=(urldir newurl)
205                                         if (DEBUG) print "Frame->: " newurl
206                                 }
207                                 retval=(retval " " get_links(newurl))
208                         } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
209                                 sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
210                                 match(odp,/href="[^"]*"/)
211                                 link=substr(odp,RSTART,RLENGTH)
212                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
213                                 link=substr(link,7,length(link)-7)
214                                 retval=(retval " " link)
215                                 if (DEBUG) print "href(\"\"): " link
216                         } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
217                                 sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
218                                 match(odp,/href='[^']*'/)
219                                 link=substr(odp,RSTART,RLENGTH)
220                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
221                                 link=substr(link,7,length(link)-7)
222                                 retval=(retval " " link)
223                                 if (DEBUG) print "href(''): " link
224                         } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
225                                 sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
226                                 match(odp,/href=[^ \t>]*/)
227                                 link=substr(odp,RSTART,RLENGTH)
228                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
229                                 link=substr(link,6,length(link)-5)
230                                 retval=(retval " " link)
231                                 if (DEBUG) print "href(): " link
232                         } else {
233                                 # <a ...> but not href - skip
234                                 if (DEBUG) print "skipping <a > without href: " odp
235                         }
236                 }
237         } else {
238                 retval=("WGET ERROR: " errno)
239         }
240
241
242         if (DEBUG) print "Returning: " retval
243         return retval
244 }
245
246 function subst_defines(var,defs) {
247 # substitute all possible RPM macros
248         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
249                 oldvar=var
250                 for (j in defs) {
251                         gsub("%{" j "}", defs[j], var)
252                         gsub("%" j , defs[j], var)
253                 }
254                 if (var==oldvar) {
255                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
256                         return var
257                 }
258         }
259         return var
260 }
261
262 function find_mirror(url) {
263
264         while (succ = (getline line < "mirrors")) {
265             if (succ==-1) { return url }
266                 nf=split(line,fields,"|")
267                 if (nf>1){
268                         origin=fields[1]
269                         mirror=fields[2]
270                         mname=fields[3]
271                         prefix=substr(url,1,length(origin))
272                         if (prefix==origin){
273                                 if ( DEBUG ) print "Mirror fount at " mname
274                                 close("mirrors")
275                                 return mirror substr(url,length(origin)+1)
276                         }
277                 }
278         }
279
280         return url
281 }
282
283 function process_source(number,lurl,name,version) {
284 # fetches file list, and compares version numbers
285         if ( DEBUG ) print "Processing " lurl
286
287         if ( index(lurl,version)==0 ) {
288                 if (DEBUG) print "There is no version number."
289                 return 0
290         }
291
292         sub("://",":",lurl)
293         sub("/",":/",lurl)
294         gsub("[^/]*$",":&",lurl)
295         split(lurl,url,":")
296         acc=url[1]
297         host=url[2]
298         dir=url[3]
299         filename=url[4]
300
301         if (index(dir,version)) {
302                 dir=substr(dir,1,index(dir,version)-1)
303                 sub("[^/]*$","",dir)
304                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
305                 if ( DEBUG ) print "Will check a directory: " dir
306                 if ( DEBUG ) print "and a file: " filename
307         }
308
309         filenameexp=filename
310         gsub("\+","\\+",filenameexp)
311         sub(version,"[A-Za-z0-9.]+",filenameexp)
312         gsub("\.","\\.",filenameexp)
313         if ( DEBUG ) print "Expression: " filenameexp
314         match(filename,version)
315         prever=substr(filename,1,RSTART-1)
316         postver=substr(filename,RSTART+RLENGTH)
317         if ( DEBUG ) print "Before number: " prever
318         if ( DEBUG ) print "and after: " postver
319         newurl=find_mirror(acc "://" host dir)
320         #print acc "://" host dir
321         #newurl=url[1]"://"url[2]url[3]url[4]
322         #newurl=acc "://" host dir filename
323         if ( DEBUG ) print "Looking at " newurl
324
325         references=0
326         finished=0
327         oldversion=version
328         odp=get_links(newurl,filename)
329         if( odp ~ "ERROR: ") {
330                 print name "(" number ") " odp
331         } else {
332                 if (DEBUG) print "WebPage downloaded"
333                 c=split(odp,linki)
334                 for (nr=1; nr<=c; nr++) {
335                         addr=linki[nr]
336                         if (DEBUG) print "Found link: " addr
337                         if ((addr ~ filenameexp) && !(addr ~ "[-_.0-9A-Za-z~]" filenameexp)) {
338                                 match(addr,filenameexp)
339                                 newfilename=substr(addr,RSTART,RLENGTH)
340                                 if (DEBUG) print "Hypothetical new: " newfilename
341                                 newfilename=fixedsub(prever,"",newfilename)
342                                 newfilename=fixedsub(postver,"",newfilename)
343                                 if (DEBUG) print "Version: " newfilename
344                                 if (newfilename ~ /\.(pkg|bin|binary|built)$/) continue
345                                 if (NUMERIC) {
346                                         if ( compare_ver_dec(version, newfilename)==1 ) {
347                                                 if (DEBUG) print "Yes, there is new one"
348                                                 version=newfilename
349                                                 finished=1
350                                         }
351                                 } else if ( compare_ver(version, newfilename)==1 ) {
352                                         if (DEBUG) print "Yes, there is new one"
353                                         version=newfilename
354                                         finished=1
355                                 }
356                         }
357                 }
358                 if (finished==0)
359                         print name "(" number ") seems ok: " oldversion
360                 else
361                         print name "(" number ") [OLD] " oldversion " [NEW] " version
362         }
363 }
364
365 # upgrade check for pear package using PEAR CLI
366 function pear_upgrade(name, ver) {
367         pname = name;
368         sub(/^php-pear-/, "", pname);
369
370         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
371         if (DEBUG) {
372                 print "pearcmd: " pearcmd
373         }
374         pearcmd | getline nver
375         close(pearcmd)
376
377         if (compare_ver(ver, nver)) {
378                 print name " [OLD] " ver " [NEW] " nver
379         } else {
380                 print name " seems ok: " ver
381         }
382
383         return
384 }
385
386 function process_data(name,ver,rel,src) {
387         if (name ~ /^php-pear-/) {
388                 return pear_upgrade(name, ver);
389         }
390
391 # this function checks if substitutions were valid, and if true:
392 # processes each URL and tries to get current file list
393         for (i in src) {
394                 if ( src[i] ~ /%{nil}/ ) {
395                         gsub(/\%\{nil\}/, "", src[i])
396                 }
397                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
398                         if ( DEBUG ) print "Source: " src[i]
399                         process_source(i,src[i],name,ver)
400                 } else {
401                         print FNAME ":" i ": impossible substitution: " src[i]
402                 }
403         }
404 }
405
406 BEGIN {
407         # if U want to use DEBUG, run script with "-v DEBUG=1"
408         # or uncomment the line below
409         # DEBUG = 1
410
411         errno=system("wget --help > /dev/null 2>&1")
412         if (errno) {
413                 print "No wget installed!"
414                 exit 1
415         }
416         if (ARGC>=3 && ARGV[2]=="-n") {
417                 NUMERIC=1
418                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
419                 ARGC=ARGC-1
420         }
421 }
422
423 FNR==1 {
424         if ( ARGIND != 1 ) {
425                 process_data(NAME,VER,REL,SRC)
426                 NAME="" ; VER="" ; REL=""
427                 for (i in DEFS) delete DEFS[i]
428                 for (i in SRC) delete SRC[i]
429         }
430         FNAME=FILENAME
431 }
432
433 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
434 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
435 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
436 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
437 /^[Ss]ource[0-9]*:/ { if (/(ftp|http):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
438 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
439
440 END {
441         process_data(NAME,VER,REL,SRC)
442 }
This page took 0.119279 seconds and 4 git commands to generate.