pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 #
   4 # Copyright (C) 2000-2008 PLD-Team <feedback@pld-linux.org>
   5 # Authors:
   6 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   7 #       Jacek Konieczny <jajcus@pld-linux.org>
   8 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   9 #       Jakub Bogusz <qboosh@pld-linux.org>
  10 #       Elan Ruusamäe <glen@pld-linux.org>
  11 #
  12 # See cvs log pldnotify.awk for list of contributors
  13 #
  14 # TODO:
  15 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  16 # - "SourceXActiveFTP" support
  17
  18 function fixedsub(s1,s2,t,      ind) {
  19 # substitutes fixed strings (not regexps)
  20         if (ind = index(t,s1)) {
  21                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  22         }
  23         return t
  24 }
  25
  26 function ispre(s) {
  27         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  28                 if (DEBUG) print "pre-version"
  29                 return 1
  30         } else {
  31                 return 0
  32         }
  33 }
  34
  35 function compare_ver(v1,v2) {
  36 # compares version numbers
  37         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  38                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  39         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  40                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  41         sub("^0*","",v1)
  42         sub("^0*","",v2)
  43         gsub("\.0*",".",v1)
  44         gsub("\.0*",".",v2)
  45         if (DEBUG) print "v1 == " v1
  46         if (DEBUG) print "v2 == " v2
  47         count=split(v1,v1a,"\.")
  48         count2=split(v2,v2a,"\.")
  49
  50         if (count<count2) mincount=count
  51         else mincount=count2
  52
  53         for (i=1; i<=mincount; i++) {
  54                 if (v1a[i]=="") v1a[i]=0
  55                 if (v2a[i]=="") v2a[i]=0
  56                 if (DEBUG) print "i == " i
  57                 if (DEBUG) print "v1[i] == " v1a[i]
  58                 if (DEBUG) print "v2[i] == " v2a[i]
  59                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  60                         if (length(v2a[i])>length(v1a[i]))
  61                                 return 1
  62                         else if (v2a[i]>v1a[i])
  63                                 return 1
  64                         else if (length(v1a[i])>length(v2a[i]))
  65                                 return 0
  66                         else if (v1a[i]>v2a[i])
  67                                 return 0
  68                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  69                         if (v2a[i]>v1a[i])
  70                                 return 1
  71                         else if (v1a[i]>v2a[i])
  72                                 return 0
  73                 } else if (ispre(v1a[i]) == 1)
  74                         return 1
  75                 else
  76                         return 0
  77         }
  78         if ((count2==mincount)&&(count!=count2)) {
  79                 for (i=count2+1; i<=count; i++)
  80                         if (ispre(v1a[i]) == 1)
  81                                 return 1
  82                 return 0
  83         } else if (count!=count2) {
  84                 for (i=count+1; i<=count2; i++)
  85                         if (ispre(v2a[i]) == 1)
  86                                 return 0
  87                 return 1
  88         }
  89         return 0
  90 }
  91
  92 function compare_ver_dec(v1,v2) {
  93 # compares version numbers as decimal floats
  94         while (match(v1,/[0-9][a-zA-Z]/))
  95                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  96         while (match(v2,/[0-9][a-zA-Z]/))
  97                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  98         sub("^0*","",v1)
  99         sub("^0*","",v2)
 100         if (DEBUG) print "v1 == " v1
 101         if (DEBUG) print "v2 == " v2
 102         count=split(v1,v1a,"\.")
 103         count2=split(v2,v2a,"\.")
 104
 105         if (count<count2) mincount=count
 106         else mincount=count2
 107
 108         for (i=1; i<=mincount; i++) {
 109                 if (v1a[i]=="") v1a[i]=0
 110                 if (v2a[i]=="") v2a[i]=0
 111                 if (DEBUG) print "i == " i
 112                 if (DEBUG) print "v1[i] == " v1a[i]
 113                 if (DEBUG) print "v2[i] == " v2a[i]
 114                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 115                         if (i==2) {
 116                                 if (0+("." v2a[i])>0+("." v1a[i]))
 117                                         return 1
 118                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 119                                         return 0
 120                         } else {
 121                                 if (length(v2a[i])>length(v1a[i]))
 122                                         return 1
 123                                 else if (v2a[i]>v1a[i])
 124                                         return 1
 125                                 else if (length(v1a[i])>length(v2a[i]))
 126                                         return 0
 127                                 else if (v1a[i]>v2a[i])
 128                                         return 0
 129                         }
 130                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 131                         if (v2a[i]>v1a[i])
 132                                 return 1
 133                         else if (v1a[i]>v2a[i])
 134                                 return 0
 135                 } else if (ispre(v1a[i]) == 1)
 136                         return 1
 137                 else
 138                         return 0
 139         }
 140         if ((count2==mincount)&&(count!=count2)) {
 141                 for (i=count2+1; i<=count; i++)
 142                         if (ispre(v1a[i]) == 1)
 143                                 return 1
 144                 return 0
 145         } else if (count!=count2) {
 146                 for (i=count+1; i<=count2; i++)
 147                         if (ispre(v2a[i]) == 1)
 148                                 return 0
 149                 return 1
 150         }
 151         return 0
 152 }
 153
 154 function link_seen(link) {
 155         for (seenlink in frameseen) {
 156                 if (seenlink == link) {
 157                         if (DEBUG) print "Link: [" link "] seen already, skipping..."
 158                         return 1
 159                 }
 160         }
 161         frameseen[link]=1
 162         return 0
 163 }
 164
 165 function mktemp(   _cmd, _tmpfile) {
 166         _cmd = "mktemp /tmp/XXXXXX"
 167         _cmd | getline _tmpfile
 168         close(_cmd)
 169         return _tmpfile
 170 }
 171
 172 # get all <A HREF=..> tags from specified URL
 173 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile) {
 174
 175         wholeerr=""
 176
 177         tmpfile = mktemp()
 178         tmpfileerr = mktemp()
 179
 180         if (url ~ /^http:\/\/(download|dl).(sf|sourceforge).net\//) {
 181                 gsub("^http://(download|dl).(sf|sourceforge).net/", "", url)
 182                 url = "http://prdownloads.sourceforge.net/" substr(url, 1, 1) "/" substr(url, 1, 2) "/" url
 183                 if (DEBUG) print "sf url, mungled url to: " url
 184         }
 185
 186         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 187                 gsub("^http://", "", url)
 188                 gsub("\..*", "", url)
 189                 url = "http://code.google.com/p/" url "/downloads/list"
 190                 if (DEBUG) print "googlecode url, mungled url to: " url
 191         }
 192
 193         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 194                 gsub("-.*", "", filename)
 195                 url = "http://pecl.php.net/package/" filename
 196                 if (DEBUG) print "pecl.php.net url, mungled url to: " url
 197         }
 198
 199         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 200                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 201                  if (DEBUG) print "mysql 5.1 url, mungled url to: " url
 202         }
 203
 204
 205         if (DEBUG) print "Retrieving: " url
 206         errno=system("wget -nv -O - \"" url "\" -t 2 -T 45 --passive-ftp > " tmpfile " 2> " tmpfileerr )
 207
 208         if (errno==0) {
 209                 while (getline oneline < tmpfile)
 210                         wholeodp=(wholeodp " " oneline)
 211                 if ( DEBUG ) print "Response: " wholeodp
 212         } else {
 213                 wholeerr = ""
 214                 while (getline oneline < tmpfileerr)
 215                         wholeerr=(wholeerr " " oneline)
 216                 if ( DEBUG ) print "Error Response: " wholeerr
 217         }
 218
 219         system("rm -f " tmpfile)
 220         system("rm -f " tmpfileerr)
 221
 222         urldir=url;
 223         sub(/[^\/]+$/,"",urldir)
 224
 225         if ( errno==0) {
 226                 while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 227                         odp=substr(wholeodp,RSTART,RLENGTH);
 228                         wholeodp=substr(wholeodp,RSTART+RLENGTH);
 229
 230                         lowerodp=tolower(odp);
 231                         if (lowerodp ~ /<frame[ \t]/) {
 232                                 sub(/[sS][rR][cC]=[ \t]*/,"src=",odp);
 233                                 match(odp,/src="[^"]+"/)
 234                                 newurl=substr(odp,RSTART+5,RLENGTH-6)
 235                                 if (DEBUG) print "Frame: " newurl
 236                                 if (newurl !~ /\//) {
 237                                         newurl=(urldir newurl)
 238                                         if (DEBUG) print "Frame->: " newurl
 239                                 }
 240
 241                                 if (link_seen(newurl)) {
 242                                         newurl=""
 243                                         continue
 244                                 }
 245
 246                                 retval=(retval " " get_links(newurl))
 247                         } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 248                                 sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 249                                 match(odp,/href="[^"]*"/)
 250                                 link=substr(odp,RSTART,RLENGTH)
 251                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 252                                 link=substr(link,7,length(link)-7)
 253
 254                                 if (link_seen(link)) {
 255                                         link=""
 256                                         continue
 257                                 }
 258
 259                                 retval=(retval " " link)
 260                                 if (DEBUG) print "href(\"\"): " link
 261                         } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 262                                 sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 263                                 match(odp,/href='[^']*'/)
 264                                 link=substr(odp,RSTART,RLENGTH)
 265                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 266                                 link=substr(link,7,length(link)-7)
 267
 268                                 if (link_seen(link)) {
 269                                         link=""
 270                                         continue
 271                                 }
 272
 273                                 retval=(retval " " link)
 274                                 if (DEBUG) print "href(''): " link
 275                         } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 276                                 sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 277                                 match(odp,/href=[^ \t>]*/)
 278                                 link=substr(odp,RSTART,RLENGTH)
 279                                 odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 280                                 link=substr(link,6,length(link)-5)
 281
 282                                 if (link_seen(link)) {
 283                                         link=""
 284                                         continue
 285                                 }
 286
 287                                 retval=(retval " " link)
 288                                 if (DEBUG) print "href(): " link
 289                         } else {
 290                                 # <a ...> but not href - skip
 291                                 if (DEBUG) print "skipping <a > without href: " odp
 292                         }
 293                 }
 294         } else {
 295                 retval=("WGET ERROR: " errno ": " wholeerr)
 296         }
 297
 298
 299         if (DEBUG) print "Returning: " retval
 300         return retval
 301 }
 302
 303 function subst_defines(var,defs) {
 304 # substitute all possible RPM macros
 305         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 306                 oldvar=var
 307                 for (j in defs) {
 308                         gsub("%{" j "}", defs[j], var)
 309                         gsub("%" j , defs[j], var)
 310                 }
 311                 if (var==oldvar) {
 312                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 313                         return var
 314                 }
 315         }
 316         return var
 317 }
 318
 319 function find_mirror(url) {
 320
 321         while (succ = (getline line < "mirrors")) {
 322             if (succ==-1) { return url }
 323                 nf=split(line,fields,"|")
 324                 if (nf>1){
 325                         origin=fields[1]
 326                         mirror=fields[2]
 327                         mname=fields[3]
 328                         prefix=substr(url,1,length(origin))
 329                         if (prefix==origin){
 330                                 if ( DEBUG ) print "Mirror fount at " mname
 331                                 close("mirrors")
 332                                 return mirror substr(url,length(origin)+1)
 333                         }
 334                 }
 335         }
 336
 337         return url
 338 }
 339
 340 function process_source(number,lurl,name,version) {
 341 # fetches file list, and compares version numbers
 342         if ( DEBUG ) print "Processing " lurl
 343
 344         if ( index(lurl,version)==0 ) {
 345                 if (DEBUG) print "There is no version number."
 346                 return 0
 347         }
 348
 349         sub("://",":",lurl)
 350         sub("/",":/",lurl)
 351         gsub("[^/]*$",":&",lurl)
 352         split(lurl,url,":")
 353         acc=url[1]
 354         host=url[2]
 355         dir=url[3]
 356         filename=url[4]
 357
 358         if (index(dir,version)) {
 359                 dir=substr(dir,1,index(dir,version)-1)
 360                 sub("[^/]*$","",dir)
 361                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 362                 if ( DEBUG ) print "Will check a directory: " dir
 363                 if ( DEBUG ) print "and a file: " filename
 364         }
 365
 366         filenameexp=filename
 367         gsub("\+","\\+",filenameexp)
 368         sub(version,"[A-Za-z0-9.]+",filenameexp)
 369         gsub("\.","\\.",filenameexp)
 370         if ( DEBUG ) print "Expression: " filenameexp
 371         match(filename,version)
 372         prever=substr(filename,1,RSTART-1)
 373         postver=substr(filename,RSTART+RLENGTH)
 374         if ( DEBUG ) print "Before number: " prever
 375         if ( DEBUG ) print "and after: " postver
 376         newurl=find_mirror(acc "://" host dir)
 377         #print acc "://" host dir
 378         #newurl=url[1]"://"url[2]url[3]url[4]
 379         #newurl=acc "://" host dir filename
 380         if ( DEBUG ) print "Looking at " newurl
 381
 382         references=0
 383         finished=0
 384         oldversion=version
 385         odp=get_links(newurl,filename)
 386         if( odp ~ "ERROR: ") {
 387                 print name "(" number ") " odp
 388         } else {
 389                 if (DEBUG) print "WebPage downloaded"
 390                 c=split(odp,linki)
 391                 for (nr=1; nr<=c; nr++) {
 392                         addr=linki[nr]
 393                         if (DEBUG) print "Found link: " addr
 394                         if ((addr ~ filenameexp) && !(addr ~ "[-_.0-9A-Za-z~]" filenameexp)) {
 395                                 match(addr,filenameexp)
 396                                 newfilename=substr(addr,RSTART,RLENGTH)
 397                                 if (DEBUG) print "Hypothetical new: " newfilename
 398                                 newfilename=fixedsub(prever,"",newfilename)
 399                                 newfilename=fixedsub(postver,"",newfilename)
 400                                 if (DEBUG) print "Version: " newfilename
 401                                 if (newfilename ~ /\.(pkg|bin|binary|built)$/) continue
 402                                 if (NUMERIC) {
 403                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 404                                                 if (DEBUG) print "Yes, there is new one"
 405                                                 version=newfilename
 406                                                 finished=1
 407                                         }
 408                                 } else if ( compare_ver(version, newfilename)==1 ) {
 409                                         if (DEBUG) print "Yes, there is new one"
 410                                         version=newfilename
 411                                         finished=1
 412                                 }
 413                         }
 414                 }
 415                 if (finished==0)
 416                         print name "(" number ") seems ok: " oldversion
 417                 else
 418                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 419         }
 420 }
 421
 422 # upgrade check for pear package using PEAR CLI
 423 function pear_upgrade(name, ver) {
 424         pname = name;
 425         sub(/^php-pear-/, "", pname);
 426
 427         pearcmd = "pear remote-info " pname " | awk '/^Latest/{print $NF}'"
 428         if (DEBUG) {
 429                 print "pearcmd: " pearcmd
 430         }
 431         pearcmd | getline nver
 432         close(pearcmd)
 433
 434         if (compare_ver(ver, nver)) {
 435                 print name " [OLD] " ver " [NEW] " nver
 436         } else {
 437                 print name " seems ok: " ver
 438         }
 439
 440         return
 441 }
 442
 443 function process_data(name,ver,rel,src) {
 444         if (name ~ /^php-pear-/) {
 445                 return pear_upgrade(name, ver);
 446         }
 447
 448 # this function checks if substitutions were valid, and if true:
 449 # processes each URL and tries to get current file list
 450         for (i in src) {
 451                 if ( src[i] ~ /%{nil}/ ) {
 452                         gsub(/\%\{nil\}/, "", src[i])
 453                 }
 454                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 455                         if ( DEBUG ) print "Source: " src[i]
 456                         process_source(i,src[i],name,ver)
 457                 } else {
 458                         print FNAME ":" i ": impossible substitution: " src[i]
 459                 }
 460         }
 461 }
 462
 463 BEGIN {
 464         # if U want to use DEBUG, run script with "-v DEBUG=1"
 465         # or uncomment the line below
 466         # DEBUG = 1
 467
 468         errno=system("wget --help > /dev/null 2>&1")
 469         if (errno) {
 470                 print "No wget installed!"
 471                 exit 1
 472         }
 473         if (ARGC>=3 && ARGV[2]=="-n") {
 474                 NUMERIC=1
 475                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 476                 ARGC=ARGC-1
 477         }
 478         frameseen[0] = 1
 479 }
 480
 481 FNR==1 {
 482         if ( ARGIND != 1 ) {
 483                 process_data(NAME,VER,REL,SRC)
 484                 NAME="" ; VER="" ; REL=""
 485                 for (i in DEFS) delete DEFS[i]
 486                 for (i in SRC) delete SRC[i]
 487         }
 488         FNAME=FILENAME
 489         DEFS["_alt_kernel"]=""
 490         DEFS["20"]="\\ "
 491 }
 492
 493 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 494 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 495 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 496 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 497 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 498 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 499
 500 END {
 501         process_data(NAME,VER,REL,SRC)
 502 }