adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2003 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Elan Ruusamäe <glen@pld-linux.org>
  13 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  14
  15 # TODO
  16 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  17 # - add "-nc" option to skip CVS interaction
  18 # - sort Summary(XX)
  19 # - sort Requires, BuildRequires
  20 # - check if %description (lang=C) contains 8bit
  21 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  22
  23 BEGIN {
  24         preamble = 1            # Is it part of preamble? Default - yes
  25         boc = 4                 # Beginning of %changelog
  26         bod = 0                 # Beginning of %description
  27         tw = 70                 # Descriptions width
  28
  29         b_idx = 0               # index of BR/R arrays
  30
  31         # If variable removed, then 1 (for removing it from export)
  32         removed["LDFLAGS"] = 0
  33         removed["CFLAGS"] = 0
  34         removed["CXXFLAGS"] = 0
  35
  36         # get cvsaddress for changelog section
  37         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  38         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  39         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  40
  41         # If 1, we are inside of comment block (started with /^#%/)
  42         comment_block = 0
  43
  44         # File with rpm groups
  45         "rpm --eval %_sourcedir" | getline groups_file
  46         groups_file = groups_file "/rpm.groups"
  47         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups >/dev/null")
  48
  49         # Temporary file for changelog section
  50         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  51
  52         # Load rpm macros
  53         "rpm --eval %_prefix"   | getline prefix
  54         "rpm --eval %_bindir"   | getline bindir
  55         "rpm --eval %_sbindir"  | getline sbindir
  56         "rpm --eval %_libdir"   | getline libdir
  57         "rpm --eval %_sysconfdir" | getline sysconfdir
  58         "rpm --eval %_datadir"  | getline datadir
  59         "rpm --eval %_includedir" | getline includedir
  60         "rpm --eval %_mandir"   | getline mandir
  61         "rpm --eval %_infodir"  | getline infodir
  62         "rpm --eval %_examplesdir"      | getline examplesdir
  63
  64         "rpm --eval %perl_sitearch" | getline perl_sitearch
  65         "rpm --eval %perl_archlib" | getline perl_archlib
  66         "rpm --eval %perl_privlib" | getline perl_privlib
  67         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  68         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  69         "rpm --eval %perl_sitelib" | getline perl_sitelib
  70
  71         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  72 }
  73
  74 # There should be a comment with CVS keywords on the first line of file.
  75 FNR == 1 {
  76         if (!/# \$Revision:/)   # If this line is already OK?
  77                 print "# $" "Revision:$, " "$" "Date:$" # No
  78         else {
  79                 print $0                                # Yes
  80                 next            # It is enough for first line
  81         }
  82 }
  83
  84 # If the latest line matched /%files/
  85 defattr == 1 {
  86         if ($0 !~ /defattr/)    # If no %defattr
  87                 print "%defattr(644,root,root,755)"     # Add it
  88         else
  89                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  90         defattr = 0
  91 }
  92
  93 function b_makekey(a, b,        s) {
  94         s = a "" b;
  95         # kill bcond
  96     gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
  97         return s;
  98 }
  99
 100 # sort BR/R!
 101 #
 102 # NOTES:
 103 # - mixing BR/R and anything else confuses this (all will be sorted together)
 104 #   so don't do that.
 105 # - comments leading the BR/R can not be associated,
 106 #   so don't adapterize when the BR/R are mixed with comments
 107 ENVIRON["SORTBR"] == 1 && preamble == 1 && /(Build)?Requires/, /(Build)?Requires/ { # && !/^%/) {
 108         b_idx++;
 109         l = substr($0, index($0, $2));
 110         b_ktmp = b_makekey($1, l);
 111         b_key[b_idx] = b_ktmp;
 112         b_val[b_ktmp] = $0;
 113
 114         next;
 115 }
 116
 117 /^%bcond_/ {
 118         # do nothing
 119         print
 120         next
 121 }
 122
 123 preamble == 1 {
 124         if (b_idx > 0) {
 125                 isort(b_key, b_idx);
 126                 for (i = 1; i <= b_idx; i++) {
 127                         print "" b_val[b_key[i]];
 128                 }
 129                 b_idx = 0
 130         }
 131 }
 132
 133 # Comments
 134 /^#/ && (description == 0) {
 135         if (/This file does not like to be adapterized!/) {
 136                 print                   # print this message
 137                 while (getline)         # print the rest of spec as it is
 138                         print
 139                 do_not_touch_anything = 1 # do not touch anything in END()
 140                 exit 0
 141         }
 142
 143         # Generally, comments are printed without touching
 144         sub(/[ \t]+$/, "")
 145         print $0
 146         next
 147 }
 148
 149 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 150 /^%define/ {
 151         if ($2 == "_applnkdir") {
 152                 next
 153         }
 154         if ($2 == "date") {
 155                 date = 1
 156         }
 157
 158         # Do not add %define of _prefix if it already is.
 159         if ($2 ~ /^_prefix/) {
 160                 sub("^"prefix, $3, bindir)
 161                 sub("^"prefix, $3, sbindir)
 162                 sub("^"prefix, $3, libdir)
 163                 sub("^"prefix, $3, datadir)
 164                 sub("^"prefix, $3, includedir)
 165                 prefix = $3
 166         }
 167
 168         if ($2 ~ /_bindir/ && !/_sbindir/)
 169                 bindir = $3
 170         if ($2 ~ /_sbindir/)
 171                 sbindir = $3
 172         if ($2 ~ /_libdir/)
 173                 libdir = $3
 174         if ($2 ~ /_sysconfdir/ && $3 !~ /^%\(/)
 175                 sysconfdir = $3
 176         if ($2 ~ /_datadir/)
 177                 datadir = $3
 178         if ($2 ~ /_includedir/)
 179                 includedir = $3
 180         if ($2 ~ /_mandir/)
 181                 mandir = $3
 182         if ($2 ~ /_infodir/)
 183                 infodir = $3
 184
 185         # version related macros
 186         if ($2 ~ /^_beta$/)
 187                 _beta = $3
 188         if ($2 ~ /^_rc$/)
 189                 _rc = $3
 190         if ($2 ~ /^_snap$/)
 191                 _snap = $3
 192
 193         # these are used usually when adapterizing external spec
 194         if ($2 ~ /^name$/)
 195                 name = $3
 196         if ($2 ~ /^version$/)
 197                 version = $3
 198         if ($2 ~ /^release$/)
 199                 release = $3
 200
 201         # do nothing further, otherwise adapter thinks we're at preamble
 202         print
 203         next
 204 }
 205
 206 # Obsolete
 207 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 208         next
 209 }
 210
 211 ################
 212 # %description #
 213 ################
 214 /^%description/, (/^%[a-z]+/ && !/^%description/ && !/^%((end)?if|else)/) {
 215         preamble = 0
 216
 217         if (/^%description/) {
 218                 bod++
 219                 format_line = ""
 220                 format_indent = -1
 221         }
 222
 223         # Format description
 224         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 225                 if (/^[ \t]*$/) {
 226                         format_flush(format_line, format_indent)
 227                         print ""
 228                         format_line = ""
 229                         format_indent = -1
 230                 } else if (/^[ \t]*[-\*][ \t]*/) {
 231                         format_flush(format_line, format_indent)
 232                         match($0, /^[ \t]*/)
 233                         format_indent = RLENGTH
 234                         match($0, /^[ \t]*[-\*][ \t]/)
 235                         format_line = substr($0, RLENGTH)
 236                 } else
 237                         format_line = format_line " " $0
 238                 next
 239         }
 240
 241         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 242                 if (NF > 3 && $2 == "-l") {
 243                         ll = $1
 244                         for (i = 4; i <= NF; i++)
 245                                 ll = ll " " $i
 246                         $0 = ll " -l " $3
 247                 }
 248                 format_flush(format_line, format_indent)
 249                 if (bod == 2) {
 250                         bod = 1
 251                         description = 1
 252                 } else {
 253                         bod = 0
 254                         description = 0
 255                 }
 256         } else
 257                 description = 1
 258 }
 259
 260 #########
 261 # %prep #
 262 #########
 263 /^%prep/, (/^%[a-z]+$/ && !/^%prep/ && !/^%((end)?if|else)/) {
 264         preamble = 0
 265
 266         use_macros()
 267
 268         # Add '-q' to %setup
 269         if (/^%setup/ && !/-q/) {
 270                 sub(/^%setup/, "%setup -q")
 271         }
 272
 273         if (/^%setup/) {
 274                 gsub(name, "%{name}");
 275                 gsub(version, "%{version}");
 276                 if (_beta) {
 277                         gsub(_beta, "%{_beta}");
 278                 }
 279                 if (_rc) {
 280                         gsub(_rc, "%{_rc}");
 281                 }
 282                 if (_snap) {
 283                         gsub(_snap, "%{_snap}");
 284                 }
 285         }
 286
 287         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 288                 sub(/ -n %{name}-%{version}/, "")
 289         }
 290
 291         # invalid in %prep
 292         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 293 }
 294
 295 ##########
 296 # %build #
 297 ##########
 298 /^%build/, (/^%[a-z]+$/ && !/^%build/ && !/^%((end)?if|else)/) {
 299         preamble = 0
 300
 301         use_macros()
 302
 303         if (/^automake$/)
 304                 sub(/$/, " -a -c")
 305
 306         if (/LDFLAGS/) {
 307                 if (/LDFLAGS="-s"/) {
 308                         removed["LDFLAGS"] = 1
 309                         next
 310                 } else {
 311                         split($0, tmp, "LDFLAGS=")
 312                         count = split(tmp[2], flags, "\"")
 313                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 314                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 315                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 316                                 for (i = 2; i < count; i++)
 317                                         $0 = $0 flags[i] "\""
 318                         }
 319                 }
 320         }
 321
 322         if (/CFLAGS=/)
 323                 if (cflags("CFLAGS") == 0)
 324                         next
 325
 326         if (/CXXFLAGS=/)
 327                 if (cflags("CXXFLAGS") == 0)
 328                         next
 329
 330         if (/^export /) {
 331                 if (removed["LDFLAGS"])
 332                         sub(" LDFLAGS", "")
 333                 if (removed["CFLAGS"])
 334                         sub(" CFLAGS", "")
 335                 if (removed["CXXFLAGS"])
 336                         sub(" CXXFLAGS", "")
 337                 # Is there still something?
 338                 if (/^export[ ]*$/)
 339                         next
 340         }
 341
 342         # quote CC
 343         if (/CC=%{__cc} /) {
 344                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 345         }
 346
 347         # use macros
 348         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 349         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 350         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 351
 352         sub(/^aclocal$/, "%{__aclocal}");
 353         sub(/^autoheader$/, "%{__autoheader}");
 354         sub(/^autoconf$/, "%{__autoconf}");
 355         sub(/^automake$/, "%{__automake}");
 356
 357         # atrpms
 358         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 359         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 360 }
 361
 362 ##########
 363 # %clean #
 364 ##########
 365 /^%clean/, (/^%[a-z]+$/ && !/^%clean/ && !/^%((end)?if|else)/) {
 366         did_clean = 1
 367         use_macros()
 368 }
 369
 370 ############
 371 # %install #
 372 ############
 373 /^%install/, (/^%[a-z]+$/ && !/^%install/ && !/^%((end)?if|else)/) {
 374
 375         preamble = 0
 376
 377         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 378                 did_rmroot=1
 379                 print "rm -rf $RPM_BUILD_ROOT"
 380                 next
 381         }
 382
 383         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 384                 print "rm -rf $RPM_BUILD_ROOT"
 385                 did_rmroot=1
 386         }
 387
 388         use_macros()
 389
 390         # 'install -d' instead 'mkdir -p'
 391         if (/mkdir -p/)
 392                 sub(/mkdir -p/, "install -d")
 393
 394         # 'install' instead 'cp -p'
 395         if (/cp -p\b/)
 396                 sub(/cp -p/, "install")
 397
 398         # No '-u root' or '-g root' for 'install'
 399         if (/^install/ && /-[ug][ \t]*root/)
 400                 gsub(/-[ug][ \t]*root /, "")
 401
 402         if (/^install/ && /-m[ \t]*[0-9]+/)
 403                 gsub(/-m[ \t]*[0-9]+ /, "")
 404
 405         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 406         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 407                 next
 408
 409         # No lines contain 'chmod' if it sets the modes to '644'
 410         if ($1 ~ /chmod/ && $2 ~ /644/)
 411                 next
 412
 413         # foreign rpms
 414         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 415         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 416
 417         # atrpms
 418         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 419 }
 420
 421 ##########
 422 # %files #
 423 ##########
 424 /^%files/, (/^%[a-z \-]+$/ && !/^%files/ && !/^%((end)?if|else)/) {
 425         preamble = 0
 426
 427         if ($0 ~ /^%files/)
 428                 defattr = 1
 429
 430         use_macros()
 431         use_files_macros()
 432 }
 433
 434 ##############
 435 # %changelog #
 436 ##############
 437 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 438         preamble = 0
 439         has_changelog = 1
 440         skip = 0
 441         # There should be some CVS keywords on the first line of %changelog.
 442         if (boc == 3) {
 443                 if ($0 !~ _cvsmailfeedback)
 444                         print "* %{date} " _cvsmailfeedback > changelog_file
 445                 else
 446                         skip = 1
 447                 boc = 2
 448         }
 449         if (boc == 2 && !skip) {
 450                 if (!/All persons listed below/) {
 451                         printf "All persons listed below can be reached at " > changelog_file
 452                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 453                 } else
 454                         skip = 1
 455                 boc = 1
 456         }
 457         if (boc == 1 && !skip) {
 458                 if (!/^$/) {
 459                         if (!/\$.*Log:.*\$/)
 460                                 print "$" "Log:$" > changelog_file
 461                         boc = 0
 462                 }
 463         }
 464         # Define date macro.
 465         if (boc == 4) {
 466                 if (date == 0) {
 467                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 468                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 469                         date = 1
 470                 }
 471                 boc = 3
 472         }
 473
 474         sub(/[ \t]+$/, "")
 475         if (!/^%[a-z]+$/ || /changelog/)
 476                 print > changelog_file
 477         else
 478                 print
 479         next
 480 }
 481
 482 ###########
 483 # SCRIPTS #
 484 ###########
 485 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 486         preamble = 0
 487
 488         # %useradd and %groupadd may not be wrapped
 489         if (/%(useradd|groupadd).*\\$/) {
 490                 a = $0; getline;
 491                 sub(/^[\s\t]*/, "");
 492                 $0 = substr(a, 1, length(a) - 1) $0;
 493         }
 494 }
 495
 496 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 497         preamble = 0
 498 }
 499 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 500         preamble = 0
 501 }
 502 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 503         preamble = 0
 504 }
 505 /^%triggerin/, (/^%[a-z]+$/ && !/^%triggerin/) {
 506         preamble = 0
 507 }
 508 /^%triggerun/, (/^%[a-z]+$/ && !/^%triggerun/) {
 509         preamble = 0
 510 }
 511 /^%triggerpostun/, (/^%[a-z]+$/ && !/^%triggerpostun/) {
 512         preamble = 0
 513 }
 514 /^%pretrans/, (/^%[a-z]+$/ && !/^%pretrans/) {
 515         preamble = 0
 516 }
 517 /^%posttrans/, (/^%[a-z]+$/ && !/^%posttrans/) {
 518         preamble = 0
 519 }
 520
 521 #############
 522 # PREAMBLES #
 523 #############
 524 preamble == 1 {
 525         # There should not be a space after the name of field
 526         # and before the colon.
 527         sub(/[ \t]*:/, ":")
 528
 529         if (/^%perl_module_wo_prefix/) {
 530                 name = $2
 531                 version = $3
 532                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 533         }
 534
 535         field = tolower($1)
 536         fieldnlower = $1
 537         if (field ~ /summary:/) {
 538                 sub(/\.$/, "", $0);
 539         }
 540         if (field ~ /group(\([^)]+\)):/)
 541                 next
 542         if (field ~ /group:/) {
 543                 format_preamble()
 544                 sub(/^Utilities\//,"Applications/",$2)
 545                 sub(/^Games/,"Applications/Games",$2)
 546                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 547                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 548                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 549                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 550                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 551                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 552                 sub(/^Shells/,"Applications/Shells",$2)
 553
 554                 sub(/^[^ \t]*[ \t]*/,"")
 555                 Grupa = $0
 556
 557                 sub(/^System Environment\/Libraries$/, "Libraries", Grupa)
 558                 sub(/^System Environment\/Daemons$/, "Daemons", Grupa)
 559                 sub(/^Applications\/Internet$/, "Applications/Networking", Grupa)
 560                 sub(/^System\/Servers$/, "Daemons", Grupa)
 561                 sub(/^X11\/Xserver$/, "X11/Servers", Grupa)
 562                 sub(/^X11\/XFree86$/, "X11", Grupa)
 563                 sub(/^Applications\/Compilers$/, "Development/Languages", Grupa)
 564                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", Grupa)
 565
 566                 print "Group:\t\t" Grupa
 567                 if (Grupa ~ /^X11/ && x11 == 0) # Is it X11 application?
 568                         x11 = 1
 569
 570                 byl_plik_z_grupami = 0
 571                 byl_opis_grupy = 0
 572                 while ((getline linia_grup < groups_file) > 0) {
 573                         byl_plik_z_grupami = 1
 574                         if (linia_grup == Grupa) {
 575                                 byl_opis_grupy = 1
 576                                 break
 577                         }
 578                 }
 579
 580                 if (!byl_plik_z_grupami)
 581                         print "######\t\t" groups_file ": no such file"
 582                 else if (!byl_opis_grupy)
 583                         print "######\t\t" "Unknown group!"
 584
 585                 close(groups_file)
 586                 next
 587         }
 588
 589         if (field ~ /prereq:/) {
 590                 $1 = "Requires:"
 591         }
 592
 593         # split (build)requires on commas
 594         if (field ~ /requires:/ && $0 ~ /,/) {
 595                 l = substr($0, index($0, $2));
 596                 n = split(l, p, / *, */);
 597                 for (i in p) {
 598                         printf("%s\t%s\n", $1, p[i]);
 599                 }
 600                 next;
 601         }
 602
 603         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 604                 next
 605
 606         if (field ~ /buildroot:/)
 607                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 608
 609         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 610         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 611                 $1 = "License:"
 612
 613         if (field ~ /name:/) {
 614                 if ($2 == "%{name}" && name) {
 615                         $2 = name
 616                 }
 617                 name = $2
 618                 name_seen = 1;
 619         }
 620
 621         if (field ~ /version:/) {
 622                 if ($2 == "%{version}" && version) {
 623                         $2 = version
 624                 }
 625                 version = $2
 626                 version_seen = 1;
 627         }
 628
 629         if (field ~ /release:/) {
 630                 if ($2 == "%{release}" && release) {
 631                         $2 = release
 632                 }
 633                 release = $2
 634                 release_seen = 1;
 635         }
 636
 637         if (field ~ /serial:/)
 638                 $1 = "Epoch:"
 639
 640         # proper caps
 641         if (field ~ /^url:$/)
 642                 $1 = "URL:"
 643
 644         # Use %{name} and %{version} in the filenames in "Source:"
 645         if (field ~ /^source/ || field ~ /patch/) {
 646                 n = split($2, url, /\//)
 647                 if (url[n] ~ /\.gz$/) {
 648                         url[n+1] = ".gz" url[n+1]
 649                         sub(/\.gz$/,"",url[n])
 650                 }
 651                 if (url[n] ~ /\.zip$/) {
 652                         url[n+1] = ".zip" url[n+1]
 653                         sub(/\.zip$/,"",url[n])
 654                 }
 655                 if (url[n] ~ /\.tar$/) {
 656                         url[n+1] = ".tar" url[n+1]
 657                         sub(/\.tar$/,"",url[n])
 658                 }
 659                 if (url[n] ~ /\.patch$/) {
 660                         url[n+1] = ".patch" url[n+1]
 661                         sub(/\.patch$/,"",url[n])
 662                 }
 663                 if (url[n] ~ /\.bz2$/) {
 664                         url[n+1] = ".bz2" url[n+1]
 665                         sub(/\.bz2$/,"",url[n])
 666                 }
 667                 if (url[n] ~ /\.logrotate$/) {
 668                         url[n+1] = ".logrotate" url[n+1]
 669                         sub(/\.logrotate$/,"",url[n])
 670                 }
 671                 if (url[n] ~ /\.pamd$/) {
 672                         url[n+1] = ".pamd" url[n+1]
 673                         sub(/\.pamd$/,"",url[n])
 674                 }
 675
 676                 # allow %{name} just in last url component
 677                 s = ""
 678                 for (i = 1; i <= n; i++) {
 679                         url[i] = fixedsub("%{name}", name, url[i])
 680                         if (s) {
 681                                 s = s "/" url[i]
 682                         } else {
 683                                 s = url[i]
 684                         }
 685                 }
 686                 $2 = s url[n+1]
 687
 688                 filename = url[n]
 689                 if (name) {
 690                         url[n] = fixedsub(name, "%{name}", url[n])
 691                 }
 692                 if (field ~ /source/) {
 693                         if (version) {
 694                                 url[n] = fixedsub(version, "%{version}", url[n])
 695                         }
 696                         if (_beta) {
 697                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 698                         }
 699                         if (_rc) {
 700                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 701                         }
 702                         if (_snap) {
 703                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 704                         }
 705                 }
 706                 $2 = fixedsub(filename, url[n], $2)
 707
 708                 # sourceforge urls
 709                 sub("[?]use_mirror=.*$", "", $2);
 710                 sub("[?]download$", "", $2);
 711                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 712
 713                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 714                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 715                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 716         }
 717
 718
 719         if (field ~ /^source:/)
 720                 $1 = "Source0:"
 721
 722         if (field ~ /patch:/)
 723                 $1 = "Patch0:"
 724
 725         format_preamble()
 726
 727
 728         if (field ~ /requires/) {
 729                 # atrpms
 730                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 731         }
 732 }
 733
 734 # main() ;-)
 735 {
 736         preamble = 1
 737
 738         sub(/[ \t]+$/, "")
 739         print
 740
 741         if (name_seen == 0 && name) {
 742                 print "Name:\t" name
 743                 name_seen = 1
 744         }
 745
 746         if (version_seen == 0 && version) {
 747                 print "Version:\t" version
 748                 version_seen = 1
 749         }
 750
 751         if (release_seen == 0 && release) {
 752                 print "Release:\t" release
 753                 release_seen = 1
 754         }
 755 }
 756
 757
 758 END {
 759         if (do_not_touch_anything)
 760                 exit 0
 761
 762         close(changelog_file)
 763         while ((getline < changelog_file) > 0)
 764                 print
 765         system("rm -f " changelog_file)
 766
 767
 768
 769         if (did_clean == 0) {
 770                 print ""
 771                 print "%clean"
 772                 print "rm -rf $RPM_BUILD_ROOT"
 773         }
 774
 775         if (date == 0) {
 776                 print ""
 777                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 778         }
 779
 780         if (has_changelog == 0)
 781                 print "%changelog"
 782
 783         if (boc > 2)
 784                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 785         if (boc > 1) {
 786                 printf "All persons listed below can be reached at "
 787                 print "<cvs_login>@pld-linux.org\n"
 788         }
 789         if (boc > 0)
 790                 print "$" "Log:$"
 791 }
 792
 793 function fixedsub(s1,s2,t, ind) {
 794 # substitutes fixed strings (not regexps)
 795         if (ind = index(t,s1))
 796                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 797         return t
 798 }
 799
 800 # There should be one or two tabs after the colon.
 801 function format_preamble()
 802 {
 803         sub(/:[ \t]*/, ":")
 804         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 805                 if (RLENGTH < 8)
 806                         sub(/:/, ":\t\t")
 807                 else
 808                         sub(/:/, ":\t")
 809         }
 810 }
 811
 812 # Replace directly specified directories with macros
 813 function use_macros()
 814 {
 815         gsub(perl_sitearch, "%{perl_sitearch}")
 816         gsub(perl_archlib, "%{perl_archlib}")
 817         gsub(perl_privlib, "%{perl_privlib}")
 818         gsub(perl_vendorlib, "%{perl_vendorlib}")
 819         gsub(perl_vendorarch, "%{perl_vendorarch}")
 820         gsub(perl_sitelib, "%{perl_sitelib}")
 821
 822         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
 823
 824         gsub(bindir, "%{_bindir}")
 825         gsub("%{prefix}/bin", "%{_bindir}")
 826         if(prefix"/bin" == bindir)
 827                 gsub("%{_prefix}/bin", "%{_bindir}")
 828
 829         for (c = 1; c <= NF; c++) {
 830                 if ($c ~ sbindir "/fix-info-dir")
 831                         continue;
 832                 if ($c ~ sbindir "/webapp")
 833                         continue;
 834                 if ($c ~ sbindir "/chsh")
 835                         continue;
 836                 if ($c ~ sbindir "/usermod")
 837                         continue;
 838                 gsub(sbindir, "%{_sbindir}", $c)
 839         }
 840
 841         gsub("%{prefix}/sbin", "%{_sbindir}")
 842         if (prefix"/sbin" == sbindir)
 843                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 844
 845         for (c = 1; c <= NF; c++) {
 846                 if ($c ~ sysconfdir "/{?cron.")
 847                         continue;
 848                 if ($c ~ sysconfdir "/{?crontab.d")
 849                         continue;
 850                 if ($c ~ sysconfdir "/{?env.d")
 851                         continue;
 852                 if ($c ~ sysconfdir "/{?logrotate.d")
 853                         continue;
 854                 if ($c ~ sysconfdir "/{?pam.d")
 855                         continue;
 856                 if ($c ~ sysconfdir "/{?profile.d")
 857                         continue;
 858                 if ($c ~ sysconfdir "/{?rc.d")
 859                         continue;
 860                 if ($c ~ sysconfdir "/{?security")
 861                         continue;
 862                 if ($c ~ sysconfdir "/{?skel")
 863                         continue;
 864                 if ($c ~ sysconfdir "/{?sysconfig")
 865                         continue;
 866                 if ($c ~ sysconfdir "/{?shrc.d")
 867                         continue;
 868                 if ($c ~ sysconfdir "/{?certs")
 869                         continue;
 870                 if ($c ~ sysconfdir "/{?X11")
 871                         continue;
 872                 if ($c ~ sysconfdir "/{?httpd") # temp
 873                         continue;
 874                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 875         }
 876
 877         for (c = 1; c <= NF; c++) {
 878                 if ($c ~ datadir "/automake")
 879                         continue;
 880                 if ($c ~ datadir "/unsermake")
 881                         continue;
 882                 if ($c ~ datadir "/file/magic.mime")
 883                         continue;
 884                 gsub(datadir, "%{_datadir}", $c)
 885         }
 886
 887         gsub("%_sbindir", "%{_sbindir}")
 888         gsub("%_mandir", "%{_mandir}")
 889         gsub("%name", "%{name}")
 890
 891         gsub("%{prefix}/share", "%{_datadir}")
 892         if (prefix"/share" == datadir)
 893                 gsub("%{_prefix}/share", "%{_datadir}")
 894
 895         gsub(includedir, "%{_includedir}")
 896         gsub("%{prefix}/include", "%{_includedir}")
 897         if (prefix"/include" == includedir)
 898                 gsub("%{_prefix}/include", "%{_includedir}")
 899
 900         gsub(mandir, "%{_mandir}")
 901         if ($0 !~ "%{_datadir}/manual")
 902                 gsub("%{_datadir}/man", "%{_mandir}")
 903         gsub("%{_prefix}/share/man", "%{_mandir}")
 904         gsub("%{prefix}/share/man", "%{_mandir}")
 905         gsub("%{prefix}/man", "%{_mandir}")
 906         gsub("%{_prefix}/man", "%{_mandir}")
 907
 908         gsub(infodir, "%{_infodir}")
 909         gsub("%{prefix}/info", "%{_infodir}")
 910         gsub("%{_prefix}/info", "%{_infodir}")
 911
 912         if (prefix !~ "/X11R6") {
 913                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 914         }
 915
 916         gsub(examplesdir, "%{_examplesdir}")
 917
 918         if (prefix != "/") {
 919                 # leave --with-foo=/usr alone
 920                 if ($0 !~ "--with.*=.*" prefix) {
 921                         for (c = 1; c <= NF; c++) {
 922                                 if ($c ~ prefix "/sbin/fix-info-dir")
 923                                         continue;
 924                                 if ($c ~ prefix "/sbin/webapp")
 925                                         continue;
 926                                 if ($c ~ prefix "/sbin/chsh")
 927                                         continue;
 928                                 if ($c ~ prefix "/sbin/usermod")
 929                                         continue;
 930                                 if ($c ~ prefix "/share/automake")
 931                                         continue;
 932                                 if ($c ~ prefix "/share/unsermake")
 933                                         continue;
 934                                 if ($c ~ prefix "/lib/sendmail")
 935                                         continue;
 936                                 if ($c ~ prefix "/lib/pkgconfig")
 937                                         continue;
 938                                 gsub(prefix, "%{_prefix}", $c)
 939                         }
 940                 }
 941                 gsub("%{prefix}", "%{_prefix}")
 942         }
 943
 944         gsub("%{PACKAGE_VERSION}", "%{version}")
 945         gsub("%{PACKAGE_NAME}", "%{name}")
 946
 947         gsub("^make$", "%{__make}")
 948         gsub("^make ", "%{__make} ")
 949         gsub("^gcc ", "%{__cc} ")
 950
 951         # mandrake specs
 952         gsub("^%make$", "%{__make}")
 953         gsub("^%make ", "%{__make} ")
 954         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 955         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 956         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 957         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 958         gsub("^%{__install}", "install")
 959         gsub("^%{__rm}", "rm")
 960         gsub("%optflags", "%{rpmcflags}")
 961         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
 962
 963         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 964         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
 965         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 966         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 967         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
 968
 969         gsub("%_bindir", "%{_bindir}")
 970         gsub("%_datadir", "%{_datadir}")
 971         gsub("%_iconsdir", "%{_iconsdir}")
 972
 973         gsub("/usr/src/linux", "%{_kernelsrcdir}")
 974         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
 975 }
 976
 977
 978 # insertion sort of A[1..n]
 979 # copied from mawk manual
 980 function isort(A,n,             i,j,hold) {
 981         for (i = 2; i <= n; i++) {
 982                 hold = A[j = i]
 983                 while (A[j-1] > hold) {
 984                         j-- ; A[j+1] = A[j]
 985                 }
 986                 A[j] = hold
 987         }
 988         # sentinel A[0] = "" will be created if needed
 989 }
 990
 991
 992 function use_files_macros(      i, n, t, a)
 993 {
 994         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 995         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 996
 997         # uid/gid nobody is not valid in %files
 998         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
 999                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1000         }
1001
1002         # replace back
1003         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1004         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1005         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1006         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1007         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1008         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1009         gsub("%{_sysconfdir}/security", "/etc/security")
1010         gsub("%{_sysconfdir}/skel", "/etc/skel")
1011         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1012         gsub("%{_sysconfdir}/certs", "/etc/certs")
1013         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1014
1015         # /etc/init.d -> /etc/rc.d/init.d
1016         if (!/^\/etc\/init\.d$/) {
1017                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1018         }
1019
1020         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1021                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1022                         $0 = "%attr(754,root,root) " $0
1023                 }
1024                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1025                         gsub("^%attr\\(... *,", "%attr(754,");
1026                 }
1027         }
1028
1029         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1030                 $0 = "%attr(755,root,root) " $0
1031         }
1032
1033         # /etc/sysconfig files
1034         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1035         # attr not required, allow default 644 attr
1036         if (!/network-scripts/) {
1037                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace\)/) {
1038                         gsub("%config", "%config(noreplace)")
1039                 }
1040
1041                 if (/\/etc\/sysconfig\// && !/%config\(noreplace\)/) {
1042                         $NF = "%config(noreplace) " $NF
1043                 }
1044
1045                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1046                         gsub("^%attr\\(... *,", "%attr(640,");
1047                 }
1048
1049                 if (/\/etc\/sysconfig\// && !/%verify/) {
1050                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1051                 }
1052         }
1053
1054         # kill leading zeros
1055         if (/%attr\(0[1-9]/) {
1056                 gsub("%attr\\(0", "%attr(")
1057         }
1058
1059         # sort %verify attrs
1060         if (match($0, /%verify\(not([^)]+)\)/)) {
1061                 t = substr($0, RSTART, RLENGTH)
1062                 gsub(/^%verify\(not |\)$/, "", t)
1063                 n = split(t, a, / /)
1064                 isort(a, n)
1065
1066                 s = "%verify(not"
1067                 for (i = 1 ; i <= n; i++) {
1068                         s = s " " a[i]
1069                 }
1070                 s = s ")"
1071
1072                 gsub(/%verify\(not[^)]+\)/, s)
1073         }
1074
1075         if (/%{_mandir}/) {
1076                 gsub("\.gz$", "*")
1077         }
1078
1079         # locale dir and no %lang -> bad
1080         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1081                 $(NF + 1) = "# FIXME consider using %find_lang"
1082         }
1083
1084         # atrpms
1085         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1086         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1087         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1088
1089         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1090         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1091         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1092
1093         gsub("%{_datadir}/applications", "%{_desktopdir}");
1094         gsub("%{_datadir}/icons", "%{_iconsdir}");
1095         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1096 }
1097
1098 function fill(ch, n, i) {
1099         for (i = 0; i < n; i++)
1100                 printf("%c", ch)
1101 }
1102
1103 function format_flush(line, indent, newline, word, first_word) {
1104         first_word = 1
1105         if (format_indent == -1)
1106                 newline = ""
1107         else
1108                 newline = fill(" ", format_indent) "- "
1109
1110         while (match(line, /[^\t ]+/)) {
1111                 word = substr(line, RSTART, RLENGTH)
1112                 if (length(newline) + length(word) + 1 > tw) {
1113                         print newline
1114
1115                         if (format_indent == -1)
1116                                 newline = ""
1117                         else
1118                                 newline = fill(" ", format_indent + 2)
1119                         first_word = 1
1120                 }
1121
1122                 if (first_word) {
1123                         newline = newline word
1124                         first_word = 0
1125                 } else
1126                         newline = newline " " word
1127
1128                 line = substr(line, RSTART + RLENGTH)
1129         }
1130         if (newline ~ /[^\t ]/) {
1131                 print newline
1132         }
1133 }
1134
1135 function cflags(var)
1136 {
1137         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1138                 removed[var] = 1
1139                 return 0
1140         }
1141
1142         if (!/!\?debug/)
1143                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1144         return 1
1145 }