adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # Adapter adapts .spec files for PLD Linux.
   4 #
   5 # Copyright (C) 1999-2007 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Michał Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Jakub Bogusz <qboosh@pld-linux.org>
  13 #       Elan Ruusamäe <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - really long sourceX make preamble sorting totally fcked up (try snake.spec r1.1)
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27
  28 BEGIN {
  29         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  30         SECTIONS = "^%(" RPM_SECTIONS ")"
  31
  32         RCSID = "$Id$"
  33         rev = RCSID # TODO: parse from RCSID
  34         VERSION = "0.31/" rev
  35
  36         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests)"
  37
  38         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  39
  40         preamble = 1    # Is it part of preamble? Default - yes
  41         boc = 4                 # Beginning of %changelog
  42         bod = 0                 # Beginning of %description
  43         tw = 70                 # Descriptions width
  44
  45         b_idx = 0               # index of BR/R arrays
  46         BR_count = 0    # number of additional BuildRequires
  47
  48         # If variable removed, then 1 (for removing it from export)
  49         removed["LDFLAGS"] = 0
  50         removed["CFLAGS"] = 0
  51         removed["CXXFLAGS"] = 0
  52
  53         # If 1, we are inside of comment block (started with /^#%/)
  54         comment_block = 0
  55
  56         import_rpm_macros()
  57
  58         groups_file = sourcedir "/rpm.groups"
  59
  60         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  61         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  62
  63         # Temporary file for changelog section
  64         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  65 }
  66
  67 # There should be a comment with CVS keywords on the first line of file.
  68 FNR == 1 {
  69         if (!/# \$Revision:/)   # If this line is already OK?
  70                 print "# $" "Revision:$, " "$" "Date:$" # No
  71         else {
  72                 print $0                                # Yes
  73                 next            # It is enough for first line
  74         }
  75 }
  76
  77 # If the latest line matched /%files/
  78 defattr == 1 {
  79         if (ENVIRON["SKIP_DEFATTR"] != 1) {
  80                 if ($0 !~ /defattr/) {  # If no %defattr
  81                         print "%defattr(644,root,root,755)"     # Add it
  82                 } else {
  83                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  84                 }
  85         }
  86         defattr = 0
  87 }
  88
  89 function b_makekey(a, b,        s) {
  90         s = a "" b;
  91         # kill bcond
  92         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
  93
  94         # kill commented out items
  95         gsub(/^#[ \t]*/, "", s);
  96
  97         # force order
  98         gsub(/^Summary\(/, "11Summary(", s);
  99         gsub(/^Summary/, "10Summary", s);
 100         gsub(/^Name/, "2Name", s);
 101         gsub(/^Version/, "3Version", s);
 102         gsub(/^Release/, "4Release", s);
 103         gsub(/^Epoch/, "5Epoch", s);
 104         gsub(/^License/, "5License", s);
 105         gsub(/^Group/, "6Group", s);
 106         gsub(/^URL/, "7URL", s);
 107
 108         gsub(/^BuildRequires/, "B1BuildRequires", s);
 109         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 110
 111         gsub(/^Suggests/, "X1Suggests", s);
 112         gsub(/^Provides/, "X2Provides", s);
 113         gsub(/^Obsoletes/, "X3Obsoletes", s);
 114         gsub(/^Conflicts/, "X4Conflicts", s);
 115         gsub(/^BuildArch/, "X5BuildArch", s);
 116         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 117         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 118         gsub(/^BuildRoot/, "X9BuildRoot", s);
 119
 120 #       printf("%s -> %s\n", a""b, s);
 121         return s;
 122 }
 123
 124 # Comments
 125 /^#/ && (description == 0) {
 126         if (/This file does not like to be adapterized!/) {
 127                 print                   # print this message
 128                 while (getline)         # print the rest of spec as it is
 129                         print
 130                 do_not_touch_anything = 1 # do not touch anything in END()
 131                 exit 0
 132         }
 133
 134         # Generally, comments are printed without touching
 135         sub(/[ \t]+$/, "")
 136
 137         if (/#[ \t]*Source.*md5/) {
 138                 if (usedigest == 1) {
 139                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 140                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 141                 }
 142                 print $0
 143                 next
 144         }
 145 }
 146
 147 /^%define/ {
 148         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 149         if ($2 == "_applnkdir") {
 150                 next
 151         }
 152         if ($2 == "date") {
 153                 date = 1
 154                 if (did_files == 0) {
 155                         print "%files"
 156                         print ""
 157                         did_files = 1
 158                 }
 159         }
 160
 161         # Do not add %define of _prefix if it already is.
 162         if ($2 ~ /^_prefix/) {
 163                 sub("^"prefix, $3, bindir)
 164                 sub("^"prefix, $3, sbindir)
 165                 sub("^"prefix, $3, libdir)
 166                 sub("^"prefix, $3, datadir)
 167                 sub("^"prefix, $3, includedir)
 168                 prefix = $3
 169         }
 170
 171         if ($2 ~ /_bindir/ && !/_sbindir/)
 172                 bindir = $3
 173         if ($2 ~ /_sbindir/)
 174                 sbindir = $3
 175         if ($2 ~ /_libdir/) {
 176                 if ($3 ~ /^%\(/) {
 177                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 178                         libdir = "%%%%%%%%%%%%%%"
 179                 } else {
 180                         libdir = $3
 181                 }
 182         }
 183         if ($2 ~ /_sysconfdir/) {
 184                 if ($3 ~ /^%\(/) {
 185                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 186                         sysconfdir = "%%%%%%%%%%%%%%"
 187                 } else {
 188                         sysconfdir = $3
 189                 }
 190         }
 191         if ($2 ~ /_datadir/) {
 192                 if ($3 ~ /^%\(/) {
 193                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 194                         datadir = "%%%%%%%%%%%%%%"
 195                 } else {
 196                         datadir = $3
 197                 }
 198         }
 199         if ($2 ~ /_includedir/)
 200                 includedir = $3
 201         if ($2 ~ /_mandir/)
 202                 mandir = $3
 203         if ($2 ~ /_infodir/)
 204                 infodir = $3
 205         if ($2 ~ /_docdir/)
 206                 docdir = $3
 207
 208         # version related macros
 209         if ($2 ~ /^_beta$/)
 210                 _beta = $3
 211         if ($2 ~ /^_rc$/)
 212                 _rc = $3
 213         if ($2 ~ /^_pre$/)
 214                 _pre = $3
 215         if ($2 ~ /^_snap$/)
 216                 _snap = $3
 217         if ($2 ~ /^subver$/)
 218                 subver = $3
 219
 220         # these are used usually when adapterizing external spec
 221         if ($2 ~ /^name$/)
 222                 name = $3
 223         if ($2 ~ /^version$/)
 224                 version = $3
 225         if ($2 ~ /^release$/)
 226                 release = $3
 227
 228         if ($2 ~ /^mod_name$/)
 229                 mod_name = $3
 230
 231         sub(/[ \t]+$/, "");
 232         # do nothing further, otherwise adapter thinks we're at preamble
 233         print
 234         next
 235 }
 236
 237 # Obsolete
 238 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 239         next
 240 }
 241
 242 ################
 243 # %description #
 244 ################
 245 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 246         preamble = 0
 247
 248         if (/^%description/) {
 249                 bod++
 250                 format_line = ""
 251                 format_indent = -1
 252         }
 253
 254         # Format description
 255         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 256                 if (/^[ \t]*$/) {
 257                         format_flush(format_line, format_indent)
 258                         print ""
 259                         format_line = ""
 260                         format_indent = -1
 261                 } else if (/^[ \t]*[-\*][ \t]*/) {
 262                         format_flush(format_line, format_indent)
 263                         match($0, /^[ \t]*/)
 264                         format_indent = RLENGTH
 265                         match($0, /^[ \t]*[-\*][ \t]/)
 266                         format_line = substr($0, RLENGTH)
 267                 } else
 268                         format_line = format_line " " $0
 269                 next
 270         }
 271
 272         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 273                 if (NF > 3 && $2 == "-l") {
 274                         ll = $1
 275                         for (i = 4; i <= NF; i++)
 276                                 ll = ll " " $i
 277                         $0 = ll " -l " $3
 278                 }
 279                 format_flush(format_line, format_indent)
 280                 if (bod == 2) {
 281                         bod = 1
 282                         description = 1
 283                 } else {
 284                         bod = 0
 285                         description = 0
 286                 }
 287         } else
 288                 description = 1
 289 }
 290
 291 #########
 292 # %prep #
 293 #########
 294 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 295         preamble = 0
 296         did_prep = 1
 297
 298         use_macros()
 299
 300         # Add '-q' to %setup
 301         if (/^%setup/ && !/-q/) {
 302                 sub(/^%setup/, "%setup -q")
 303         }
 304
 305         if (/^%setup/ && name != "setup") {
 306                 $0 = fixedsub(name, "%{name}", $0);
 307                 $0 = fixedsub(version, "%{version}", $0);
 308                 if (_beta) {
 309                         $0 = fixedsub(_beta, "%{_beta}", $0);
 310                 }
 311                 if (_rc) {
 312                         $0 = fixedsub(_rc, "%{_rc}", $0);
 313                 }
 314                 if (_pre) {
 315                         $0 = fixedsub(_pre, "%{_pre}", $0);
 316                 }
 317                 if (_snap) {
 318                         $0 = fixedsub(_snap, "%{_snap}", $0);
 319                 }
 320                 if (subver) {
 321                         $0 = fixedsub(subver, "%{subver}", $0);
 322                 }
 323         }
 324
 325         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 326                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 327         }
 328         sub("^%patch ", "%patch0 ");
 329
 330         # invalid in %prep
 331         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 332 }
 333
 334 ##########
 335 # %build #
 336 ##########
 337 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 338         preamble = 0
 339
 340         if (did_prep == 0) {
 341                 print "%prep"
 342                 print ""
 343                 did_prep = 1
 344         }
 345
 346         use_macros()
 347         use_tabs()
 348
 349         if (/^automake$/)
 350                 sub(/$/, " -a -c")
 351
 352         if (/LDFLAGS/) {
 353                 if (/LDFLAGS="-s"/) {
 354                         removed["LDFLAGS"] = 1
 355                         next
 356                 } else {
 357                         split($0, tmp, "LDFLAGS=")
 358                         count = split(tmp[2], flags, "\"")
 359                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 360                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 361                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 362                                 for (i = 2; i < count; i++)
 363                                         $0 = $0 flags[i] "\""
 364                         }
 365                 }
 366         }
 367
 368         if (/CFLAGS=/)
 369                 if (cflags("CFLAGS") == 0)
 370                         next
 371
 372         if (/CXXFLAGS=/)
 373                 if (cflags("CXXFLAGS") == 0)
 374                         next
 375
 376         if (/^export /) {
 377                 if (removed["LDFLAGS"])
 378                         sub(" LDFLAGS", "")
 379                 if (removed["CFLAGS"])
 380                         sub(" CFLAGS", "")
 381                 if (removed["CXXFLAGS"])
 382                         sub(" CXXFLAGS", "")
 383                 # Is there still something?
 384                 if (/^export[ ]*$/)
 385                         next
 386         }
 387
 388         # quote CC
 389         if (/CC=%{__cc} /) {
 390                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 391         }
 392
 393         # use PLD Linux macros
 394         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 395         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 396         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 397         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 398         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 399         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 400         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 401         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 402
 403         sub(/^aclocal$/, "%{__aclocal}");
 404         sub(/^autoheader$/, "%{__autoheader}");
 405         sub(/^autoconf$/, "%{__autoconf}");
 406         sub(/^automake$/, "%{__automake}");
 407         sub(/^libtoolize$/, "%{__libtoolize}");
 408
 409         # atrpms
 410         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 411         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 412 }
 413
 414 ##########
 415 # %clean #
 416 ##########
 417 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 418         did_clean = 1
 419
 420         use_macros()
 421 }
 422
 423 ############
 424 # %install #
 425 ############
 426 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 427
 428         preamble = 0
 429
 430         # foreign rpms
 431         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 432         sub("%buildroot", "$RPM_BUILD_ROOT");
 433         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 434
 435         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 436                 did_rmroot=1
 437                 print "rm -rf $RPM_BUILD_ROOT"
 438                 next
 439         }
 440
 441         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 442                 print "rm -rf $RPM_BUILD_ROOT"
 443                 did_rmroot=1
 444         }
 445
 446         if (tmpdir) {
 447                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 448                 gsub(buildroot, "$RPM_BUILD_ROOT")
 449         }
 450
 451         if (!/%{_lib}/) {
 452                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 453         }
 454
 455         use_macros()
 456
 457         # 'install -d' instead 'mkdir -p'
 458         if (/mkdir -p/)
 459                 sub(/mkdir -p/, "install -d")
 460
 461         # cp -a already implies cp -r
 462         sub(/^cp -ar/, "cp -a")
 463
 464         # No '-u root' or '-g root' for 'install'
 465         if (/^install/ && /-[ug][ \t]*root/)
 466                 gsub(/-[ug][ \t]*root /, "")
 467
 468         if (/^install/ && /-m[ \t]*[0-9]+/)
 469                 gsub(/-m[ \t]*[0-9]+ /, "")
 470
 471         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 472         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 473                 next
 474
 475         # No lines contain 'chmod' if it sets the modes to '644'
 476         if ($1 ~ /chmod/ && $2 ~ /644/)
 477                 next
 478
 479         # atrpms
 480         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 481 }
 482
 483 ##########
 484 # %files #
 485 ##########
 486 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 487         preamble = 0
 488         did_files = 1
 489
 490         if ($0 ~ /^%files/)
 491                 defattr = 1
 492
 493         if (!use_files_macros()) {
 494                 next
 495         }
 496 }
 497
 498 ##############
 499 # %changelog #
 500 ##############
 501 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 502         preamble = 0
 503         has_changelog = 1
 504         skip = 0
 505         # There should be some CVS keywords on the first line of %changelog.
 506         if (boc == 3) {
 507                 if ($0 !~ _cvsmailfeedback) {
 508                         print "* %{date} " _cvsmailfeedback > changelog_file
 509                 } else {
 510                         skip = 1
 511                 }
 512                 boc = 2
 513         }
 514         if (boc == 2 && !skip) {
 515                 if (!/All persons listed below/) {
 516                         printf "All persons listed below can be reached at " > changelog_file
 517                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 518                 } else {
 519                         skip = 1
 520                 }
 521                 boc = 1
 522         }
 523         if (boc == 1 && !skip) {
 524                 if (!/^$/) {
 525                         if (!/\$.*Log:.*\$/) {
 526                                 print "$" "Log:$" > changelog_file
 527                         }
 528                         boc = 0
 529                 }
 530         }
 531         # Define date macro.
 532         if (boc == 4) {
 533                 if (date == 0) {
 534                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 535                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 536                         date = 1
 537                 }
 538                 boc = 3
 539         }
 540
 541         sub(/[ \t]+$/, "");
 542         if (!/^%[a-z]+$/ || /changelog/) {
 543                 # stop changelog if "real" changelog starts
 544                 if (boc == 0 && /^\* /) {
 545                         boc = -1
 546                 }
 547                 if (boc == -1) {
 548                         next;
 549                 }
 550                 print > changelog_file
 551         } else {
 552                 print
 553         }
 554         next
 555 }
 556
 557 ###########
 558 # SCRIPTS #
 559 ###########
 560 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 561         preamble = 0
 562
 563         if (gsub("/usr/sbin/useradd", "%useradd")) {
 564                 sub(" 2> /dev/null \|\| :", "");
 565                 sub(" >/dev/null 2>&1 \|\|:", "");
 566         }
 567
 568         # %useradd and %groupadd may not be wrapped
 569         if (/%(useradd|groupadd).*\\$/) {
 570                 a = $0; getline;
 571                 sub(/^[\s\t]*/, "");
 572                 $0 = substr(a, 1, length(a) - 1) $0;
 573         }
 574         use_script_macros()
 575 }
 576
 577 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 578         preamble = 0
 579         use_macros()
 580 }
 581 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 582         preamble = 0
 583         use_macros()
 584 }
 585 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 586         preamble = 0
 587         use_script_macros()
 588 }
 589 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 590         preamble = 0
 591         use_script_macros()
 592 }
 593 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 594         preamble = 0
 595         use_script_macros()
 596 }
 597 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 598         preamble = 0
 599         use_script_macros()
 600 }
 601 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 602         preamble = 0
 603         use_script_macros()
 604 }
 605 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 606         preamble = 0
 607         use_script_macros()
 608 }
 609 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 610         preamble = 0
 611         use_script_macros()
 612 }
 613 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 614         preamble = 0
 615         use_script_macros()
 616 }
 617
 618 #############
 619 # PREAMBLES #
 620 #############
 621 preamble == 1 {
 622         # There should not be a space after the name of field
 623         # and before the colon.
 624         sub(/[ \t]*:/, ":")
 625
 626         if (/^%perl_module_wo_prefix/) {
 627                 name = $2
 628                 version = $3
 629                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 630         }
 631
 632         field = tolower($1)
 633         fieldnlower = $1
 634         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 635                 sub(/\.$/, "", $0);
 636         }
 637         if (field ~ /group(\([^)]+\)):/)
 638                 next
 639         if (field ~ /group:/) {
 640                 format_preamble()
 641                 group = $0;
 642                 sub(/^[^ \t]*[ \t]*/, "", group);
 643                 group = replace_groupnames(group);
 644                 $0 = "Group:\t\t" group
 645
 646                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 647                         x11 = 1
 648
 649                 byl_plik_z_groupmi = 0
 650                 byl_opis_grupy = 0
 651                 while ((getline linia_grup < groups_file) > 0) {
 652                         byl_plik_z_groupmi = 1
 653                         if (linia_grup == group) {
 654                                 byl_opis_grupy = 1
 655                                 break
 656                         }
 657                 }
 658
 659                 if (!byl_plik_z_groupmi)
 660                         print "######\t\t" groups_file ": no such file"
 661                 else if (!byl_opis_grupy)
 662                         print "######\t\t" "Unknown group!"
 663
 664                 close(groups_file)
 665                 did_groups = 1
 666         }
 667
 668         if (field ~ /prereq:/) {
 669                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 670         }
 671
 672         # split (build)requires, obsoletes on commas
 673         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 674                 value = substr($0, index($0, $2));
 675                 $0 = format_requires($1, value);
 676         }
 677
 678         # BR: tar (and others) is to common (rpm-build requires it)
 679         if (field ~ /^buildrequires:/) {
 680                 l = substr($0, index($0, $2));
 681                 if (l == "awk" ||
 682                         l == "binutils" ||
 683                         l == "bzip2" ||
 684                         l == "cpio" ||
 685                         l == "diffutils" ||
 686                         l == "elfutils" ||
 687                         l == "fileutils" ||
 688                         l == "findutils" ||
 689                         l == "glibc-devel" ||
 690                         l == "grep" ||
 691                         l == "gzip" ||
 692                         l == "make" ||
 693                         l == "patch" ||
 694                         l == "sed" ||
 695                         l == "sh-utils" ||
 696                         l == "tar" ||
 697                         l == "textutils") {
 698                         next
 699                 }
 700
 701                 replace_requires();
 702         }
 703
 704         if (field ~ /^requires:/) {
 705                 replace_requires();
 706         }
 707
 708
 709         # obsolete/unwanted tags
 710         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 711                 next
 712         }
 713
 714         if (field ~ /buildroot:/) {
 715                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 716                 did_build_root = 1
 717         }
 718
 719         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 720         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 721                 $1 = "License:"
 722         }
 723
 724         if (field ~ /license:/) {
 725                 l = substr($0, index($0, $2));
 726                 if (l == "Python Software Foundation License") {
 727                         l = "PSF"
 728                 }
 729                 if (l == "Apache License 2.0" || l == "Apache 2.0" || l == "Apache License Version 2.0" || l == "Apache License, Version 2.0" || l == "Apache Software License v2") {
 730                         l = "Apache v2.0"
 731                 }
 732                 if (l == "Apache Group License" || l == "Apache Software License" || l == "Apache License") {
 733                         l = "Apache"
 734                 }
 735                 if (l == "Apache-style License" || l == "Apache-style Software License") {
 736                         l = "Apache-like"
 737                 }
 738                 if (l == "Apache Software License 1.1" || l == "Apache 1.1") {
 739                         l = "Apache v1.1"
 740                 }
 741                 if (l == "GPLv2") {
 742                         l = "GPL v2"
 743                 }
 744                 if (l == "GPLv2+") {
 745                         l = "GPL v2+"
 746                 }
 747                 $0 = "License:\t" l;
 748         }
 749
 750
 751         if (field ~ /name:/) {
 752                 if ($2 == "%{name}" && name) {
 753                         $2 = name
 754                 }
 755                 name = $2
 756                 name_seen = 1;
 757         }
 758
 759         if (field ~ /version:/) {
 760                 if ($2 == "%{version}" && version) {
 761                         $2 = version
 762                 }
 763                 version = $2
 764                 version_seen = 1;
 765         }
 766
 767         if (field ~ /release:/) {
 768                 if ($2 == "%{release}" && release) {
 769                         $2 = release
 770                 }
 771                 sub(/%atrelease /, "0.", $0)
 772                 release = $2
 773                 release_seen = 1;
 774         }
 775
 776
 777         if (field ~ /serial:/)
 778                 $1 = "Epoch:"
 779
 780         if (field ~ /home-page:/)
 781                 $1 = "URL:"
 782
 783         # proper caps
 784         if (field ~ /^url:$/)
 785                 $1 = "URL:"
 786
 787         if (field ~ /^description:$/)
 788                 $1 = "\n%description\n"
 789
 790         # Use %{name} and %{version} in the filenames in "Source:"
 791         if (field ~ /^source/ || field ~ /patch/) {
 792                 n = split($2, url, /\//)
 793                 if (url[n] ~ /\.gz$/) {
 794                         url[n+1] = ".gz" url[n+1]
 795                         sub(/\.gz$/,"",url[n])
 796                 }
 797                 if (url[n] ~ /\.zip$/) {
 798                         url[n+1] = ".zip" url[n+1]
 799                         sub(/\.zip$/,"",url[n])
 800                 }
 801                 if (url[n] ~ /\.tar$/) {
 802                         url[n+1] = ".tar" url[n+1]
 803                         sub(/\.tar$/,"",url[n])
 804                 }
 805                 if (url[n] ~ /\.patch$/) {
 806                         url[n+1] = ".patch" url[n+1]
 807                         sub(/\.patch$/,"",url[n])
 808                 }
 809                 if (url[n] ~ /\.bz2$/) {
 810                         url[n+1] = ".bz2" url[n+1]
 811                         sub(/\.bz2$/,"",url[n])
 812                 }
 813                 if (url[n] ~ /\.logrotate$/) {
 814                         url[n+1] = ".logrotate" url[n+1]
 815                         sub(/\.logrotate$/,"",url[n])
 816                 }
 817                 if (url[n] ~ /\.pamd$/) {
 818                         url[n+1] = ".pamd" url[n+1]
 819                         sub(/\.pamd$/,"",url[n])
 820                 }
 821
 822                 # allow %{name} only in last url component
 823                 s = ""
 824                 for (i = 1; i <= n; i++) {
 825                         url[i] = fixedsub("%{name}", name, url[i])
 826                         if (s) {
 827                                 s = s "/" url[i]
 828                         } else {
 829                                 s = url[i]
 830                         }
 831                 }
 832                 $2 = s url[n+1]
 833
 834                 filename = url[n]
 835                 if (name) {
 836                         url[n] = fixedsub(name, "%{name}", url[n])
 837                 }
 838                 if (field ~ /source/) {
 839                         if (version) {
 840                                 url[n] = fixedsub(version, "%{version}", url[n])
 841                         }
 842                         if (_beta) {
 843                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 844                         }
 845                         if (_rc) {
 846                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 847                         }
 848                         if (_pre) {
 849                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 850                         }
 851                         if (_snap) {
 852                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 853                         }
 854                         if (subver) {
 855                                 url[n] = fixedsub(subver, "%{subver}", url[n])
 856                         }
 857                 }
 858                 # assigning to $2 kills preamble formatting
 859                 $2 = fixedsub(filename, url[n], $2)
 860
 861                 $2 = unify_url($2)
 862         }
 863
 864
 865         if (field ~ /^source:/)
 866                 $1 = "Source0:"
 867
 868         if (field ~ /^patch:/)
 869                 $1 = "Patch0:"
 870
 871         kill_preamble_macros();
 872         format_preamble()
 873
 874         if (field ~ /requires/) {
 875                 # atrpms
 876                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 877         }
 878 }
 879
 880 /^%bcond_/ {
 881         # do nothing
 882         print
 883         next
 884 }
 885
 886 # sort BR/R!
 887 #
 888 # NOTES:
 889 # - mixing BR/R and anything else confuses this (all will be sorted together)
 890 #       so don't do that.
 891 # - comments leading the BR/R can not be associated,
 892 #       so don't adapterize when the BR/R are mixed with comments
 893 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 894         if ($1 ~ /Pre[Rr]eq:/) {
 895                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 896         }
 897         if ($1 == "BR:" ) {
 898                 $1 = "BuildRequires:"
 899         }
 900         if ($1 == "R:" ) {
 901                 $1 = "Requires:"
 902         }
 903         format_preamble()
 904 #       kill_preamble_macros(); # breaks tabbing
 905
 906         b_idx++;
 907         l = substr($0, index($0, $2));
 908         b_ktmp = b_makekey($1, l);
 909         b_key[b_idx] = b_ktmp;
 910         b_val[b_ktmp] = $0;
 911
 912         next;
 913 }
 914
 915 preamble == 1 {
 916         if (b_idx > 0) {
 917                 isort(b_key, b_idx);
 918                 for (i = 1; i <= b_idx; i++) {
 919                         v = b_val[b_key[i]];
 920                         sub(/[ \t]+$/, "", v);
 921                         print "" v;
 922                 }
 923                 b_idx = 0
 924         }
 925 }
 926
 927 # main() ;-)
 928 {
 929         preamble = 1
 930
 931         sub(/[ \t]+$/, "")
 932         print
 933
 934         if (name_seen == 0 && name) {
 935                 print "Name:\t\t" name
 936                 name_seen = 1
 937         }
 938
 939         if (version_seen == 0 && version) {
 940                 print "Version:\t" version
 941                 version_seen = 1
 942         }
 943
 944         if (release_seen == 0 && release) {
 945                 print "Release:\t" release
 946                 release_seen = 1
 947         }
 948
 949         if (did_build_root == 0) {
 950 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 951                 did_build_root = 1
 952         }
 953         if (did_groups == 0) {
 954 #               print "Group:\t\tunknown"
 955                 did_groups = 1
 956         }
 957 }
 958
 959
 960 END {
 961         if (do_not_touch_anything)
 962                 exit 0
 963
 964         # TODO: need to output these in proper place
 965         if (BR_count > 0) {
 966                 for (i = 0; i <= BR_count; i++) {
 967                         print BR[i];
 968                 }
 969         }
 970
 971         close(changelog_file)
 972         while ((getline < changelog_file) > 0)
 973                 print
 974         system("rm -f " changelog_file)
 975
 976         if (did_clean == 0) {
 977                 print ""
 978                 print "%clean"
 979                 print "rm -rf $RPM_BUILD_ROOT"
 980         }
 981
 982         if (date == 0) {
 983                 print ""
 984                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 985         }
 986
 987         if (has_changelog == 0) {
 988                 print "%changelog"
 989         }
 990
 991         if (boc > 2) {
 992                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 993         }
 994         if (boc > 1) {
 995                 printf "All persons listed below can be reached at "
 996                 print "<cvs_login>@pld-linux.org\n"
 997         }
 998         if (boc > 0) {
 999                 print "$" "Log:$"
1000         }
1001 }
1002
1003 # substitutes fixed strings (not regexps)
1004 function fixedsub(s1,s2,t, ind) {
1005         if (ind = index(t,s1))
1006                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1007         return t
1008 }
1009
1010 # replace s with s2 if it equals to s1
1011 function replace(s, s1, s2) {
1012         if (s == s1) {
1013                 return s2;
1014         } else {
1015                 return s;
1016         }
1017 }
1018
1019 # There should be one or two tabs after the colon.
1020 function format_preamble()
1021 {
1022         if (/^#/ || /^%bcond_with/) {
1023                 return;
1024         }
1025         sub(/:[ \t]*/, ":")
1026         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1027                 if (RLENGTH < 8) {
1028                         sub(/:/, ":\t\t")
1029                 } else {
1030                         sub(/:/, ":\t")
1031                 }
1032         }
1033 }
1034
1035 # Replace directly specified directories with macros
1036 function use_macros()
1037 {
1038         # -m, --skip-macros, --no-macros -- skip macros subst
1039         if (ENVIRON["SKIP_MACROS"]) {
1040                 return
1041         }
1042
1043         # leave inline sed lines alone
1044         if (/(%{__sed}|sed) -i -e/) {
1045                 return;
1046         }
1047
1048         sub("%{_defaultdocdir}", "%{_docdir}");
1049         sub("%{_bindir}/perl", "%{__perl}");
1050         sub("%{_bindir}/python", "%{__python}");
1051
1052         gsub(infodir, "%{_infodir}")
1053
1054         gsub(perl_sitearch, "%{perl_sitearch}")
1055         gsub(perl_archlib, "%{perl_archlib}")
1056         gsub(perl_privlib, "%{perl_privlib}")
1057         gsub(perl_vendorlib, "%{perl_vendorlib}")
1058         gsub(perl_vendorarch, "%{perl_vendorarch}")
1059         gsub(perl_sitelib, "%{perl_sitelib}")
1060
1061         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1062         gsub(py_sitedir, "%{py_sitedir}")
1063         gsub(py_scriptdir, "%{py_scriptdir}")
1064         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1065         gsub("%{python_sitelib}", "%{py_sitedir}")
1066
1067         gsub(ruby_archdir, "%{ruby_archdir}")
1068         gsub(ruby_ridir, "%{ruby_ridir}")
1069         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1070         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1071         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1072
1073         gsub("%{_datadir}/applications", "%{_desktopdir}")
1074         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1075         gsub("%{_datadir}/java", "%{_javadir}")
1076
1077         gsub(libdir, "%{_libdir}")
1078         gsub(javadir, "%{_javadir}")
1079
1080         gsub(bindir, "%{_bindir}")
1081         gsub("%{prefix}/bin", "%{_bindir}")
1082         if (prefix"/bin" == bindir)
1083                 gsub("%{_prefix}/bin", "%{_bindir}")
1084
1085         for (c = 1; c <= NF; c++) {
1086                 if ($c ~ sbindir "/fix-info-dir")
1087                         continue;
1088                 if ($c ~ sbindir "/webapp")
1089                         continue;
1090                 if ($c ~ sbindir "/ldconfig")
1091                         continue;
1092                 if ($c ~ sbindir "/chsh")
1093                         continue;
1094                 if ($c ~ sbindir "/usermod")
1095                         continue;
1096                 if ($c ~ sbindir "/chkconfig")
1097                         continue;
1098                 if ($c ~ sbindir "/installzope(product|3package)")
1099                         continue;
1100                 gsub(sbindir, "%{_sbindir}", $c)
1101         }
1102
1103         gsub("%{prefix}/sbin", "%{_sbindir}")
1104         if (prefix"/sbin" == sbindir) {
1105                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1106         }
1107
1108         for (c = 1; c <= NF; c++) {
1109                 if ($c ~ sysconfdir "/{?cron.")
1110                         continue;
1111                 if ($c ~ sysconfdir "/{?crontab.d")
1112                         continue;
1113                 if ($c ~ sysconfdir "/{?env.d")
1114                         continue;
1115                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1116                         continue;
1117                 if ($c ~ sysconfdir "/{?udev")
1118                         continue;
1119                 if ($c ~ sysconfdir "/{?hotplug")
1120                         continue;
1121                 if ($c ~ sysconfdir "/{?logrotate.d")
1122                         continue;
1123                 if ($c ~ sysconfdir "/{?pam.d")
1124                         continue;
1125                 if ($c ~ sysconfdir "/{?profile.d")
1126                         continue;
1127                 if ($c ~ sysconfdir "/{?rc.d")
1128                         continue;
1129                 if ($c ~ sysconfdir "/{?security")
1130                         continue;
1131                 if ($c ~ sysconfdir "/{?skel")
1132                         continue;
1133                 if ($c ~ sysconfdir "/{?sysconfig")
1134                         continue;
1135                 if ($c ~ sysconfdir "/{?shrc.d")
1136                         continue;
1137                 if ($c ~ sysconfdir "/{?certs")
1138                         continue;
1139                 if ($c ~ sysconfdir "/{?X11")
1140                         continue;
1141                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1142                         continue;
1143                 if ($c ~ sysconfdir "/{?rpm")
1144                         continue;
1145                 if ($c ~ sysconfdir "/{?bash_completion.d")
1146                         continue;
1147                 if ($c ~ sysconfdir "/{?samba")
1148                         continue;
1149                 if ($c ~ sysconfdir "/shells")
1150                         continue;
1151                 if ($c ~ sysconfdir "/ppp")
1152                         continue;
1153                 if ($c ~ sysconfdir "/dbus-1")
1154                         continue;
1155                 if ($c ~ sysconfdir "/tmpwatch")
1156                         continue;
1157                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1158         }
1159
1160         gsub(docdir, "%{_docdir}")
1161
1162         gsub(kdedocdir, "%{_kdedocdir}")
1163
1164         gsub(gtkdocdir, "%{_gtkdocdir}")
1165         gsub("%{_docdir}/gtk-doc/html", "%{_gtkdocdir}")
1166
1167         gsub(php_pear_dir, "%{php_pear_dir}")
1168         gsub(php_data_dir, "%{php_data_dir}")
1169
1170         for (c = 1; c <= NF; c++) {
1171                 if ($c ~ datadir "/automake")
1172                         continue;
1173                 if ($c ~ datadir "/unsermake")
1174                         continue;
1175                 if ($c ~ datadir "/file/magic.mime")
1176                         continue;
1177                 gsub(datadir, "%{_datadir}", $c)
1178         }
1179
1180         gsub("%{prefix}/share", "%{_datadir}")
1181         if (prefix"/share" == datadir)
1182                 gsub("%{_prefix}/share", "%{_datadir}")
1183
1184         # CFLAGS="-I/usr/include/ncurses is usually correct.
1185         if (!/-I\/usr\/include/) {
1186                 gsub(includedir, "%{_includedir}")
1187         }
1188
1189         gsub("%{prefix}/include", "%{_includedir}")
1190         if (prefix"/include" == includedir) {
1191                 gsub("%{_prefix}/include", "%{_includedir}")
1192         }
1193
1194         gsub(mandir, "%{_mandir}")
1195         if ($0 !~ "%{_datadir}/manual") {
1196                 gsub("%{_datadir}/man", "%{_mandir}")
1197         }
1198         gsub("%{_prefix}/share/man", "%{_mandir}")
1199         gsub("%{prefix}/share/man", "%{_mandir}")
1200         gsub("%{prefix}/man", "%{_mandir}")
1201         gsub("%{_prefix}/man", "%{_mandir}")
1202
1203         gsub(infodir, "%{_infodir}")
1204         gsub("%{prefix}/info", "%{_infodir}")
1205         gsub("%{_prefix}/info", "%{_infodir}")
1206
1207         if (prefix !~ "/X11R6") {
1208                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1209         }
1210
1211         gsub(examplesdir, "%{_examplesdir}")
1212
1213         if (prefix != "/") {
1214                 # leave --with-foo=/usr alone
1215                 if ($0 !~ "--with.*=.*" prefix) {
1216                         for (c = 1; c <= NF; c++) {
1217                                 if ($c ~ prefix "/sbin/fix-info-dir")
1218                                         continue;
1219                                 if ($c ~ prefix "/sbin/webapp")
1220                                         continue;
1221                                 if ($c ~ prefix "/sbin/chsh")
1222                                         continue;
1223                                 if ($c ~ prefix "/sbin/usermod")
1224                                         continue;
1225                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1226                                         continue;
1227                                 if ($c ~ prefix "/share/automake")
1228                                         continue;
1229                                 if ($c ~ prefix "/share/unsermake")
1230                                         continue;
1231                                 if ($c ~ prefix "/lib/sendmail")
1232                                         continue;
1233                                 if ($c ~ prefix "/lib/pkgconfig")
1234                                         continue;
1235
1236                                 # CFLAGS="-I/usr..." is usually correct.
1237                                 if (/-I\/usr/)
1238                                         continue;
1239                                 # same for LDFLAGS="-L/usr..."
1240                                 if (/-L\/usr/)
1241                                         continue;
1242
1243                                 gsub(prefix, "%{_prefix}", $c)
1244                         }
1245                 }
1246                 gsub("%{prefix}", "%{_prefix}")
1247         }
1248
1249         # replace back
1250         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1251         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1252
1253         gsub("%{PACKAGE_VERSION}", "%{version}")
1254         gsub("%{PACKAGE_NAME}", "%{name}")
1255
1256         gsub("^make$", "%{__make}")
1257         gsub("^make ", "%{__make} ")
1258         gsub("^gcc ", "%{__cc} ")
1259         gsub("^rm --interactive=never ", "%{__rm} ")
1260
1261         # mandrake specs
1262         gsub("^%make$", "%{__make}")
1263         gsub("^%make ", "%{__make} ")
1264         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1265         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1266         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1267         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1268         gsub("^%{__install}", "install")
1269         gsub("%optflags", "%{rpmcflags}")
1270         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1271
1272         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1273         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1274         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1275         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1276         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1277         $0 = fixedsub("%__install", "install", $0);
1278
1279         # split configure line to multiple lines
1280         if (/%configure / && !/\\$/) {
1281                 $0 = format_configure($0);
1282         }
1283
1284         gsub("%_bindir", "%{_bindir}")
1285         gsub("%_datadir", "%{_datadir}")
1286         gsub("%_iconsdir", "%{_iconsdir}")
1287         gsub("%_sbindir", "%{_sbindir}")
1288         gsub("%_mandir", "%{_mandir}")
1289         gsub("%name", "%{name}")
1290         gsub(/%__rm/, "rm");
1291         gsub(/%__mkdir_p/, "install -d");
1292         gsub(/%__cp/, "cp");
1293         gsub(/%__ln_s/, "ln -s");
1294         gsub(/%__sed/, "%{__sed}");
1295         gsub(/%__cat/, "cat");
1296         gsub(/%__chmod/, "chmod");
1297
1298         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1299         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1300
1301         if (/^ant / || /^%{ant}/) {
1302                 sub(/^ant/, "%ant")
1303                 sub(/^%{ant}/, "%ant")
1304                 add_br("BuildRequires:  jpackage-utils");
1305                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1306         }
1307
1308         $0 = fixedsub("%(%{__cc} -dumpversion)", "%{cc_version}", $0);
1309         $0 = fixedsub("%(%{__cxx} -dumpversion)", "%{cxx_version}", $0);
1310 }
1311
1312 function format_configure(line,         n, a, s) {
1313         n = split(line, a, / /);
1314         s = a[1] " \\\n";
1315         for (i = 2; i <= n; i++) {
1316                 s = s "\t" a[i] " \\\n"
1317         }
1318         return s
1319 }
1320
1321
1322 # insertion sort of A[1..n]
1323 # copied from mawk manual
1324 function isort(A,n,             i,j,hold) {
1325         for (i = 2; i <= n; i++) {
1326                 hold = A[j = i]
1327                 while (A[j-1] > hold) {
1328                         j-- ; A[j+1] = A[j]
1329                 }
1330                 A[j] = hold
1331         }
1332         # sentinel A[0] = "" will be created if needed
1333 }
1334
1335
1336 function use_files_macros(      i, n, t, a, l)
1337 {
1338         use_macros()
1339
1340         # skip comments
1341         if (/^#/) {
1342                 return 1;
1343         }
1344
1345         sub("^%doc %{_mandir}", "%{_mandir}")
1346
1347         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1348         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1349
1350         # uid/gid nobody is not valid in %files
1351         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1352                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1353         }
1354
1355         # s[gu]id programs with globs are evil
1356         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1357                 $0 = $0 " # FIXME no globs for suid/sgid files"
1358         }
1359
1360         # replace back
1361         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1362         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1363         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1364         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1365         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1366         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1367         gsub("%{_sysconfdir}/security", "/etc/security")
1368         gsub("%{_sysconfdir}/skel", "/etc/skel")
1369         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1370         gsub("%{_sysconfdir}/certs", "/etc/certs")
1371         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1372         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1373         gsub("%{_sysconfdir}/pki", "/etc/pki")
1374         gsub("%{_sysconfdir}/tmpwatch", "/etc/tmpwatch")
1375
1376         # /etc/init.d -> /etc/rc.d/init.d
1377         if (!/^\/etc\/init\.d$/) {
1378                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1379         }
1380
1381         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1382                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1383                         $0 = "%attr(754,root,root) " $0
1384                 }
1385                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1386                         gsub("^%attr\\(... *,", "%attr(754,");
1387                 }
1388         }
1389
1390         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1391                 $0 = "%attr(755,root,root) " $0
1392         }
1393
1394         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1395                 $0 = "%attr(755,root,root) " $0
1396         }
1397
1398         # /etc/sysconfig files
1399         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1400         # attr not required, allow default 644 attr
1401         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1402                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1403                         gsub("%config", "%config(noreplace)")
1404                 }
1405
1406                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1407                         $NF = "%config(noreplace) " $NF
1408                 }
1409
1410                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1411                         gsub("^%attr\\(... *,", "%attr(640,");
1412                 }
1413
1414                 if (/\/etc\/sysconfig\// && !/%verify/) {
1415                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1416                 }
1417         }
1418
1419         # kill leading zeros
1420         if (/%attr\(0[1-9]/) {
1421                 gsub("%attr\\(0", "%attr(")
1422         }
1423
1424         # kill leading whitespace
1425         gsub(/^ +/, "");
1426
1427         # kill default attrs
1428         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1429         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1430         if (!/%dir/) {
1431                 gsub(/%attr\(644,root,root\) /, "");
1432         }
1433
1434         # sort %verify attrs
1435         if (match($0, /%verify\(not([^)]+)\)/)) {
1436                 t = substr($0, RSTART, RLENGTH)
1437                 # kill commas: %verify(not,md5,size,mtime)
1438                 gsub(/,/, " ", t);
1439
1440                 gsub(/^%verify\(not |\)$/, "", t)
1441                 n = split(t, a, / /)
1442                 isort(a, n)
1443
1444                 s = "%verify(not"
1445                 for (i = 1 ; i <= n; i++) {
1446                         s = s " " a[i]
1447                 }
1448                 s = s ")"
1449
1450                 gsub(/%verify\(not[^)]+\)/, s)
1451         }
1452
1453         if (/%{_mandir}/) {
1454                 gsub("\.gz$", "*")
1455         }
1456
1457         # locale dir and no %lang -> bad
1458         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1459                 $(NF + 1) = "# FIXME consider using %find_lang"
1460         }
1461
1462         # python egg-infos
1463         if (match($0, "^%{py_site(script)?dir}/.+-py"py_ver".egg-info$")) {
1464                 # tests:
1465                 #%{py_sitedir}/*-py2.4.egg-info
1466                 #%{py_sitescriptdir}/GnuPGInterface-%{version}-py2.4.egg-info
1467                 #%{py_sitescriptdir}/python_mpd-%{version}-py2.4.egg-info
1468                 #%{py_sitescriptdir}/mechanize-0.1.6b-py2.4.egg-info
1469
1470                 l = index($0, "/");
1471                 t = substr($0, 0, l);
1472                 s = substr($0, l + 1, RLENGTH - l - length("-py"py_ver".egg-info"));
1473                 if (match(s, "[^-]+$")) {
1474 #printf("s[%s]; start[%d]; length[%d]\n", s, RSTART, RLENGTH);
1475                         if (RSTART > 1) {
1476                                 s = substr(s, 0, RSTART - 1);
1477                         }
1478 #printf("s2[%s]\n", s);
1479                         print "%if \"%{py_ver}\" > \"2.4\""
1480 #print t "/.+.egg-info"
1481                         gsub(t "/.+.egg-info", t "/" s "-*.egg-info");
1482                         print
1483                         print "%endif"
1484                         return 0;
1485                 }
1486         }
1487
1488         # atrpms
1489         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1490         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1491         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1492
1493         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1494         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1495         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1496
1497         gsub("%{_datadir}/applications", "%{_desktopdir}");
1498         gsub("%{_datadir}/icons", "%{_iconsdir}");
1499         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1500         gsub("%{_datadir}/pear", "%{php_pear_dir}");
1501         gsub("%{_datadir}/php", "%{php_data_dir}");
1502
1503         return 1
1504 }
1505
1506 function use_script_macros()
1507 {
1508         if (gsub("/sbin/service", "%service")) {
1509                 sub(" >/dev/null 2>&1 \|\|:", "");
1510                 sub(" 2> /dev/null \|\| :", "");
1511         }
1512 }
1513
1514 function fill(ch, n, i) {
1515         for (i = 0; i < n; i++)
1516                 printf("%c", ch)
1517 }
1518
1519 function format_flush(line, indent, newline, word, first_word) {
1520         first_word = 1
1521         if (format_indent == -1)
1522                 newline = ""
1523         else
1524                 newline = fill(" ", format_indent) "- "
1525
1526         while (match(line, /[^\t ]+/)) {
1527                 word = substr(line, RSTART, RLENGTH)
1528                 if (length(newline) + length(word) + 1 > tw) {
1529                         print newline
1530
1531                         if (format_indent == -1)
1532                                 newline = ""
1533                         else
1534                                 newline = fill(" ", format_indent + 2)
1535                         first_word = 1
1536                 }
1537
1538                 if (first_word) {
1539                         newline = newline word
1540                         first_word = 0
1541                 } else
1542                         newline = newline " " word
1543
1544                 line = substr(line, RSTART + RLENGTH)
1545         }
1546         if (newline ~ /[^\t ]/) {
1547                 print newline
1548         }
1549 }
1550
1551 function cflags(var)
1552 {
1553         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1554                 removed[var] = 1
1555                 return 0
1556         }
1557
1558         if (!/!\?debug/)
1559                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1560         return 1
1561 }
1562
1563 function unify_url(url)
1564 {
1565
1566         # sourceforge urls
1567         sub("[?&]big_mirror=.*$", "", url);
1568         sub("[?&]modtime=.*$", "", url);
1569         sub("[?]use_mirror=.*$", "", url);
1570         sub("[?]download$", "", url);
1571
1572         sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1573         sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", url)
1574         sub("^http://download\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1575         sub("^http://downloads\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1576
1577         sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1578         sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", url)
1579         sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", url)
1580
1581         sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", url)
1582         sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", url)
1583
1584         # apache urls
1585         sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", url)
1586
1587         # gnu.org
1588         sub("^ftp://ftp.gnu.org/", "http://ftp.gnu.org/", url)
1589         sub("^http://ftp.gnu.org/pub/gnu/", "http://ftp.gnu.org/gnu/", url)
1590
1591         return url
1592 }
1593
1594 function demacroize(str)
1595 {
1596         if (mod_name) {
1597                 sub("%{mod_name}", mod_name, str);
1598         }
1599         if (name) {
1600                 sub("%{name}", name, str);
1601         }
1602         if (version) {
1603                 sub("%{version}", version, str);
1604         }
1605         if (_beta) {
1606                 sub("%{_beta}", _beta, str);
1607         }
1608         if (_rc) {
1609                 sub("%{_rc}", _rc, str);
1610         }
1611         if (_pre) {
1612                 sub("%{_pre}", _pre, str);
1613         }
1614         if (_snap) {
1615                 sub("%{_snap}", _snap, str);
1616         }
1617         if (subver) {
1618                 sub("%{subver}", subver, str);
1619         }
1620         return str;
1621 }
1622
1623 function kill_preamble_macros()
1624 {
1625         if ($1 ~ /^Obsoletes:/) {
1626                 # NB! assigning $2 a value breaks tabbing
1627                 $2 = demacroize($2);
1628         }
1629         if ($1 ~ /^URL:/) {
1630                 # NB! assigning $2 a value breaks tabbing
1631                 $2 = demacroize($2);
1632                 $2 = unify_url($2)
1633         }
1634 }
1635
1636 function get_epoch(pkg, ver,    epoch)
1637 {
1638         return
1639 # should parse the BR lines more adequately:
1640 #       freetype = 2.0.0 -> correct
1641 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1642
1643         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1644         shell | getline epoch;
1645         return epoch;
1646 }
1647
1648 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1649         # skip any formatting for commented out items or some weird macros
1650         if (/^#/ || /%\(/) {
1651                 return tag "\t" value
1652         }
1653         n = split(value, p, / *,? */);
1654         for (i = 1; i <= n; i++) {
1655                 if (p[i+1] ~ /[<=>]/) {
1656                         # add epoch if the version doesn't have it but BuildRequires.txt has
1657                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1658                                 epoch = get_epoch(p[i], p[i+2])
1659                                 if (epoch) {
1660                                         p[i+2] = epoch ":" p[i+2];
1661                                 }
1662                         }
1663                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1664                         i += 2;
1665                 } else {
1666                         deps[ndeps++] = p[i];
1667                 }
1668         }
1669         s = ""
1670         for (i in deps) {
1671                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1672         }
1673         return substr(s, 1, length(s)-1);
1674 }
1675
1676 function use_tabs()
1677 {
1678         # reverse vim: ts=4 sw=4 et
1679         gsub(/    /, "\t");
1680 }
1681
1682 function add_br(br)
1683 {
1684         BR[BR_count++] = br
1685 }
1686
1687 function replace_requires()
1688 {
1689
1690         # jpackages
1691         sub(/^java-devel$/, "jdk", $2);
1692         sub(/^log4j$/, "logging-log4j", $2);
1693         sub(/^jakarta-log4j$/, "logging-log4j", $2);
1694         sub(/^oro$/, "jakarta-oro", $2);
1695         sub(/^jakarta-ant$/, "ant", $2);
1696         sub(/^xerces-j2$/, "xerces-j", $2);
1697         sub(/^ldapjdk$/, "ldapsdk", $2);
1698         sub(/^saxon-scripts$/, "saxon", $2);
1699         sub(/^xalan-j2$/, "xalan-j", $2);
1700         sub(/^xerces-j2$/, "xerces-j", $2);
1701         sub(/^gnu-regexp$/, "gnu.regexp", $2);
1702
1703         # redhat virtual
1704         sub(/^tftp-server$/, "tftpdaemon", $2);
1705
1706         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2);
1707         sub(/^chkconfig$/, "/sbin/chkconfig", $2);
1708
1709         # fedora
1710         sub(/^iscsi-initiator-utils$/, "open-iscsi", $2);
1711
1712         replace_php_virtual_deps()
1713 }
1714
1715 # php virtual deps as discussed in devel-en
1716 function replace_php_virtual_deps()
1717 {
1718         pkg = $2
1719 #       if (pkg == "php-program") {
1720 #               $0 = $1 "\t/usr/bin/php"
1721 #               return
1722 #       }
1723
1724 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1725 #               sub(/^php-/, "php(", pkg);
1726 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1727 #               $2 = pkg
1728 #       }
1729
1730         if (pkg ~/^php$/) {
1731                 $2 = "webserver(php)";
1732                 if ($4 ~ /^[0-9]:/) {
1733                         $4 = substr($4, 3);
1734                 }
1735         }
1736
1737         if (pkg ~/^php4$/) {
1738                 $2 = "webserver(php)";
1739                 if ($4 ~ /^[0-9]:/) {
1740                         $4 = substr($4, 3);
1741                 }
1742         }
1743 }
1744
1745 # Load rpm macros
1746 # you should update the list also in adapter when making changes here
1747 function import_rpm_macros() {
1748         # get cvsaddress for changelog section
1749         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
1750         _cvsmaildomain = ENVIRON["_cvsmaildomain"]
1751         _cvsmailfeedback = ENVIRON["_cvsmailfeedback"]
1752
1753         # File with rpm groups
1754         sourcedir = ENVIRON["_sourcedir"]
1755
1756         prefix = ENVIRON["_prefix"]
1757         bindir = ENVIRON["_bindir"]
1758         sbindir = ENVIRON["_sbindir"]
1759         libdir = ENVIRON["_libdir"]
1760         sysconfdir = ENVIRON["_sysconfdir"]
1761         datadir = ENVIRON["_datadir"]
1762         includedir = ENVIRON["_includedir"]
1763         mandir = ENVIRON["_mandir"]
1764         infodir = ENVIRON["_infodir"]
1765         examplesdir = ENVIRON["_examplesdir"]
1766         docdir = ENVIRON["_defaultdocdir"]
1767         kdedocdir = ENVIRON["_kdedocdir"]
1768         gtkdocdir = ENVIRON["_gtkdocdir"]
1769         desktopdir = ENVIRON["_desktopdir"]
1770         pixmapsdir = ENVIRON["_pixmapsdir"]
1771         javadir = ENVIRON["_javadir"]
1772
1773         perl_sitearch = ENVIRON["perl_sitearch"]
1774         perl_archlib = ENVIRON["perl_archlib"]
1775         perl_privlib = ENVIRON["perl_privlib"]
1776         perl_vendorlib = ENVIRON["perl_vendorlib"]
1777         perl_vendorarch = ENVIRON["perl_vendorarch"]
1778         perl_sitelib = ENVIRON["perl_sitelib"]
1779
1780         py_sitescriptdir = ENVIRON["py_sitescriptdir"]
1781         py_sitedir = ENVIRON["py_sitedir"]
1782         py_scriptdir = ENVIRON["py_scriptdir"]
1783         py_ver = ENVIRON["py_ver"]
1784
1785         ruby_archdir = ENVIRON["ruby_archdir"]
1786         ruby_ridir = ENVIRON["ruby_ridir"]
1787         ruby_rubylibdir = ENVIRON["ruby_rubylibdir"]
1788         ruby_sitearchdir = ENVIRON["ruby_sitearchdir"]
1789         ruby_sitelibdir = ENVIRON["ruby_sitelibdir"]
1790
1791         php_pear_dir = ENVIRON["php_pear_dir"]
1792         php_data_dir = ENVIRON["php_data_dir"]
1793         tmpdir = ENVIRON["tmpdir"]
1794 }
1795
1796 function replace_groupnames(group) {
1797         group = replace(group, "Amusements/Games/Strategy/Real Time", "X11/Applications/Games/Strategy");
1798         group = replace(group, "Application/Multimedia", "Applications/Multimedia");
1799         group = replace(group, "Application/System", "Applications/System");
1800         group = replace(group, "Applications/Compilers", "Development/Languages");
1801         group = replace(group, "Applications/Daemons", "Daemons");
1802         group = replace(group, "Applications/Internet", "Applications/Networking");
1803         group = replace(group, "Applications/Internet/Peer to Peer", "Applications/Networking");
1804         group = replace(group, "Applications/Productivity", "X11/Applications");
1805         group = replace(group, "Database", "Applications/Databases");
1806         group = replace(group, "Development/C", "Development/Libraries");
1807         group = replace(group, "Development/Code Generators", "Development");
1808         group = replace(group, "Development/Docs", "Documentation");
1809         group = replace(group, "Development/Documentation", "Documentation");
1810         group = replace(group, "Development/Java", "Development/Languages/Java");
1811         group = replace(group, "Development/Languages/Other", "Development/Languages");;
1812         group = replace(group, "Development/Languages/Ruby", "Development/Languages");
1813         group = replace(group, "Development/Libraries/C and C++", "Development/Libraries");
1814         group = replace(group, "Development/Libraries/Java", "Development/Languages/Java");
1815         group = replace(group, "Development/Libraries/Python", "Development/Languages/Python");
1816         group = replace(group, "Development/Libraries/TCL", "Development/Languages/Tcl");;
1817         group = replace(group, "Development/Other", "Development");
1818         group = replace(group, "Development/Python", "Development/Languages/Python");
1819         group = replace(group, "Development/Testing", "Development");
1820         group = replace(group, "Emulators", "Applications/Emulators");
1821         group = replace(group, "Games", "Applications/Games");
1822         group = replace(group, "Library/Development", "Development/Libraries");
1823         group = replace(group, "Networking/Deamons", "Networking/Daemons");
1824         group = replace(group, "Productivity/Databases/Servers", "Applications/Databases");
1825         group = replace(group, "Productivity/Networking/Web/Servers", "Networking/Daemons/HTTP");;
1826         group = replace(group, "Shells", "Applications/Shells");
1827         group = replace(group, "System Environment/Base", "Base");
1828         group = replace(group, "System Environment/Daemons", "Daemons");
1829         group = replace(group, "System Environment/Kernel", "Base/Kernel");
1830         group = replace(group, "System Environment/Libraries", "Libraries");
1831         group = replace(group, "System", "Base");
1832         group = replace(group, "System/Base", "Base");
1833         group = replace(group, "System/Kernel and hardware", "Base/Kernel");
1834         group = replace(group, "System/Libraries", "Libraries");
1835         group = replace(group, "System/Servers", "Daemons");
1836         group = replace(group, "Text Processing/Markup/HTML", "Applications/Text");
1837         group = replace(group, "Text Processing/Markup/XML", "Applications/Text");
1838         group = replace(group, "Web/Database", "Applications/WWW");
1839         group = replace(group, "X11/GNOME", "X11/Applications");
1840         group = replace(group, "X11/GNOME/Applications", "X11/Applications");
1841         group = replace(group, "X11/GNOME/Development/Libraries", "X11/Development/Libraries");
1842         group = replace(group, "X11/Games", "X11/Applications/Games");
1843         group = replace(group, "X11/Games/Strategy", "X11/Applications/Games/Strategy");
1844         group = replace(group, "X11/Library", "X11/Libraries");
1845         group = replace(group, "X11/Utilities", "X11/Applications");
1846         group = replace(group, "X11/XFree86", "X11");
1847         group = replace(group, "X11/Xserver", "X11/Servers");
1848
1849         return group;
1850 }
1851
1852 # vim:ts=4:sw=4