adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2003 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Elan Ruusamäe <glen@pld-linux.org>
  13 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  14
  15 # TODO
  16 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  17 # - add "-nc" option to skip CVS interaction
  18 # - sort Summary(XX)
  19 # - sort Requires, BuildRequires
  20
  21 BEGIN {
  22         preamble = 1            # Is it part of preamble? Default - yes
  23         boc = 4                 # Beggining of %changelog
  24         bod = 0                 # Beggining of %description
  25         tw = 70                 # Descriptions width
  26
  27         b_idx = 0               # index of BR/R arrays
  28
  29         # If variable removed, then 1 (for removing it from export)
  30         removed["LDFLAGS"] = 0
  31         removed["CFLAGS"] = 0
  32         removed["CXXFLAGS"] = 0
  33
  34         # get cvsaddress for changelog section
  35         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  36         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  37         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  38
  39         # If 1, we are inside of comment block (started with /^#%/)
  40         comment_block = 0
  41
  42         # File with rpm groups
  43         "rpm --eval %_sourcedir" | getline groups_file
  44         groups_file = groups_file "/rpm.groups"
  45         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups >/dev/null")
  46
  47         # Temporary file for changelog section
  48         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  49
  50         # Load rpm macros
  51         "rpm --eval %_prefix"   | getline prefix
  52         "rpm --eval %_bindir"   | getline bindir
  53         "rpm --eval %_sbindir"  | getline sbindir
  54         "rpm --eval %_libdir"   | getline libdir
  55         "rpm --eval %_sysconfdir" | getline sysconfdir
  56         "rpm --eval %_datadir"  | getline datadir
  57         "rpm --eval %_includedir" | getline includedir
  58         "rpm --eval %_mandir"   | getline mandir
  59         "rpm --eval %_infodir"  | getline infodir
  60         "rpm --eval %_examplesdir"      | getline examplesdir
  61
  62         "rpm --eval %perl_sitearch" | getline perl_sitearch
  63         "rpm --eval %perl_archlib" | getline perl_archlib
  64         "rpm --eval %perl_privlib" | getline perl_privlib
  65         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  66         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  67         "rpm --eval %perl_sitelib" | getline perl_sitelib
  68
  69         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  70 }
  71
  72 # There should be a comment with CVS keywords on the first line of file.
  73 FNR == 1 {
  74         if (!/# \$Revision:/)   # If this line is already OK?
  75                 print "# $" "Revision:$, " "$" "Date:$" # No
  76         else {
  77                 print $0                                # Yes
  78                 next            # It is enough for first line
  79         }
  80 }
  81
  82 # If the latest line matched /%files/
  83 defattr == 1 {
  84         if ($0 !~ /defattr/)    # If no %defattr
  85                 print "%defattr(644,root,root,755)"     # Add it
  86         else
  87                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  88         defattr = 0
  89 }
  90
  91 function b_makekey(a, b,        s) {
  92         s = a "" b;
  93         # kill bcond
  94         gsub("%{\\?[_a-zA-Z0-9]+:", "", s);
  95         return s;
  96 }
  97
  98 # sort BR/R!
  99 #
 100 # NOTES:
 101 # - mixing BR/R and anything else confuses this (all will be sorted together)
 102 #   so don't do that.
 103 # - comments leading the BR/R can not be associated,
 104 #   so don't adapterize when the BR/R are mixed with comments
 105 ENVIRON["SORTBR"] == 1 && preamble == 1 && /(Build)?Requires/, /(Build)?Requires/ { # && !/^%/) {
 106         b_idx++;
 107         l = substr($0, index($0, $2));
 108         b_ktmp = b_makekey($1, l);
 109         b_key[b_idx] = b_ktmp;
 110         b_val[b_ktmp] = $0;
 111
 112         next;
 113 }
 114
 115 /^%bcond_/ {
 116         # do nothing
 117         print
 118         next
 119 }
 120
 121 preamble == 1 {
 122         if (b_idx > 0) {
 123                 isort(b_key, b_idx);
 124                 for (i = 1; i <= b_idx; i++) {
 125                         print "" b_val[b_key[i]];
 126                 }
 127                 b_idx = 0
 128         }
 129 }
 130
 131 # Comments
 132 /^#/ && (description == 0) {
 133         if (/This file does not like to be adapterized!/) {
 134                 print                   # print this message
 135                 while (getline)         # print the rest of spec as it is
 136                         print
 137                 do_not_touch_anything = 1 # do not touch anything in END()
 138                 exit 0
 139         }
 140
 141         # Generally, comments are printed without touching
 142         sub(/[ \t]+$/, "")
 143         print $0
 144         next
 145 }
 146
 147 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 148 /^%define/ {
 149         if ($2 == "_applnkdir")
 150                 next
 151         if ($2 == "date")
 152                 date = 1
 153 }
 154
 155 # Obsolete
 156 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 157         next
 158 }
 159
 160 ################
 161 # %description #
 162 ################
 163 /^%description/, (/^%[a-z]+/ && !/^%description/ && !/^%((end)?if|else)/) {
 164         preamble = 0
 165
 166         if (/^%description/) {
 167                 bod++
 168                 format_line = ""
 169                 format_indent = -1
 170         }
 171
 172         # Format description
 173         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 174                 if (/^[ \t]*$/) {
 175                         format_flush(format_line, format_indent)
 176                         print ""
 177                         format_line = ""
 178                         format_indent = -1
 179                 } else if (/^[ \t]*[-\*][ \t]*/) {
 180                         format_flush(format_line, format_indent)
 181                         match($0, /^[ \t]*/)
 182                         format_indent = RLENGTH
 183                         match($0, /^[ \t]*[-\*][ \t]/)
 184                         format_line = substr($0, RLENGTH)
 185                 } else
 186                         format_line = format_line " " $0
 187                 next
 188         }
 189
 190         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 191                 if (NF > 3 && $2 == "-l") {
 192                         ll = $1
 193                         for (i = 4; i <= NF; i++)
 194                                 ll = ll " " $i
 195                         $0 = ll " -l " $3
 196                 }
 197                 format_flush(format_line, format_indent)
 198                 if (bod == 2) {
 199                         bod = 1
 200                         description = 1
 201                 } else {
 202                         bod = 0
 203                         description = 0
 204                 }
 205         } else
 206                 description = 1
 207 }
 208
 209 #########
 210 # %prep #
 211 #########
 212 /^%prep/, (/^%[a-z]+$/ && !/^%prep/ && !/^%((end)?if|else)/) {
 213         preamble = 0
 214
 215         use_macros()
 216
 217         # Add '-q' to %setup
 218         if (/^%setup/ && !/-q/) {
 219                 sub(/^%setup/, "%setup -q")
 220         }
 221
 222         if (/^%setup/) {
 223                 gsub(name, "%{name}");
 224                 gsub(version, "%{version}");
 225                 if (_beta) {
 226                         gsub(_beta, "%{_beta}");
 227                 }
 228                 if (_rc) {
 229                         gsub(_rc, "%{_rc}");
 230                 }
 231                 if (_snap) {
 232                         gsub(_snap, "%{_snap}");
 233                 }
 234         }
 235
 236         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 237                 sub(/ -n %{name}-%{version}/, "")
 238         }
 239
 240         # invalid in %prep
 241         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 242 }
 243
 244 ##########
 245 # %build #
 246 ##########
 247 /^%build/, (/^%[a-z]+$/ && !/^%build/ && !/^%((end)?if|else)/) {
 248         preamble = 0
 249
 250         use_macros()
 251
 252         if (/^automake$/)
 253                 sub(/$/, " -a -c")
 254
 255         if (/LDFLAGS/) {
 256                 if (/LDFLAGS="-s"/) {
 257                         removed["LDFLAGS"] = 1
 258                         next
 259                 } else {
 260                         split($0, tmp, "LDFLAGS=")
 261                         count = split(tmp[2], flags, "\"")
 262                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 263                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 264                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 265                                 for (i = 2; i < count; i++)
 266                                         $0 = $0 flags[i] "\""
 267                         }
 268                 }
 269         }
 270
 271         if (/CFLAGS=/)
 272                 if (cflags("CFLAGS") == 0)
 273                         next
 274
 275         if (/CXXFLAGS=/)
 276                 if (cflags("CXXFLAGS") == 0)
 277                         next
 278
 279         if (/^export /) {
 280                 if (removed["LDFLAGS"])
 281                         sub(" LDFLAGS", "")
 282                 if (removed["CFLAGS"])
 283                         sub(" CFLAGS", "")
 284                 if (removed["CXXFLAGS"])
 285                         sub(" CXXFLAGS", "")
 286                 # Is there still something?
 287                 if (/^export[ ]*$/)
 288                         next
 289         }
 290
 291         # use macros
 292         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 293         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 294
 295         # atrpms
 296         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 297         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 298 }
 299
 300 ##########
 301 # %clean #
 302 ##########
 303 /^%clean/, (/^%[a-z]+$/ && !/^%clean/ && !/^%((end)?if|else)/) {
 304         did_clean = 1
 305         use_macros()
 306 }
 307
 308 ############
 309 # %install #
 310 ############
 311 /^%install/, (/^%[a-z]+$/ && !/^%install/ && !/^%((end)?if|else)/) {
 312
 313         preamble = 0
 314
 315         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 316                 did_rmroot=1
 317                 print "rm -rf $RPM_BUILD_ROOT"
 318                 next
 319         }
 320
 321         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 322                 print "rm -rf $RPM_BUILD_ROOT"
 323                 did_rmroot=1
 324         }
 325
 326         use_macros()
 327
 328         # 'install -d' instead 'mkdir -p'
 329         if (/mkdir -p/)
 330                 sub(/mkdir -p/, "install -d")
 331
 332         # 'install' instead 'cp -p'
 333         if (/cp -p\b/)
 334                 sub(/cp -p/, "install")
 335
 336         # No '-u root' or '-g root' for 'install'
 337         if (/^install/ && /-[ug][ \t]*root/)
 338                 gsub(/-[ug][ \t]*root /, "")
 339
 340         if (/^install/ && /-m[ \t]*[0-9]+/)
 341                 gsub(/-m[ \t]*[0-9]+ /, "")
 342
 343         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 344         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 345                 next
 346
 347         # No lines contain 'chmod' if it sets the modes to '644'
 348         if ($1 ~ /chmod/ && $2 ~ /644/)
 349                 next
 350
 351         # foreign rpms
 352         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 353         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 354
 355         # atrpms
 356         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 357 }
 358
 359 ##########
 360 # %files #
 361 ##########
 362 /^%files/, (/^%[a-z \-]+$/ && !/^%files/ && !/^%((end)?if|else)/) {
 363         preamble = 0
 364
 365         if ($0 ~ /^%files/)
 366                 defattr = 1
 367
 368         use_macros()
 369         use_files_macros()
 370 }
 371
 372 ##############
 373 # %changelog #
 374 ##############
 375 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 376         preamble = 0
 377         has_changelog = 1
 378         skip = 0
 379         # There should be some CVS keywords on the first line of %changelog.
 380         if (boc == 3) {
 381                 if ($0 !~ _cvsmailfeedback)
 382                         print "* %{date} " _cvsmailfeedback > changelog_file
 383                 else
 384                         skip = 1
 385                 boc = 2
 386         }
 387         if (boc == 2 && !skip) {
 388                 if (!/All persons listed below/) {
 389                         printf "All persons listed below can be reached at " > changelog_file
 390                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 391                 } else
 392                         skip = 1
 393                 boc = 1
 394         }
 395         if (boc == 1 && !skip) {
 396                 if (!/^$/) {
 397                         if (!/\$.*Log:.*\$/)
 398                                 print "$" "Log:$" > changelog_file
 399                         boc = 0
 400                 }
 401         }
 402         # Define date macro.
 403         if (boc == 4) {
 404                 if (date == 0) {
 405                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 406                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 407                         date = 1
 408                 }
 409                 boc = 3
 410         }
 411
 412         sub(/[ \t]+$/, "")
 413         if (!/^%[a-z]+$/ || /changelog/)
 414                 print > changelog_file
 415         else
 416                 print
 417         next
 418 }
 419
 420 ###########
 421 # SCRIPTS #
 422 ###########
 423 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 424         preamble = 0
 425
 426         # %useradd and %groupadd may not be wrapped
 427         if (/%(useradd|groupadd).*\\$/) {
 428                 a = $0; getline;
 429                 sub(/^[\s\t]*/, "");
 430                 $0 = substr(a, 1, length(a) - 1) $0;
 431         }
 432 }
 433
 434 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 435         preamble = 0
 436 }
 437 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 438         preamble = 0
 439 }
 440 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 441         preamble = 0
 442 }
 443 /^%triggerin/, (/^%[a-z]+$/ && !/^%triggerin/) {
 444         preamble = 0
 445 }
 446 /^%triggerun/, (/^%[a-z]+$/ && !/^%triggerun/) {
 447         preamble = 0
 448 }
 449 /^%triggerpostun/, (/^%[a-z]+$/ && !/^%triggerpostun/) {
 450         preamble = 0
 451 }
 452 /^%pretrans/, (/^%[a-z]+$/ && !/^%pretrans/) {
 453         preamble = 0
 454 }
 455 /^%posttrans/, (/^%[a-z]+$/ && !/^%posttrans/) {
 456         preamble = 0
 457 }
 458
 459 #############
 460 # PREAMBLES #
 461 #############
 462 preamble == 1 {
 463         # There should not be a space after the name of field
 464         # and before the colon.
 465         sub(/[ \t]*:/, ":")
 466
 467         if (/^%perl_module_wo_prefix/) {
 468                 name = $2
 469                 version = $3
 470                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 471         }
 472
 473         field = tolower($1)
 474         fieldnlower = $1
 475         if (field ~ /group(\([^)]+\)):/)
 476                 next
 477         if (field ~ /group:/) {
 478                 format_preamble()
 479                 sub(/^Utilities\//,"Applications/",$2)
 480                 sub(/^Games/,"Applications/Games",$2)
 481                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 482                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 483                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 484                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 485                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 486                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 487                 sub(/^Shells/,"Applications/Shells",$2)
 488
 489                 sub(/^[^ \t]*[ \t]*/,"")
 490                 Grupa = $0
 491
 492                 sub(/^System Environment\/Libraries/, "Libraries", Grupa)
 493
 494                 print "Group:\t\t" Grupa
 495                 if (Grupa ~ /^X11/ && x11 == 0) # Is it X11 application?
 496                         x11 = 1
 497
 498                 byl_plik_z_grupami = 0
 499                 byl_opis_grupy = 0
 500                 while ((getline linia_grup < groups_file) > 0) {
 501                         byl_plik_z_grupami = 1
 502                         if (linia_grup == Grupa) {
 503                                 byl_opis_grupy = 1
 504                                 break
 505                         }
 506                 }
 507
 508                 if (!byl_plik_z_grupami)
 509                         print "######\t\t" groups_file ": no such file"
 510                 else if (!byl_opis_grupy)
 511                         print "######\t\t" "Unknown group!"
 512
 513                 close(groups_file)
 514                 next
 515         }
 516
 517         if (field ~ /prereq:/) {
 518                 $1 = "Requires:"
 519                 $(NF + 1) = " # FIXME add Requires(scriptlet) -adapter.awk"
 520         }
 521
 522         # split (build)requires on commas
 523         if (field ~ /requires:/ && $0 ~ /,/) {
 524                 l = substr($0, index($0, $2));
 525                 n = split(l, p, / *, */);
 526                 for (i in p) {
 527                         printf("%s\t%s\n", $1, p[i]);
 528                 }
 529                 next;
 530         }
 531
 532         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 533                 next
 534
 535         if (field ~ /buildroot:/)
 536                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 537
 538         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 539         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 540                 $1 = "License:"
 541
 542         if (field ~ /name:/) {
 543                 if ($2 == "%{name}" && name) {
 544                         $2 = name
 545                 }
 546                 name = $2
 547                 name_seen = 1;
 548         }
 549
 550         if (field ~ /version:/) {
 551                 if ($2 == "%{version}" && version) {
 552                         $2 = version
 553                 }
 554                 version = $2
 555                 version_seen = 1;
 556         }
 557
 558         if (field ~ /release:/) {
 559                 if ($2 == "%{release}" && release) {
 560                         $2 = release
 561                 }
 562                 release = $2
 563                 release_seen = 1;
 564         }
 565
 566         if (field ~ /serial:/)
 567                 $1 = "Epoch:"
 568
 569         # Use %{name} and %{version} in the filenames in "Source:"
 570         if (field ~ /^source/ || field ~ /patch/) {
 571                 n = split($2, url, /\//)
 572                 if (url[n] ~ /\.gz$/) {
 573                         url[n+1] = ".gz" url[n+1]
 574                         sub(/\.gz$/,"",url[n])
 575                 }
 576                 if (url[n] ~ /\.zip$/) {
 577                         url[n+1] = ".zip" url[n+1]
 578                         sub(/\.zip$/,"",url[n])
 579                 }
 580                 if (url[n] ~ /\.tar$/) {
 581                         url[n+1] = ".tar" url[n+1]
 582                         sub(/\.tar$/,"",url[n])
 583                 }
 584                 if (url[n] ~ /\.patch$/) {
 585                         url[n+1] = ".patch" url[n+1]
 586                         sub(/\.patch$/,"",url[n])
 587                 }
 588                 if (url[n] ~ /\.bz2$/) {
 589                         url[n+1] = ".bz2" url[n+1]
 590                         sub(/\.bz2$/,"",url[n])
 591                 }
 592                 if (url[n] ~ /\.logrotate$/) {
 593                         url[n+1] = ".logrotate" url[n+1]
 594                         sub(/\.logrotate$/,"",url[n])
 595                 }
 596                 if (url[n] ~ /\.pamd$/) {
 597                         url[n+1] = ".pamd" url[n+1]
 598                         sub(/\.pamd$/,"",url[n])
 599                 }
 600
 601                 # allow %{name} just in last url component
 602                 s = ""
 603                 for (i = 1; i <= n; i++) {
 604                         url[i] = fixedsub("%{name}", name, url[i])
 605                         if (s) {
 606                                 s = s "/" url[i]
 607                         } else {
 608                                 s = url[i]
 609                         }
 610                 }
 611                 $2 = s url[n+1]
 612
 613                 filename = url[n]
 614                 if (name) {
 615                         url[n] = fixedsub(name, "%{name}", url[n])
 616                 }
 617                 if (field ~ /source/) {
 618                         if (version) {
 619                                 url[n] = fixedsub(version, "%{version}", url[n])
 620                         }
 621                         if (_beta) {
 622                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 623                         }
 624                         if (_rc) {
 625                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 626                         }
 627                         if (_snap) {
 628                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 629                         }
 630                 }
 631                 $2 = fixedsub(filename, url[n], $2)
 632
 633                 # sourceforge urls
 634                 sub("[?]use_mirror=.*$", "", $2);
 635                 sub("[?]download$", "", $2);
 636                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 637
 638                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 639                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 640                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 641         }
 642
 643
 644         if (field ~ /^source:/)
 645                 $1 = "Source0:"
 646
 647         if (field ~ /patch:/)
 648                 $1 = "Patch0:"
 649
 650         format_preamble()
 651
 652         if ($1 ~ /%define/) {
 653                 # Do not add %define of _prefix if it already is.
 654                 if ($2 ~ /^_prefix/) {
 655                         sub("^"prefix, $3, bindir)
 656                         sub("^"prefix, $3, sbindir)
 657                         sub("^"prefix, $3, libdir)
 658                         sub("^"prefix, $3, datadir)
 659                         sub("^"prefix, $3, includedir)
 660                         prefix = $3
 661                 }
 662
 663                 if ($2 ~ /_bindir/ && !/_sbindir/)
 664                         bindir = $3
 665                 if ($2 ~ /_sbindir/)
 666                         sbindir = $3
 667                 if ($2 ~ /_libdir/)
 668                         libdir = $3
 669                 if ($2 ~ /_sysconfdir/ && $3 !~ /^%\(/)
 670                         sysconfdir = $3
 671                 if ($2 ~ /_datadir/)
 672                         datadir = $3
 673                 if ($2 ~ /_includedir/)
 674                         includedir = $3
 675                 if ($2 ~ /_mandir/)
 676                         mandir = $3
 677                 if ($2 ~ /_infodir/)
 678                         infodir = $3
 679
 680                 if ($2 ~ /_beta/)
 681                         _beta = $3
 682                 if ($2 ~ /_rc/)
 683                         _rc = $3
 684                 if ($2 ~ /_snap/)
 685                         _snap = $3
 686
 687                 if ($2 ~ /^name$/)
 688                         name = $3
 689                 if ($2 ~ /^version$/)
 690                         version = $3
 691                 if ($2 ~ /^release$/)
 692                         release = $3
 693         }
 694
 695         if (field ~ /requires/) {
 696                 # atrpms
 697                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 698         }
 699 }
 700
 701 # main() ;-)
 702 {
 703         preamble = 1
 704
 705         sub(/[ \t]+$/, "")
 706         print
 707
 708         if (name_seen == 0 && name) {
 709                 print "Name:\t" name
 710                 name_seen = 1
 711         }
 712
 713         if (version_seen == 0 && version) {
 714                 print "Version:\t" version
 715                 version_seen = 1
 716         }
 717
 718         if (release_seen == 0 && release) {
 719                 print "Release:\t" release
 720                 release_seen = 1
 721         }
 722 }
 723
 724
 725 END {
 726         if (do_not_touch_anything)
 727                 exit 0
 728
 729         close(changelog_file)
 730         while ((getline < changelog_file) > 0)
 731                 print
 732         system("rm -f " changelog_file)
 733
 734
 735
 736         if (did_clean == 0) {
 737                 print ""
 738                 print "%clean"
 739                 print "rm -rf $RPM_BUILD_ROOT"
 740         }
 741
 742         if (date == 0) {
 743                 print ""
 744                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 745         }
 746
 747         if (has_changelog == 0)
 748                 print "%changelog"
 749
 750         if (boc > 2)
 751                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 752         if (boc > 1) {
 753                 printf "All persons listed below can be reached at "
 754                 print "<cvs_login>@pld-linux.org\n"
 755         }
 756         if (boc > 0)
 757                 print "$" "Log:$"
 758 }
 759
 760 function fixedsub(s1,s2,t, ind) {
 761 # substitutes fixed strings (not regexps)
 762         if (ind = index(t,s1))
 763                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 764         return t
 765 }
 766
 767 # There should be one or two tabs after the colon.
 768 function format_preamble()
 769 {
 770         sub(/:[ \t]*/, ":")
 771         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 772                 if (RLENGTH < 8)
 773                         sub(/:/, ":\t\t")
 774                 else
 775                         sub(/:/, ":\t")
 776         }
 777 }
 778
 779 # Replace directly specified directories with macros
 780 function use_macros()
 781 {
 782         gsub(perl_sitearch, "%{perl_sitearch}")
 783         gsub(perl_archlib, "%{perl_archlib}")
 784         gsub(perl_privlib, "%{perl_privlib}")
 785         gsub(perl_vendorlib, "%{perl_vendorlib}")
 786         gsub(perl_vendorarch, "%{perl_vendorarch}")
 787         gsub(perl_sitelib, "%{perl_sitelib}")
 788
 789         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
 790
 791         gsub(bindir, "%{_bindir}")
 792         gsub("%{prefix}/bin", "%{_bindir}")
 793         if(prefix"/bin" == bindir)
 794                 gsub("%{_prefix}/bin", "%{_bindir}")
 795
 796         for (c = 1; c <= NF; c++) {
 797                 if ($c ~ sbindir "/fix-info-dir")
 798                         continue;
 799                 gsub(sbindir, "%{_sbindir}", $c)
 800         }
 801
 802         gsub("%{prefix}/sbin", "%{_sbindir}")
 803         if (prefix"/sbin" == sbindir)
 804                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 805
 806         for (c = 1; c <= NF; c++) {
 807                 if ($c ~ sysconfdir "/{?cron.")
 808                         continue;
 809                 if ($c ~ sysconfdir "/{?crontab.d")
 810                         continue;
 811                 if ($c ~ sysconfdir "/{?logrotate.d")
 812                         continue;
 813                 if ($c ~ sysconfdir "/{?pam.d")
 814                         continue;
 815                 if ($c ~ sysconfdir "/{?profile.d")
 816                         continue;
 817                 if ($c ~ sysconfdir "/{?rc.d")
 818                         continue;
 819                 if ($c ~ sysconfdir "/{?security")
 820                         continue;
 821                 if ($c ~ sysconfdir "/{?skel")
 822                         continue;
 823                 if ($c ~ sysconfdir "/{?sysconfig")
 824                         continue;
 825                 if ($c ~ sysconfdir "/{?certs")
 826                         continue;
 827                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 828         }
 829
 830         for (c = 1; c <= NF; c++) {
 831                 if ($c ~ datadir "/automake")
 832                         continue;
 833                 if ($c ~ datadir "/unsermake")
 834                         continue;
 835                 if ($c ~ datadir "/file/magic.mime")
 836                         continue;
 837                 gsub(datadir, "%{_datadir}", $c)
 838         }
 839
 840
 841         gsub("%{prefix}/share", "%{_datadir}")
 842         if (prefix"/share" == datadir)
 843                 gsub("%{_prefix}/share", "%{_datadir}")
 844
 845         gsub(includedir, "%{_includedir}")
 846         gsub("%{prefix}/include", "%{_includedir}")
 847         if (prefix"/include" == includedir)
 848                 gsub("%{_prefix}/include", "%{_includedir}")
 849
 850         gsub(mandir, "%{_mandir}")
 851         if ($0 !~ "%{_datadir}/manual")
 852                 gsub("%{_datadir}/man", "%{_mandir}")
 853         gsub("%{_prefix}/share/man", "%{_mandir}")
 854         gsub("%{prefix}/share/man", "%{_mandir}")
 855         gsub("%{prefix}/man", "%{_mandir}")
 856         gsub("%{_prefix}/man", "%{_mandir}")
 857
 858         gsub(infodir, "%{_infodir}")
 859         gsub("%{prefix}/info", "%{_infodir}")
 860         gsub("%{_prefix}/info", "%{_infodir}")
 861
 862         if (prefix !~ "/X11R6") {
 863                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 864         }
 865
 866         gsub(examplesdir, "%{_examplesdir}")
 867
 868         if (prefix != "/") {
 869                 # leave --with-foo=/usr alone
 870                 if ($0 !~ "--with.*=.*" prefix) {
 871                         for (c = 1; c <= NF; c++) {
 872                                 if ($c ~ prefix "/sbin/fix-info-dir")
 873                                         continue;
 874                                 if ($c ~ prefix "/share/automake")
 875                                         continue;
 876                                 if ($c ~ prefix "/share/unsermake")
 877                                         continue;
 878                                 if ($c ~ prefix "/lib/sendmail")
 879                                         continue;
 880                                 if ($c ~ prefix "/lib/pkgconfig")
 881                                         continue;
 882                                 gsub(prefix, "%{_prefix}", $c)
 883                         }
 884                 }
 885                 gsub("%{prefix}", "%{_prefix}")
 886         }
 887
 888         gsub("%{PACKAGE_VERSION}", "%{version}")
 889         gsub("%{PACKAGE_NAME}", "%{name}")
 890
 891         gsub("^make$", "%{__make}")
 892         gsub("^make ", "%{__make} ")
 893         gsub("^gcc ", "%{__cc} ")
 894
 895         # mandrake specs
 896         gsub("^%make$", "%{__make}")
 897         gsub("^%make ", "%{__make} ")
 898         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 899         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 900         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 901         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 902         gsub("^%{__install}", "install")
 903         gsub("^%{__rm}", "rm")
 904         gsub("%optflags", "%{rpmcflags}")
 905         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
 906
 907         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 908         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
 909         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 910         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 911         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
 912
 913         gsub("%_bindir", "%{_bindir}")
 914         gsub("%_datadir", "%{_datadir}")
 915         gsub("%_iconsdir", "%{_iconsdir}")
 916
 917         gsub("/usr/src/linux", "%{_kernelsrcdir}")
 918         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
 919 }
 920
 921
 922 # insertion sort of A[1..n]
 923 # copied from mawk manual
 924 function isort(A,n,             i,j,hold) {
 925         for (i = 2; i <= n; i++) {
 926                 hold = A[j = i]
 927                 while (A[j-1] > hold) {
 928                         j-- ; A[j+1] = A[j]
 929                 }
 930                 A[j] = hold
 931         }
 932         # sentinel A[0] = "" will be created if needed
 933 }
 934
 935
 936 function use_files_macros(      i, n, t, a)
 937 {
 938         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 939         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 940
 941         # replace back
 942         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
 943         gsub("%{_sysconfdir}/crontab\.d", "/etc/cron.d")
 944         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
 945         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
 946         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
 947         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
 948         gsub("%{_sysconfdir}/security", "/etc/security")
 949         gsub("%{_sysconfdir}/skel", "/etc/skel")
 950         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
 951         gsub("%{_sysconfdir}/certs", "/etc/certs")
 952         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
 953
 954         # /etc/init.d -> /etc/rc.d/init.d
 955         if (!/^\/etc\/init\.d$/) {
 956                  gsub("/etc/init.d", "/etc/rc.d/init.d")
 957         }
 958
 959         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
 960                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
 961                         $0 = "%attr(754,root,root) " $0
 962                 }
 963                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
 964                         gsub("^%attr\\(... *,", "%attr(754,");
 965                 }
 966         }
 967
 968         if (/lib.+\.so/ && !/^%attr.*/) {
 969                 $0 = "%attr(755,root,root) " $0
 970         }
 971
 972         # /etc/sysconfig files
 973         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
 974         # attr not required, allow default 644 attr
 975         if (!/network-scripts/) {
 976                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace\)/) {
 977                         gsub("%config", "%config(noreplace)")
 978                 }
 979
 980                 if (/\/etc\/sysconfig\// && !/%config\(noreplace\)/) {
 981                         $NF = "%config(noreplace) " $NF
 982                 }
 983
 984                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
 985                         gsub("^%attr\\(... *,", "%attr(640,");
 986                 }
 987
 988                 if (/\/etc\/sysconfig\// && !/%verify/) {
 989                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
 990                 }
 991         }
 992
 993         # kill leading zeros
 994         if (/%attr\(0[1-9]/) {
 995                 gsub("%attr\\(0", "%attr(")
 996         }
 997
 998         # sort %verify attrs
 999         if (match($0, /%verify\(not([^)]+)\)/)) {
1000                 t = substr($0, RSTART, RLENGTH)
1001                 gsub(/^%verify\(not |\)$/, "", t)
1002                 n = split(t, a, / /)
1003                 isort(a, n)
1004
1005                 s = "%verify(not"
1006                 for (i = 1 ; i <= n; i++) {
1007                         s = s " " a[i]
1008                 }
1009                 s = s ")"
1010
1011                 gsub(/%verify\(not[^)]+\)/, s)
1012         }
1013
1014         if (/%{_mandir}/) {
1015                 gsub("\.gz$", "*")
1016         }
1017
1018         # atrpms
1019         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1020         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1021         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1022
1023         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1024         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1025         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1026 }
1027
1028 function fill(ch, n, i) {
1029         for (i = 0; i < n; i++)
1030                 printf("%c", ch)
1031 }
1032
1033 function format_flush(line, indent, newline, word, first_word) {
1034         first_word = 1
1035         if (format_indent == -1)
1036                 newline = ""
1037         else
1038                 newline = fill(" ", format_indent) "- "
1039
1040         while (match(line, /[^\t ]+/)) {
1041                 word = substr(line, RSTART, RLENGTH)
1042                 if (length(newline) + length(word) + 1 > tw) {
1043                         print newline
1044
1045                         if (format_indent == -1)
1046                                 newline = ""
1047                         else
1048                                 newline = fill(" ", format_indent + 2)
1049                         first_word = 1
1050                 }
1051
1052                 if (first_word) {
1053                         newline = newline word
1054                         first_word = 0
1055                 } else
1056                         newline = newline " " word
1057
1058                 line = substr(line, RSTART + RLENGTH)
1059         }
1060         if (newline ~ /[^\t ]/) {
1061                 print newline
1062         }
1063 }
1064
1065 function cflags(var)
1066 {
1067         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1068                 removed[var] = 1
1069                 return 0
1070         }
1071
1072         if (!/!\?debug/)
1073                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1074         return 1
1075 }