adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # Adapter adapts .spec files for PLD Linux.
   4 #
   5 # Copyright (C) 1999-2007 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Michał Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Jakub Bogusz <qboosh@pld-linux.org>
  13 #       Elan Ruusamäe <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - really long sourceX make preamble sorting totally fcked up (try snake.spec r1.1)
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27
  28 BEGIN {
  29         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  30         SECTIONS = "^%(" RPM_SECTIONS ")"
  31
  32         RCSID = "$Id$"
  33         rev = RCSID # TODO: parse from RCSID
  34         VERSION = "0.31/" rev
  35
  36         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests)"
  37
  38         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  39
  40         preamble = 1    # Is it part of preamble? Default - yes
  41         boc = 4                 # Beginning of %changelog
  42         bod = 0                 # Beginning of %description
  43         tw = 70                 # Descriptions width
  44
  45         b_idx = 0               # index of BR/R arrays
  46         BR_count = 0    # number of additional BuildRequires
  47
  48         # If variable removed, then 1 (for removing it from export)
  49         removed["LDFLAGS"] = 0
  50         removed["CFLAGS"] = 0
  51         removed["CXXFLAGS"] = 0
  52
  53         # get cvsaddress for changelog section
  54         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  55         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  56         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  57
  58         # If 1, we are inside of comment block (started with /^#%/)
  59         comment_block = 0
  60
  61         # File with rpm groups
  62         "rpm --eval %_sourcedir" | getline groups_file
  63         groups_file = groups_file "/rpm.groups"
  64         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  65         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  66
  67         # Temporary file for changelog section
  68         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  69
  70         # Load rpm macros
  71         "rpm --eval %_prefix"   | getline prefix
  72         "rpm --eval %_bindir"   | getline bindir
  73         "rpm --eval %_sbindir"  | getline sbindir
  74         "rpm --eval %_libdir"   | getline libdir
  75         "rpm --eval %_sysconfdir" | getline sysconfdir
  76         "rpm --eval %_datadir"  | getline datadir
  77         "rpm --eval %_includedir" | getline includedir
  78         "rpm --eval %_mandir"   | getline mandir
  79         "rpm --eval %_infodir"  | getline infodir
  80         "rpm --eval %_examplesdir"      | getline examplesdir
  81         "rpm --eval %_defaultdocdir"    | getline docdir
  82         "rpm --eval %_kdedocdir"        | getline kdedocdir
  83         "rpm --eval %_gtkdocdir"        | getline gtkdocdir
  84         "rpm --eval %_desktopdir" | getline desktopdir
  85         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  86         "rpm --eval %_javadir" | getline javadir
  87
  88         "rpm --eval %perl_sitearch" | getline perl_sitearch
  89         "rpm --eval %perl_archlib" | getline perl_archlib
  90         "rpm --eval %perl_privlib" | getline perl_privlib
  91         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  92         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  93         "rpm --eval %perl_sitelib" | getline perl_sitelib
  94
  95         "rpm --eval %py_sitescriptdir 2>/dev/null" | getline py_sitescriptdir
  96         "rpm --eval %py_sitedir 2>/dev/null" | getline py_sitedir
  97         "rpm --eval %py_scriptdir 2>/dev/null" | getline py_scriptdir
  98         "rpm --eval %py_ver 2>/dev/null" | getline py_ver
  99
 100         "rpm --eval %ruby_archdir" | getline ruby_archdir
 101         "rpm --eval %ruby_ridir" | getline ruby_ridir
 102         "rpm --eval %ruby_rubylibdir" | getline ruby_rubylibdir
 103         "rpm --eval %ruby_sitearchdir" | getline ruby_sitearchdir
 104         "rpm --eval %ruby_sitelibdir" | getline ruby_sitelibdir
 105
 106         "rpm --eval %php_pear_dir" | getline php_pear_dir
 107         "rpm --eval %php_data_dir" | getline php_data_dir
 108         "rpm --eval %tmpdir" | getline tmpdir
 109 }
 110
 111 # There should be a comment with CVS keywords on the first line of file.
 112 FNR == 1 {
 113         if (!/# \$Revision:/)   # If this line is already OK?
 114                 print "# $" "Revision:$, " "$" "Date:$" # No
 115         else {
 116                 print $0                                # Yes
 117                 next            # It is enough for first line
 118         }
 119 }
 120
 121 # If the latest line matched /%files/
 122 defattr == 1 {
 123         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 124                 if ($0 !~ /defattr/) {  # If no %defattr
 125                         print "%defattr(644,root,root,755)"     # Add it
 126                 } else {
 127                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 128                 }
 129         }
 130         defattr = 0
 131 }
 132
 133 function b_makekey(a, b,        s) {
 134         s = a "" b;
 135         # kill bcond
 136         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 137
 138         # kill commented out items
 139         gsub(/^#[ \t]*/, "", s);
 140
 141         # force order
 142         gsub(/^Summary\(/, "11Summary(", s);
 143         gsub(/^Summary/, "10Summary", s);
 144         gsub(/^Name/, "2Name", s);
 145         gsub(/^Version/, "3Version", s);
 146         gsub(/^Release/, "4Release", s);
 147         gsub(/^Epoch/, "5Epoch", s);
 148         gsub(/^License/, "5License", s);
 149         gsub(/^Group/, "6Group", s);
 150         gsub(/^URL/, "7URL", s);
 151
 152         gsub(/^BuildRequires/, "B1BuildRequires", s);
 153         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 154
 155         gsub(/^Suggests/, "X1Suggests", s);
 156         gsub(/^Provides/, "X2Provides", s);
 157         gsub(/^Obsoletes/, "X3Obsoletes", s);
 158         gsub(/^Conflicts/, "X4Conflicts", s);
 159         gsub(/^BuildArch/, "X5BuildArch", s);
 160         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 161         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 162         gsub(/^BuildRoot/, "X9BuildRoot", s);
 163
 164 #       printf("%s -> %s\n", a""b, s);
 165         return s;
 166 }
 167
 168 # Comments
 169 /^#/ && (description == 0) {
 170         if (/This file does not like to be adapterized!/) {
 171                 print                   # print this message
 172                 while (getline)         # print the rest of spec as it is
 173                         print
 174                 do_not_touch_anything = 1 # do not touch anything in END()
 175                 exit 0
 176         }
 177
 178         # Generally, comments are printed without touching
 179         sub(/[ \t]+$/, "")
 180
 181         if (/#[ \t]*Source.*md5/) {
 182                 if (usedigest == 1) {
 183                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 184                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 185                 }
 186                 print $0
 187                 next
 188         }
 189 }
 190
 191 /^%define/ {
 192         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 193         if ($2 == "_applnkdir") {
 194                 next
 195         }
 196         if ($2 == "date") {
 197                 date = 1
 198                 if (did_files == 0) {
 199                         print "%files"
 200                         print ""
 201                         did_files = 1
 202                 }
 203         }
 204
 205         # Do not add %define of _prefix if it already is.
 206         if ($2 ~ /^_prefix/) {
 207                 sub("^"prefix, $3, bindir)
 208                 sub("^"prefix, $3, sbindir)
 209                 sub("^"prefix, $3, libdir)
 210                 sub("^"prefix, $3, datadir)
 211                 sub("^"prefix, $3, includedir)
 212                 prefix = $3
 213         }
 214
 215         if ($2 ~ /_bindir/ && !/_sbindir/)
 216                 bindir = $3
 217         if ($2 ~ /_sbindir/)
 218                 sbindir = $3
 219         if ($2 ~ /_libdir/) {
 220                 if ($3 ~ /^%\(/) {
 221                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 222                         libdir = "%%%%%%%%%%%%%%"
 223                 } else {
 224                         libdir = $3
 225                 }
 226         }
 227         if ($2 ~ /_sysconfdir/) {
 228                 if ($3 ~ /^%\(/) {
 229                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 230                         sysconfdir = "%%%%%%%%%%%%%%"
 231                 } else {
 232                         sysconfdir = $3
 233                 }
 234         }
 235         if ($2 ~ /_datadir/) {
 236                 if ($3 ~ /^%\(/) {
 237                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 238                         datadir = "%%%%%%%%%%%%%%"
 239                 } else {
 240                         datadir = $3
 241                 }
 242         }
 243         if ($2 ~ /_includedir/)
 244                 includedir = $3
 245         if ($2 ~ /_mandir/)
 246                 mandir = $3
 247         if ($2 ~ /_infodir/)
 248                 infodir = $3
 249         if ($2 ~ /_docdir/)
 250                 docdir = $3
 251
 252         # version related macros
 253         if ($2 ~ /^_beta$/)
 254                 _beta = $3
 255         if ($2 ~ /^_rc$/)
 256                 _rc = $3
 257         if ($2 ~ /^_pre$/)
 258                 _pre = $3
 259         if ($2 ~ /^_snap$/)
 260                 _snap = $3
 261         if ($2 ~ /^subver$/)
 262                 subver = $3
 263
 264         # these are used usually when adapterizing external spec
 265         if ($2 ~ /^name$/)
 266                 name = $3
 267         if ($2 ~ /^version$/)
 268                 version = $3
 269         if ($2 ~ /^release$/)
 270                 release = $3
 271
 272         if ($2 ~ /^mod_name$/)
 273                 mod_name = $3
 274
 275         sub(/[ \t]+$/, "");
 276         # do nothing further, otherwise adapter thinks we're at preamble
 277         print
 278         next
 279 }
 280
 281 # Obsolete
 282 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 283         next
 284 }
 285
 286 ################
 287 # %description #
 288 ################
 289 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 290         preamble = 0
 291
 292         if (/^%description/) {
 293                 bod++
 294                 format_line = ""
 295                 format_indent = -1
 296         }
 297
 298         # Format description
 299         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 300                 if (/^[ \t]*$/) {
 301                         format_flush(format_line, format_indent)
 302                         print ""
 303                         format_line = ""
 304                         format_indent = -1
 305                 } else if (/^[ \t]*[-\*][ \t]*/) {
 306                         format_flush(format_line, format_indent)
 307                         match($0, /^[ \t]*/)
 308                         format_indent = RLENGTH
 309                         match($0, /^[ \t]*[-\*][ \t]/)
 310                         format_line = substr($0, RLENGTH)
 311                 } else
 312                         format_line = format_line " " $0
 313                 next
 314         }
 315
 316         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 317                 if (NF > 3 && $2 == "-l") {
 318                         ll = $1
 319                         for (i = 4; i <= NF; i++)
 320                                 ll = ll " " $i
 321                         $0 = ll " -l " $3
 322                 }
 323                 format_flush(format_line, format_indent)
 324                 if (bod == 2) {
 325                         bod = 1
 326                         description = 1
 327                 } else {
 328                         bod = 0
 329                         description = 0
 330                 }
 331         } else
 332                 description = 1
 333 }
 334
 335 #########
 336 # %prep #
 337 #########
 338 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 339         preamble = 0
 340         did_prep = 1
 341
 342         use_macros()
 343
 344         # Add '-q' to %setup
 345         if (/^%setup/ && !/-q/) {
 346                 sub(/^%setup/, "%setup -q")
 347         }
 348
 349         if (/^%setup/ && name != "setup") {
 350                 $0 = fixedsub(name, "%{name}", $0);
 351                 $0 = fixedsub(version, "%{version}", $0);
 352                 if (_beta) {
 353                         $0 = fixedsub(_beta, "%{_beta}", $0);
 354                 }
 355                 if (_rc) {
 356                         $0 = fixedsub(_rc, "%{_rc}", $0);
 357                 }
 358                 if (_pre) {
 359                         $0 = fixedsub(_pre, "%{_pre}", $0);
 360                 }
 361                 if (_snap) {
 362                         $0 = fixedsub(_snap, "%{_snap}", $0);
 363                 }
 364                 if (subver) {
 365                         $0 = fixedsub(subver, "%{subver}", $0);
 366                 }
 367         }
 368
 369         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 370                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 371         }
 372         sub("^%patch ", "%patch0 ");
 373
 374         # invalid in %prep
 375         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 376 }
 377
 378 ##########
 379 # %build #
 380 ##########
 381 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 382         preamble = 0
 383
 384         if (did_prep == 0) {
 385                 print "%prep"
 386                 print ""
 387                 did_prep = 1
 388         }
 389
 390         use_macros()
 391         use_tabs()
 392
 393         if (/^automake$/)
 394                 sub(/$/, " -a -c")
 395
 396         if (/LDFLAGS/) {
 397                 if (/LDFLAGS="-s"/) {
 398                         removed["LDFLAGS"] = 1
 399                         next
 400                 } else {
 401                         split($0, tmp, "LDFLAGS=")
 402                         count = split(tmp[2], flags, "\"")
 403                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 404                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 405                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 406                                 for (i = 2; i < count; i++)
 407                                         $0 = $0 flags[i] "\""
 408                         }
 409                 }
 410         }
 411
 412         if (/CFLAGS=/)
 413                 if (cflags("CFLAGS") == 0)
 414                         next
 415
 416         if (/CXXFLAGS=/)
 417                 if (cflags("CXXFLAGS") == 0)
 418                         next
 419
 420         if (/^export /) {
 421                 if (removed["LDFLAGS"])
 422                         sub(" LDFLAGS", "")
 423                 if (removed["CFLAGS"])
 424                         sub(" CFLAGS", "")
 425                 if (removed["CXXFLAGS"])
 426                         sub(" CXXFLAGS", "")
 427                 # Is there still something?
 428                 if (/^export[ ]*$/)
 429                         next
 430         }
 431
 432         # quote CC
 433         if (/CC=%{__cc} /) {
 434                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 435         }
 436
 437         # use PLD Linux macros
 438         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 439         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 440         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 441         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 442         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 443         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 444         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 445         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 446
 447         sub(/^aclocal$/, "%{__aclocal}");
 448         sub(/^autoheader$/, "%{__autoheader}");
 449         sub(/^autoconf$/, "%{__autoconf}");
 450         sub(/^automake$/, "%{__automake}");
 451         sub(/^libtoolize$/, "%{__libtoolize}");
 452
 453         # atrpms
 454         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 455         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 456 }
 457
 458 ##########
 459 # %clean #
 460 ##########
 461 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 462         did_clean = 1
 463
 464         use_macros()
 465 }
 466
 467 ############
 468 # %install #
 469 ############
 470 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 471
 472         preamble = 0
 473
 474         # foreign rpms
 475         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 476         sub("%buildroot", "$RPM_BUILD_ROOT");
 477         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 478
 479         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 480                 did_rmroot=1
 481                 print "rm -rf $RPM_BUILD_ROOT"
 482                 next
 483         }
 484
 485         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 486                 print "rm -rf $RPM_BUILD_ROOT"
 487                 did_rmroot=1
 488         }
 489
 490         if (tmpdir) {
 491                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 492                 gsub(buildroot, "$RPM_BUILD_ROOT")
 493         }
 494
 495         if (!/%{_lib}/) {
 496                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 497         }
 498
 499         use_macros()
 500
 501         # 'install -d' instead 'mkdir -p'
 502         if (/mkdir -p/)
 503                 sub(/mkdir -p/, "install -d")
 504
 505         # cp -a already implies cp -r
 506         sub(/^cp -ar/, "cp -a")
 507
 508         # No '-u root' or '-g root' for 'install'
 509         if (/^install/ && /-[ug][ \t]*root/)
 510                 gsub(/-[ug][ \t]*root /, "")
 511
 512         if (/^install/ && /-m[ \t]*[0-9]+/)
 513                 gsub(/-m[ \t]*[0-9]+ /, "")
 514
 515         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 516         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 517                 next
 518
 519         # No lines contain 'chmod' if it sets the modes to '644'
 520         if ($1 ~ /chmod/ && $2 ~ /644/)
 521                 next
 522
 523         # atrpms
 524         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 525 }
 526
 527 ##########
 528 # %files #
 529 ##########
 530 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 531         preamble = 0
 532         did_files = 1
 533
 534         if ($0 ~ /^%files/)
 535                 defattr = 1
 536
 537         if (!use_files_macros()) {
 538                 next
 539         }
 540 }
 541
 542 ##############
 543 # %changelog #
 544 ##############
 545 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 546         preamble = 0
 547         has_changelog = 1
 548         skip = 0
 549         # There should be some CVS keywords on the first line of %changelog.
 550         if (boc == 3) {
 551                 if ($0 !~ _cvsmailfeedback) {
 552                         print "* %{date} " _cvsmailfeedback > changelog_file
 553                 } else {
 554                         skip = 1
 555                 }
 556                 boc = 2
 557         }
 558         if (boc == 2 && !skip) {
 559                 if (!/All persons listed below/) {
 560                         printf "All persons listed below can be reached at " > changelog_file
 561                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 562                 } else {
 563                         skip = 1
 564                 }
 565                 boc = 1
 566         }
 567         if (boc == 1 && !skip) {
 568                 if (!/^$/) {
 569                         if (!/\$.*Log:.*\$/) {
 570                                 print "$" "Log:$" > changelog_file
 571                         }
 572                         boc = 0
 573                 }
 574         }
 575         # Define date macro.
 576         if (boc == 4) {
 577                 if (date == 0) {
 578                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 579                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 580                         date = 1
 581                 }
 582                 boc = 3
 583         }
 584
 585         sub(/[ \t]+$/, "");
 586         if (!/^%[a-z]+$/ || /changelog/) {
 587                 # stop changelog if "real" changelog starts
 588                 if (boc == 0 && /^\* /) {
 589                         boc = -1
 590                 }
 591                 if (boc == -1) {
 592                         next;
 593                 }
 594                 print > changelog_file
 595         } else {
 596                 print
 597         }
 598         next
 599 }
 600
 601 ###########
 602 # SCRIPTS #
 603 ###########
 604 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 605         preamble = 0
 606
 607         if (gsub("/usr/sbin/useradd", "%useradd")) {
 608                 sub(" 2> /dev/null \|\| :", "");
 609                 sub(" >/dev/null 2>&1 \|\|:", "");
 610         }
 611
 612         # %useradd and %groupadd may not be wrapped
 613         if (/%(useradd|groupadd).*\\$/) {
 614                 a = $0; getline;
 615                 sub(/^[\s\t]*/, "");
 616                 $0 = substr(a, 1, length(a) - 1) $0;
 617         }
 618         use_script_macros()
 619 }
 620
 621 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 622         preamble = 0
 623         use_macros()
 624 }
 625 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 626         preamble = 0
 627         use_macros()
 628 }
 629 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 630         preamble = 0
 631         use_script_macros()
 632 }
 633 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 634         preamble = 0
 635         use_script_macros()
 636 }
 637 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 638         preamble = 0
 639         use_script_macros()
 640 }
 641 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 642         preamble = 0
 643         use_script_macros()
 644 }
 645 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 646         preamble = 0
 647         use_script_macros()
 648 }
 649 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 650         preamble = 0
 651         use_script_macros()
 652 }
 653 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 654         preamble = 0
 655         use_script_macros()
 656 }
 657 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 658         preamble = 0
 659         use_script_macros()
 660 }
 661
 662 #############
 663 # PREAMBLES #
 664 #############
 665 preamble == 1 {
 666         # There should not be a space after the name of field
 667         # and before the colon.
 668         sub(/[ \t]*:/, ":")
 669
 670         if (/^%perl_module_wo_prefix/) {
 671                 name = $2
 672                 version = $3
 673                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 674         }
 675
 676         field = tolower($1)
 677         fieldnlower = $1
 678         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 679                 sub(/\.$/, "", $0);
 680         }
 681         if (field ~ /group(\([^)]+\)):/)
 682                 next
 683         if (field ~ /group:/) {
 684                 format_preamble()
 685                 group = $0;
 686                 sub(/^[^ \t]*[ \t]*/, "", group);
 687                 group = replace_groupnames(group);
 688                 $0 = "Group:\t\t" group
 689
 690                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 691                         x11 = 1
 692
 693                 byl_plik_z_groupmi = 0
 694                 byl_opis_grupy = 0
 695                 while ((getline linia_grup < groups_file) > 0) {
 696                         byl_plik_z_groupmi = 1
 697                         if (linia_grup == group) {
 698                                 byl_opis_grupy = 1
 699                                 break
 700                         }
 701                 }
 702
 703                 if (!byl_plik_z_groupmi)
 704                         print "######\t\t" groups_file ": no such file"
 705                 else if (!byl_opis_grupy)
 706                         print "######\t\t" "Unknown group!"
 707
 708                 close(groups_file)
 709                 did_groups = 1
 710         }
 711
 712         if (field ~ /prereq:/) {
 713                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 714         }
 715
 716         # split (build)requires, obsoletes on commas
 717         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 718                 value = substr($0, index($0, $2));
 719                 $0 = format_requires($1, value);
 720         }
 721
 722         # BR: tar (and others) is to common (rpm-build requires it)
 723         if (field ~ /^buildrequires:/) {
 724                 l = substr($0, index($0, $2));
 725                 if (l == "awk" ||
 726                         l == "binutils" ||
 727                         l == "bzip2" ||
 728                         l == "cpio" ||
 729                         l == "diffutils" ||
 730                         l == "elfutils" ||
 731                         l == "fileutils" ||
 732                         l == "findutils" ||
 733                         l == "glibc-devel" ||
 734                         l == "grep" ||
 735                         l == "gzip" ||
 736                         l == "make" ||
 737                         l == "patch" ||
 738                         l == "sed" ||
 739                         l == "sh-utils" ||
 740                         l == "tar" ||
 741                         l == "textutils") {
 742                         next
 743                 }
 744
 745                 replace_requires();
 746         }
 747
 748         if (field ~ /^requires:/) {
 749                 replace_requires();
 750         }
 751
 752
 753         # obsolete/unwanted tags
 754         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 755                 next
 756         }
 757
 758         if (field ~ /buildroot:/) {
 759                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 760                 did_build_root = 1
 761         }
 762
 763         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 764         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 765                 $1 = "License:"
 766         }
 767
 768         if (field ~ /license:/) {
 769                 l = substr($0, index($0, $2));
 770                 if (l == "Python Software Foundation License") {
 771                         l = "PSF"
 772                 }
 773                 if (l == "Apache License 2.0" || l == "Apache 2.0" || l == "Apache License Version 2.0" || l == "Apache License, Version 2.0" || l == "Apache Software License v2") {
 774                         l = "Apache v2.0"
 775                 }
 776                 if (l == "Apache Group License" || l == "Apache Software License" || l == "Apache License") {
 777                         l = "Apache"
 778                 }
 779                 if (l == "Apache-style License" || l == "Apache-style Software License") {
 780                         l = "Apache-like"
 781                 }
 782                 if (l == "Apache Software License 1.1" || l == "Apache 1.1") {
 783                         l = "Apache v1.1"
 784                 }
 785                 if (l == "GPLv2") {
 786                         l = "GPL v2"
 787                 }
 788                 if (l == "GPLv2+") {
 789                         l = "GPL v2+"
 790                 }
 791                 $0 = "License:\t" l;
 792         }
 793
 794
 795         if (field ~ /name:/) {
 796                 if ($2 == "%{name}" && name) {
 797                         $2 = name
 798                 }
 799                 name = $2
 800                 name_seen = 1;
 801         }
 802
 803         if (field ~ /version:/) {
 804                 if ($2 == "%{version}" && version) {
 805                         $2 = version
 806                 }
 807                 version = $2
 808                 version_seen = 1;
 809         }
 810
 811         if (field ~ /release:/) {
 812                 if ($2 == "%{release}" && release) {
 813                         $2 = release
 814                 }
 815                 sub(/%atrelease /, "0.", $0)
 816                 release = $2
 817                 release_seen = 1;
 818         }
 819
 820
 821         if (field ~ /serial:/)
 822                 $1 = "Epoch:"
 823
 824         if (field ~ /home-page:/)
 825                 $1 = "URL:"
 826
 827         # proper caps
 828         if (field ~ /^url:$/)
 829                 $1 = "URL:"
 830
 831         if (field ~ /^description:$/)
 832                 $1 = "\n%description\n"
 833
 834         # Use %{name} and %{version} in the filenames in "Source:"
 835         if (field ~ /^source/ || field ~ /patch/) {
 836                 n = split($2, url, /\//)
 837                 if (url[n] ~ /\.gz$/) {
 838                         url[n+1] = ".gz" url[n+1]
 839                         sub(/\.gz$/,"",url[n])
 840                 }
 841                 if (url[n] ~ /\.zip$/) {
 842                         url[n+1] = ".zip" url[n+1]
 843                         sub(/\.zip$/,"",url[n])
 844                 }
 845                 if (url[n] ~ /\.tar$/) {
 846                         url[n+1] = ".tar" url[n+1]
 847                         sub(/\.tar$/,"",url[n])
 848                 }
 849                 if (url[n] ~ /\.patch$/) {
 850                         url[n+1] = ".patch" url[n+1]
 851                         sub(/\.patch$/,"",url[n])
 852                 }
 853                 if (url[n] ~ /\.bz2$/) {
 854                         url[n+1] = ".bz2" url[n+1]
 855                         sub(/\.bz2$/,"",url[n])
 856                 }
 857                 if (url[n] ~ /\.logrotate$/) {
 858                         url[n+1] = ".logrotate" url[n+1]
 859                         sub(/\.logrotate$/,"",url[n])
 860                 }
 861                 if (url[n] ~ /\.pamd$/) {
 862                         url[n+1] = ".pamd" url[n+1]
 863                         sub(/\.pamd$/,"",url[n])
 864                 }
 865
 866                 # allow %{name} only in last url component
 867                 s = ""
 868                 for (i = 1; i <= n; i++) {
 869                         url[i] = fixedsub("%{name}", name, url[i])
 870                         if (s) {
 871                                 s = s "/" url[i]
 872                         } else {
 873                                 s = url[i]
 874                         }
 875                 }
 876                 $2 = s url[n+1]
 877
 878                 filename = url[n]
 879                 if (name) {
 880                         url[n] = fixedsub(name, "%{name}", url[n])
 881                 }
 882                 if (field ~ /source/) {
 883                         if (version) {
 884                                 url[n] = fixedsub(version, "%{version}", url[n])
 885                         }
 886                         if (_beta) {
 887                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 888                         }
 889                         if (_rc) {
 890                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 891                         }
 892                         if (_pre) {
 893                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 894                         }
 895                         if (_snap) {
 896                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 897                         }
 898                         if (subver) {
 899                                 url[n] = fixedsub(subver, "%{subver}", url[n])
 900                         }
 901                 }
 902                 # assigning to $2 kills preamble formatting
 903                 $2 = fixedsub(filename, url[n], $2)
 904
 905                 $2 = unify_url($2)
 906         }
 907
 908
 909         if (field ~ /^source:/)
 910                 $1 = "Source0:"
 911
 912         if (field ~ /^patch:/)
 913                 $1 = "Patch0:"
 914
 915         kill_preamble_macros();
 916         format_preamble()
 917
 918         if (field ~ /requires/) {
 919                 # atrpms
 920                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 921         }
 922 }
 923
 924 /^%bcond_/ {
 925         # do nothing
 926         print
 927         next
 928 }
 929
 930 # sort BR/R!
 931 #
 932 # NOTES:
 933 # - mixing BR/R and anything else confuses this (all will be sorted together)
 934 #       so don't do that.
 935 # - comments leading the BR/R can not be associated,
 936 #       so don't adapterize when the BR/R are mixed with comments
 937 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 938         if ($1 ~ /Pre[Rr]eq:/) {
 939                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 940         }
 941         if ($1 == "BR:" ) {
 942                 $1 = "BuildRequires:"
 943         }
 944         if ($1 == "R:" ) {
 945                 $1 = "Requires:"
 946         }
 947         format_preamble()
 948 #       kill_preamble_macros(); # breaks tabbing
 949
 950         b_idx++;
 951         l = substr($0, index($0, $2));
 952         b_ktmp = b_makekey($1, l);
 953         b_key[b_idx] = b_ktmp;
 954         b_val[b_ktmp] = $0;
 955
 956         next;
 957 }
 958
 959 preamble == 1 {
 960         if (b_idx > 0) {
 961                 isort(b_key, b_idx);
 962                 for (i = 1; i <= b_idx; i++) {
 963                         v = b_val[b_key[i]];
 964                         sub(/[ \t]+$/, "", v);
 965                         print "" v;
 966                 }
 967                 b_idx = 0
 968         }
 969 }
 970
 971 # main() ;-)
 972 {
 973         preamble = 1
 974
 975         sub(/[ \t]+$/, "")
 976         print
 977
 978         if (name_seen == 0 && name) {
 979                 print "Name:\t\t" name
 980                 name_seen = 1
 981         }
 982
 983         if (version_seen == 0 && version) {
 984                 print "Version:\t" version
 985                 version_seen = 1
 986         }
 987
 988         if (release_seen == 0 && release) {
 989                 print "Release:\t" release
 990                 release_seen = 1
 991         }
 992
 993         if (did_build_root == 0) {
 994 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 995                 did_build_root = 1
 996         }
 997         if (did_groups == 0) {
 998 #               print "Group:\t\tunknown"
 999                 did_groups = 1
1000         }
1001 }
1002
1003
1004 END {
1005         if (do_not_touch_anything)
1006                 exit 0
1007
1008         # TODO: need to output these in proper place
1009         if (BR_count > 0) {
1010                 for (i = 0; i <= BR_count; i++) {
1011                         print BR[i];
1012                 }
1013         }
1014
1015         close(changelog_file)
1016         while ((getline < changelog_file) > 0)
1017                 print
1018         system("rm -f " changelog_file)
1019
1020         if (did_clean == 0) {
1021                 print ""
1022                 print "%clean"
1023                 print "rm -rf $RPM_BUILD_ROOT"
1024         }
1025
1026         if (date == 0) {
1027                 print ""
1028                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1029         }
1030
1031         if (has_changelog == 0) {
1032                 print "%changelog"
1033         }
1034
1035         if (boc > 2) {
1036                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1037         }
1038         if (boc > 1) {
1039                 printf "All persons listed below can be reached at "
1040                 print "<cvs_login>@pld-linux.org\n"
1041         }
1042         if (boc > 0) {
1043                 print "$" "Log:$"
1044         }
1045 }
1046
1047 function fixedsub(s1,s2,t, ind) {
1048 # substitutes fixed strings (not regexps)
1049         if (ind = index(t,s1))
1050                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1051         return t
1052 }
1053
1054 # There should be one or two tabs after the colon.
1055 function format_preamble()
1056 {
1057         if (/^#/ || /^%bcond_with/) {
1058                 return;
1059         }
1060         sub(/:[ \t]*/, ":")
1061         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1062                 if (RLENGTH < 8) {
1063                         sub(/:/, ":\t\t")
1064                 } else {
1065                         sub(/:/, ":\t")
1066                 }
1067         }
1068 }
1069
1070 # Replace directly specified directories with macros
1071 function use_macros()
1072 {
1073         # -m, --skip-macros, --no-macros -- skip macros subst
1074         if (ENVIRON["SKIP_MACROS"]) {
1075                 return
1076         }
1077
1078         # leave inline sed lines alone
1079         if (/(%{__sed}|sed) -i -e/) {
1080                 return;
1081         }
1082
1083         sub("%{_defaultdocdir}", "%{_docdir}");
1084         sub("%{_bindir}/perl", "%{__perl}");
1085         sub("%{_bindir}/python", "%{__python}");
1086
1087         gsub(infodir, "%{_infodir}")
1088
1089         gsub(perl_sitearch, "%{perl_sitearch}")
1090         gsub(perl_archlib, "%{perl_archlib}")
1091         gsub(perl_privlib, "%{perl_privlib}")
1092         gsub(perl_vendorlib, "%{perl_vendorlib}")
1093         gsub(perl_vendorarch, "%{perl_vendorarch}")
1094         gsub(perl_sitelib, "%{perl_sitelib}")
1095
1096         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1097         gsub(py_sitedir, "%{py_sitedir}")
1098         gsub(py_scriptdir, "%{py_scriptdir}")
1099         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1100         gsub("%{python_sitelib}", "%{py_sitedir}")
1101
1102         gsub(ruby_archdir, "%{ruby_archdir}")
1103         gsub(ruby_ridir, "%{ruby_ridir}")
1104         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1105         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1106         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1107
1108         gsub("%{_datadir}/applications", "%{_desktopdir}")
1109         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1110         gsub("%{_datadir}/java", "%{_javadir}")
1111
1112         gsub(libdir, "%{_libdir}")
1113         gsub(javadir, "%{_javadir}")
1114
1115         gsub(bindir, "%{_bindir}")
1116         gsub("%{prefix}/bin", "%{_bindir}")
1117         if (prefix"/bin" == bindir)
1118                 gsub("%{_prefix}/bin", "%{_bindir}")
1119
1120         for (c = 1; c <= NF; c++) {
1121                 if ($c ~ sbindir "/fix-info-dir")
1122                         continue;
1123                 if ($c ~ sbindir "/webapp")
1124                         continue;
1125                 if ($c ~ sbindir "/ldconfig")
1126                         continue;
1127                 if ($c ~ sbindir "/chsh")
1128                         continue;
1129                 if ($c ~ sbindir "/usermod")
1130                         continue;
1131                 if ($c ~ sbindir "/chkconfig")
1132                         continue;
1133                 if ($c ~ sbindir "/installzope(product|3package)")
1134                         continue;
1135                 gsub(sbindir, "%{_sbindir}", $c)
1136         }
1137
1138         gsub("%{prefix}/sbin", "%{_sbindir}")
1139         if (prefix"/sbin" == sbindir) {
1140                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1141         }
1142
1143         for (c = 1; c <= NF; c++) {
1144                 if ($c ~ sysconfdir "/{?cron.")
1145                         continue;
1146                 if ($c ~ sysconfdir "/{?crontab.d")
1147                         continue;
1148                 if ($c ~ sysconfdir "/{?env.d")
1149                         continue;
1150                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1151                         continue;
1152                 if ($c ~ sysconfdir "/{?udev")
1153                         continue;
1154                 if ($c ~ sysconfdir "/{?hotplug")
1155                         continue;
1156                 if ($c ~ sysconfdir "/{?logrotate.d")
1157                         continue;
1158                 if ($c ~ sysconfdir "/{?pam.d")
1159                         continue;
1160                 if ($c ~ sysconfdir "/{?profile.d")
1161                         continue;
1162                 if ($c ~ sysconfdir "/{?rc.d")
1163                         continue;
1164                 if ($c ~ sysconfdir "/{?security")
1165                         continue;
1166                 if ($c ~ sysconfdir "/{?skel")
1167                         continue;
1168                 if ($c ~ sysconfdir "/{?sysconfig")
1169                         continue;
1170                 if ($c ~ sysconfdir "/{?shrc.d")
1171                         continue;
1172                 if ($c ~ sysconfdir "/{?certs")
1173                         continue;
1174                 if ($c ~ sysconfdir "/{?X11")
1175                         continue;
1176                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1177                         continue;
1178                 if ($c ~ sysconfdir "/{?rpm")
1179                         continue;
1180                 if ($c ~ sysconfdir "/{?bash_completion.d")
1181                         continue;
1182                 if ($c ~ sysconfdir "/{?samba")
1183                         continue;
1184                 if ($c ~ sysconfdir "/shells")
1185                         continue;
1186                 if ($c ~ sysconfdir "/ppp")
1187                         continue;
1188                 if ($c ~ sysconfdir "/dbus-1")
1189                         continue;
1190                 if ($c ~ sysconfdir "/tmpwatch")
1191                         continue;
1192                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1193         }
1194
1195         gsub(docdir, "%{_docdir}")
1196
1197         gsub(kdedocdir, "%{_kdedocdir}")
1198
1199         gsub(gtkdocdir, "%{_gtkdocdir}")
1200         gsub("%{_docdir}/gtk-doc/html", "%{_gtkdocdir}")
1201
1202         gsub(php_pear_dir, "%{php_pear_dir}")
1203         gsub(php_data_dir, "%{php_data_dir}")
1204
1205         for (c = 1; c <= NF; c++) {
1206                 if ($c ~ datadir "/automake")
1207                         continue;
1208                 if ($c ~ datadir "/unsermake")
1209                         continue;
1210                 if ($c ~ datadir "/file/magic.mime")
1211                         continue;
1212                 gsub(datadir, "%{_datadir}", $c)
1213         }
1214
1215         gsub("%{prefix}/share", "%{_datadir}")
1216         if (prefix"/share" == datadir)
1217                 gsub("%{_prefix}/share", "%{_datadir}")
1218
1219         # CFLAGS="-I/usr/include/ncurses is usually correct.
1220         if (!/-I\/usr\/include/) {
1221                 gsub(includedir, "%{_includedir}")
1222         }
1223
1224         gsub("%{prefix}/include", "%{_includedir}")
1225         if (prefix"/include" == includedir) {
1226                 gsub("%{_prefix}/include", "%{_includedir}")
1227         }
1228
1229         gsub(mandir, "%{_mandir}")
1230         if ($0 !~ "%{_datadir}/manual") {
1231                 gsub("%{_datadir}/man", "%{_mandir}")
1232         }
1233         gsub("%{_prefix}/share/man", "%{_mandir}")
1234         gsub("%{prefix}/share/man", "%{_mandir}")
1235         gsub("%{prefix}/man", "%{_mandir}")
1236         gsub("%{_prefix}/man", "%{_mandir}")
1237
1238         gsub(infodir, "%{_infodir}")
1239         gsub("%{prefix}/info", "%{_infodir}")
1240         gsub("%{_prefix}/info", "%{_infodir}")
1241
1242         if (prefix !~ "/X11R6") {
1243                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1244         }
1245
1246         gsub(examplesdir, "%{_examplesdir}")
1247
1248         if (prefix != "/") {
1249                 # leave --with-foo=/usr alone
1250                 if ($0 !~ "--with.*=.*" prefix) {
1251                         for (c = 1; c <= NF; c++) {
1252                                 if ($c ~ prefix "/sbin/fix-info-dir")
1253                                         continue;
1254                                 if ($c ~ prefix "/sbin/webapp")
1255                                         continue;
1256                                 if ($c ~ prefix "/sbin/chsh")
1257                                         continue;
1258                                 if ($c ~ prefix "/sbin/usermod")
1259                                         continue;
1260                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1261                                         continue;
1262                                 if ($c ~ prefix "/share/automake")
1263                                         continue;
1264                                 if ($c ~ prefix "/share/unsermake")
1265                                         continue;
1266                                 if ($c ~ prefix "/lib/sendmail")
1267                                         continue;
1268                                 if ($c ~ prefix "/lib/pkgconfig")
1269                                         continue;
1270
1271                                 # CFLAGS="-I/usr..." is usually correct.
1272                                 if (/-I\/usr/)
1273                                         continue;
1274                                 # same for LDFLAGS="-L/usr..."
1275                                 if (/-L\/usr/)
1276                                         continue;
1277
1278                                 gsub(prefix, "%{_prefix}", $c)
1279                         }
1280                 }
1281                 gsub("%{prefix}", "%{_prefix}")
1282         }
1283
1284         # replace back
1285         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1286         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1287
1288         gsub("%{PACKAGE_VERSION}", "%{version}")
1289         gsub("%{PACKAGE_NAME}", "%{name}")
1290
1291         gsub("^make$", "%{__make}")
1292         gsub("^make ", "%{__make} ")
1293         gsub("^gcc ", "%{__cc} ")
1294         gsub("^rm --interactive=never ", "%{__rm} ")
1295
1296         # mandrake specs
1297         gsub("^%make$", "%{__make}")
1298         gsub("^%make ", "%{__make} ")
1299         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1300         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1301         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1302         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1303         gsub("^%{__install}", "install")
1304         gsub("%optflags", "%{rpmcflags}")
1305         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1306
1307         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1308         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1309         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1310         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1311         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1312         $0 = fixedsub("%__install", "install", $0);
1313
1314         # split configure line to multiple lines
1315         if (/%configure / && !/\\$/) {
1316                 $0 = format_configure($0);
1317         }
1318
1319         gsub("%_bindir", "%{_bindir}")
1320         gsub("%_datadir", "%{_datadir}")
1321         gsub("%_iconsdir", "%{_iconsdir}")
1322         gsub("%_sbindir", "%{_sbindir}")
1323         gsub("%_mandir", "%{_mandir}")
1324         gsub("%name", "%{name}")
1325         gsub(/%__rm/, "rm");
1326         gsub(/%__mkdir_p/, "install -d");
1327         gsub(/%__cp/, "cp");
1328         gsub(/%__ln_s/, "ln -s");
1329         gsub(/%__sed/, "%{__sed}");
1330         gsub(/%__cat/, "cat");
1331         gsub(/%__chmod/, "chmod");
1332
1333         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1334         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1335
1336         if (/^ant / || /^%{ant}/) {
1337                 sub(/^ant/, "%ant")
1338                 sub(/^%{ant}/, "%ant")
1339                 add_br("BuildRequires:  jpackage-utils");
1340                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1341         }
1342
1343         $0 = fixedsub("%(%{__cc} -dumpversion)", "%{cc_version}", $0);
1344         $0 = fixedsub("%(%{__cxx} -dumpversion)", "%{cxx_version}", $0);
1345 }
1346
1347 function format_configure(line,         n, a, s) {
1348         n = split(line, a, / /);
1349         s = a[1] " \\\n";
1350         for (i = 2; i <= n; i++) {
1351                 s = s "\t" a[i] " \\\n"
1352         }
1353         return s
1354 }
1355
1356
1357 # insertion sort of A[1..n]
1358 # copied from mawk manual
1359 function isort(A,n,             i,j,hold) {
1360         for (i = 2; i <= n; i++) {
1361                 hold = A[j = i]
1362                 while (A[j-1] > hold) {
1363                         j-- ; A[j+1] = A[j]
1364                 }
1365                 A[j] = hold
1366         }
1367         # sentinel A[0] = "" will be created if needed
1368 }
1369
1370
1371 function use_files_macros(      i, n, t, a, l)
1372 {
1373         use_macros()
1374
1375         # skip comments
1376         if (/^#/) {
1377                 return 1;
1378         }
1379
1380         sub("^%doc %{_mandir}", "%{_mandir}")
1381
1382         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1383         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1384
1385         # uid/gid nobody is not valid in %files
1386         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1387                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1388         }
1389
1390         # s[gu]id programs with globs are evil
1391         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1392                 $0 = $0 " # FIXME no globs for suid/sgid files"
1393         }
1394
1395         # replace back
1396         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1397         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1398         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1399         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1400         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1401         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1402         gsub("%{_sysconfdir}/security", "/etc/security")
1403         gsub("%{_sysconfdir}/skel", "/etc/skel")
1404         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1405         gsub("%{_sysconfdir}/certs", "/etc/certs")
1406         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1407         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1408         gsub("%{_sysconfdir}/pki", "/etc/pki")
1409         gsub("%{_sysconfdir}/tmpwatch", "/etc/tmpwatch")
1410
1411         # /etc/init.d -> /etc/rc.d/init.d
1412         if (!/^\/etc\/init\.d$/) {
1413                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1414         }
1415
1416         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1417                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1418                         $0 = "%attr(754,root,root) " $0
1419                 }
1420                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1421                         gsub("^%attr\\(... *,", "%attr(754,");
1422                 }
1423         }
1424
1425         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1426                 $0 = "%attr(755,root,root) " $0
1427         }
1428
1429         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1430                 $0 = "%attr(755,root,root) " $0
1431         }
1432
1433         # /etc/sysconfig files
1434         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1435         # attr not required, allow default 644 attr
1436         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1437                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1438                         gsub("%config", "%config(noreplace)")
1439                 }
1440
1441                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1442                         $NF = "%config(noreplace) " $NF
1443                 }
1444
1445                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1446                         gsub("^%attr\\(... *,", "%attr(640,");
1447                 }
1448
1449                 if (/\/etc\/sysconfig\// && !/%verify/) {
1450                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1451                 }
1452         }
1453
1454         # kill leading zeros
1455         if (/%attr\(0[1-9]/) {
1456                 gsub("%attr\\(0", "%attr(")
1457         }
1458
1459         # kill leading whitespace
1460         gsub(/^ +/, "");
1461
1462         # kill default attrs
1463         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1464         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1465         if (!/%dir/) {
1466                 gsub(/%attr\(644,root,root\) /, "");
1467         }
1468
1469         # sort %verify attrs
1470         if (match($0, /%verify\(not([^)]+)\)/)) {
1471                 t = substr($0, RSTART, RLENGTH)
1472                 # kill commas: %verify(not,md5,size,mtime)
1473                 gsub(/,/, " ", t);
1474
1475                 gsub(/^%verify\(not |\)$/, "", t)
1476                 n = split(t, a, / /)
1477                 isort(a, n)
1478
1479                 s = "%verify(not"
1480                 for (i = 1 ; i <= n; i++) {
1481                         s = s " " a[i]
1482                 }
1483                 s = s ")"
1484
1485                 gsub(/%verify\(not[^)]+\)/, s)
1486         }
1487
1488         if (/%{_mandir}/) {
1489                 gsub("\.gz$", "*")
1490         }
1491
1492         # locale dir and no %lang -> bad
1493         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1494                 $(NF + 1) = "# FIXME consider using %find_lang"
1495         }
1496
1497         # python egg-infos
1498         if (match($0, "^%{py_site(script)?dir}/.+-py"py_ver".egg-info$")) {
1499                 # tests:
1500                 #%{py_sitedir}/*-py2.4.egg-info
1501                 #%{py_sitescriptdir}/GnuPGInterface-%{version}-py2.4.egg-info
1502                 #%{py_sitescriptdir}/python_mpd-%{version}-py2.4.egg-info
1503                 #%{py_sitescriptdir}/mechanize-0.1.6b-py2.4.egg-info
1504
1505                 l = index($0, "/");
1506                 t = substr($0, 0, l);
1507                 s = substr($0, l + 1, RLENGTH - l - length("-py"py_ver".egg-info"));
1508                 if (match(s, "[^-]+$")) {
1509 #printf("s[%s]; start[%d]; length[%d]\n", s, RSTART, RLENGTH);
1510                         if (RSTART > 1) {
1511                                 s = substr(s, 0, RSTART - 1);
1512                         }
1513 #printf("s2[%s]\n", s);
1514                         print "%if \"%{py_ver}\" > \"2.4\""
1515 #print t "/.+.egg-info"
1516                         gsub(t "/.+.egg-info", t "/" s "-*.egg-info");
1517                         print
1518                         print "%endif"
1519                         return 0;
1520                 }
1521         }
1522
1523         # atrpms
1524         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1525         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1526         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1527
1528         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1529         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1530         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1531
1532         gsub("%{_datadir}/applications", "%{_desktopdir}");
1533         gsub("%{_datadir}/icons", "%{_iconsdir}");
1534         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1535         gsub("%{_datadir}/pear", "%{php_pear_dir}");
1536         gsub("%{_datadir}/php", "%{php_data_dir}");
1537
1538         return 1
1539 }
1540
1541 function use_script_macros()
1542 {
1543         if (gsub("/sbin/service", "%service")) {
1544                 sub(" >/dev/null 2>&1 \|\|:", "");
1545                 sub(" 2> /dev/null \|\| :", "");
1546         }
1547 }
1548
1549 function fill(ch, n, i) {
1550         for (i = 0; i < n; i++)
1551                 printf("%c", ch)
1552 }
1553
1554 function format_flush(line, indent, newline, word, first_word) {
1555         first_word = 1
1556         if (format_indent == -1)
1557                 newline = ""
1558         else
1559                 newline = fill(" ", format_indent) "- "
1560
1561         while (match(line, /[^\t ]+/)) {
1562                 word = substr(line, RSTART, RLENGTH)
1563                 if (length(newline) + length(word) + 1 > tw) {
1564                         print newline
1565
1566                         if (format_indent == -1)
1567                                 newline = ""
1568                         else
1569                                 newline = fill(" ", format_indent + 2)
1570                         first_word = 1
1571                 }
1572
1573                 if (first_word) {
1574                         newline = newline word
1575                         first_word = 0
1576                 } else
1577                         newline = newline " " word
1578
1579                 line = substr(line, RSTART + RLENGTH)
1580         }
1581         if (newline ~ /[^\t ]/) {
1582                 print newline
1583         }
1584 }
1585
1586 function cflags(var)
1587 {
1588         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1589                 removed[var] = 1
1590                 return 0
1591         }
1592
1593         if (!/!\?debug/)
1594                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1595         return 1
1596 }
1597
1598 function unify_url(url)
1599 {
1600
1601         # sourceforge urls
1602         sub("[?&]big_mirror=.*$", "", url);
1603         sub("[?&]modtime=.*$", "", url);
1604         sub("[?]use_mirror=.*$", "", url);
1605         sub("[?]download$", "", url);
1606
1607         sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1608         sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", url)
1609         sub("^http://download\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1610         sub("^http://downloads\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1611
1612         sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1613         sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", url)
1614         sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", url)
1615
1616         sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", url)
1617         sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", url)
1618
1619         # apache urls
1620         sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", url)
1621
1622         # gnu.org
1623         sub("^ftp://ftp.gnu.org/", "http://ftp.gnu.org/", url)
1624         sub("^http://ftp.gnu.org/pub/gnu/", "http://ftp.gnu.org/gnu/", url)
1625
1626         return url
1627 }
1628
1629 function demacroize(str)
1630 {
1631         if (mod_name) {
1632                 sub("%{mod_name}", mod_name, str);
1633         }
1634         if (name) {
1635                 sub("%{name}", name, str);
1636         }
1637         if (version) {
1638                 sub("%{version}", version, str);
1639         }
1640         if (_beta) {
1641                 sub("%{_beta}", _beta, str);
1642         }
1643         if (_rc) {
1644                 sub("%{_rc}", _rc, str);
1645         }
1646         if (_pre) {
1647                 sub("%{_pre}", _pre, str);
1648         }
1649         if (_snap) {
1650                 sub("%{_snap}", _snap, str);
1651         }
1652         if (subver) {
1653                 sub("%{subver}", subver, str);
1654         }
1655         return str;
1656 }
1657
1658 function kill_preamble_macros()
1659 {
1660         if ($1 ~ /^Obsoletes:/) {
1661                 # NB! assigning $2 a value breaks tabbing
1662                 $2 = demacroize($2);
1663         }
1664         if ($1 ~ /^URL:/) {
1665                 # NB! assigning $2 a value breaks tabbing
1666                 $2 = demacroize($2);
1667                 $2 = unify_url($2)
1668         }
1669 }
1670
1671 function get_epoch(pkg, ver,    epoch)
1672 {
1673         return
1674 # should parse the BR lines more adequately:
1675 #       freetype = 2.0.0 -> correct
1676 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1677
1678         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1679         shell | getline epoch;
1680         return epoch;
1681 }
1682
1683 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1684         # skip any formatting for commented out items or some weird macros
1685         if (/^#/ || /%\(/) {
1686                 return tag "\t" value
1687         }
1688         n = split(value, p, / *,? */);
1689         for (i = 1; i <= n; i++) {
1690                 if (p[i+1] ~ /[<=>]/) {
1691                         # add epoch if the version doesn't have it but BuildRequires.txt has
1692                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1693                                 epoch = get_epoch(p[i], p[i+2])
1694                                 if (epoch) {
1695                                         p[i+2] = epoch ":" p[i+2];
1696                                 }
1697                         }
1698                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1699                         i += 2;
1700                 } else {
1701                         deps[ndeps++] = p[i];
1702                 }
1703         }
1704         s = ""
1705         for (i in deps) {
1706                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1707         }
1708         return substr(s, 1, length(s)-1);
1709 }
1710
1711 function use_tabs()
1712 {
1713         # reverse vim: ts=4 sw=4 et
1714         gsub(/    /, "\t");
1715 }
1716
1717 function add_br(br)
1718 {
1719         BR[BR_count++] = br
1720 }
1721
1722 function replace_requires()
1723 {
1724
1725         # jpackages
1726         sub(/^java-devel$/, "jdk", $2);
1727         sub(/^log4j$/, "logging-log4j", $2);
1728         sub(/^jakarta-log4j$/, "logging-log4j", $2);
1729         sub(/^oro$/, "jakarta-oro", $2);
1730         sub(/^jakarta-ant$/, "ant", $2);
1731         sub(/^xerces-j2$/, "xerces-j", $2);
1732         sub(/^ldapjdk$/, "ldapsdk", $2);
1733         sub(/^saxon-scripts$/, "saxon", $2);
1734         sub(/^xalan-j2$/, "xalan-j", $2);
1735         sub(/^xerces-j2$/, "xerces-j", $2);
1736         sub(/^gnu-regexp$/, "gnu.regexp", $2);
1737
1738         # redhat virtual
1739         sub(/^tftp-server$/, "tftpdaemon", $2);
1740
1741         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2);
1742         sub(/^chkconfig$/, "/sbin/chkconfig", $2);
1743
1744         # fedora
1745         sub(/^iscsi-initiator-utils$/, "open-iscsi", $2);
1746
1747         replace_php_virtual_deps()
1748 }
1749
1750 # php virtual deps as discussed in devel-en
1751 function replace_php_virtual_deps()
1752 {
1753         pkg = $2
1754 #       if (pkg == "php-program") {
1755 #               $0 = $1 "\t/usr/bin/php"
1756 #               return
1757 #       }
1758
1759 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1760 #               sub(/^php-/, "php(", pkg);
1761 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1762 #               $2 = pkg
1763 #       }
1764
1765         if (pkg ~/^php$/) {
1766                 $2 = "webserver(php)";
1767                 if ($4 ~ /^[0-9]:/) {
1768                         $4 = substr($4, 3);
1769                 }
1770         }
1771
1772         if (pkg ~/^php4$/) {
1773                 $2 = "webserver(php)";
1774                 if ($4 ~ /^[0-9]:/) {
1775                         $4 = substr($4, 3);
1776                 }
1777         }
1778 }
1779
1780 function replace_groupnames(group)
1781 {
1782         sub(/^Amusements\/Games\/Strategy\/Real Time/, "X11/Applications/Games/Strategy", group)
1783         sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
1784         sub(/^Applications\/Compilers$/, "Development/Languages", group)
1785         sub(/^Applications\/Daemons$/, "Daemons", group)
1786         sub(/^Applications\/Internet$/, "Applications/Networking", group)
1787         sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
1788         sub(/^Applications\/Productivity$/, "X11/Applications", group)
1789         sub(/^Database$/, "Applications/Databases", group)
1790         sub(/^Development\/Code Generators$/, "Development", group)
1791         sub(/^Development\/Docs$/, "Documentation", group)
1792         sub(/^Development\/Documentation$/, "Documentation", group)
1793         sub(/^Development\/Java/, "Development/Languages/Java", group)
1794         sub(/^Development\/Libraries\/C and C\+\+$/, "Development/Libraries", group)
1795         sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
1796         sub(/^Development\/Other/,"Development", group)
1797         sub(/^Development\/Testing$/, "Development", group)
1798         sub(/^Emulators$/, "Applications/Emulators", group)
1799         sub(/^Games/,"Applications/Games", group)
1800         sub(/^Library\/Development$/, "Development/Libraries", group)
1801         sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
1802         sub(/^Shells/,"Applications/Shells", group)
1803         sub(/^System Environment\/Base$/, "Base", group)
1804         sub(/^System Environment\/Daemons$/, "Daemons", group)
1805         sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
1806         sub(/^System Environment\/Libraries$/, "Libraries", group)
1807         sub(/^System$/, "Base", group)
1808         sub(/^System\/Base$/, "Base", group)
1809         sub(/^System\/Libraries$/, "Libraries", group)
1810         sub(/^System\/Servers$/, "Daemons", group)
1811         sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
1812         sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
1813         sub(/^Utilities\//,"Applications/", group)
1814         sub(/^Web\/Database$/, "Applications/WWW", group)
1815         sub(/^X11\/GNOME/,"X11/Applications", group)
1816         sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
1817         sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
1818         sub(/^X11\/Games/,"X11/Applications/Games", group)
1819         sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
1820         sub(/^X11\/Library/,"X11/Libraries", group)
1821         sub(/^X11\/Utilities/,"X11/Applications", group)
1822         sub(/^X11\/XFree86/, "X11", group)
1823         sub(/^X11\/Xserver$/, "X11/Servers", group)
1824         sub(/^Development\/C$/, "Development/Libraries", group)
1825         sub(/^Development\/Python$/, "Development/Languages/Python", group)
1826         sub(/^System\/Kernel and hardware$/, "Base/Kernel", group)
1827         sub(/^Application\/System$/, "Applications/System", group)
1828         sub(/^Productivity\/Databases\/Servers$/, "Applications/Databases", group)
1829         sub(/^Development\/Libraries\/Python$/, "Development/Languages/Python", group)
1830         sub(/^Development\/Languages\/Ruby$/, "Development/Languages", group)
1831         sub(/^Development\/Libraries\/TCL$/, "Development/Languages/Tcl", group);
1832         sub(/^Development\/Languages\/Other$/, "Development/Languages", group);
1833         sub(/^Productivity\/Networking\/Web\/Servers$/, "Networking/Daemons", group);
1834
1835         return group;
1836 }
1837
1838 # vim:ts=4:sw=4