pldnotify.awk

   1 #!/bin/awk -f
   2 # $Revision$, $Date$
   3 function fixedsub(s1,s2,t,      ind) {
   4 # substitutes fixed strings (not regexps)
   5         if (ind = index(t,s1)) {
   6                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
   7         }
   8         return t
   9 }
  10
  11 function compare_ver(v1,v2) {
  12 # compares version numbers
  13         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  14                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  15         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  16                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  17         sub("^0*","",v1)
  18         sub("^0*","",v2)
  19         if (DEBUG) print "v1 == " v1
  20         if (DEBUG) print "v2 == " v2
  21         count=split(v1,v1a,"\.")
  22         count2=split(v2,v2a,"\.")
  23
  24         if (count<count2) mincount=count
  25         else mincount=count2
  26
  27         for (i=1; i<=mincount; i++) {
  28                 if (v1a[i]=="") v1a[i]=0
  29                 if (v2a[i]=="") v2a[i]=0
  30                 if (DEBUG) print "i == " i
  31                 if (DEBUG) print "v1[i] == " v1a[i]
  32                 if (DEBUG) print "v2[i] == " v2a[i]
  33                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  34                         if (length(v2a[i])>length(v1a[i]))
  35                                 return 1
  36                         else if (v2a[i]>v1a[i])
  37                                 return 1
  38                         else if (length(v1a[i])>length(v2a[i]))
  39                                 return 0
  40                         else if (v1a[i]>v2a[i])
  41                                 return 0
  42                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  43                         if (v2a[i]>v1a[i])
  44                                 return 1
  45                         else if (v1a[i]>v2a[i])
  46                                 return 0
  47                 } else if ((v1a[i]~"pre")||(v1a[i]~"beta")||(v1a[i]~"alpha"))
  48                         return 1
  49                 else
  50                         return 0
  51         }
  52         if ((count2==mincount)&&(count!=count2)) {
  53                 for (i=count2+1; i<=count; i++)
  54                         if ((v1a[i]~"pre")||(v1a[i]~"beta")||(v1a[i]~"alpha"))
  55                                 return 1
  56                 return 0
  57         } else if (count!=count2) {
  58                 for (i=count+1; i<=count2; i++)
  59                         if ((v2a[i]~"pre")||(v2a[i]~"beta")||(v2a[i]~"alpha"))
  60                                 return 0
  61                 return 1
  62         }
  63         return 0
  64 }
  65
  66 function get_links(url, errno,link,oneline,retval,odp,tmpfile) {
  67 # get all <A HREF=..> tags from specified URL
  68         "mktemp /tmp/XXXXXX" | getline tmpfile
  69         close("mktemp /tmp/XXXXXX")
  70
  71         if (DEBUG) print "Retrieving: " url
  72         errno=system("wget -O - \"" url "\" -t 1 -T 300 --passive-ftp > " tmpfile " 2>/dev/null" )
  73
  74         if (errno==0) {
  75                 while (getline oneline < tmpfile)
  76                         odp=(odp " " oneline)
  77                 if ( DEBUG ) print "Odpowiedz: " odp
  78         }
  79
  80         close(tmpfile)
  81         system("rm -f " tmpfile)
  82         urldir=url;
  83         sub(/[^\/]+$/,"",urldir)
  84         if ( errno==0) {
  85                 while ((tolower(odp) ~ /<frame[ \t]/)||(tolower(odp) ~ /href=/)) {
  86                         if (tolower(odp) ~ /<frame[ \t]/) {
  87                                 match(tolower(odp),/<frame[ \t][^>]*>/)
  88                                 ramka=substr(odp,RSTART,RLENGTH)
  89                                 odp=substr(odp,RSTART+RLENGTH)
  90                                 sub(/[sS][rR][cC]=[ \t]+/,"src=",ramka);
  91                                 match(tolower(ramka),/src="[^"]+"/)
  92                                 newurl=substr(ramka,RSTART+5,RLENGTH-6)
  93                                 if (DEBUG) print "Ramka: " newurl
  94                                 if (newurl !~ /\//) {
  95                                         newurl=(urldir newurl)
  96                                         if (DEBUG) print "Ramka->: " newurl
  97                                 }
  98                                 retval=(retval " " get_links(newurl))
  99                         } else if (tolower(odp) ~ /href=[ \t]*"[^"]+"/) {
 100                                 sub(/[hH][rR][eE][fF]=[ \t]+/,"href=",odp)
 101                                 match(tolower(odp),/href="[^"]+"/)
 102                                 link=substr(odp,RSTART,RLENGTH)
 103                                 odp=substr(odp,RSTART+RLENGTH)
 104                                 link=substr(link,7,length(link)-7)
 105                                 retval=(retval " " link)
 106                         } else if (tolower(odp) ~ /href=[ \t]*[^ \t>]+/) {
 107                                 sub(/[hH][rR][eE][fF]=[ \t]+/,"href=",odp)
 108                                 match(tolower(odp),/href=[^ \t>]+/)
 109                                 link=substr(odp,RSTART,RLENGTH)
 110                                 odp=substr(odp,RSTART+RLENGTH)
 111                                 link=substr(link,6,length(link)-5)
 112                                 retval=(retval " " link)
 113                         } else {
 114                                 retval=(retval " INTERNAL_ERROR")
 115                                 break
 116                         }
 117                 }
 118         } else {
 119                 retval=("WGET ERROR: " errno)
 120         }
 121
 122
 123         if (DEBUG) print "Zwracane: " retval
 124         return retval
 125 }
 126
 127 function subst_defines(var,defs) {
 128 # substitute all possible RPM macros
 129         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 130                 oldvar=var
 131                 for (j in defs) {
 132                         gsub("%{" j "}", defs[j], var)
 133                         gsub("%" j , defs[j], var)
 134                 }
 135                 if (var==oldvar) {
 136                         if ( DEBUG ) for (i in defs) print i " == " defs[i]
 137                         return var
 138                 }
 139         }
 140         return var
 141 }
 142
 143 function find_mirror(url) {
 144
 145         while (succ = (getline line < "mirrors")) {
 146             if (succ==-1) { return url }
 147                 nf=split(line,fields,"|")
 148                 if (nf>1){
 149                         origin=fields[1]
 150                         mirror=fields[2]
 151                         mname=fields[3]
 152                         prefix=substr(url,1,length(origin))
 153                         if (prefix==origin){
 154                                 if ( DEBUG ) print "Mirror znaleziony na " mname
 155                                 close("mirrors")
 156                                 return mirror substr(url,length(origin))
 157                         }
 158                 }
 159         }
 160
 161         return url
 162 }
 163
 164 function process_source(number,lurl,name,version) {
 165 # fetches file list, and compares version numbers
 166         if ( DEBUG ) print "Przetwarzam " lurl
 167
 168         if ( index(lurl,version)==0 ) {
 169                 if (DEBUG) print "Nie ma numeru wersji."
 170                 return 0
 171         }
 172
 173         sub("://",":",lurl)
 174         sub("/",":/",lurl)
 175         gsub("[^/]*$",":&",lurl)
 176         split(lurl,url,":")
 177         acc=url[1]
 178         host=url[2]
 179         dir=url[3]
 180         filename=url[4]
 181
 182         if (index(dir,version)) {
 183                 dir=substr(dir,1,index(dir,version)-1)
 184                 sub("[^/]*$","",dir)
 185                 sub("(\.tar\.(bz|bz2|gz)|zip)$","",filename)
 186                 if ( DEBUG ) print "Sprawdze katalog: " dir
 187                 if ( DEBUG ) print "i plik: " filename
 188         }
 189
 190         filenameexp=filename
 191         gsub("\+","\\+",filenameexp)
 192         sub(version,"[A-Za-z0-9\\.]+",filenameexp)
 193         if ( DEBUG ) print "Wzorzec: " filenameexp
 194         match(filename,version)
 195         prever=substr(filename,1,RSTART-1)
 196         postver=substr(filename,RSTART+RLENGTH)
 197         if ( DEBUG ) print "Przed numerkiem: " prever
 198         if ( DEBUG ) print "i po: " postver
 199         newurl=find_mirror(acc "://" host dir)
 200         #print acc "://" host dir
 201         #newurl=url[1]"://"url[2]url[3]url[4]
 202         #newurl=acc "://" host dir filename
 203         if ( DEBUG ) print "Zagl±dam na " newurl
 204
 205         references=0
 206         finished=0
 207         oldversion=version
 208         odp=get_links(newurl)
 209         if( odp ~ "ERROR: ") {
 210                 print name "(" number ") " odp
 211         } else {
 212                 if (DEBUG) print "Sciagnieta strona"
 213                 c=split(odp,linki)
 214                 for (nr=1; nr<=c; nr++) {
 215                         addr=linki[nr]
 216                         if (DEBUG) print "Znaleziony link: " addr
 217                         if (addr ~ filenameexp) {
 218                                 match(addr,filenameexp)
 219                                 newfilename=substr(addr,RSTART,RLENGTH)
 220                                 if (DEBUG) print "Hipotetyczny nowy: " newfilename
 221                                 newfilename=fixedsub(prever,"",newfilename)
 222                                 newfilename=fixedsub(postver,"",newfilename)
 223                                 if (DEBUG) print "Wersja: " newfilename
 224                                 if ( compare_ver(version, newfilename)==1 ) {
 225                                         if (DEBUG) print "Tak, jest nowa"
 226                                         version=newfilename
 227                                         finished=1
 228                                 }
 229                         }
 230                 }
 231                 if (finished==0)
 232                         print name "(" number ") seems ok: " oldversion
 233                 else
 234                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 235         }
 236 }
 237
 238 function process_data(name,ver,rel,src) {
 239 # this function checks if substitutions were valid, and if true:
 240 # processes each URL and tries to get current file list
 241         for (i in src) {
 242                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 243                         if ( DEBUG ) print "Zrodlo: " src[i]
 244                         process_source(i,src[i],name,ver)
 245                 } else {
 246                         print FNAME ":" i ": niemozliwe podstawienie: " src[i]
 247                 }
 248         }
 249 }
 250
 251 BEGIN {
 252         # if U want to use DEBUG, run script with "-v DEBUG=1"
 253         # or uncomment the line below
 254         # DEBUG = 1
 255
 256         errno=system("wget --help > /dev/null 2>&1")
 257         if (errno) {
 258                 print "No wget installed!"
 259                 exit 1
 260         }
 261 }
 262
 263 FNR==1 {
 264         if ( ARGIND != 1 ) {
 265                 process_data(NAME,VER,REL,SRC)
 266                 NAME="" ; VER="" ; REL=""
 267                 for (i in DEFS) delete DEFS[i]
 268                 for (i in SRC) delete SRC[i]
 269         }
 270         FNAME=FILENAME
 271 }
 272
 273 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 274 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 275 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 276 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 277 /^[Ss]ource[0-9]*:/ { if (/(ftp|http):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 278 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 279
 280 END {
 281         process_data(NAME,VER,REL,SRC)
 282 }