adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2003 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Elan Ruusamäe <glen@pld-linux.org>
  13 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  14
  15 # TODO
  16 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  17 # - add "-nc" option to skip CVS interaction
  18 # - sort Summary(XX)
  19 # - sort Requires, BuildRequires
  20
  21 BEGIN {
  22         preamble = 1            # Is it part of preamble? Default - yes
  23         boc = 4                 # Beggining of %changelog
  24         bod = 0                 # Beggining of %description
  25         tw = 70                 # Descriptions width
  26
  27         b_idx = 0               # index of BR/R arrays
  28
  29         # If variable removed, then 1 (for removing it from export)
  30         removed["LDFLAGS"] = 0
  31         removed["CFLAGS"] = 0
  32         removed["CXXFLAGS"] = 0
  33
  34         # get cvsaddress for changelog section
  35         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  36         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  37         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  38
  39         # If 1, we are inside of comment block (started with /^#%/)
  40         comment_block = 0
  41
  42         # File with rpm groups
  43         "rpm --eval %_sourcedir" | getline groups_file
  44         groups_file = groups_file "/rpm.groups"
  45         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups >/dev/null")
  46
  47         # Temporary file for changelog section
  48         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  49
  50         # Load rpm macros
  51         "rpm --eval %_prefix"   | getline prefix
  52         "rpm --eval %_bindir"   | getline bindir
  53         "rpm --eval %_sbindir"  | getline sbindir
  54         "rpm --eval %_libdir"   | getline libdir
  55         "rpm --eval %_sysconfdir" | getline sysconfdir
  56         "rpm --eval %_datadir"  | getline datadir
  57         "rpm --eval %_includedir" | getline includedir
  58         "rpm --eval %_mandir"   | getline mandir
  59         "rpm --eval %_infodir"  | getline infodir
  60         "rpm --eval %_examplesdir"      | getline examplesdir
  61
  62         "rpm --eval %perl_sitearch" | getline perl_sitearch
  63         "rpm --eval %perl_archlib" | getline perl_archlib
  64         "rpm --eval %perl_privlib" | getline perl_privlib
  65         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  66         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  67         "rpm --eval %perl_sitelib" | getline perl_sitelib
  68
  69         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  70 }
  71
  72 # There should be a comment with CVS keywords on the first line of file.
  73 FNR == 1 {
  74         if (!/# \$Revision:/)   # If this line is already OK?
  75                 print "# $" "Revision:$, " "$" "Date:$" # No
  76         else {
  77                 print $0                                # Yes
  78                 next            # It is enough for first line
  79         }
  80 }
  81
  82 # If the latest line matched /%files/
  83 defattr == 1 {
  84         if ($0 !~ /defattr/)    # If no %defattr
  85                 print "%defattr(644,root,root,755)"     # Add it
  86         else
  87                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  88         defattr = 0
  89 }
  90
  91 function b_makekey(a, b,        s) {
  92         s = a "" b;
  93         # kill bcond
  94         gsub("%{\\?[_a-zA-Z0-9]+:", "", s);
  95         return s;
  96 }
  97
  98 # sort BR/R!
  99 #
 100 # NOTES:
 101 # - mixing BR/R and anything else confuses this (all will be sorted together)
 102 #   so don't do that.
 103 # - comments leading the BR/R can not be associated,
 104 #   so don't adapterize when the BR/R are mixed with comments
 105 ENVIRON["SORTBR"] == 1 && preamble == 1 && /(Build)?Requires/, /(Build)?Requires/ { # && !/^%/) {
 106         b_idx++;
 107         l = substr($0, index($0, $2));
 108         b_ktmp = b_makekey($1, l);
 109         b_key[b_idx] = b_ktmp;
 110         b_val[b_ktmp] = $0;
 111
 112         next;
 113 }
 114
 115 /^%bcond_/ {
 116         # do nothing
 117         print
 118         next
 119 }
 120
 121 preamble == 1 {
 122         if (b_idx > 0) {
 123                 isort(b_key, b_idx);
 124                 for (i = 1; i <= b_idx; i++) {
 125                         print "" b_val[b_key[i]];
 126                 }
 127                 b_idx = 0
 128         }
 129 }
 130
 131 # Comments
 132 /^#/ && (description == 0) {
 133         if (/This file does not like to be adapterized!/) {
 134                 print                   # print this message
 135                 while (getline)         # print the rest of spec as it is
 136                         print
 137                 do_not_touch_anything = 1 # do not touch anything in END()
 138                 exit 0
 139         }
 140
 141         # Generally, comments are printed without touching
 142         sub(/[ \t]+$/, "")
 143         print $0
 144         next
 145 }
 146
 147 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 148 /^%define/ {
 149         if ($2 == "_applnkdir")
 150                 next
 151         if ($2 == "date")
 152                 date = 1
 153 }
 154
 155 # Obsolete
 156 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 157         next
 158 }
 159
 160 ################
 161 # %description #
 162 ################
 163 /^%description/, (/^%[a-z]+/ && !/^%description/ && !/^%((end)?if|else)/) {
 164         preamble = 0
 165
 166         if (/^%description/) {
 167                 bod++
 168                 format_line = ""
 169                 format_indent = -1
 170         }
 171
 172         # Format description
 173         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 174                 if (/^[ \t]*$/) {
 175                         format_flush(format_line, format_indent)
 176                         print ""
 177                         format_line = ""
 178                         format_indent = -1
 179                 } else if (/^[ \t]*[-\*][ \t]*/) {
 180                         format_flush(format_line, format_indent)
 181                         match($0, /^[ \t]*/)
 182                         format_indent = RLENGTH
 183                         match($0, /^[ \t]*[-\*][ \t]/)
 184                         format_line = substr($0, RLENGTH)
 185                 } else
 186                         format_line = format_line " " $0
 187                 next
 188         }
 189
 190         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 191                 if (NF > 3 && $2 == "-l") {
 192                         ll = $1
 193                         for (i = 4; i <= NF; i++)
 194                                 ll = ll " " $i
 195                         $0 = ll " -l " $3
 196                 }
 197                 format_flush(format_line, format_indent)
 198                 if (bod == 2) {
 199                         bod = 1
 200                         description = 1
 201                 } else {
 202                         bod = 0
 203                         description = 0
 204                 }
 205         } else
 206                 description = 1
 207 }
 208
 209 #########
 210 # %prep #
 211 #########
 212 /^%prep/, (/^%[a-z]+$/ && !/^%prep/ && !/^%((end)?if|else)/) {
 213         preamble = 0
 214
 215         use_macros()
 216
 217         # Add '-q' to %setup
 218         if (/^%setup/ && !/-q/) {
 219                 sub(/^%setup/, "%setup -q")
 220         }
 221
 222         if (/^%setup/) {
 223                 gsub(name, "%{name}");
 224                 gsub(version, "%{version}");
 225                 if (_beta) {
 226                         gsub(_beta, "%{_beta}");
 227                 }
 228                 if (_rc) {
 229                         gsub(_rc, "%{_rc}");
 230                 }
 231                 if (_snap) {
 232                         gsub(_snap, "%{_snap}");
 233                 }
 234         }
 235
 236         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 237                 sub(/ -n %{name}-%{version}/, "")
 238         }
 239
 240         # invalid in %prep
 241         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 242 }
 243
 244 ##########
 245 # %build #
 246 ##########
 247 /^%build/, (/^%[a-z]+$/ && !/^%build/ && !/^%((end)?if|else)/) {
 248         preamble = 0
 249
 250         use_macros()
 251
 252         if (/^automake$/)
 253                 sub(/$/, " -a -c")
 254
 255         if (/LDFLAGS/) {
 256                 if (/LDFLAGS="-s"/) {
 257                         removed["LDFLAGS"] = 1
 258                         next
 259                 } else {
 260                         split($0, tmp, "LDFLAGS=")
 261                         count = split(tmp[2], flags, "\"")
 262                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 263                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 264                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 265                                 for (i = 2; i < count; i++)
 266                                         $0 = $0 flags[i] "\""
 267                         }
 268                 }
 269         }
 270
 271         if (/CFLAGS=/)
 272                 if (cflags("CFLAGS") == 0)
 273                         next
 274
 275         if (/CXXFLAGS=/)
 276                 if (cflags("CXXFLAGS") == 0)
 277                         next
 278
 279         if (/^export /) {
 280                 if (removed["LDFLAGS"])
 281                         sub(" LDFLAGS", "")
 282                 if (removed["CFLAGS"])
 283                         sub(" CFLAGS", "")
 284                 if (removed["CXXFLAGS"])
 285                         sub(" CXXFLAGS", "")
 286                 # Is there still something?
 287                 if (/^export[ ]*$/)
 288                         next
 289         }
 290
 291         # use macros
 292         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 293         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 294
 295         # atrpms
 296         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 297         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 298 }
 299
 300 ##########
 301 # %clean #
 302 ##########
 303 /^%clean/, (/^%[a-z]+$/ && !/^%clean/ && !/^%((end)?if|else)/) {
 304         did_clean = 1
 305         use_macros()
 306 }
 307
 308 ############
 309 # %install #
 310 ############
 311 /^%install/, (/^%[a-z]+$/ && !/^%install/ && !/^%((end)?if|else)/) {
 312
 313         preamble = 0
 314
 315         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 316                 did_rmroot=1
 317                 print "rm -rf $RPM_BUILD_ROOT"
 318                 next
 319         }
 320
 321         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 322                 print "rm -rf $RPM_BUILD_ROOT"
 323                 did_rmroot=1
 324         }
 325
 326         use_macros()
 327
 328         # 'install -d' instead 'mkdir -p'
 329         if (/mkdir -p/)
 330                 sub(/mkdir -p/, "install -d")
 331
 332         # 'install' instead 'cp -p'
 333         if (/cp -p\b/)
 334                 sub(/cp -p/, "install")
 335
 336         # No '-u root' or '-g root' for 'install'
 337         if (/^install/ && /-[ug][ \t]*root/)
 338                 gsub(/-[ug][ \t]*root /, "")
 339
 340         if (/^install/ && /-m[ \t]*[0-9]+/)
 341                 gsub(/-m[ \t]*[0-9]+ /, "")
 342
 343         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 344         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 345                 next
 346
 347         # No lines contain 'chmod' if it sets the modes to '644'
 348         if ($1 ~ /chmod/ && $2 ~ /644/)
 349                 next
 350
 351         # foreign rpms
 352         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 353         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 354
 355         # atrpms
 356         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 357 }
 358
 359 ##########
 360 # %files #
 361 ##########
 362 /^%files/, (/^%[a-z \-]+$/ && !/^%files/ && !/^%((end)?if|else)/) {
 363         preamble = 0
 364
 365         if ($0 ~ /^%files/)
 366                 defattr = 1
 367
 368         use_macros()
 369         use_files_macros()
 370 }
 371
 372 ##############
 373 # %changelog #
 374 ##############
 375 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 376         preamble = 0
 377         has_changelog = 1
 378         skip = 0
 379         # There should be some CVS keywords on the first line of %changelog.
 380         if (boc == 3) {
 381                 if ($0 !~ _cvsmailfeedback)
 382                         print "* %{date} " _cvsmailfeedback > changelog_file
 383                 else
 384                         skip = 1
 385                 boc = 2
 386         }
 387         if (boc == 2 && !skip) {
 388                 if (!/All persons listed below/) {
 389                         printf "All persons listed below can be reached at " > changelog_file
 390                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 391                 } else
 392                         skip = 1
 393                 boc = 1
 394         }
 395         if (boc == 1 && !skip) {
 396                 if (!/^$/) {
 397                         if (!/\$.*Log:.*\$/)
 398                                 print "$" "Log:$" > changelog_file
 399                         boc = 0
 400                 }
 401         }
 402         # Define date macro.
 403         if (boc == 4) {
 404                 if (date == 0) {
 405                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 406                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 407                         date = 1
 408                 }
 409                 boc = 3
 410         }
 411
 412         sub(/[ \t]+$/, "")
 413         if (!/^%[a-z]+$/ || /changelog/)
 414                 print > changelog_file
 415         else
 416                 print
 417         next
 418 }
 419
 420 ###########
 421 # SCRIPTS #
 422 ###########
 423 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 424         preamble = 0
 425
 426         # %useradd and %groupadd may not be wrapped
 427         if (/%(useradd|groupadd).*\\$/) {
 428                 a = $0; getline;
 429                 sub(/^[\s\t]*/, "");
 430                 $0 = substr(a, 1, length(a) - 1) $0;
 431         }
 432 }
 433
 434 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 435         preamble = 0
 436 }
 437 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 438         preamble = 0
 439 }
 440 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 441         preamble = 0
 442 }
 443 /^%triggerin/, (/^%[a-z]+$/ && !/^%triggerin/) {
 444         preamble = 0
 445 }
 446 /^%triggerun/, (/^%[a-z]+$/ && !/^%triggerun/) {
 447         preamble = 0
 448 }
 449 /^%triggerpostun/, (/^%[a-z]+$/ && !/^%triggerpostun/) {
 450         preamble = 0
 451 }
 452 /^%pretrans/, (/^%[a-z]+$/ && !/^%pretrans/) {
 453         preamble = 0
 454 }
 455 /^%posttrans/, (/^%[a-z]+$/ && !/^%posttrans/) {
 456         preamble = 0
 457 }
 458
 459 #############
 460 # PREAMBLES #
 461 #############
 462 preamble == 1 {
 463         # There should not be a space after the name of field
 464         # and before the colon.
 465         sub(/[ \t]*:/, ":")
 466
 467         if (/^%perl_module_wo_prefix/) {
 468                 name = $2
 469                 version = $3
 470                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 471         }
 472
 473         field = tolower($1)
 474         fieldnlower = $1
 475         if (field ~ /summary:/) {
 476                 sub(/\.$/, "", $0);
 477         }
 478         if (field ~ /group(\([^)]+\)):/)
 479                 next
 480         if (field ~ /group:/) {
 481                 format_preamble()
 482                 sub(/^Utilities\//,"Applications/",$2)
 483                 sub(/^Games/,"Applications/Games",$2)
 484                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 485                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 486                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 487                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 488                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 489                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 490                 sub(/^Shells/,"Applications/Shells",$2)
 491
 492                 sub(/^[^ \t]*[ \t]*/,"")
 493                 Grupa = $0
 494
 495                 sub(/^System Environment\/Libraries/, "Libraries", Grupa)
 496
 497                 print "Group:\t\t" Grupa
 498                 if (Grupa ~ /^X11/ && x11 == 0) # Is it X11 application?
 499                         x11 = 1
 500
 501                 byl_plik_z_grupami = 0
 502                 byl_opis_grupy = 0
 503                 while ((getline linia_grup < groups_file) > 0) {
 504                         byl_plik_z_grupami = 1
 505                         if (linia_grup == Grupa) {
 506                                 byl_opis_grupy = 1
 507                                 break
 508                         }
 509                 }
 510
 511                 if (!byl_plik_z_grupami)
 512                         print "######\t\t" groups_file ": no such file"
 513                 else if (!byl_opis_grupy)
 514                         print "######\t\t" "Unknown group!"
 515
 516                 close(groups_file)
 517                 next
 518         }
 519
 520         if (field ~ /prereq:/) {
 521                 $1 = "Requires:"
 522                 $(NF + 1) = " # FIXME add Requires(scriptlet) -adapter.awk"
 523         }
 524
 525         # split (build)requires on commas
 526         if (field ~ /requires:/ && $0 ~ /,/) {
 527                 l = substr($0, index($0, $2));
 528                 n = split(l, p, / *, */);
 529                 for (i in p) {
 530                         printf("%s\t%s\n", $1, p[i]);
 531                 }
 532                 next;
 533         }
 534
 535         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 536                 next
 537
 538         if (field ~ /buildroot:/)
 539                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 540
 541         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 542         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 543                 $1 = "License:"
 544
 545         if (field ~ /name:/) {
 546                 if ($2 == "%{name}" && name) {
 547                         $2 = name
 548                 }
 549                 name = $2
 550                 name_seen = 1;
 551         }
 552
 553         if (field ~ /version:/) {
 554                 if ($2 == "%{version}" && version) {
 555                         $2 = version
 556                 }
 557                 version = $2
 558                 version_seen = 1;
 559         }
 560
 561         if (field ~ /release:/) {
 562                 if ($2 == "%{release}" && release) {
 563                         $2 = release
 564                 }
 565                 release = $2
 566                 release_seen = 1;
 567         }
 568
 569         if (field ~ /serial:/)
 570                 $1 = "Epoch:"
 571
 572         # Use %{name} and %{version} in the filenames in "Source:"
 573         if (field ~ /^source/ || field ~ /patch/) {
 574                 n = split($2, url, /\//)
 575                 if (url[n] ~ /\.gz$/) {
 576                         url[n+1] = ".gz" url[n+1]
 577                         sub(/\.gz$/,"",url[n])
 578                 }
 579                 if (url[n] ~ /\.zip$/) {
 580                         url[n+1] = ".zip" url[n+1]
 581                         sub(/\.zip$/,"",url[n])
 582                 }
 583                 if (url[n] ~ /\.tar$/) {
 584                         url[n+1] = ".tar" url[n+1]
 585                         sub(/\.tar$/,"",url[n])
 586                 }
 587                 if (url[n] ~ /\.patch$/) {
 588                         url[n+1] = ".patch" url[n+1]
 589                         sub(/\.patch$/,"",url[n])
 590                 }
 591                 if (url[n] ~ /\.bz2$/) {
 592                         url[n+1] = ".bz2" url[n+1]
 593                         sub(/\.bz2$/,"",url[n])
 594                 }
 595                 if (url[n] ~ /\.logrotate$/) {
 596                         url[n+1] = ".logrotate" url[n+1]
 597                         sub(/\.logrotate$/,"",url[n])
 598                 }
 599                 if (url[n] ~ /\.pamd$/) {
 600                         url[n+1] = ".pamd" url[n+1]
 601                         sub(/\.pamd$/,"",url[n])
 602                 }
 603
 604                 # allow %{name} just in last url component
 605                 s = ""
 606                 for (i = 1; i <= n; i++) {
 607                         url[i] = fixedsub("%{name}", name, url[i])
 608                         if (s) {
 609                                 s = s "/" url[i]
 610                         } else {
 611                                 s = url[i]
 612                         }
 613                 }
 614                 $2 = s url[n+1]
 615
 616                 filename = url[n]
 617                 if (name) {
 618                         url[n] = fixedsub(name, "%{name}", url[n])
 619                 }
 620                 if (field ~ /source/) {
 621                         if (version) {
 622                                 url[n] = fixedsub(version, "%{version}", url[n])
 623                         }
 624                         if (_beta) {
 625                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 626                         }
 627                         if (_rc) {
 628                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 629                         }
 630                         if (_snap) {
 631                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 632                         }
 633                 }
 634                 $2 = fixedsub(filename, url[n], $2)
 635
 636                 # sourceforge urls
 637                 sub("[?]use_mirror=.*$", "", $2);
 638                 sub("[?]download$", "", $2);
 639                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 640
 641                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 642                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 643                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 644         }
 645
 646
 647         if (field ~ /^source:/)
 648                 $1 = "Source0:"
 649
 650         if (field ~ /patch:/)
 651                 $1 = "Patch0:"
 652
 653         format_preamble()
 654
 655         if ($1 ~ /%define/) {
 656                 # Do not add %define of _prefix if it already is.
 657                 if ($2 ~ /^_prefix/) {
 658                         sub("^"prefix, $3, bindir)
 659                         sub("^"prefix, $3, sbindir)
 660                         sub("^"prefix, $3, libdir)
 661                         sub("^"prefix, $3, datadir)
 662                         sub("^"prefix, $3, includedir)
 663                         prefix = $3
 664                 }
 665
 666                 if ($2 ~ /_bindir/ && !/_sbindir/)
 667                         bindir = $3
 668                 if ($2 ~ /_sbindir/)
 669                         sbindir = $3
 670                 if ($2 ~ /_libdir/)
 671                         libdir = $3
 672                 if ($2 ~ /_sysconfdir/ && $3 !~ /^%\(/)
 673                         sysconfdir = $3
 674                 if ($2 ~ /_datadir/)
 675                         datadir = $3
 676                 if ($2 ~ /_includedir/)
 677                         includedir = $3
 678                 if ($2 ~ /_mandir/)
 679                         mandir = $3
 680                 if ($2 ~ /_infodir/)
 681                         infodir = $3
 682
 683                 if ($2 ~ /^_beta$/)
 684                         _beta = $3
 685                 if ($2 ~ /^_rc$/)
 686                         _rc = $3
 687                 if ($2 ~ /^_snap$/)
 688                         _snap = $3
 689
 690                 if ($2 ~ /^name$/)
 691                         name = $3
 692                 if ($2 ~ /^version$/)
 693                         version = $3
 694                 if ($2 ~ /^release$/)
 695                         release = $3
 696         }
 697
 698         if (field ~ /requires/) {
 699                 # atrpms
 700                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 701         }
 702 }
 703
 704 # main() ;-)
 705 {
 706         preamble = 1
 707
 708         sub(/[ \t]+$/, "")
 709         print
 710
 711         if (name_seen == 0 && name) {
 712                 print "Name:\t" name
 713                 name_seen = 1
 714         }
 715
 716         if (version_seen == 0 && version) {
 717                 print "Version:\t" version
 718                 version_seen = 1
 719         }
 720
 721         if (release_seen == 0 && release) {
 722                 print "Release:\t" release
 723                 release_seen = 1
 724         }
 725 }
 726
 727
 728 END {
 729         if (do_not_touch_anything)
 730                 exit 0
 731
 732         close(changelog_file)
 733         while ((getline < changelog_file) > 0)
 734                 print
 735         system("rm -f " changelog_file)
 736
 737
 738
 739         if (did_clean == 0) {
 740                 print ""
 741                 print "%clean"
 742                 print "rm -rf $RPM_BUILD_ROOT"
 743         }
 744
 745         if (date == 0) {
 746                 print ""
 747                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 748         }
 749
 750         if (has_changelog == 0)
 751                 print "%changelog"
 752
 753         if (boc > 2)
 754                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 755         if (boc > 1) {
 756                 printf "All persons listed below can be reached at "
 757                 print "<cvs_login>@pld-linux.org\n"
 758         }
 759         if (boc > 0)
 760                 print "$" "Log:$"
 761 }
 762
 763 function fixedsub(s1,s2,t, ind) {
 764 # substitutes fixed strings (not regexps)
 765         if (ind = index(t,s1))
 766                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 767         return t
 768 }
 769
 770 # There should be one or two tabs after the colon.
 771 function format_preamble()
 772 {
 773         sub(/:[ \t]*/, ":")
 774         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 775                 if (RLENGTH < 8)
 776                         sub(/:/, ":\t\t")
 777                 else
 778                         sub(/:/, ":\t")
 779         }
 780 }
 781
 782 # Replace directly specified directories with macros
 783 function use_macros()
 784 {
 785         gsub(perl_sitearch, "%{perl_sitearch}")
 786         gsub(perl_archlib, "%{perl_archlib}")
 787         gsub(perl_privlib, "%{perl_privlib}")
 788         gsub(perl_vendorlib, "%{perl_vendorlib}")
 789         gsub(perl_vendorarch, "%{perl_vendorarch}")
 790         gsub(perl_sitelib, "%{perl_sitelib}")
 791
 792         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
 793
 794         gsub(bindir, "%{_bindir}")
 795         gsub("%{prefix}/bin", "%{_bindir}")
 796         if(prefix"/bin" == bindir)
 797                 gsub("%{_prefix}/bin", "%{_bindir}")
 798
 799         for (c = 1; c <= NF; c++) {
 800                 if ($c ~ sbindir "/fix-info-dir")
 801                         continue;
 802                 gsub(sbindir, "%{_sbindir}", $c)
 803         }
 804
 805         gsub("%{prefix}/sbin", "%{_sbindir}")
 806         if (prefix"/sbin" == sbindir)
 807                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 808
 809         for (c = 1; c <= NF; c++) {
 810                 if ($c ~ sysconfdir "/{?cron.")
 811                         continue;
 812                 if ($c ~ sysconfdir "/{?crontab.d")
 813                         continue;
 814                 if ($c ~ sysconfdir "/{?logrotate.d")
 815                         continue;
 816                 if ($c ~ sysconfdir "/{?pam.d")
 817                         continue;
 818                 if ($c ~ sysconfdir "/{?profile.d")
 819                         continue;
 820                 if ($c ~ sysconfdir "/{?rc.d")
 821                         continue;
 822                 if ($c ~ sysconfdir "/{?security")
 823                         continue;
 824                 if ($c ~ sysconfdir "/{?skel")
 825                         continue;
 826                 if ($c ~ sysconfdir "/{?sysconfig")
 827                         continue;
 828                 if ($c ~ sysconfdir "/{?certs")
 829                         continue;
 830                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 831         }
 832
 833         for (c = 1; c <= NF; c++) {
 834                 if ($c ~ datadir "/automake")
 835                         continue;
 836                 if ($c ~ datadir "/unsermake")
 837                         continue;
 838                 if ($c ~ datadir "/file/magic.mime")
 839                         continue;
 840                 gsub(datadir, "%{_datadir}", $c)
 841         }
 842
 843
 844         gsub("%{prefix}/share", "%{_datadir}")
 845         if (prefix"/share" == datadir)
 846                 gsub("%{_prefix}/share", "%{_datadir}")
 847
 848         gsub(includedir, "%{_includedir}")
 849         gsub("%{prefix}/include", "%{_includedir}")
 850         if (prefix"/include" == includedir)
 851                 gsub("%{_prefix}/include", "%{_includedir}")
 852
 853         gsub(mandir, "%{_mandir}")
 854         if ($0 !~ "%{_datadir}/manual")
 855                 gsub("%{_datadir}/man", "%{_mandir}")
 856         gsub("%{_prefix}/share/man", "%{_mandir}")
 857         gsub("%{prefix}/share/man", "%{_mandir}")
 858         gsub("%{prefix}/man", "%{_mandir}")
 859         gsub("%{_prefix}/man", "%{_mandir}")
 860
 861         gsub(infodir, "%{_infodir}")
 862         gsub("%{prefix}/info", "%{_infodir}")
 863         gsub("%{_prefix}/info", "%{_infodir}")
 864
 865         if (prefix !~ "/X11R6") {
 866                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 867         }
 868
 869         gsub(examplesdir, "%{_examplesdir}")
 870
 871         if (prefix != "/") {
 872                 # leave --with-foo=/usr alone
 873                 if ($0 !~ "--with.*=.*" prefix) {
 874                         for (c = 1; c <= NF; c++) {
 875                                 if ($c ~ prefix "/sbin/fix-info-dir")
 876                                         continue;
 877                                 if ($c ~ prefix "/share/automake")
 878                                         continue;
 879                                 if ($c ~ prefix "/share/unsermake")
 880                                         continue;
 881                                 if ($c ~ prefix "/lib/sendmail")
 882                                         continue;
 883                                 if ($c ~ prefix "/lib/pkgconfig")
 884                                         continue;
 885                                 gsub(prefix, "%{_prefix}", $c)
 886                         }
 887                 }
 888                 gsub("%{prefix}", "%{_prefix}")
 889         }
 890
 891         gsub("%{PACKAGE_VERSION}", "%{version}")
 892         gsub("%{PACKAGE_NAME}", "%{name}")
 893
 894         gsub("^make$", "%{__make}")
 895         gsub("^make ", "%{__make} ")
 896         gsub("^gcc ", "%{__cc} ")
 897
 898         # mandrake specs
 899         gsub("^%make$", "%{__make}")
 900         gsub("^%make ", "%{__make} ")
 901         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 902         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 903         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 904         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 905         gsub("^%{__install}", "install")
 906         gsub("^%{__rm}", "rm")
 907         gsub("%optflags", "%{rpmcflags}")
 908         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
 909
 910         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 911         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
 912         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 913         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 914         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
 915
 916         gsub("%_bindir", "%{_bindir}")
 917         gsub("%_datadir", "%{_datadir}")
 918         gsub("%_iconsdir", "%{_iconsdir}")
 919
 920         gsub("/usr/src/linux", "%{_kernelsrcdir}")
 921         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
 922 }
 923
 924
 925 # insertion sort of A[1..n]
 926 # copied from mawk manual
 927 function isort(A,n,             i,j,hold) {
 928         for (i = 2; i <= n; i++) {
 929                 hold = A[j = i]
 930                 while (A[j-1] > hold) {
 931                         j-- ; A[j+1] = A[j]
 932                 }
 933                 A[j] = hold
 934         }
 935         # sentinel A[0] = "" will be created if needed
 936 }
 937
 938
 939 function use_files_macros(      i, n, t, a)
 940 {
 941         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 942         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 943
 944         # uid/gid nobody is not valid in %files
 945         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
 946                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
 947         }
 948
 949         # replace back
 950         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
 951         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
 952         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
 953         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
 954         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
 955         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
 956         gsub("%{_sysconfdir}/security", "/etc/security")
 957         gsub("%{_sysconfdir}/skel", "/etc/skel")
 958         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
 959         gsub("%{_sysconfdir}/certs", "/etc/certs")
 960         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
 961
 962         # /etc/init.d -> /etc/rc.d/init.d
 963         if (!/^\/etc\/init\.d$/) {
 964                  gsub("/etc/init.d", "/etc/rc.d/init.d")
 965         }
 966
 967         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
 968                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
 969                         $0 = "%attr(754,root,root) " $0
 970                 }
 971                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
 972                         gsub("^%attr\\(... *,", "%attr(754,");
 973                 }
 974         }
 975
 976         if (/lib.+\.so/ && !/^%attr.*/) {
 977                 $0 = "%attr(755,root,root) " $0
 978         }
 979
 980         # /etc/sysconfig files
 981         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
 982         # attr not required, allow default 644 attr
 983         if (!/network-scripts/) {
 984                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace\)/) {
 985                         gsub("%config", "%config(noreplace)")
 986                 }
 987
 988                 if (/\/etc\/sysconfig\// && !/%config\(noreplace\)/) {
 989                         $NF = "%config(noreplace) " $NF
 990                 }
 991
 992                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
 993                         gsub("^%attr\\(... *,", "%attr(640,");
 994                 }
 995
 996                 if (/\/etc\/sysconfig\// && !/%verify/) {
 997                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
 998                 }
 999         }
1000
1001         # kill leading zeros
1002         if (/%attr\(0[1-9]/) {
1003                 gsub("%attr\\(0", "%attr(")
1004         }
1005
1006         # sort %verify attrs
1007         if (match($0, /%verify\(not([^)]+)\)/)) {
1008                 t = substr($0, RSTART, RLENGTH)
1009                 gsub(/^%verify\(not |\)$/, "", t)
1010                 n = split(t, a, / /)
1011                 isort(a, n)
1012
1013                 s = "%verify(not"
1014                 for (i = 1 ; i <= n; i++) {
1015                         s = s " " a[i]
1016                 }
1017                 s = s ")"
1018
1019                 gsub(/%verify\(not[^)]+\)/, s)
1020         }
1021
1022         if (/%{_mandir}/) {
1023                 gsub("\.gz$", "*")
1024         }
1025
1026         # atrpms
1027         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1028         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1029         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1030
1031         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1032         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1033         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1034 }
1035
1036 function fill(ch, n, i) {
1037         for (i = 0; i < n; i++)
1038                 printf("%c", ch)
1039 }
1040
1041 function format_flush(line, indent, newline, word, first_word) {
1042         first_word = 1
1043         if (format_indent == -1)
1044                 newline = ""
1045         else
1046                 newline = fill(" ", format_indent) "- "
1047
1048         while (match(line, /[^\t ]+/)) {
1049                 word = substr(line, RSTART, RLENGTH)
1050                 if (length(newline) + length(word) + 1 > tw) {
1051                         print newline
1052
1053                         if (format_indent == -1)
1054                                 newline = ""
1055                         else
1056                                 newline = fill(" ", format_indent + 2)
1057                         first_word = 1
1058                 }
1059
1060                 if (first_word) {
1061                         newline = newline word
1062                         first_word = 0
1063                 } else
1064                         newline = newline " " word
1065
1066                 line = substr(line, RSTART + RLENGTH)
1067         }
1068         if (newline ~ /[^\t ]/) {
1069                 print newline
1070         }
1071 }
1072
1073 function cflags(var)
1074 {
1075         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1076                 removed[var] = 1
1077                 return 0
1078         }
1079
1080         if (!/!\?debug/)
1081                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1082         return 1
1083 }