adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2003 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Elan Ruusamäe <glen@pld-linux.org>
  13 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  14
  15 # TODO
  16 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  17 # - add "-nc" option to skip CVS interaction
  18 # - sort Summary(XX)
  19 # - sort Requires, BuildRequires
  20
  21 BEGIN {
  22         preamble = 1            # Is it part of preamble? Default - yes
  23         boc = 4                 # Beggining of %changelog
  24         bod = 0                 # Beggining of %description
  25         tw = 70                 # Descriptions width
  26
  27         b_idx = 0               # index of BR/R arrays
  28
  29         # If variable removed, then 1 (for removing it from export)
  30         removed["LDFLAGS"] = 0
  31         removed["CFLAGS"] = 0
  32         removed["CXXFLAGS"] = 0
  33
  34         # get cvsaddress for changelog section
  35         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  36         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  37         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  38
  39         # If 1, we are inside of comment block (started with /^#%/)
  40         comment_block = 0
  41
  42         # File with rpm groups
  43         "rpm --eval %_sourcedir" | getline groups_file
  44         groups_file = groups_file "/rpm.groups"
  45         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups >/dev/null")
  46
  47         # Temporary file for changelog section
  48         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  49
  50         # Load rpm macros
  51         "rpm --eval %_prefix"   | getline prefix
  52         "rpm --eval %_bindir"   | getline bindir
  53         "rpm --eval %_sbindir"  | getline sbindir
  54         "rpm --eval %_libdir"   | getline libdir
  55         "rpm --eval %_sysconfdir" | getline sysconfdir
  56         "rpm --eval %_datadir"  | getline datadir
  57         "rpm --eval %_includedir" | getline includedir
  58         "rpm --eval %_mandir"   | getline mandir
  59         "rpm --eval %_infodir"  | getline infodir
  60         "rpm --eval %_examplesdir"      | getline examplesdir
  61
  62         "rpm --eval %perl_sitearch" | getline perl_sitearch
  63         "rpm --eval %perl_archlib" | getline perl_archlib
  64         "rpm --eval %perl_privlib" | getline perl_privlib
  65         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  66         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  67         "rpm --eval %perl_sitelib" | getline perl_sitelib
  68
  69         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  70 }
  71
  72 # There should be a comment with CVS keywords on the first line of file.
  73 FNR == 1 {
  74         if (!/# \$Revision:/)   # If this line is already OK?
  75                 print "# $" "Revision:$, " "$" "Date:$" # No
  76         else {
  77                 print $0                                # Yes
  78                 next            # It is enough for first line
  79         }
  80 }
  81
  82 # If the latest line matched /%files/
  83 defattr == 1 {
  84         if ($0 !~ /defattr/)    # If no %defattr
  85                 print "%defattr(644,root,root,755)"     # Add it
  86         else
  87                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  88         defattr = 0
  89 }
  90
  91 function b_makekey(a, b,        s) {
  92         s = a "" b;
  93         # kill bcond
  94         gsub("%{\\?[_a-zA-Z0-9]+:", "", s);
  95         return s;
  96 }
  97
  98 # sort BR/R!
  99 #
 100 # NOTES:
 101 # - mixing BR/R and anything else confuses this (all will be sorted together)
 102 #   so don't do that.
 103 # - comments leading the BR/R can not be associated,
 104 #   so don't adapterize when the BR/R are mixed with comments
 105 ENVIRON["SORTBR"] == 1 && preamble == 1 && /(Build)?Requires/, /(Build)?Requires/ { # && !/^%/) {
 106         b_idx++;
 107         l = substr($0, index($0, $2));
 108         b_ktmp = b_makekey($1, l);
 109         b_key[b_idx] = b_ktmp;
 110         b_val[b_ktmp] = $0;
 111
 112         next;
 113 }
 114
 115 preamble == 1 {
 116         if (b_idx > 0) {
 117                 isort(b_key, b_idx);
 118                 for (i = 1; i <= b_idx; i++) {
 119                         print "" b_val[b_key[i]];
 120                 }
 121                 b_idx = 0
 122         }
 123 }
 124
 125 # Comments
 126 /^#/ && (description == 0) {
 127         if (/This file does not like to be adapterized!/) {
 128                 print                   # print this message
 129                 while (getline)         # print the rest of spec as it is
 130                         print
 131                 do_not_touch_anything = 1 # do not touch anything in END()
 132                 exit 0
 133         }
 134
 135         # Generally, comments are printed without touching
 136         sub(/[ \t]+$/, "")
 137         print $0
 138         next
 139 }
 140
 141 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 142 /^%define/ {
 143         if ($2 == "_applnkdir")
 144                 next
 145         if ($2 == "date")
 146                 date = 1
 147 }
 148
 149 # Obsolete
 150 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 151         next
 152 }
 153
 154 ################
 155 # %description #
 156 ################
 157 /^%description/, (/^%[a-z]+/ && !/^%description/ && !/^%((end)?if|else)/) {
 158         preamble = 0
 159
 160         if (/^%description/) {
 161                 bod++
 162                 format_line = ""
 163                 format_indent = -1
 164         }
 165
 166         # Format description
 167         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 168                 if (/^[ \t]*$/) {
 169                         format_flush(format_line, format_indent)
 170                         print ""
 171                         format_line = ""
 172                         format_indent = -1
 173                 } else if (/^[ \t]*[-\*][ \t]*/) {
 174                         format_flush(format_line, format_indent)
 175                         match($0, /^[ \t]*/)
 176                         format_indent = RLENGTH
 177                         match($0, /^[ \t]*[-\*][ \t]/)
 178                         format_line = substr($0, RLENGTH)
 179                 } else
 180                         format_line = format_line " " $0
 181                 next
 182         }
 183
 184         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 185                 if (NF > 3 && $2 == "-l") {
 186                         ll = $1
 187                         for (i = 4; i <= NF; i++)
 188                                 ll = ll " " $i
 189                         $0 = ll " -l " $3
 190                 }
 191                 format_flush(format_line, format_indent)
 192                 if (bod == 2) {
 193                         bod = 1
 194                         description = 1
 195                 } else {
 196                         bod = 0
 197                         description = 0
 198                 }
 199         } else
 200                 description = 1
 201 }
 202
 203 #########
 204 # %prep #
 205 #########
 206 /^%prep/, (/^%[a-z]+$/ && !/^%prep/ && !/^%((end)?if|else)/) {
 207         preamble = 0
 208
 209         use_macros()
 210
 211         # Add '-q' to %setup
 212         if (/^%setup/ && !/-q/) {
 213                 sub(/^%setup/, "%setup -q")
 214         }
 215
 216         if (/^%setup/) {
 217                 gsub(name, "%{name}");
 218                 gsub(version, "%{version}");
 219                 if (_beta) {
 220                         gsub(_beta, "%{_beta}");
 221                 }
 222                 if (_rc) {
 223                         gsub(_rc, "%{_rc}");
 224                 }
 225                 if (_snap) {
 226                         gsub(_snap, "%{_snap}");
 227                 }
 228         }
 229
 230         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 231                 sub(/ -n %{name}-%{version}/, "")
 232         }
 233
 234         # invalid in %prep
 235         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 236 }
 237
 238 ##########
 239 # %build #
 240 ##########
 241 /^%build/, (/^%[a-z]+$/ && !/^%build/ && !/^%((end)?if|else)/) {
 242         preamble = 0
 243
 244         use_macros()
 245
 246         if (/^automake$/)
 247                 sub(/$/, " -a -c")
 248
 249         if (/LDFLAGS/) {
 250                 if (/LDFLAGS="-s"/) {
 251                         removed["LDFLAGS"] = 1
 252                         next
 253                 } else {
 254                         split($0, tmp, "LDFLAGS=")
 255                         count = split(tmp[2], flags, "\"")
 256                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 257                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 258                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 259                                 for (i = 2; i < count; i++)
 260                                         $0 = $0 flags[i] "\""
 261                         }
 262                 }
 263         }
 264
 265         if (/CFLAGS=/)
 266                 if (cflags("CFLAGS") == 0)
 267                         next
 268
 269         if (/CXXFLAGS=/)
 270                 if (cflags("CXXFLAGS") == 0)
 271                         next
 272
 273         if (/^export /) {
 274                 if (removed["LDFLAGS"])
 275                         sub(" LDFLAGS", "")
 276                 if (removed["CFLAGS"])
 277                         sub(" CFLAGS", "")
 278                 if (removed["CXXFLAGS"])
 279                         sub(" CXXFLAGS", "")
 280                 # Is there still something?
 281                 if (/^export[ ]*$/)
 282                         next
 283         }
 284
 285         # use macros
 286         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 287         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 288
 289         # atrpms
 290         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 291         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 292 }
 293
 294 ##########
 295 # %clean #
 296 ##########
 297 /^%clean/, (/^%[a-z]+$/ && !/^%clean/ && !/^%((end)?if|else)/) {
 298         did_clean = 1
 299         use_macros()
 300 }
 301
 302 ############
 303 # %install #
 304 ############
 305 /^%install/, (/^%[a-z]+$/ && !/^%install/ && !/^%((end)?if|else)/) {
 306
 307         preamble = 0
 308
 309         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 310                 did_rmroot=1
 311                 print "rm -rf $RPM_BUILD_ROOT"
 312                 next
 313         }
 314
 315         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 316                 print "rm -rf $RPM_BUILD_ROOT"
 317                 did_rmroot=1
 318         }
 319
 320         use_macros()
 321
 322         # 'install -d' instead 'mkdir -p'
 323         if (/mkdir -p/)
 324                 sub(/mkdir -p/, "install -d")
 325
 326         # 'install' instead 'cp -p'
 327         if (/cp -p\b/)
 328                 sub(/cp -p/, "install")
 329
 330         # No '-u root' or '-g root' for 'install'
 331         if (/^install/ && /-[ug][ \t]*root/)
 332                 gsub(/-[ug][ \t]*root /, "")
 333
 334         if (/^install/ && /-m[ \t]*[0-9]+/)
 335                 gsub(/-m[ \t]*[0-9]+ /, "")
 336
 337         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 338         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 339                 next
 340
 341         # No lines contain 'chmod' if it sets the modes to '644'
 342         if ($1 ~ /chmod/ && $2 ~ /644/)
 343                 next
 344
 345         # foreign rpms
 346         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 347         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 348
 349         # atrpms
 350         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 351 }
 352
 353 ##########
 354 # %files #
 355 ##########
 356 /^%files/, (/^%[a-z \-]+$/ && !/^%files/ && !/^%((end)?if|else)/) {
 357         preamble = 0
 358
 359         if ($0 ~ /^%files/)
 360                 defattr = 1
 361
 362         use_macros()
 363         use_files_macros()
 364 }
 365
 366 ##############
 367 # %changelog #
 368 ##############
 369 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 370         preamble = 0
 371         has_changelog = 1
 372         skip = 0
 373         # There should be some CVS keywords on the first line of %changelog.
 374         if (boc == 3) {
 375                 if ($0 !~ _cvsmailfeedback)
 376                         print "* %{date} " _cvsmailfeedback > changelog_file
 377                 else
 378                         skip = 1
 379                 boc = 2
 380         }
 381         if (boc == 2 && !skip) {
 382                 if (!/All persons listed below/) {
 383                         printf "All persons listed below can be reached at " > changelog_file
 384                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 385                 } else
 386                         skip = 1
 387                 boc = 1
 388         }
 389         if (boc == 1 && !skip) {
 390                 if (!/^$/) {
 391                         if (!/\$.*Log:.*\$/)
 392                                 print "$" "Log:$" > changelog_file
 393                         boc = 0
 394                 }
 395         }
 396         # Define date macro.
 397         if (boc == 4) {
 398                 if (date == 0) {
 399                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 400                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 401                         date = 1
 402                 }
 403                 boc = 3
 404         }
 405
 406         sub(/[ \t]+$/, "")
 407         if (!/^%[a-z]+$/ || /changelog/)
 408                 print > changelog_file
 409         else
 410                 print
 411         next
 412 }
 413
 414 ###########
 415 # SCRIPTS #
 416 ###########
 417 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 418         preamble = 0
 419 }
 420 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 421         preamble = 0
 422 }
 423 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 424         preamble = 0
 425 }
 426 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 427         preamble = 0
 428 }
 429 /^%triggerin/, (/^%[a-z]+$/ && !/^%triggerin/) {
 430         preamble = 0
 431 }
 432 /^%triggerun/, (/^%[a-z]+$/ && !/^%triggerun/) {
 433         preamble = 0
 434 }
 435 /^%triggerpostun/, (/^%[a-z]+$/ && !/^%triggerpostun/) {
 436         preamble = 0
 437 }
 438 /^%pretrans/, (/^%[a-z]+$/ && !/^%pretrans/) {
 439         preamble = 0
 440 }
 441 /^%posttrans/, (/^%[a-z]+$/ && !/^%posttrans/) {
 442         preamble = 0
 443 }
 444
 445 #############
 446 # PREAMBLES #
 447 #############
 448 preamble == 1 {
 449         # There should not be a space after the name of field
 450         # and before the colon.
 451         sub(/[ \t]*:/, ":")
 452
 453         if (/^%perl_module_wo_prefix/) {
 454                 name = $2
 455                 version = $3
 456                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 457         }
 458
 459         field = tolower($1)
 460         fieldnlower = $1
 461         if (field ~ /group(\([^)]+\)):/)
 462                 next
 463         if (field ~ /group:/) {
 464                 format_preamble()
 465                 sub(/^Utilities\//,"Applications/",$2)
 466                 sub(/^Games/,"Applications/Games",$2)
 467                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 468                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 469                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 470                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 471                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 472                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 473                 sub(/^Shells/,"Applications/Shells",$2)
 474
 475                 sub(/^[^ \t]*[ \t]*/,"")
 476                 Grupa = $0
 477
 478                 print "Group:\t\t" Grupa
 479                 if (Grupa ~ /^X11/ && x11 == 0) # Is it X11 application?
 480                         x11 = 1
 481
 482                 byl_plik_z_grupami = 0
 483                 byl_opis_grupy = 0
 484                 while ((getline linia_grup < groups_file) > 0) {
 485                         byl_plik_z_grupami = 1
 486                         if (linia_grup == Grupa) {
 487                                 byl_opis_grupy = 1
 488                                 break
 489                         }
 490                 }
 491
 492                 if (!byl_plik_z_grupami)
 493                         print "######\t\t" groups_file ": no such file"
 494                 else if (!byl_opis_grupy)
 495                         print "######\t\t" "Unknown group!"
 496
 497                 close(groups_file)
 498                 next
 499         }
 500
 501         if (field ~ /prereq:/) {
 502                 $1 = "Requires:"
 503                 $(NF + 1) = " # FIXME add Requires(scriptlet) -adapter.awk"
 504         }
 505
 506         # split (build)requires on commas
 507         if (field ~ /requires:/ && $0 ~ /,/) {
 508                 l = substr($0, index($0, $2));
 509                 n = split(l, p, / *, */);
 510                 for (i in p) {
 511                         printf("%s\t%s\n", $1, p[i]);
 512                 }
 513                 next;
 514         }
 515
 516         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 517                 next
 518
 519         if (field ~ /buildroot:/)
 520                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 521
 522         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 523         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 524                 $1 = "License:"
 525
 526         if (field ~ /name:/) {
 527                 name = $2
 528                 name_seen = 1;
 529         }
 530
 531         if (field ~ /version:/) {
 532                 version = $2
 533                 version_seen = 1;
 534         }
 535
 536         if (field ~ /release:/) {
 537                 release = $2
 538                 release_seen = 1;
 539         }
 540
 541         if (field ~ /serial:/)
 542                 $1 = "Epoch:"
 543
 544         # Use %{name} and %{version} in the filenames in "Source:"
 545         if (field ~ /^source/ || field ~ /patch/) {
 546                 n = split($2, url, /\//)
 547                 if (url[n] ~ /\.gz$/) {
 548                         url[n+1] = ".gz" url[n+1]
 549                         sub(/\.gz$/,"",url[n])
 550                 }
 551                 if (url[n] ~ /\.zip$/) {
 552                         url[n+1] = ".zip" url[n+1]
 553                         sub(/\.zip$/,"",url[n])
 554                 }
 555                 if (url[n] ~ /\.tar$/) {
 556                         url[n+1] = ".tar" url[n+1]
 557                         sub(/\.tar$/,"",url[n])
 558                 }
 559                 if (url[n] ~ /\.patch$/) {
 560                         url[n+1] = ".patch" url[n+1]
 561                         sub(/\.patch$/,"",url[n])
 562                 }
 563                 if (url[n] ~ /\.bz2$/) {
 564                         url[n+1] = ".bz2" url[n+1]
 565                         sub(/\.bz2$/,"",url[n])
 566                 }
 567                 if (url[n] ~ /\.logrotate$/) {
 568                         url[n+1] = ".logrotate" url[n+1]
 569                         sub(/\.logrotate$/,"",url[n])
 570                 }
 571                 if (url[n] ~ /\.pamd$/) {
 572                         url[n+1] = ".pamd" url[n+1]
 573                         sub(/\.pamd$/,"",url[n])
 574                 }
 575
 576                 # allow %{name} just in last url component
 577                 s = ""
 578                 for (i = 1; i <= n; i++) {
 579                         url[i] = fixedsub("%{name}", name, url[i])
 580                         if (s) {
 581                                 s = s "/" url[i]
 582                         } else {
 583                                 s = url[i]
 584                         }
 585                 }
 586                 $2 = s url[n+1]
 587
 588                 filename = url[n]
 589                 if (name) {
 590                         url[n] = fixedsub(name, "%{name}", url[n])
 591                 }
 592                 if (field ~ /source/) {
 593                         if (version) {
 594                                 url[n] = fixedsub(version, "%{version}", url[n])
 595                         }
 596                         if (_beta) {
 597                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 598                         }
 599                         if (_rc) {
 600                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 601                         }
 602                         if (_snap) {
 603                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 604                         }
 605                 }
 606                 $2 = fixedsub(filename, url[n], $2)
 607
 608                 # sourceforge urls
 609                 sub("[?]use_mirror=.*$", "", $2);
 610                 sub("[?]download$", "", $2);
 611                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 612
 613                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 614                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 615         }
 616
 617
 618         if (field ~ /^source:/)
 619                 $1 = "Source0:"
 620
 621         if (field ~ /patch:/)
 622                 $1 = "Patch0:"
 623
 624         format_preamble()
 625
 626         if ($1 ~ /%define/) {
 627                 # Do not add %define of _prefix if it already is.
 628                 if ($2 ~ /^_prefix/) {
 629                         sub("^"prefix, $3, bindir)
 630                         sub("^"prefix, $3, sbindir)
 631                         sub("^"prefix, $3, libdir)
 632                         sub("^"prefix, $3, datadir)
 633                         sub("^"prefix, $3, includedir)
 634                         prefix = $3
 635                 }
 636                 if ($2 ~ /_bindir/ && !/_sbindir/)
 637                         bindir = $3
 638                 if ($2 ~ /_sbindir/)
 639                         sbindir = $3
 640                 if ($2 ~ /_libdir/)
 641                         libdir = $3
 642                 if ($2 ~ /_sysconfdir/ && $3 !~ /^%\(/)
 643                         sysconfdir = $3
 644                 if ($2 ~ /_datadir/)
 645                         datadir = $3
 646                 if ($2 ~ /_includedir/)
 647                         includedir = $3
 648                 if ($2 ~ /_mandir/)
 649                         mandir = $3
 650                 if ($2 ~ /_infodir/)
 651                         infodir = $3
 652
 653                 if ($2 ~ /_beta/)
 654                         _beta = $3
 655                 if ($2 ~ /_rc/)
 656                         _rc = $3
 657                 if ($2 ~ /_snap/)
 658                         _snap = $3
 659         }
 660
 661         if (field ~ /requires/) {
 662                 # atrpms
 663                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 664         }
 665 }
 666
 667 # main() ;-)
 668 {
 669         preamble = 1
 670
 671         sub(/[ \t]+$/, "")
 672         print
 673
 674         if (name_seen == 0 && name) {
 675                 print "Name:\t" name
 676                 name_seen = 1
 677         }
 678
 679         if (version_seen == 0 && version) {
 680                 print "Version:\t" version
 681                 version_seen = 1
 682         }
 683
 684         if (release_seen == 0 && release) {
 685                 print "Release:\t" release
 686                 release_seen = 1
 687         }
 688 }
 689
 690
 691 END {
 692         if (do_not_touch_anything)
 693                 exit 0
 694
 695         close(changelog_file)
 696         while ((getline < changelog_file) > 0)
 697                 print
 698         system("rm -f " changelog_file)
 699
 700
 701
 702         if (did_clean == 0) {
 703                 print ""
 704                 print "%clean"
 705                 print "rm -rf $RPM_BUILD_ROOT"
 706         }
 707
 708         if (date == 0) {
 709                 print ""
 710                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 711         }
 712
 713         if (has_changelog == 0)
 714                 print "%changelog"
 715
 716         if (boc > 2)
 717                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 718         if (boc > 1) {
 719                 printf "All persons listed below can be reached at "
 720                 print "<cvs_login>@pld-linux.org\n"
 721         }
 722         if (boc > 0)
 723                 print "$" "Log:$"
 724 }
 725
 726 function fixedsub(s1,s2,t, ind) {
 727 # substitutes fixed strings (not regexps)
 728         if (ind = index(t,s1))
 729                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 730         return t
 731 }
 732
 733 # There should be one or two tabs after the colon.
 734 function format_preamble()
 735 {
 736         sub(/:[ \t]*/, ":")
 737         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 738                 if (RLENGTH < 8)
 739                         sub(/:/, ":\t\t")
 740                 else
 741                         sub(/:/, ":\t")
 742         }
 743 }
 744
 745 # Replace directly specified directories with macros
 746 function use_macros()
 747 {
 748         gsub(perl_sitearch, "%{perl_sitearch}")
 749         gsub(perl_archlib, "%{perl_archlib}")
 750         gsub(perl_privlib, "%{perl_privlib}")
 751         gsub(perl_vendorlib, "%{perl_vendorlib}")
 752         gsub(perl_vendorarch, "%{perl_vendorarch}")
 753         gsub(perl_sitelib, "%{perl_sitelib}")
 754
 755         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
 756
 757         gsub(bindir, "%{_bindir}")
 758         gsub("%{prefix}/bin", "%{_bindir}")
 759         if(prefix"/bin" == bindir)
 760                 gsub("%{_prefix}/bin", "%{_bindir}")
 761
 762         for (c = 1; c <= NF; c++) {
 763                 if ($c ~ sbindir "/fix-info-dir")
 764                         continue;
 765                 gsub(sbindir, "%{_sbindir}", $c)
 766         }
 767
 768         gsub("%{prefix}/sbin", "%{_sbindir}")
 769         if (prefix"/sbin" == sbindir)
 770                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 771
 772         for (c = 1; c <= NF; c++) {
 773                 if ($c ~ sysconfdir "/{?cron.")
 774                         continue;
 775                 if ($c ~ sysconfdir "/{?crontab.d")
 776                         continue;
 777                 if ($c ~ sysconfdir "/{?logrotate.d")
 778                         continue;
 779                 if ($c ~ sysconfdir "/{?pam.d")
 780                         continue;
 781                 if ($c ~ sysconfdir "/{?profile.d")
 782                         continue;
 783                 if ($c ~ sysconfdir "/{?rc.d")
 784                         continue;
 785                 if ($c ~ sysconfdir "/{?security")
 786                         continue;
 787                 if ($c ~ sysconfdir "/{?skel")
 788                         continue;
 789                 if ($c ~ sysconfdir "/{?sysconfig")
 790                         continue;
 791                 if ($c ~ sysconfdir "/{?certs")
 792                         continue;
 793                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 794         }
 795
 796         for (c = 1; c <= NF; c++) {
 797                 if ($c ~ datadir "/automake")
 798                         continue;
 799                 if ($c ~ datadir "/unsermake")
 800                         continue;
 801                 gsub(datadir, "%{_datadir}", $c)
 802         }
 803
 804
 805         gsub("%{prefix}/share", "%{_datadir}")
 806         if (prefix"/share" == datadir)
 807                 gsub("%{_prefix}/share", "%{_datadir}")
 808
 809         gsub(includedir, "%{_includedir}")
 810         gsub("%{prefix}/include", "%{_includedir}")
 811         if (prefix"/include" == includedir)
 812                 gsub("%{_prefix}/include", "%{_includedir}")
 813
 814         gsub(mandir, "%{_mandir}")
 815         if ($0 !~ "%{_datadir}/manual")
 816                 gsub("%{_datadir}/man", "%{_mandir}")
 817         gsub("%{_prefix}/share/man", "%{_mandir}")
 818         gsub("%{prefix}/share/man", "%{_mandir}")
 819         gsub("%{prefix}/man", "%{_mandir}")
 820         gsub("%{_prefix}/man", "%{_mandir}")
 821
 822         gsub(infodir, "%{_infodir}")
 823         gsub("%{prefix}/info", "%{_infodir}")
 824         gsub("%{_prefix}/info", "%{_infodir}")
 825
 826         if (prefix !~ "/X11R6") {
 827                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 828         }
 829
 830         gsub(examplesdir, "%{_examplesdir}")
 831
 832         if (prefix != "/") {
 833                 for (c = 1; c <= NF; c++) {
 834                         if ($c ~ prefix "/sbin/fix-info-dir")
 835                                 continue;
 836                         if ($c ~ prefix "/share/automake")
 837                                 continue;
 838                         if ($c ~ prefix "/share/unsermake")
 839                                 continue;
 840                         gsub(prefix, "%{_prefix}", $c)
 841                 }
 842                 gsub("%{prefix}", "%{_prefix}")
 843         }
 844
 845         gsub("%{PACKAGE_VERSION}", "%{version}")
 846         gsub("%{PACKAGE_NAME}", "%{name}")
 847
 848         # we can move files between the dirs below
 849         if ($0 !~ "%{_applnkdir}") {
 850                 gsub("%{_datadir}/gnome/apps", "%{_applnkdir}")
 851         }
 852
 853         gsub("^make$", "%{__make}")
 854         gsub("^make ", "%{__make} ")
 855
 856         # mandrake specs
 857         gsub("^%make$", "%{__make}")
 858         gsub("^%make ", "%{__make} ")
 859         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 860         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 861         gsub("%optflags", "%{rpmcflags}")
 862         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
 863
 864         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 865         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
 866         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 867         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 868         gsub("%_bindir", "%{_bindir}")
 869         gsub("%_datadir", "%{_datadir}")
 870         gsub("%_iconsdir", "%{_iconsdir}")
 871
 872         gsub("/usr/src/linux", "%{_kernelsrcdir}")
 873         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
 874 }
 875
 876
 877 # insertion sort of A[1..n]
 878 # copied from mawk manual
 879 function isort(A,n,             i,j,hold) {
 880         for (i = 2; i <= n; i++) {
 881                 hold = A[j = i]
 882                 while (A[j-1] > hold) {
 883                         j-- ; A[j+1] = A[j]
 884                 }
 885                 A[j] = hold
 886         }
 887         # sentinel A[0] = "" will be created if needed
 888 }
 889
 890
 891 function use_files_macros(      i, n, t, a)
 892 {
 893         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 894         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 895
 896         # replace back
 897         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
 898         gsub("%{_sysconfdir}/crontab\.d", "/etc/cron.d")
 899         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
 900         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
 901         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
 902         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
 903         gsub("%{_sysconfdir}/security", "/etc/security")
 904         gsub("%{_sysconfdir}/skel", "/etc/skel")
 905         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
 906         gsub("%{_sysconfdir}/certs", "/etc/certs")
 907         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
 908
 909         # /etc/init.d -> /etc/rc.d/init.d
 910         if (!/^\/etc\/init\.d$/) {
 911                  gsub("/etc/init.d", "/etc/rc.d/init.d")
 912         }
 913
 914         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
 915                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
 916                         $0 = "%attr(754,root,root) " $0
 917                 }
 918                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
 919                         gsub("^%attr\\(... *,", "%attr(754,");
 920                 }
 921         }
 922
 923         if (/lib.+\.so/ && !/^%attr.*/) {
 924                 $0 = "%attr(755,root,root) " $0
 925         }
 926
 927         # /etc/sysconfig files
 928         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
 929         # attr not required, allow default 644 attr
 930         if (!/network-scripts/) {
 931                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace\)/) {
 932                         gsub("%config", "%config(noreplace)")
 933                 }
 934
 935                 if (/\/etc\/sysconfig\// && !/%config\(noreplace\)/) {
 936                         $NF = "%config(noreplace) " $NF
 937                 }
 938
 939                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
 940                         gsub("^%attr\\(... *,", "%attr(640,");
 941                 }
 942
 943                 if (/\/etc\/sysconfig\// && !/%verify/) {
 944                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
 945                 }
 946         }
 947
 948
 949         # kill leading zeros
 950         gsub("%attr\\(0", "%attr(")
 951
 952         # sort %verify attrs
 953         if (match($0, /%verify\(not([^)]+)\)/)) {
 954                 t = substr($0, RSTART, RLENGTH)
 955                 gsub(/^%verify\(not |\)$/, "", t)
 956                 n = split(t, a, / /)
 957                 isort(a, n)
 958
 959                 s = "%verify(not"
 960                 for (i = 1 ; i <= n; i++) {
 961                         s = s " " a[i]
 962                 }
 963                 s = s ")"
 964
 965                 gsub(/%verify\(not[^)]+\)/, s)
 966         }
 967
 968         if (/%{_mandir}/) {
 969                 gsub("\.gz$", "*")
 970         }
 971
 972         # atrpms
 973         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
 974         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
 975         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
 976 }
 977
 978 function fill(ch, n, i) {
 979         for (i = 0; i < n; i++)
 980                 printf("%c", ch)
 981 }
 982
 983 function format_flush(line, indent, newline, word, first_word) {
 984         first_word = 1
 985         if (format_indent == -1)
 986                 newline = ""
 987         else
 988                 newline = fill(" ", format_indent) "- "
 989
 990         while (match(line, /[^\t ]+/)) {
 991                 word = substr(line, RSTART, RLENGTH)
 992                 if (length(newline) + length(word) + 1 > tw) {
 993                         print newline
 994
 995                         if (format_indent == -1)
 996                                 newline = ""
 997                         else
 998                                 newline = fill(" ", format_indent + 2)
 999                         first_word = 1
1000                 }
1001
1002                 if (first_word) {
1003                         newline = newline word
1004                         first_word = 0
1005                 } else
1006                         newline = newline " " word
1007
1008                 line = substr(line, RSTART + RLENGTH)
1009         }
1010         if (newline ~ /[^\t ]/) {
1011                 print newline
1012         }
1013 }
1014
1015 function cflags(var)
1016 {
1017         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1018                 removed[var] = 1
1019                 return 0
1020         }
1021
1022         if (!/!\?debug/)
1023                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1024         return 1
1025 }