adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2006 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Micha³ Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Elan Ruusamä¤e <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  21 # - add "-nc" option to skip CVS interaction
  22 # - sort Summary(XX)
  23 # - sort Requires, BuildRequires
  24 # - check if %description (lang=C) contains 8bit
  25 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  26
  27 BEGIN {
  28         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  29         SECTIONS = "^%(" RPM_SECTIONS ")"
  30
  31         PREAMBLE_TAGS = "(Summary|Name|Version|Release|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires)"
  32
  33         preamble = 1            # Is it part of preamble? Default - yes
  34         boc = 4                 # Beginning of %changelog
  35         bod = 0                 # Beginning of %description
  36         tw = 70                 # Descriptions width
  37
  38         b_idx = 0               # index of BR/R arrays
  39
  40         # If variable removed, then 1 (for removing it from export)
  41         removed["LDFLAGS"] = 0
  42         removed["CFLAGS"] = 0
  43         removed["CXXFLAGS"] = 0
  44
  45         # get cvsaddress for changelog section
  46         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  47         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  48         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  49
  50         # If 1, we are inside of comment block (started with /^#%/)
  51         comment_block = 0
  52
  53         # File with rpm groups
  54         "rpm --eval %_sourcedir" | getline groups_file
  55         groups_file = groups_file "/rpm.groups"
  56         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  57         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  58
  59         # Temporary file for changelog section
  60         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  61
  62         # Load rpm macros
  63         "rpm --eval %_prefix"   | getline prefix
  64         "rpm --eval %_bindir"   | getline bindir
  65         "rpm --eval %_sbindir"  | getline sbindir
  66         "rpm --eval %_libdir"   | getline libdir
  67         "rpm --eval %_sysconfdir" | getline sysconfdir
  68         "rpm --eval %_datadir"  | getline datadir
  69         "rpm --eval %_includedir" | getline includedir
  70         "rpm --eval %_mandir"   | getline mandir
  71         "rpm --eval %_infodir"  | getline infodir
  72         "rpm --eval %_examplesdir"      | getline examplesdir
  73         "rpm --eval %_defaultdocdir"    | getline docdir
  74
  75         "rpm --eval %perl_sitearch" | getline perl_sitearch
  76         "rpm --eval %perl_archlib" | getline perl_archlib
  77         "rpm --eval %perl_privlib" | getline perl_privlib
  78         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  79         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  80         "rpm --eval %perl_sitelib" | getline perl_sitelib
  81
  82         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  83         "rpm --eval %py_scriptdir " | getline py_scriptdir
  84         "rpm --eval %php_pear_dir" | getline php_pear_dir
  85 }
  86
  87 # There should be a comment with CVS keywords on the first line of file.
  88 FNR == 1 {
  89         if (!/# \$Revision:/)   # If this line is already OK?
  90                 print "# $" "Revision:$, " "$" "Date:$" # No
  91         else {
  92                 print $0                                # Yes
  93                 next            # It is enough for first line
  94         }
  95 }
  96
  97 # If the latest line matched /%files/
  98 defattr == 1 {
  99         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 100                 if ($0 !~ /defattr/) {  # If no %defattr
 101                         print "%defattr(644,root,root,755)"     # Add it
 102                 } else {
 103                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 104                 }
 105         }
 106         defattr = 0
 107 }
 108
 109 function b_makekey(a, b,        s) {
 110         s = a "" b;
 111         # kill bcond
 112     gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 113
 114         # kill commented out items
 115     gsub(/^#[ \t]*/, "", s);
 116
 117         # force order
 118     gsub(/^Summary\(/, "11Summary(", s);
 119     gsub(/^Summary/, "10Summary", s);
 120     gsub(/^Name/, "2Name", s);
 121     gsub(/^Version/, "3Version", s);
 122     gsub(/^Release/, "4Release", s);
 123     gsub(/^License/, "5License", s);
 124     gsub(/^Group/, "6Group", s);
 125     gsub(/^URL/, "7URL", s);
 126
 127     gsub(/^BuildRequires/, "B1BuildRequires", s);
 128     gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 129     gsub(/^Provides/, "X1Provides", s);
 130     gsub(/^Obsoletes/, "X2Obsoletes", s);
 131     gsub(/^Conflicts/, "X3Conflicts", s);
 132     gsub(/^BuildArch/, "X4BuildArch", s);
 133     gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 134     gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 135     gsub(/^BuildRoot/, "X9BuildRoot", s);
 136
 137 #       printf("%s -> %s\n", a""b, s);
 138         return s;
 139 }
 140
 141 # Comments
 142 /^#/ && (description == 0) {
 143         if (/This file does not like to be adapterized!/) {
 144                 print                   # print this message
 145                 while (getline)         # print the rest of spec as it is
 146                         print
 147                 do_not_touch_anything = 1 # do not touch anything in END()
 148                 exit 0
 149         }
 150
 151         # Generally, comments are printed without touching
 152         sub(/[ \t]+$/, "")
 153
 154         if (/Source.*md5/) {
 155                 print $0
 156                 next
 157         }
 158 }
 159
 160 /^%define/ {
 161         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 162         if ($2 == "_applnkdir") {
 163                 next
 164         }
 165         if ($2 == "date") {
 166                 date = 1
 167         }
 168
 169         # Do not add %define of _prefix if it already is.
 170         if ($2 ~ /^_prefix/) {
 171                 sub("^"prefix, $3, bindir)
 172                 sub("^"prefix, $3, sbindir)
 173                 sub("^"prefix, $3, libdir)
 174                 sub("^"prefix, $3, datadir)
 175                 sub("^"prefix, $3, includedir)
 176                 prefix = $3
 177         }
 178
 179         if ($2 ~ /_bindir/ && !/_sbindir/)
 180                 bindir = $3
 181         if ($2 ~ /_sbindir/)
 182                 sbindir = $3
 183         if ($2 ~ /_libdir/)
 184                 libdir = $3
 185         if ($2 ~ /_sysconfdir/) {
 186                 if ($3 ~ /^%\(/) {
 187                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 188                         sysconfdir = "%%%%%%%%%%%%%%"
 189                 } else {
 190                         sysconfdir = $3
 191                 }
 192         }
 193         if ($2 ~ /_datadir/)
 194                 datadir = $3
 195         if ($2 ~ /_includedir/)
 196                 includedir = $3
 197         if ($2 ~ /_mandir/)
 198                 mandir = $3
 199         if ($2 ~ /_infodir/)
 200                 infodir = $3
 201         if ($2 ~ /_docdir/)
 202                 docdir = $3
 203
 204         # version related macros
 205         if ($2 ~ /^_beta$/)
 206                 _beta = $3
 207         if ($2 ~ /^_rc$/)
 208                 _rc = $3
 209         if ($2 ~ /^_snap$/)
 210                 _snap = $3
 211
 212         # these are used usually when adapterizing external spec
 213         if ($2 ~ /^name$/)
 214                 name = $3
 215         if ($2 ~ /^version$/)
 216                 version = $3
 217         if ($2 ~ /^release$/)
 218                 release = $3
 219
 220         if ($2 ~ /^mod_name$/)
 221                 mod_name = $3
 222
 223         # do nothing further, otherwise adapter thinks we're at preamble
 224         print
 225         next
 226 }
 227
 228 # Obsolete
 229 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 230         next
 231 }
 232
 233 ################
 234 # %description #
 235 ################
 236 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 237         preamble = 0
 238
 239         if (/^%description/) {
 240                 bod++
 241                 format_line = ""
 242                 format_indent = -1
 243         }
 244
 245         # Format description
 246         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !$0 ~ SECTIONS && !/^%description/) {
 247                 if (/^[ \t]*$/) {
 248                         format_flush(format_line, format_indent)
 249                         print ""
 250                         format_line = ""
 251                         format_indent = -1
 252                 } else if (/^[ \t]*[-\*][ \t]*/) {
 253                         format_flush(format_line, format_indent)
 254                         match($0, /^[ \t]*/)
 255                         format_indent = RLENGTH
 256                         match($0, /^[ \t]*[-\*][ \t]/)
 257                         format_line = substr($0, RLENGTH)
 258                 } else
 259                         format_line = format_line " " $0
 260                 next
 261         }
 262
 263         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 264                 if (NF > 3 && $2 == "-l") {
 265                         ll = $1
 266                         for (i = 4; i <= NF; i++)
 267                                 ll = ll " " $i
 268                         $0 = ll " -l " $3
 269                 }
 270                 format_flush(format_line, format_indent)
 271                 if (bod == 2) {
 272                         bod = 1
 273                         description = 1
 274                 } else {
 275                         bod = 0
 276                         description = 0
 277                 }
 278         } else
 279                 description = 1
 280 }
 281
 282 #########
 283 # %prep #
 284 #########
 285 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 286         preamble = 0
 287
 288         use_macros()
 289
 290         # Add '-q' to %setup
 291         if (/^%setup/ && !/-q/) {
 292                 sub(/^%setup/, "%setup -q")
 293         }
 294
 295         if (/^%setup/) {
 296                 $0 = fixedsub(name, "%{name}", $0);
 297                 $0 = fixedsub(version, "%{version}", $0);
 298                 if (_beta) {
 299                         $0 = fixedsub(_beta, "%{_beta}", $0);
 300                 }
 301                 if (_rc) {
 302                         $0 = fixedsub(_rc, "%{_rc}", $0);
 303                 }
 304                 if (_snap) {
 305                         $0 = fixedsub(_snap, "%{_snap}", $0);
 306                 }
 307         }
 308
 309         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 310                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 311         }
 312
 313         # invalid in %prep
 314         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 315 }
 316
 317 ##########
 318 # %build #
 319 ##########
 320 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 321         preamble = 0
 322
 323         use_macros()
 324
 325         if (/^automake$/)
 326                 sub(/$/, " -a -c")
 327
 328         if (/LDFLAGS/) {
 329                 if (/LDFLAGS="-s"/) {
 330                         removed["LDFLAGS"] = 1
 331                         next
 332                 } else {
 333                         split($0, tmp, "LDFLAGS=")
 334                         count = split(tmp[2], flags, "\"")
 335                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 336                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 337                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 338                                 for (i = 2; i < count; i++)
 339                                         $0 = $0 flags[i] "\""
 340                         }
 341                 }
 342         }
 343
 344         if (/CFLAGS=/)
 345                 if (cflags("CFLAGS") == 0)
 346                         next
 347
 348         if (/CXXFLAGS=/)
 349                 if (cflags("CXXFLAGS") == 0)
 350                         next
 351
 352         if (/^export /) {
 353                 if (removed["LDFLAGS"])
 354                         sub(" LDFLAGS", "")
 355                 if (removed["CFLAGS"])
 356                         sub(" CFLAGS", "")
 357                 if (removed["CXXFLAGS"])
 358                         sub(" CXXFLAGS", "")
 359                 # Is there still something?
 360                 if (/^export[ ]*$/)
 361                         next
 362         }
 363
 364         # quote CC
 365         if (/CC=%{__cc} /) {
 366                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 367         }
 368
 369         # use PLD Linux macros
 370         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 371         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 372         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 373         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 374         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 375         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 376         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 377
 378         sub(/^aclocal$/, "%{__aclocal}");
 379         sub(/^autoheader$/, "%{__autoheader}");
 380         sub(/^autoconf$/, "%{__autoconf}");
 381         sub(/^automake$/, "%{__automake}");
 382
 383         # atrpms
 384         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 385         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 386 }
 387
 388 ##########
 389 # %clean #
 390 ##########
 391 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 392         did_clean = 1
 393
 394         # prevent next section header like "%post -p /sbin/ldconfig" being adapterized
 395         if (!/^%/) {
 396                 use_macros()
 397         }
 398 }
 399
 400 ############
 401 # %install #
 402 ############
 403 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 404
 405         preamble = 0
 406
 407         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 408                 did_rmroot=1
 409                 print "rm -rf $RPM_BUILD_ROOT"
 410                 next
 411         }
 412
 413         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 414                 print "rm -rf $RPM_BUILD_ROOT"
 415                 did_rmroot=1
 416         }
 417
 418         use_macros()
 419
 420         # 'install -d' instead 'mkdir -p'
 421         if (/mkdir -p/)
 422                 sub(/mkdir -p/, "install -d")
 423
 424         # 'install' instead 'cp -p'
 425         if (/cp -p\b/)
 426                 sub(/cp -p/, "install")
 427
 428         # No '-u root' or '-g root' for 'install'
 429         if (/^install/ && /-[ug][ \t]*root/)
 430                 gsub(/-[ug][ \t]*root /, "")
 431
 432         if (/^install/ && /-m[ \t]*[0-9]+/)
 433                 gsub(/-m[ \t]*[0-9]+ /, "")
 434
 435         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 436         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 437                 next
 438
 439         # No lines contain 'chmod' if it sets the modes to '644'
 440         if ($1 ~ /chmod/ && $2 ~ /644/)
 441                 next
 442
 443         # foreign rpms
 444         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 445         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 446
 447         # atrpms
 448         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 449 }
 450
 451 ##########
 452 # %files #
 453 ##########
 454 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 455         preamble = 0
 456
 457         if ($0 ~ /^%files/)
 458                 defattr = 1
 459
 460         use_files_macros()
 461 }
 462
 463 ##############
 464 # %changelog #
 465 ##############
 466 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 467         preamble = 0
 468         has_changelog = 1
 469         skip = 0
 470         # There should be some CVS keywords on the first line of %changelog.
 471         if (boc == 3) {
 472                 if ($0 !~ _cvsmailfeedback)
 473                         print "* %{date} " _cvsmailfeedback > changelog_file
 474                 else
 475                         skip = 1
 476                 boc = 2
 477         }
 478         if (boc == 2 && !skip) {
 479                 if (!/All persons listed below/) {
 480                         printf "All persons listed below can be reached at " > changelog_file
 481                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 482                 } else
 483                         skip = 1
 484                 boc = 1
 485         }
 486         if (boc == 1 && !skip) {
 487                 if (!/^$/) {
 488                         if (!/\$.*Log:.*\$/)
 489                                 print "$" "Log:$" > changelog_file
 490                         boc = 0
 491                 }
 492         }
 493         # Define date macro.
 494         if (boc == 4) {
 495                 if (date == 0) {
 496                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 497                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 498                         date = 1
 499                 }
 500                 boc = 3
 501         }
 502
 503         sub(/[ \t]+$/, "")
 504         if (!/^%[a-z]+$/ || /changelog/)
 505                 print > changelog_file
 506         else
 507                 print
 508         next
 509 }
 510
 511 ###########
 512 # SCRIPTS #
 513 ###########
 514 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 515         preamble = 0
 516
 517         # %useradd and %groupadd may not be wrapped
 518         if (/%(useradd|groupadd).*\\$/) {
 519                 a = $0; getline;
 520                 sub(/^[\s\t]*/, "");
 521                 $0 = substr(a, 1, length(a) - 1) $0;
 522         }
 523 }
 524
 525 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 526         preamble = 0
 527         use_macros()
 528 }
 529 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 530         preamble = 0
 531 }
 532 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 533         preamble = 0
 534 }
 535 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 536         preamble = 0
 537 }
 538 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 539         preamble = 0
 540 }
 541 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 542         preamble = 0
 543 }
 544 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 545         preamble = 0
 546 }
 547 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 548         preamble = 0
 549 }
 550 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 551         preamble = 0
 552 }
 553 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 554         preamble = 0
 555 }
 556
 557 #############
 558 # PREAMBLES #
 559 #############
 560 preamble == 1 {
 561         # There should not be a space after the name of field
 562         # and before the colon.
 563         sub(/[ \t]*:/, ":")
 564
 565         if (/^%perl_module_wo_prefix/) {
 566                 name = $2
 567                 version = $3
 568                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 569         }
 570
 571         field = tolower($1)
 572         fieldnlower = $1
 573         if (field ~ /summary:/ && !/etc\.$/) {
 574                 sub(/\.$/, "", $0);
 575         }
 576         if (field ~ /group(\([^)]+\)):/)
 577                 next
 578         if (field ~ /group:/) {
 579                 format_preamble()
 580                 group = $0;
 581                 sub(/^[^ \t]*[ \t]*/, "", group);
 582
 583                 sub(/^Utilities\//,"Applications/", group)
 584                 sub(/^Games/,"Applications/Games", group)
 585                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 586                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 587                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 588                 sub(/^X11\/GNOME/,"X11/Applications", group)
 589                 sub(/^X11\/Utilities/,"X11/Applications", group)
 590                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 591                 sub(/^Shells/,"Applications/Shells", group)
 592                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 593                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 594                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 595                 sub(/^Applications\/Daemons$/, "Daemons", group)
 596                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 597                 sub(/^System\/Servers$/, "Daemons", group)
 598                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 599                 sub(/^X11\/XFree86/, "X11", group)
 600                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 601                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 602                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 603                 sub(/^Development\/Docs$/, "Documentation", group)
 604
 605                 $0 = "Group:\t\t" group
 606
 607                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 608                         x11 = 1
 609
 610                 byl_plik_z_groupmi = 0
 611                 byl_opis_grupy = 0
 612                 while ((getline linia_grup < groups_file) > 0) {
 613                         byl_plik_z_groupmi = 1
 614                         if (linia_grup == group) {
 615                                 byl_opis_grupy = 1
 616                                 break
 617                         }
 618                 }
 619
 620                 if (!byl_plik_z_groupmi)
 621                         print "######\t\t" groups_file ": no such file"
 622                 else if (!byl_opis_grupy)
 623                         print "######\t\t" "Unknown group!"
 624
 625                 close(groups_file)
 626         }
 627
 628         if (field ~ /prereq:/) {
 629                 sub(/PreReq:/, "Requires:", $1);
 630         }
 631
 632         # split (build)requires, obsoletes on commas
 633         if (field ~ /(obsoletes|requires):/ && NF > 2) {
 634                 value = substr($0, index($0, $2));
 635                 $0 = format_requires($1, value);
 636         }
 637
 638         # obsolete/unwanted tags
 639         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:/) {
 640                 next
 641         }
 642
 643         if (field ~ /buildroot:/)
 644                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 645
 646         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 647         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 648                 $1 = "License:"
 649         }
 650
 651         if (field ~ /name:/) {
 652                 if ($2 == "%{name}" && name) {
 653                         $2 = name
 654                 }
 655                 name = $2
 656                 name_seen = 1;
 657         }
 658
 659         if (field ~ /version:/) {
 660                 if ($2 == "%{version}" && version) {
 661                         $2 = version
 662                 }
 663                 version = $2
 664                 version_seen = 1;
 665         }
 666
 667         if (field ~ /release:/) {
 668                 if ($2 == "%{release}" && release) {
 669                         $2 = release
 670                 }
 671                 release = $2
 672                 release_seen = 1;
 673         }
 674
 675         if (field ~ /serial:/)
 676                 $1 = "Epoch:"
 677
 678         # proper caps
 679         if (field ~ /^url:$/)
 680                 $1 = "URL:"
 681
 682         # Use %{name} and %{version} in the filenames in "Source:"
 683         if (field ~ /^source/ || field ~ /patch/) {
 684                 n = split($2, url, /\//)
 685                 if (url[n] ~ /\.gz$/) {
 686                         url[n+1] = ".gz" url[n+1]
 687                         sub(/\.gz$/,"",url[n])
 688                 }
 689                 if (url[n] ~ /\.zip$/) {
 690                         url[n+1] = ".zip" url[n+1]
 691                         sub(/\.zip$/,"",url[n])
 692                 }
 693                 if (url[n] ~ /\.tar$/) {
 694                         url[n+1] = ".tar" url[n+1]
 695                         sub(/\.tar$/,"",url[n])
 696                 }
 697                 if (url[n] ~ /\.patch$/) {
 698                         url[n+1] = ".patch" url[n+1]
 699                         sub(/\.patch$/,"",url[n])
 700                 }
 701                 if (url[n] ~ /\.bz2$/) {
 702                         url[n+1] = ".bz2" url[n+1]
 703                         sub(/\.bz2$/,"",url[n])
 704                 }
 705                 if (url[n] ~ /\.logrotate$/) {
 706                         url[n+1] = ".logrotate" url[n+1]
 707                         sub(/\.logrotate$/,"",url[n])
 708                 }
 709                 if (url[n] ~ /\.pamd$/) {
 710                         url[n+1] = ".pamd" url[n+1]
 711                         sub(/\.pamd$/,"",url[n])
 712                 }
 713
 714                 # allow %{name} only in last url component
 715                 s = ""
 716                 for (i = 1; i <= n; i++) {
 717                         url[i] = fixedsub("%{name}", name, url[i])
 718                         if (s) {
 719                                 s = s "/" url[i]
 720                         } else {
 721                                 s = url[i]
 722                         }
 723                 }
 724                 $2 = s url[n+1]
 725
 726                 filename = url[n]
 727                 if (name) {
 728                         url[n] = fixedsub(name, "%{name}", url[n])
 729                 }
 730                 if (field ~ /source/) {
 731                         if (version) {
 732                                 url[n] = fixedsub(version, "%{version}", url[n])
 733                         }
 734                         if (_beta) {
 735                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 736                         }
 737                         if (_rc) {
 738                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 739                         }
 740                         if (_snap) {
 741                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 742                         }
 743                 }
 744                 # assigning to $2 kills preamble formatting
 745                 $2 = fixedsub(filename, url[n], $2)
 746
 747                 # sourceforge urls
 748                 sub("[?]use_mirror=.*$", "", $2);
 749                 sub("[?]download$", "", $2);
 750                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 751
 752                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 753                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 754                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 755         }
 756
 757
 758         if (field ~ /^source:/)
 759                 $1 = "Source0:"
 760
 761         if (field ~ /^patch:/)
 762                 $1 = "Patch0:"
 763
 764         kill_preamble_macros();
 765         format_preamble()
 766
 767         if (field ~ /requires/) {
 768                 # atrpms
 769                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 770         }
 771 }
 772
 773
 774 # sort BR/R!
 775 #
 776 # NOTES:
 777 # - mixing BR/R and anything else confuses this (all will be sorted together)
 778 #   so don't do that.
 779 # - comments leading the BR/R can not be associated,
 780 #   so don't adapterize when the BR/R are mixed with comments
 781 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 782         if ($1 ~ /Pre[Rr]eq:/) {
 783                 sub(/PreReq:/, "Requires:", $1);
 784         }
 785         format_preamble()
 786 #       kill_preamble_macros(); # breaks tabbing
 787
 788         b_idx++;
 789         l = substr($0, index($0, $2));
 790         b_ktmp = b_makekey($1, l);
 791         b_key[b_idx] = b_ktmp;
 792         b_val[b_ktmp] = $0;
 793
 794         next;
 795 }
 796
 797 /^%bcond_/ {
 798         # do nothing
 799         print
 800         next
 801 }
 802
 803 preamble == 1 {
 804         if (b_idx > 0) {
 805                 isort(b_key, b_idx);
 806                 for (i = 1; i <= b_idx; i++) {
 807                         v = b_val[b_key[i]];
 808                         sub(/[ \t]+$/, "", v);
 809                         print "" v;
 810                 }
 811                 b_idx = 0
 812         }
 813 }
 814
 815 # main() ;-)
 816 {
 817         preamble = 1
 818
 819         sub(/[ \t]+$/, "")
 820         print
 821
 822         if (name_seen == 0 && name) {
 823                 print "Name:\t" name
 824                 name_seen = 1
 825         }
 826
 827         if (version_seen == 0 && version) {
 828                 print "Version:\t" version
 829                 version_seen = 1
 830         }
 831
 832         if (release_seen == 0 && release) {
 833                 print "Release:\t" release
 834                 release_seen = 1
 835         }
 836 }
 837
 838
 839 END {
 840         if (do_not_touch_anything)
 841                 exit 0
 842
 843         close(changelog_file)
 844         while ((getline < changelog_file) > 0)
 845                 print
 846         system("rm -f " changelog_file)
 847
 848         if (did_clean == 0) {
 849                 print ""
 850                 print "%clean"
 851                 print "rm -rf $RPM_BUILD_ROOT"
 852         }
 853
 854         if (date == 0) {
 855                 print ""
 856                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 857         }
 858
 859         if (has_changelog == 0)
 860                 print "%changelog"
 861
 862         if (boc > 2)
 863                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 864         if (boc > 1) {
 865                 printf "All persons listed below can be reached at "
 866                 print "<cvs_login>@pld-linux.org\n"
 867         }
 868         if (boc > 0)
 869                 print "$" "Log:$"
 870 }
 871
 872 function fixedsub(s1,s2,t, ind) {
 873 # substitutes fixed strings (not regexps)
 874         if (ind = index(t,s1))
 875                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 876         return t
 877 }
 878
 879 # There should be one or two tabs after the colon.
 880 function format_preamble()
 881 {
 882         if (/^#/ || /^%bcond_with/) {
 883                 return;
 884         }
 885         sub(/:[ \t]*/, ":")
 886         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 887                 if (RLENGTH < 8)
 888                         sub(/:/, ":\t\t")
 889                 else
 890                         sub(/:/, ":\t")
 891         }
 892 }
 893
 894 # Replace directly specified directories with macros
 895 function use_macros()
 896 {
 897         # -m, --skip-macros, --no-macros -- skip macros subst
 898         if (ENVIRON["SKIP_MACROS"]) {
 899                 return
 900         }
 901
 902         # leave inline sed lines alone
 903         if (/(%{__sed}|sed) -i -e/) {
 904                 return;
 905         }
 906
 907         gsub(perl_sitearch, "%{perl_sitearch}")
 908         gsub(perl_archlib, "%{perl_archlib}")
 909         gsub(perl_privlib, "%{perl_privlib}")
 910         gsub(perl_vendorlib, "%{perl_vendorlib}")
 911         gsub(perl_vendorarch, "%{perl_vendorarch}")
 912         gsub(perl_sitelib, "%{perl_sitelib}")
 913
 914         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
 915         gsub(py_scriptdir, "%{py_scriptdir}")
 916
 917         gsub(bindir, "%{_bindir}")
 918         gsub("%{prefix}/bin", "%{_bindir}")
 919         if (prefix"/bin" == bindir)
 920                 gsub("%{_prefix}/bin", "%{_bindir}")
 921
 922         for (c = 1; c <= NF; c++) {
 923                 if ($c ~ sbindir "/fix-info-dir")
 924                         continue;
 925                 if ($c ~ sbindir "/webapp")
 926                         continue;
 927                 if ($c ~ sbindir "/chsh")
 928                         continue;
 929                 if ($c ~ sbindir "/usermod")
 930                         continue;
 931                 gsub(sbindir, "%{_sbindir}", $c)
 932         }
 933
 934         gsub("%{prefix}/sbin", "%{_sbindir}")
 935         if (prefix"/sbin" == sbindir)
 936                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 937
 938         for (c = 1; c <= NF; c++) {
 939                 if ($c ~ sysconfdir "/{?cron.")
 940                         continue;
 941                 if ($c ~ sysconfdir "/{?crontab.d")
 942                         continue;
 943                 if ($c ~ sysconfdir "/{?env.d")
 944                         continue;
 945                 if ($c ~ sysconfdir "/{?logrotate.d")
 946                         continue;
 947                 if ($c ~ sysconfdir "/{?pam.d")
 948                         continue;
 949                 if ($c ~ sysconfdir "/{?profile.d")
 950                         continue;
 951                 if ($c ~ sysconfdir "/{?rc.d")
 952                         continue;
 953                 if ($c ~ sysconfdir "/{?security")
 954                         continue;
 955                 if ($c ~ sysconfdir "/{?skel")
 956                         continue;
 957                 if ($c ~ sysconfdir "/{?sysconfig")
 958                         continue;
 959                 if ($c ~ sysconfdir "/{?shrc.d")
 960                         continue;
 961                 if ($c ~ sysconfdir "/{?certs")
 962                         continue;
 963                 if ($c ~ sysconfdir "/{?X11")
 964                         continue;
 965                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
 966                         continue;
 967                 if ($c ~ sysconfdir "/{?rpm")
 968                         continue;
 969                 if ($c ~ sysconfdir "/{?bash_completion.d")
 970                         continue;
 971                 if ($c ~ sysconfdir "/{?samba")
 972                         continue;
 973                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 974         }
 975
 976         gsub(docdir, "%{_docdir}")
 977         gsub(php_pear_dir, "%{php_pear_dir}")
 978
 979         for (c = 1; c <= NF; c++) {
 980                 if ($c ~ datadir "/automake")
 981                         continue;
 982                 if ($c ~ datadir "/unsermake")
 983                         continue;
 984                 if ($c ~ datadir "/file/magic.mime")
 985                         continue;
 986                 gsub(datadir, "%{_datadir}", $c)
 987         }
 988
 989         gsub("%{prefix}/share", "%{_datadir}")
 990         if (prefix"/share" == datadir)
 991                 gsub("%{_prefix}/share", "%{_datadir}")
 992
 993         # CFLAGS="-I/usr/include/ncurses is usually correct.
 994         if (!/-I\/usr\/include/) {
 995                 gsub(includedir, "%{_includedir}")
 996         }
 997
 998         gsub("%{prefix}/include", "%{_includedir}")
 999         if (prefix"/include" == includedir) {
1000                 gsub("%{_prefix}/include", "%{_includedir}")
1001         }
1002
1003         gsub(mandir, "%{_mandir}")
1004         if ($0 !~ "%{_datadir}/manual") {
1005                 gsub("%{_datadir}/man", "%{_mandir}")
1006         }
1007         gsub("%{_prefix}/share/man", "%{_mandir}")
1008         gsub("%{prefix}/share/man", "%{_mandir}")
1009         gsub("%{prefix}/man", "%{_mandir}")
1010         gsub("%{_prefix}/man", "%{_mandir}")
1011
1012         gsub(infodir, "%{_infodir}")
1013         gsub("%{prefix}/info", "%{_infodir}")
1014         gsub("%{_prefix}/info", "%{_infodir}")
1015
1016         if (prefix !~ "/X11R6") {
1017                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1018         }
1019
1020         gsub(examplesdir, "%{_examplesdir}")
1021
1022         if (prefix != "/") {
1023                 # leave --with-foo=/usr alone
1024                 if ($0 !~ "--with.*=.*" prefix) {
1025                         for (c = 1; c <= NF; c++) {
1026                                 if ($c ~ prefix "/sbin/fix-info-dir")
1027                                         continue;
1028                                 if ($c ~ prefix "/sbin/webapp")
1029                                         continue;
1030                                 if ($c ~ prefix "/sbin/chsh")
1031                                         continue;
1032                                 if ($c ~ prefix "/sbin/usermod")
1033                                         continue;
1034                                 if ($c ~ prefix "/share/automake")
1035                                         continue;
1036                                 if ($c ~ prefix "/share/unsermake")
1037                                         continue;
1038                                 if ($c ~ prefix "/lib/sendmail")
1039                                         continue;
1040                                 if ($c ~ prefix "/lib/pkgconfig")
1041                                         continue;
1042
1043                                 # CFLAGS="-I/usr..." is usually correct.
1044                                 if (/-I\/usr/)
1045                                         continue;
1046                                 # same for LDFLAGS="-L/usr..."
1047                                 if (/-L\/usr/)
1048                                         continue;
1049
1050                                 gsub(prefix, "%{_prefix}", $c)
1051                         }
1052                 }
1053                 gsub("%{prefix}", "%{_prefix}")
1054         }
1055
1056         # replace back
1057         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1058         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1059
1060         gsub("%{PACKAGE_VERSION}", "%{version}")
1061         gsub("%{PACKAGE_NAME}", "%{name}")
1062
1063         gsub("^make$", "%{__make}")
1064         gsub("^make ", "%{__make} ")
1065         gsub("^gcc ", "%{__cc} ")
1066
1067         # mandrake specs
1068         gsub("^%make$", "%{__make}")
1069         gsub("^%make ", "%{__make} ")
1070         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1071         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1072         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1073         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1074         gsub("^%{__install}", "install")
1075         gsub("^%{__rm}", "rm")
1076         gsub("%optflags", "%{rpmcflags}")
1077         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1078
1079         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1080         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
1081         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1082         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1083         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1084
1085         # split configure line to multiple lines
1086         if (/%configure / && !/\\$/) {
1087                 $0 = format_configure($0);
1088         }
1089
1090         gsub("%_bindir", "%{_bindir}")
1091         gsub("%_datadir", "%{_datadir}")
1092         gsub("%_iconsdir", "%{_iconsdir}")
1093         gsub("%_sbindir", "%{_sbindir}")
1094         gsub("%_mandir", "%{_mandir}")
1095         gsub("%name", "%{name}")
1096
1097         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1098         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1099 }
1100
1101 function format_configure(line,         n, a, s) {
1102         n = split(line, a, / /);
1103         s = a[1] " \\\n";
1104         for (i = 2; i <= n; i++) {
1105                 s = s "\t" a[i] " \\\n"
1106         }
1107         return s
1108 }
1109
1110
1111 # insertion sort of A[1..n]
1112 # copied from mawk manual
1113 function isort(A,n,             i,j,hold) {
1114         for (i = 2; i <= n; i++) {
1115                 hold = A[j = i]
1116                 while (A[j-1] > hold) {
1117                         j-- ; A[j+1] = A[j]
1118                 }
1119                 A[j] = hold
1120         }
1121         # sentinel A[0] = "" will be created if needed
1122 }
1123
1124
1125 function use_files_macros(      i, n, t, a)
1126 {
1127         use_macros()
1128
1129         # skip comments
1130         if (/^#/) {
1131                 return;
1132         }
1133
1134         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1135         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1136
1137         # uid/gid nobody is not valid in %files
1138         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1139                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1140         }
1141
1142         # s[gu]id programs with globs are evil
1143         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1144                 $0 = $0 " # FIXME no globs for suid/sgid files"
1145         }
1146
1147         # replace back
1148         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1149         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1150         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1151         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1152         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1153         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1154         gsub("%{_sysconfdir}/security", "/etc/security")
1155         gsub("%{_sysconfdir}/skel", "/etc/skel")
1156         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1157         gsub("%{_sysconfdir}/certs", "/etc/certs")
1158         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1159
1160         # /etc/init.d -> /etc/rc.d/init.d
1161         if (!/^\/etc\/init\.d$/) {
1162                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1163         }
1164
1165         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1166                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1167                         $0 = "%attr(754,root,root) " $0
1168                 }
1169                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1170                         gsub("^%attr\\(... *,", "%attr(754,");
1171                 }
1172         }
1173
1174         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1175                 $0 = "%attr(755,root,root) " $0
1176         }
1177
1178         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1179                 $0 = "%attr(755,root,root) " $0
1180         }
1181
1182         # /etc/sysconfig files
1183         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1184         # attr not required, allow default 644 attr
1185         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1186                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace\)/) {
1187                         gsub("%config", "%config(noreplace)")
1188                 }
1189
1190                 if (/\/etc\/sysconfig\// && !/%config\(noreplace\)/) {
1191                         $NF = "%config(noreplace) " $NF
1192                 }
1193
1194                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1195                         gsub("^%attr\\(... *,", "%attr(640,");
1196                 }
1197
1198                 if (/\/etc\/sysconfig\// && !/%verify/) {
1199                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1200                 }
1201         }
1202
1203         # kill leading zeros
1204         if (/%attr\(0[1-9]/) {
1205                 gsub("%attr\\(0", "%attr(")
1206         }
1207
1208         # sort %verify attrs
1209         if (match($0, /%verify\(not([^)]+)\)/)) {
1210                 t = substr($0, RSTART, RLENGTH)
1211                 # kill commas: %verify(not,md5,size,mtime)
1212                 gsub(/,/, " ", t);
1213
1214                 gsub(/^%verify\(not |\)$/, "", t)
1215                 n = split(t, a, / /)
1216                 isort(a, n)
1217
1218                 s = "%verify(not"
1219                 for (i = 1 ; i <= n; i++) {
1220                         s = s " " a[i]
1221                 }
1222                 s = s ")"
1223
1224                 gsub(/%verify\(not[^)]+\)/, s)
1225         }
1226
1227         if (/%{_mandir}/) {
1228                 gsub("\.gz$", "*")
1229         }
1230
1231         # locale dir and no %lang -> bad
1232         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1233                 $(NF + 1) = "# FIXME consider using %find_lang"
1234         }
1235
1236         # atrpms
1237         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1238         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1239         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1240
1241         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1242         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1243         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1244
1245         gsub("%{_datadir}/applications", "%{_desktopdir}");
1246         gsub("%{_datadir}/icons", "%{_iconsdir}");
1247         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1248 }
1249
1250 function fill(ch, n, i) {
1251         for (i = 0; i < n; i++)
1252                 printf("%c", ch)
1253 }
1254
1255 function format_flush(line, indent, newline, word, first_word) {
1256         first_word = 1
1257         if (format_indent == -1)
1258                 newline = ""
1259         else
1260                 newline = fill(" ", format_indent) "- "
1261
1262         while (match(line, /[^\t ]+/)) {
1263                 word = substr(line, RSTART, RLENGTH)
1264                 if (length(newline) + length(word) + 1 > tw) {
1265                         print newline
1266
1267                         if (format_indent == -1)
1268                                 newline = ""
1269                         else
1270                                 newline = fill(" ", format_indent + 2)
1271                         first_word = 1
1272                 }
1273
1274                 if (first_word) {
1275                         newline = newline word
1276                         first_word = 0
1277                 } else
1278                         newline = newline " " word
1279
1280                 line = substr(line, RSTART + RLENGTH)
1281         }
1282         if (newline ~ /[^\t ]/) {
1283                 print newline
1284         }
1285 }
1286
1287 function cflags(var)
1288 {
1289         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1290                 removed[var] = 1
1291                 return 0
1292         }
1293
1294         if (!/!\?debug/)
1295                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1296         return 1
1297 }
1298
1299 function demacroize(str)
1300 {
1301         if (mod_name) {
1302                 sub("%{mod_name}", mod_name, str);
1303         }
1304         if (name) {
1305                 sub("%{name}", name, str);
1306         }
1307         if (version) {
1308                 sub("%{version}", version, str);
1309         }
1310         if (_beta) {
1311                 sub("%{_beta}", _beta, str);
1312         }
1313         if (_rc) {
1314                 sub("%{_rc}", _rc, str);
1315         }
1316         if (_snap) {
1317                 sub("%{_snap}", _snap, str);
1318         }
1319         return str;
1320 }
1321
1322 function kill_preamble_macros()
1323 {
1324         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1325                 # NB! assigning $2 a value breaks tabbing
1326                 $2 = demacroize($2);
1327                 # unify sourceforge url
1328                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1329         }
1330 }
1331
1332 function get_epoch(pkg, ver,    epoch)
1333 {
1334         return
1335 # should parse the BR lines more adequately:
1336 #       freetype = 2.0.0 -> correct
1337 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1338
1339         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1340         shell | getline epoch;
1341         return epoch;
1342 }
1343
1344 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1345         # skip any formatting for commented out items or some weird macros
1346         if (/^#/ || /%\(/) {
1347                 return tag "\t" value
1348         }
1349         n = split(value, p, / *,? */);
1350         for (i = 1; i <= n; i++) {
1351                 if (p[i+1] ~ /[<=>]/) {
1352                         # add epoch if the version doesn't have it but BuildRequires.txt has
1353                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1354                                 epoch = get_epoch(p[i], p[i+2])
1355                                 if (epoch) {
1356                                         p[i+2] = epoch ":" p[i+2];
1357                                 }
1358                         }
1359                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1360                         i += 2;
1361                 } else {
1362                         deps[ndeps++] = p[i];
1363                 }
1364         }
1365         s = ""
1366         for (i in deps) {
1367                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1368         }
1369         return substr(s, 1, length(s)-1);
1370 }