adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # This is adapter v0.28. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2007 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Michał Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Jakub Bogusz <qboosh@pld-linux.org>
  14 #       Elan Ruusamäe <glen@pld-linux.org>
  15 #
  16 # See cvs log adapter{,.awk} for list of contributors
  17 #
  18 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  19
  20 # TODO
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27
  28 BEGIN {
  29         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  30         SECTIONS = "^%(" RPM_SECTIONS ")"
  31
  32         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests)"
  33
  34         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  35
  36         preamble = 1    # Is it part of preamble? Default - yes
  37         boc = 4                 # Beginning of %changelog
  38         bod = 0                 # Beginning of %description
  39         tw = 70                 # Descriptions width
  40
  41         b_idx = 0               # index of BR/R arrays
  42         BR_count = 0    # number of additional BuildRequires
  43
  44         # If variable removed, then 1 (for removing it from export)
  45         removed["LDFLAGS"] = 0
  46         removed["CFLAGS"] = 0
  47         removed["CXXFLAGS"] = 0
  48
  49         # get cvsaddress for changelog section
  50         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  51         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  52         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  53
  54         # If 1, we are inside of comment block (started with /^#%/)
  55         comment_block = 0
  56
  57         # File with rpm groups
  58         "rpm --eval %_sourcedir" | getline groups_file
  59         groups_file = groups_file "/rpm.groups"
  60         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  61         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  62
  63         # Temporary file for changelog section
  64         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  65
  66         # Load rpm macros
  67         "rpm --eval %_prefix"   | getline prefix
  68         "rpm --eval %_bindir"   | getline bindir
  69         "rpm --eval %_sbindir"  | getline sbindir
  70         "rpm --eval %_libdir"   | getline libdir
  71         "rpm --eval %_sysconfdir" | getline sysconfdir
  72         "rpm --eval %_datadir"  | getline datadir
  73         "rpm --eval %_includedir" | getline includedir
  74         "rpm --eval %_mandir"   | getline mandir
  75         "rpm --eval %_infodir"  | getline infodir
  76         "rpm --eval %_examplesdir"      | getline examplesdir
  77         "rpm --eval %_defaultdocdir"    | getline docdir
  78         "rpm --eval %_kdedocdir"        | getline kdedocdir
  79         "rpm --eval %_desktopdir" | getline desktopdir
  80         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  81
  82         "rpm --eval %perl_sitearch" | getline perl_sitearch
  83         "rpm --eval %perl_archlib" | getline perl_archlib
  84         "rpm --eval %perl_privlib" | getline perl_privlib
  85         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  86         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  87         "rpm --eval %perl_sitelib" | getline perl_sitelib
  88
  89         "rpm --eval %py_sitescriptdir 2>/dev/null" | getline py_sitescriptdir
  90         "rpm --eval %py_sitedir 2>/dev/null" | getline py_sitedir
  91         "rpm --eval %py_scriptdir 2>/dev/null" | getline py_scriptdir
  92
  93         "rpm --eval %ruby_archdir" | getline ruby_archdir
  94         "rpm --eval %ruby_ridir" | getline ruby_ridir
  95         "rpm --eval %ruby_rubylibdir" | getline ruby_rubylibdir
  96         "rpm --eval %ruby_sitearchdir" | getline ruby_sitearchdir
  97         "rpm --eval %ruby_sitelibdir" | getline ruby_sitelibdir
  98
  99         "rpm --eval %php_pear_dir" | getline php_pear_dir
 100         "rpm --eval %tmpdir" | getline tmpdir
 101 }
 102
 103 # There should be a comment with CVS keywords on the first line of file.
 104 FNR == 1 {
 105         if (!/# \$Revision:/)   # If this line is already OK?
 106                 print "# $" "Revision:$, " "$" "Date:$" # No
 107         else {
 108                 print $0                                # Yes
 109                 next            # It is enough for first line
 110         }
 111 }
 112
 113 # If the latest line matched /%files/
 114 defattr == 1 {
 115         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 116                 if ($0 !~ /defattr/) {  # If no %defattr
 117                         print "%defattr(644,root,root,755)"     # Add it
 118                 } else {
 119                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 120                 }
 121         }
 122         defattr = 0
 123 }
 124
 125 function b_makekey(a, b,        s) {
 126         s = a "" b;
 127         # kill bcond
 128         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 129
 130         # kill commented out items
 131         gsub(/^#[ \t]*/, "", s);
 132
 133         # force order
 134         gsub(/^Summary\(/, "11Summary(", s);
 135         gsub(/^Summary/, "10Summary", s);
 136         gsub(/^Name/, "2Name", s);
 137         gsub(/^Version/, "3Version", s);
 138         gsub(/^Release/, "4Release", s);
 139         gsub(/^Epoch/, "5Epoch", s);
 140         gsub(/^License/, "5License", s);
 141         gsub(/^Group/, "6Group", s);
 142         gsub(/^URL/, "7URL", s);
 143
 144         gsub(/^BuildRequires/, "B1BuildRequires", s);
 145         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 146
 147         gsub(/^Suggests/, "X1Suggests", s);
 148         gsub(/^Provides/, "X2Provides", s);
 149         gsub(/^Obsoletes/, "X3Obsoletes", s);
 150         gsub(/^Conflicts/, "X4Conflicts", s);
 151         gsub(/^BuildArch/, "X5BuildArch", s);
 152         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 153         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 154         gsub(/^BuildRoot/, "X9BuildRoot", s);
 155
 156 #       printf("%s -> %s\n", a""b, s);
 157         return s;
 158 }
 159
 160 # Comments
 161 /^#/ && (description == 0) {
 162         if (/This file does not like to be adapterized!/) {
 163                 print                   # print this message
 164                 while (getline)         # print the rest of spec as it is
 165                         print
 166                 do_not_touch_anything = 1 # do not touch anything in END()
 167                 exit 0
 168         }
 169
 170         # Generally, comments are printed without touching
 171         sub(/[ \t]+$/, "")
 172
 173         if (/#[ \t]*Source.*md5/) {
 174                 if (usedigest == 1) {
 175                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 176                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 177                 }
 178                 print $0
 179                 next
 180         }
 181 }
 182
 183 /^%define/ {
 184         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 185         if ($2 == "_applnkdir") {
 186                 next
 187         }
 188         if ($2 == "date") {
 189                 date = 1
 190                 if (did_files == 0) {
 191                         print "%files"
 192                         print ""
 193                         did_files = 1
 194                 }
 195         }
 196
 197         # Do not add %define of _prefix if it already is.
 198         if ($2 ~ /^_prefix/) {
 199                 sub("^"prefix, $3, bindir)
 200                 sub("^"prefix, $3, sbindir)
 201                 sub("^"prefix, $3, libdir)
 202                 sub("^"prefix, $3, datadir)
 203                 sub("^"prefix, $3, includedir)
 204                 prefix = $3
 205         }
 206
 207         if ($2 ~ /_bindir/ && !/_sbindir/)
 208                 bindir = $3
 209         if ($2 ~ /_sbindir/)
 210                 sbindir = $3
 211         if ($2 ~ /_libdir/) {
 212                 if ($3 ~ /^%\(/) {
 213                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 214                         libdir = "%%%%%%%%%%%%%%"
 215                 } else {
 216                         libdir = $3
 217                 }
 218         }
 219         if ($2 ~ /_sysconfdir/) {
 220                 if ($3 ~ /^%\(/) {
 221                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 222                         sysconfdir = "%%%%%%%%%%%%%%"
 223                 } else {
 224                         sysconfdir = $3
 225                 }
 226         }
 227         if ($2 ~ /_datadir/) {
 228                 if ($3 ~ /^%\(/) {
 229                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 230                         datadir = "%%%%%%%%%%%%%%"
 231                 } else {
 232                         datadir = $3
 233                 }
 234         }
 235         if ($2 ~ /_includedir/)
 236                 includedir = $3
 237         if ($2 ~ /_mandir/)
 238                 mandir = $3
 239         if ($2 ~ /_infodir/)
 240                 infodir = $3
 241         if ($2 ~ /_docdir/)
 242                 docdir = $3
 243
 244         # version related macros
 245         if ($2 ~ /^_beta$/)
 246                 _beta = $3
 247         if ($2 ~ /^_rc$/)
 248                 _rc = $3
 249         if ($2 ~ /^_pre$/)
 250                 _pre = $3
 251         if ($2 ~ /^_snap$/)
 252                 _snap = $3
 253
 254         # these are used usually when adapterizing external spec
 255         if ($2 ~ /^name$/)
 256                 name = $3
 257         if ($2 ~ /^version$/)
 258                 version = $3
 259         if ($2 ~ /^release$/)
 260                 release = $3
 261
 262         if ($2 ~ /^mod_name$/)
 263                 mod_name = $3
 264
 265         sub(/[ \t]+$/, "");
 266         # do nothing further, otherwise adapter thinks we're at preamble
 267         print
 268         next
 269 }
 270
 271 # Obsolete
 272 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 273         next
 274 }
 275
 276 ################
 277 # %description #
 278 ################
 279 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 280         preamble = 0
 281
 282         if (/^%description/) {
 283                 bod++
 284                 format_line = ""
 285                 format_indent = -1
 286         }
 287
 288         # Format description
 289         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 290                 if (/^[ \t]*$/) {
 291                         format_flush(format_line, format_indent)
 292                         print ""
 293                         format_line = ""
 294                         format_indent = -1
 295                 } else if (/^[ \t]*[-\*][ \t]*/) {
 296                         format_flush(format_line, format_indent)
 297                         match($0, /^[ \t]*/)
 298                         format_indent = RLENGTH
 299                         match($0, /^[ \t]*[-\*][ \t]/)
 300                         format_line = substr($0, RLENGTH)
 301                 } else
 302                         format_line = format_line " " $0
 303                 next
 304         }
 305
 306         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 307                 if (NF > 3 && $2 == "-l") {
 308                         ll = $1
 309                         for (i = 4; i <= NF; i++)
 310                                 ll = ll " " $i
 311                         $0 = ll " -l " $3
 312                 }
 313                 format_flush(format_line, format_indent)
 314                 if (bod == 2) {
 315                         bod = 1
 316                         description = 1
 317                 } else {
 318                         bod = 0
 319                         description = 0
 320                 }
 321         } else
 322                 description = 1
 323 }
 324
 325 #########
 326 # %prep #
 327 #########
 328 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 329         preamble = 0
 330         did_prep = 1
 331
 332         use_macros()
 333
 334         # Add '-q' to %setup
 335         if (/^%setup/ && !/-q/) {
 336                 sub(/^%setup/, "%setup -q")
 337         }
 338
 339         if (/^%setup/ && name != "setup") {
 340                 $0 = fixedsub(name, "%{name}", $0);
 341                 $0 = fixedsub(version, "%{version}", $0);
 342                 if (_beta) {
 343                         $0 = fixedsub(_beta, "%{_beta}", $0);
 344                 }
 345                 if (_rc) {
 346                         $0 = fixedsub(_rc, "%{_rc}", $0);
 347                 }
 348                 if (_pre) {
 349                         $0 = fixedsub(_pre, "%{_pre}", $0);
 350                 }
 351                 if (_snap) {
 352                         $0 = fixedsub(_snap, "%{_snap}", $0);
 353                 }
 354         }
 355
 356         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 357                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 358         }
 359         sub("^%patch ", "%patch0 ");
 360
 361         # invalid in %prep
 362         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 363 }
 364
 365 ##########
 366 # %build #
 367 ##########
 368 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 369         preamble = 0
 370
 371         if (did_prep == 0) {
 372                 print "%prep"
 373                 print ""
 374                 did_prep = 1
 375         }
 376
 377         use_macros()
 378         use_tabs()
 379
 380         if (/^automake$/)
 381                 sub(/$/, " -a -c")
 382
 383         if (/LDFLAGS/) {
 384                 if (/LDFLAGS="-s"/) {
 385                         removed["LDFLAGS"] = 1
 386                         next
 387                 } else {
 388                         split($0, tmp, "LDFLAGS=")
 389                         count = split(tmp[2], flags, "\"")
 390                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 391                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 392                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 393                                 for (i = 2; i < count; i++)
 394                                         $0 = $0 flags[i] "\""
 395                         }
 396                 }
 397         }
 398
 399         if (/CFLAGS=/)
 400                 if (cflags("CFLAGS") == 0)
 401                         next
 402
 403         if (/CXXFLAGS=/)
 404                 if (cflags("CXXFLAGS") == 0)
 405                         next
 406
 407         if (/^export /) {
 408                 if (removed["LDFLAGS"])
 409                         sub(" LDFLAGS", "")
 410                 if (removed["CFLAGS"])
 411                         sub(" CFLAGS", "")
 412                 if (removed["CXXFLAGS"])
 413                         sub(" CXXFLAGS", "")
 414                 # Is there still something?
 415                 if (/^export[ ]*$/)
 416                         next
 417         }
 418
 419         # quote CC
 420         if (/CC=%{__cc} /) {
 421                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 422         }
 423
 424         # use PLD Linux macros
 425         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 426         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 427         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 428         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 429         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 430         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 431         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 432         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 433
 434         sub(/^aclocal$/, "%{__aclocal}");
 435         sub(/^autoheader$/, "%{__autoheader}");
 436         sub(/^autoconf$/, "%{__autoconf}");
 437         sub(/^automake$/, "%{__automake}");
 438         sub(/^libtoolize$/, "%{__libtoolize}");
 439
 440         # atrpms
 441         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 442         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 443 }
 444
 445 ##########
 446 # %clean #
 447 ##########
 448 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 449         did_clean = 1
 450
 451         use_macros()
 452 }
 453
 454 ############
 455 # %install #
 456 ############
 457 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 458
 459         preamble = 0
 460
 461         # foreign rpms
 462         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 463         sub("%buildroot", "$RPM_BUILD_ROOT");
 464         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 465
 466         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 467                 did_rmroot=1
 468                 print "rm -rf $RPM_BUILD_ROOT"
 469                 next
 470         }
 471
 472         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 473                 print "rm -rf $RPM_BUILD_ROOT"
 474                 did_rmroot=1
 475         }
 476
 477         if (tmpdir) {
 478                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 479                 gsub(buildroot, "$RPM_BUILD_ROOT")
 480         }
 481
 482         if (!/%{_lib}/) {
 483                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 484         }
 485
 486         use_macros()
 487
 488         # 'install -d' instead 'mkdir -p'
 489         if (/mkdir -p/)
 490                 sub(/mkdir -p/, "install -d")
 491
 492         # cp -a already implies cp -r
 493         sub(/^cp -ar/, "cp -a")
 494
 495         # No '-u root' or '-g root' for 'install'
 496         if (/^install/ && /-[ug][ \t]*root/)
 497                 gsub(/-[ug][ \t]*root /, "")
 498
 499         if (/^install/ && /-m[ \t]*[0-9]+/)
 500                 gsub(/-m[ \t]*[0-9]+ /, "")
 501
 502         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 503         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 504                 next
 505
 506         # No lines contain 'chmod' if it sets the modes to '644'
 507         if ($1 ~ /chmod/ && $2 ~ /644/)
 508                 next
 509
 510         # atrpms
 511         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 512 }
 513
 514 ##########
 515 # %files #
 516 ##########
 517 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 518         preamble = 0
 519         did_files = 1
 520
 521         if ($0 ~ /^%files/)
 522                 defattr = 1
 523
 524         use_files_macros()
 525 }
 526
 527 ##############
 528 # %changelog #
 529 ##############
 530 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 531         preamble = 0
 532         has_changelog = 1
 533         skip = 0
 534         # There should be some CVS keywords on the first line of %changelog.
 535         if (boc == 3) {
 536                 if ($0 !~ _cvsmailfeedback) {
 537                         print "* %{date} " _cvsmailfeedback > changelog_file
 538                 } else {
 539                         skip = 1
 540                 }
 541                 boc = 2
 542         }
 543         if (boc == 2 && !skip) {
 544                 if (!/All persons listed below/) {
 545                         printf "All persons listed below can be reached at " > changelog_file
 546                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 547                 } else {
 548                         skip = 1
 549                 }
 550                 boc = 1
 551         }
 552         if (boc == 1 && !skip) {
 553                 if (!/^$/) {
 554                         if (!/\$.*Log:.*\$/) {
 555                                 print "$" "Log:$" > changelog_file
 556                         }
 557                         boc = 0
 558                 }
 559         }
 560         # Define date macro.
 561         if (boc == 4) {
 562                 if (date == 0) {
 563                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 564                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 565                         date = 1
 566                 }
 567                 boc = 3
 568         }
 569
 570         sub(/[ \t]+$/, "");
 571         if (!/^%[a-z]+$/ || /changelog/) {
 572                 # stop changelog if "real" changelog starts
 573                 if (boc == 0 && /^\* /) {
 574                         boc = -1
 575                 }
 576                 if (boc == -1) {
 577                         next;
 578                 }
 579                 print > changelog_file
 580         } else {
 581                 print
 582         }
 583         next
 584 }
 585
 586 ###########
 587 # SCRIPTS #
 588 ###########
 589 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 590         preamble = 0
 591
 592         if (gsub("/usr/sbin/useradd", "%useradd")) {
 593                 sub(" 2> /dev/null \|\| :", "");
 594                 sub(" >/dev/null 2>&1 \|\|:", "");
 595         }
 596
 597         # %useradd and %groupadd may not be wrapped
 598         if (/%(useradd|groupadd).*\\$/) {
 599                 a = $0; getline;
 600                 sub(/^[\s\t]*/, "");
 601                 $0 = substr(a, 1, length(a) - 1) $0;
 602         }
 603         use_script_macros()
 604 }
 605
 606 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 607         preamble = 0
 608         use_macros()
 609 }
 610 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 611         preamble = 0
 612         use_macros()
 613 }
 614 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 615         preamble = 0
 616         use_script_macros()
 617 }
 618 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 619         preamble = 0
 620         use_script_macros()
 621 }
 622 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 623         preamble = 0
 624         use_script_macros()
 625 }
 626 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 627         preamble = 0
 628         use_script_macros()
 629 }
 630 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 631         preamble = 0
 632         use_script_macros()
 633 }
 634 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 635         preamble = 0
 636         use_script_macros()
 637 }
 638 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 639         preamble = 0
 640         use_script_macros()
 641 }
 642 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 643         preamble = 0
 644         use_script_macros()
 645 }
 646
 647 #############
 648 # PREAMBLES #
 649 #############
 650 preamble == 1 {
 651         # There should not be a space after the name of field
 652         # and before the colon.
 653         sub(/[ \t]*:/, ":")
 654
 655         if (/^%perl_module_wo_prefix/) {
 656                 name = $2
 657                 version = $3
 658                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 659         }
 660
 661         field = tolower($1)
 662         fieldnlower = $1
 663         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 664                 sub(/\.$/, "", $0);
 665         }
 666         if (field ~ /group(\([^)]+\)):/)
 667                 next
 668         if (field ~ /group:/) {
 669                 format_preamble()
 670                 group = $0;
 671                 sub(/^[^ \t]*[ \t]*/, "", group);
 672
 673                 sub(/^Utilities\//,"Applications/", group)
 674                 sub(/^Games/,"Applications/Games", group)
 675                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 676                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 677                 sub(/^Development\/Other/,"Development", group)
 678                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 679                 sub(/^X11\/GNOME/,"X11/Applications", group)
 680                 sub(/^X11\/Utilities/,"X11/Applications", group)
 681                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 682                 sub(/^Amusements\/Games\/Strategy\/Real Time/, "X11/Applications/Games/Strategy", group)
 683                 sub(/^X11\/Library/,"X11/Libraries", group)
 684                 sub(/^Shells/,"Applications/Shells", group)
 685                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 686                 sub(/^Library\/Development$/, "Development/Libraries", group)
 687                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 688                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 689                 sub(/^Applications\/Daemons$/, "Daemons", group)
 690                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 691                 sub(/^System\/Servers$/, "Daemons", group)
 692                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 693                 sub(/^X11\/XFree86/, "X11", group)
 694                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 695                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 696                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 697                 sub(/^Development\/Docs$/, "Documentation", group)
 698                 sub(/^Development\/Documentation$/, "Documentation", group)
 699                 sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
 700                 sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
 701                 sub(/^Development\/Java/, "Development/Languages/Java", group)
 702                 sub(/^Development\/Testing$/, "Development", group)
 703                 sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
 704                 sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
 705                 sub(/^Web\/Database$/, "Applications/WWW", group)
 706                 sub(/^System Environment\/Base$/, "Base", group)
 707                 sub(/^System$/, "Base", group)
 708                 sub(/^Applications\/Productivity$/, "X11/Applications", group)
 709                 sub(/^Database$/, "Applications/Databases", group)
 710                 sub(/^Development\/Code Generators$/, "Development", group)
 711                 sub(/^Emulators$/, "Applications/Emulators", group)
 712                 sub(/^System\/Libraries$/, "Libraries", group)
 713                 sub(/^Development\/Libraries\/C and C\+\+$/, "Development/Libraries", group)
 714
 715                 $0 = "Group:\t\t" group
 716
 717                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 718                         x11 = 1
 719
 720                 byl_plik_z_groupmi = 0
 721                 byl_opis_grupy = 0
 722                 while ((getline linia_grup < groups_file) > 0) {
 723                         byl_plik_z_groupmi = 1
 724                         if (linia_grup == group) {
 725                                 byl_opis_grupy = 1
 726                                 break
 727                         }
 728                 }
 729
 730                 if (!byl_plik_z_groupmi)
 731                         print "######\t\t" groups_file ": no such file"
 732                 else if (!byl_opis_grupy)
 733                         print "######\t\t" "Unknown group!"
 734
 735                 close(groups_file)
 736                 did_groups = 1
 737         }
 738
 739         if (field ~ /prereq:/) {
 740                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 741         }
 742
 743         # split (build)requires, obsoletes on commas
 744         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 745                 value = substr($0, index($0, $2));
 746                 $0 = format_requires($1, value);
 747         }
 748
 749         # BR: tar (and others) is to common (rpm-build requires it)
 750         if (field ~ /^buildrequires:/) {
 751                 l = substr($0, index($0, $2));
 752                 if (l == "awk" ||
 753                         l == "binutils" ||
 754                         l == "bzip2" ||
 755                         l == "cpio" ||
 756                         l == "diffutils" ||
 757                         l == "elfutils" ||
 758                         l == "fileutils" ||
 759                         l == "findutils" ||
 760                         l == "glibc-devel" ||
 761                         l == "grep" ||
 762                         l == "gzip" ||
 763                         l == "make" ||
 764                         l == "patch" ||
 765                         l == "sed" ||
 766                         l == "sh-utils" ||
 767                         l == "tar" ||
 768                         l == "textutils") {
 769                         next
 770                 }
 771
 772                 replace_requires();
 773         }
 774
 775         if (field ~ /^requires:/) {
 776                 replace_requires();
 777         }
 778
 779
 780         # obsolete/unwanted tags
 781         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 782                 next
 783         }
 784
 785         if (field ~ /buildroot:/) {
 786                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 787                 did_build_root = 1
 788         }
 789
 790         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 791         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 792                 $1 = "License:"
 793         }
 794
 795         if (field ~ /license:/) {
 796                 l = substr($0, index($0, $2));
 797                 if (l == "Python Software Foundation License") {
 798                         l = "PSF"
 799                 }
 800                 $0 = "License:\t" l;
 801         }
 802
 803
 804         if (field ~ /name:/) {
 805                 if ($2 == "%{name}" && name) {
 806                         $2 = name
 807                 }
 808                 name = $2
 809                 name_seen = 1;
 810         }
 811
 812         if (field ~ /version:/) {
 813                 if ($2 == "%{version}" && version) {
 814                         $2 = version
 815                 }
 816                 version = $2
 817                 version_seen = 1;
 818         }
 819
 820         if (field ~ /release:/) {
 821                 if ($2 == "%{release}" && release) {
 822                         $2 = release
 823                 }
 824                 sub(/%atrelease /, "0.", $0)
 825                 release = $2
 826                 release_seen = 1;
 827         }
 828
 829
 830         if (field ~ /serial:/)
 831                 $1 = "Epoch:"
 832
 833         if (field ~ /home-page:/)
 834                 $1 = "URL:"
 835
 836         # proper caps
 837         if (field ~ /^url:$/)
 838                 $1 = "URL:"
 839
 840         if (field ~ /^description:$/)
 841                 $1 = "\n%description\n"
 842
 843         # Use %{name} and %{version} in the filenames in "Source:"
 844         if (field ~ /^source/ || field ~ /patch/) {
 845                 n = split($2, url, /\//)
 846                 if (url[n] ~ /\.gz$/) {
 847                         url[n+1] = ".gz" url[n+1]
 848                         sub(/\.gz$/,"",url[n])
 849                 }
 850                 if (url[n] ~ /\.zip$/) {
 851                         url[n+1] = ".zip" url[n+1]
 852                         sub(/\.zip$/,"",url[n])
 853                 }
 854                 if (url[n] ~ /\.tar$/) {
 855                         url[n+1] = ".tar" url[n+1]
 856                         sub(/\.tar$/,"",url[n])
 857                 }
 858                 if (url[n] ~ /\.patch$/) {
 859                         url[n+1] = ".patch" url[n+1]
 860                         sub(/\.patch$/,"",url[n])
 861                 }
 862                 if (url[n] ~ /\.bz2$/) {
 863                         url[n+1] = ".bz2" url[n+1]
 864                         sub(/\.bz2$/,"",url[n])
 865                 }
 866                 if (url[n] ~ /\.logrotate$/) {
 867                         url[n+1] = ".logrotate" url[n+1]
 868                         sub(/\.logrotate$/,"",url[n])
 869                 }
 870                 if (url[n] ~ /\.pamd$/) {
 871                         url[n+1] = ".pamd" url[n+1]
 872                         sub(/\.pamd$/,"",url[n])
 873                 }
 874
 875                 # allow %{name} only in last url component
 876                 s = ""
 877                 for (i = 1; i <= n; i++) {
 878                         url[i] = fixedsub("%{name}", name, url[i])
 879                         if (s) {
 880                                 s = s "/" url[i]
 881                         } else {
 882                                 s = url[i]
 883                         }
 884                 }
 885                 $2 = s url[n+1]
 886
 887                 filename = url[n]
 888                 if (name) {
 889                         url[n] = fixedsub(name, "%{name}", url[n])
 890                 }
 891                 if (field ~ /source/) {
 892                         if (version) {
 893                                 url[n] = fixedsub(version, "%{version}", url[n])
 894                         }
 895                         if (_beta) {
 896                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 897                         }
 898                         if (_rc) {
 899                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 900                         }
 901                         if (_pre) {
 902                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 903                         }
 904                         if (_snap) {
 905                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 906                         }
 907                 }
 908                 # assigning to $2 kills preamble formatting
 909                 $2 = fixedsub(filename, url[n], $2)
 910
 911                 # sourceforge urls
 912                 sub("[?&]big_mirror=.*$", "", $2);
 913                 sub("[?&]modtime=.*$", "", $2);
 914
 915                 sub("[?]use_mirror=.*$", "", $2);
 916                 sub("[?]download$", "", $2);
 917
 918                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 919                 sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", $2)
 920                 sub("^http://download\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 921                 sub("^http://downloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 922
 923                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 924                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 925                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 926
 927                 sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", $2)
 928                 sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", $2)
 929
 930                 # apache urls
 931                 sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", $2)
 932         }
 933
 934
 935         if (field ~ /^source:/)
 936                 $1 = "Source0:"
 937
 938         if (field ~ /^patch:/)
 939                 $1 = "Patch0:"
 940
 941         kill_preamble_macros();
 942         format_preamble()
 943
 944         if (field ~ /requires/) {
 945                 # atrpms
 946                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 947         }
 948 }
 949
 950 /^%bcond_/ {
 951         # do nothing
 952         print
 953         next
 954 }
 955
 956 # sort BR/R!
 957 #
 958 # NOTES:
 959 # - mixing BR/R and anything else confuses this (all will be sorted together)
 960 #       so don't do that.
 961 # - comments leading the BR/R can not be associated,
 962 #       so don't adapterize when the BR/R are mixed with comments
 963 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 964         if ($1 ~ /Pre[Rr]eq:/) {
 965                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 966         }
 967         if ($1 == "BR:" ) {
 968                 $1 = "BuildRequires:"
 969         }
 970         if ($1 == "R:" ) {
 971                 $1 = "Requires:"
 972         }
 973         format_preamble()
 974 #       kill_preamble_macros(); # breaks tabbing
 975
 976         b_idx++;
 977         l = substr($0, index($0, $2));
 978         b_ktmp = b_makekey($1, l);
 979         b_key[b_idx] = b_ktmp;
 980         b_val[b_ktmp] = $0;
 981
 982         next;
 983 }
 984
 985 preamble == 1 {
 986         if (b_idx > 0) {
 987                 isort(b_key, b_idx);
 988                 for (i = 1; i <= b_idx; i++) {
 989                         v = b_val[b_key[i]];
 990                         sub(/[ \t]+$/, "", v);
 991                         print "" v;
 992                 }
 993                 b_idx = 0
 994         }
 995 }
 996
 997 # main() ;-)
 998 {
 999         preamble = 1
1000
1001         sub(/[ \t]+$/, "")
1002         print
1003
1004         if (name_seen == 0 && name) {
1005                 print "Name:\t\t" name
1006                 name_seen = 1
1007         }
1008
1009         if (version_seen == 0 && version) {
1010                 print "Version:\t" version
1011                 version_seen = 1
1012         }
1013
1014         if (release_seen == 0 && release) {
1015                 print "Release:\t" release
1016                 release_seen = 1
1017         }
1018
1019         if (did_build_root == 0) {
1020 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
1021                 did_build_root = 1
1022         }
1023         if (did_groups == 0) {
1024 #               print "Group:\t\tunknown"
1025                 did_groups = 1
1026         }
1027 }
1028
1029
1030 END {
1031         if (do_not_touch_anything)
1032                 exit 0
1033
1034         # TODO: need to output these in proper place
1035         if (BR_count > 0) {
1036                 for (i = 0; i <= BR_count; i++) {
1037                         print BR[i];
1038                 }
1039         }
1040
1041         close(changelog_file)
1042         while ((getline < changelog_file) > 0)
1043                 print
1044         system("rm -f " changelog_file)
1045
1046         if (did_clean == 0) {
1047                 print ""
1048                 print "%clean"
1049                 print "rm -rf $RPM_BUILD_ROOT"
1050         }
1051
1052         if (date == 0) {
1053                 print ""
1054                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1055         }
1056
1057         if (has_changelog == 0) {
1058                 print "%changelog"
1059         }
1060
1061         if (boc > 2) {
1062                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1063         }
1064         if (boc > 1) {
1065                 printf "All persons listed below can be reached at "
1066                 print "<cvs_login>@pld-linux.org\n"
1067         }
1068         if (boc > 0) {
1069                 print "$" "Log:$"
1070         }
1071 }
1072
1073 function fixedsub(s1,s2,t, ind) {
1074 # substitutes fixed strings (not regexps)
1075         if (ind = index(t,s1))
1076                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1077         return t
1078 }
1079
1080 # There should be one or two tabs after the colon.
1081 function format_preamble()
1082 {
1083         if (/^#/ || /^%bcond_with/) {
1084                 return;
1085         }
1086         sub(/:[ \t]*/, ":")
1087         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1088                 if (RLENGTH < 8) {
1089                         sub(/:/, ":\t\t")
1090                 } else {
1091                         sub(/:/, ":\t")
1092                 }
1093         }
1094 }
1095
1096 # Replace directly specified directories with macros
1097 function use_macros()
1098 {
1099         # -m, --skip-macros, --no-macros -- skip macros subst
1100         if (ENVIRON["SKIP_MACROS"]) {
1101                 return
1102         }
1103
1104         # leave inline sed lines alone
1105         if (/(%{__sed}|sed) -i -e/) {
1106                 return;
1107         }
1108
1109         sub("%{_defaultdocdir}", "%{_docdir}");
1110         sub("%{_bindir}/perl", "%{__perl}");
1111         sub("%{_bindir}/python", "%{__python}");
1112
1113         gsub(infodir, "%{_infodir}")
1114
1115         gsub(perl_sitearch, "%{perl_sitearch}")
1116         gsub(perl_archlib, "%{perl_archlib}")
1117         gsub(perl_privlib, "%{perl_privlib}")
1118         gsub(perl_vendorlib, "%{perl_vendorlib}")
1119         gsub(perl_vendorarch, "%{perl_vendorarch}")
1120         gsub(perl_sitelib, "%{perl_sitelib}")
1121
1122         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1123         gsub(py_sitedir, "%{py_sitedir}")
1124         gsub(py_scriptdir, "%{py_scriptdir}")
1125         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1126         gsub("%{python_sitelib}", "%{py_sitedir}")
1127
1128         gsub(ruby_archdir, "%{ruby_archdir}")
1129         gsub(ruby_ridir, "%{ruby_ridir}")
1130         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1131         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1132         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1133
1134         gsub("%{_datadir}/applications", "%{_desktopdir}")
1135         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1136
1137         gsub(libdir, "%{_libdir}")
1138
1139         gsub(bindir, "%{_bindir}")
1140         gsub("%{prefix}/bin", "%{_bindir}")
1141         if (prefix"/bin" == bindir)
1142                 gsub("%{_prefix}/bin", "%{_bindir}")
1143
1144         for (c = 1; c <= NF; c++) {
1145                 if ($c ~ sbindir "/fix-info-dir")
1146                         continue;
1147                 if ($c ~ sbindir "/webapp")
1148                         continue;
1149                 if ($c ~ sbindir "/ldconfig")
1150                         continue;
1151                 if ($c ~ sbindir "/chsh")
1152                         continue;
1153                 if ($c ~ sbindir "/usermod")
1154                         continue;
1155                 if ($c ~ sbindir "/chkconfig")
1156                         continue;
1157                 if ($c ~ sbindir "/installzope(product|3package)")
1158                         continue;
1159                 gsub(sbindir, "%{_sbindir}", $c)
1160         }
1161
1162         gsub("%{prefix}/sbin", "%{_sbindir}")
1163         if (prefix"/sbin" == sbindir) {
1164                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1165         }
1166
1167         for (c = 1; c <= NF; c++) {
1168                 if ($c ~ sysconfdir "/{?cron.")
1169                         continue;
1170                 if ($c ~ sysconfdir "/{?crontab.d")
1171                         continue;
1172                 if ($c ~ sysconfdir "/{?env.d")
1173                         continue;
1174                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1175                         continue;
1176                 if ($c ~ sysconfdir "/{?udev/rules.d")
1177                         continue;
1178                 if ($c ~ sysconfdir "/{?logrotate.d")
1179                         continue;
1180                 if ($c ~ sysconfdir "/{?pam.d")
1181                         continue;
1182                 if ($c ~ sysconfdir "/{?profile.d")
1183                         continue;
1184                 if ($c ~ sysconfdir "/{?rc.d")
1185                         continue;
1186                 if ($c ~ sysconfdir "/{?security")
1187                         continue;
1188                 if ($c ~ sysconfdir "/{?skel")
1189                         continue;
1190                 if ($c ~ sysconfdir "/{?sysconfig")
1191                         continue;
1192                 if ($c ~ sysconfdir "/{?shrc.d")
1193                         continue;
1194                 if ($c ~ sysconfdir "/{?certs")
1195                         continue;
1196                 if ($c ~ sysconfdir "/{?X11")
1197                         continue;
1198                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1199                         continue;
1200                 if ($c ~ sysconfdir "/{?rpm")
1201                         continue;
1202                 if ($c ~ sysconfdir "/{?bash_completion.d")
1203                         continue;
1204                 if ($c ~ sysconfdir "/{?samba")
1205                         continue;
1206                 if ($c ~ sysconfdir "/shells")
1207                         continue;
1208                 if ($c ~ sysconfdir "/ppp")
1209                         continue;
1210                 if ($c ~ sysconfdir "/dbus-1")
1211                         continue;
1212                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1213         }
1214
1215         gsub(kdedocdir, "%{_kdedocdir}")
1216         gsub(docdir, "%{_docdir}")
1217         gsub(php_pear_dir, "%{php_pear_dir}")
1218
1219         for (c = 1; c <= NF; c++) {
1220                 if ($c ~ datadir "/automake")
1221                         continue;
1222                 if ($c ~ datadir "/unsermake")
1223                         continue;
1224                 if ($c ~ datadir "/file/magic.mime")
1225                         continue;
1226                 gsub(datadir, "%{_datadir}", $c)
1227         }
1228
1229         gsub("%{prefix}/share", "%{_datadir}")
1230         if (prefix"/share" == datadir)
1231                 gsub("%{_prefix}/share", "%{_datadir}")
1232
1233         # CFLAGS="-I/usr/include/ncurses is usually correct.
1234         if (!/-I\/usr\/include/) {
1235                 gsub(includedir, "%{_includedir}")
1236         }
1237
1238         gsub("%{prefix}/include", "%{_includedir}")
1239         if (prefix"/include" == includedir) {
1240                 gsub("%{_prefix}/include", "%{_includedir}")
1241         }
1242
1243         gsub(mandir, "%{_mandir}")
1244         if ($0 !~ "%{_datadir}/manual") {
1245                 gsub("%{_datadir}/man", "%{_mandir}")
1246         }
1247         gsub("%{_prefix}/share/man", "%{_mandir}")
1248         gsub("%{prefix}/share/man", "%{_mandir}")
1249         gsub("%{prefix}/man", "%{_mandir}")
1250         gsub("%{_prefix}/man", "%{_mandir}")
1251
1252         gsub(infodir, "%{_infodir}")
1253         gsub("%{prefix}/info", "%{_infodir}")
1254         gsub("%{_prefix}/info", "%{_infodir}")
1255
1256         if (prefix !~ "/X11R6") {
1257                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1258         }
1259
1260         gsub(examplesdir, "%{_examplesdir}")
1261
1262         if (prefix != "/") {
1263                 # leave --with-foo=/usr alone
1264                 if ($0 !~ "--with.*=.*" prefix) {
1265                         for (c = 1; c <= NF; c++) {
1266                                 if ($c ~ prefix "/sbin/fix-info-dir")
1267                                         continue;
1268                                 if ($c ~ prefix "/sbin/webapp")
1269                                         continue;
1270                                 if ($c ~ prefix "/sbin/chsh")
1271                                         continue;
1272                                 if ($c ~ prefix "/sbin/usermod")
1273                                         continue;
1274                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1275                                         continue;
1276                                 if ($c ~ prefix "/share/automake")
1277                                         continue;
1278                                 if ($c ~ prefix "/share/unsermake")
1279                                         continue;
1280                                 if ($c ~ prefix "/lib/sendmail")
1281                                         continue;
1282                                 if ($c ~ prefix "/lib/pkgconfig")
1283                                         continue;
1284
1285                                 # CFLAGS="-I/usr..." is usually correct.
1286                                 if (/-I\/usr/)
1287                                         continue;
1288                                 # same for LDFLAGS="-L/usr..."
1289                                 if (/-L\/usr/)
1290                                         continue;
1291
1292                                 gsub(prefix, "%{_prefix}", $c)
1293                         }
1294                 }
1295                 gsub("%{prefix}", "%{_prefix}")
1296         }
1297
1298         # replace back
1299         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1300         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1301
1302         gsub("%{PACKAGE_VERSION}", "%{version}")
1303         gsub("%{PACKAGE_NAME}", "%{name}")
1304
1305         gsub("^make$", "%{__make}")
1306         gsub("^make ", "%{__make} ")
1307         gsub("^gcc ", "%{__cc} ")
1308
1309         # mandrake specs
1310         gsub("^%make$", "%{__make}")
1311         gsub("^%make ", "%{__make} ")
1312         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1313         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1314         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1315         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1316         gsub("^%{__install}", "install")
1317         gsub("^%{__rm}", "rm")
1318         gsub("%optflags", "%{rpmcflags}")
1319         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1320
1321         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1322         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1323         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1324         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1325         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1326         $0 = fixedsub("%__install", "install", $0);
1327
1328         # split configure line to multiple lines
1329         if (/%configure / && !/\\$/) {
1330                 $0 = format_configure($0);
1331         }
1332
1333         gsub("%_bindir", "%{_bindir}")
1334         gsub("%_datadir", "%{_datadir}")
1335         gsub("%_iconsdir", "%{_iconsdir}")
1336         gsub("%_sbindir", "%{_sbindir}")
1337         gsub("%_mandir", "%{_mandir}")
1338         gsub("%name", "%{name}")
1339         gsub(/%__rm/, "rm");
1340         gsub(/%__mkdir_p/, "install -d");
1341         gsub(/%__cp/, "cp");
1342         gsub(/%__ln_s/, "ln -s");
1343         gsub(/%__sed/, "%{__sed}");
1344         gsub(/%__cat/, "cat");
1345         gsub(/%__chmod/, "chmod");
1346
1347         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1348         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1349
1350         if (/^ant /) {
1351                 sub(/^ant/, "%ant")
1352                 add_br("BuildRequires:  jpackage-utils");
1353                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1354         }
1355
1356 }
1357
1358 function format_configure(line,         n, a, s) {
1359         n = split(line, a, / /);
1360         s = a[1] " \\\n";
1361         for (i = 2; i <= n; i++) {
1362                 s = s "\t" a[i] " \\\n"
1363         }
1364         return s
1365 }
1366
1367
1368 # insertion sort of A[1..n]
1369 # copied from mawk manual
1370 function isort(A,n,             i,j,hold) {
1371         for (i = 2; i <= n; i++) {
1372                 hold = A[j = i]
1373                 while (A[j-1] > hold) {
1374                         j-- ; A[j+1] = A[j]
1375                 }
1376                 A[j] = hold
1377         }
1378         # sentinel A[0] = "" will be created if needed
1379 }
1380
1381
1382 function use_files_macros(      i, n, t, a)
1383 {
1384         use_macros()
1385
1386         # skip comments
1387         if (/^#/) {
1388                 return;
1389         }
1390
1391         sub("^%doc %{_mandir}", "%{_mandir}")
1392
1393         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1394         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1395
1396         # uid/gid nobody is not valid in %files
1397         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1398                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1399         }
1400
1401         # s[gu]id programs with globs are evil
1402         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1403                 $0 = $0 " # FIXME no globs for suid/sgid files"
1404         }
1405
1406         # replace back
1407         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1408         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1409         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1410         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1411         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1412         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1413         gsub("%{_sysconfdir}/security", "/etc/security")
1414         gsub("%{_sysconfdir}/skel", "/etc/skel")
1415         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1416         gsub("%{_sysconfdir}/certs", "/etc/certs")
1417         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1418         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1419
1420         # /etc/init.d -> /etc/rc.d/init.d
1421         if (!/^\/etc\/init\.d$/) {
1422                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1423         }
1424
1425         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1426                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1427                         $0 = "%attr(754,root,root) " $0
1428                 }
1429                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1430                         gsub("^%attr\\(... *,", "%attr(754,");
1431                 }
1432         }
1433
1434         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1435                 $0 = "%attr(755,root,root) " $0
1436         }
1437
1438         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1439                 $0 = "%attr(755,root,root) " $0
1440         }
1441
1442         # /etc/sysconfig files
1443         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1444         # attr not required, allow default 644 attr
1445         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1446                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1447                         gsub("%config", "%config(noreplace)")
1448                 }
1449
1450                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1451                         $NF = "%config(noreplace) " $NF
1452                 }
1453
1454                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1455                         gsub("^%attr\\(... *,", "%attr(640,");
1456                 }
1457
1458                 if (/\/etc\/sysconfig\// && !/%verify/) {
1459                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1460                 }
1461         }
1462
1463         # kill leading zeros
1464         if (/%attr\(0[1-9]/) {
1465                 gsub("%attr\\(0", "%attr(")
1466         }
1467
1468         # kill leading whitespace
1469         gsub(/^ +/, "");
1470
1471         # kill default attrs
1472         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1473         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1474         if (!/%dir/) {
1475                 gsub(/%attr\(644,root,root\) /, "");
1476         }
1477
1478         # sort %verify attrs
1479         if (match($0, /%verify\(not([^)]+)\)/)) {
1480                 t = substr($0, RSTART, RLENGTH)
1481                 # kill commas: %verify(not,md5,size,mtime)
1482                 gsub(/,/, " ", t);
1483
1484                 gsub(/^%verify\(not |\)$/, "", t)
1485                 n = split(t, a, / /)
1486                 isort(a, n)
1487
1488                 s = "%verify(not"
1489                 for (i = 1 ; i <= n; i++) {
1490                         s = s " " a[i]
1491                 }
1492                 s = s ")"
1493
1494                 gsub(/%verify\(not[^)]+\)/, s)
1495         }
1496
1497         if (/%{_mandir}/) {
1498                 gsub("\.gz$", "*")
1499         }
1500
1501         # locale dir and no %lang -> bad
1502         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1503                 $(NF + 1) = "# FIXME consider using %find_lang"
1504         }
1505
1506         # atrpms
1507         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1508         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1509         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1510
1511         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1512         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1513         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1514
1515         gsub("%{_datadir}/applications", "%{_desktopdir}");
1516         gsub("%{_datadir}/icons", "%{_iconsdir}");
1517         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1518 }
1519
1520 function use_script_macros()
1521 {
1522         if (gsub("/sbin/service", "%service")) {
1523                 sub(" >/dev/null 2>&1 \|\|:", "");
1524                 sub(" 2> /dev/null \|\| :", "");
1525         }
1526 }
1527
1528 function fill(ch, n, i) {
1529         for (i = 0; i < n; i++)
1530                 printf("%c", ch)
1531 }
1532
1533 function format_flush(line, indent, newline, word, first_word) {
1534         first_word = 1
1535         if (format_indent == -1)
1536                 newline = ""
1537         else
1538                 newline = fill(" ", format_indent) "- "
1539
1540         while (match(line, /[^\t ]+/)) {
1541                 word = substr(line, RSTART, RLENGTH)
1542                 if (length(newline) + length(word) + 1 > tw) {
1543                         print newline
1544
1545                         if (format_indent == -1)
1546                                 newline = ""
1547                         else
1548                                 newline = fill(" ", format_indent + 2)
1549                         first_word = 1
1550                 }
1551
1552                 if (first_word) {
1553                         newline = newline word
1554                         first_word = 0
1555                 } else
1556                         newline = newline " " word
1557
1558                 line = substr(line, RSTART + RLENGTH)
1559         }
1560         if (newline ~ /[^\t ]/) {
1561                 print newline
1562         }
1563 }
1564
1565 function cflags(var)
1566 {
1567         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1568                 removed[var] = 1
1569                 return 0
1570         }
1571
1572         if (!/!\?debug/)
1573                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1574         return 1
1575 }
1576
1577 function demacroize(str)
1578 {
1579         if (mod_name) {
1580                 sub("%{mod_name}", mod_name, str);
1581         }
1582         if (name) {
1583                 sub("%{name}", name, str);
1584         }
1585         if (version) {
1586                 sub("%{version}", version, str);
1587         }
1588         if (_beta) {
1589                 sub("%{_beta}", _beta, str);
1590         }
1591         if (_rc) {
1592                 sub("%{_rc}", _rc, str);
1593         }
1594         if (_pre) {
1595                 sub("%{_pre}", _pre, str);
1596         }
1597         if (_snap) {
1598                 sub("%{_snap}", _snap, str);
1599         }
1600         return str;
1601 }
1602
1603 function kill_preamble_macros()
1604 {
1605         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1606                 # NB! assigning $2 a value breaks tabbing
1607                 $2 = demacroize($2);
1608                 # unify sourceforge url
1609                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1610         }
1611 }
1612
1613 function get_epoch(pkg, ver,    epoch)
1614 {
1615         return
1616 # should parse the BR lines more adequately:
1617 #       freetype = 2.0.0 -> correct
1618 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1619
1620         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1621         shell | getline epoch;
1622         return epoch;
1623 }
1624
1625 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1626         # skip any formatting for commented out items or some weird macros
1627         if (/^#/ || /%\(/) {
1628                 return tag "\t" value
1629         }
1630         n = split(value, p, / *,? */);
1631         for (i = 1; i <= n; i++) {
1632                 if (p[i+1] ~ /[<=>]/) {
1633                         # add epoch if the version doesn't have it but BuildRequires.txt has
1634                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1635                                 epoch = get_epoch(p[i], p[i+2])
1636                                 if (epoch) {
1637                                         p[i+2] = epoch ":" p[i+2];
1638                                 }
1639                         }
1640                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1641                         i += 2;
1642                 } else {
1643                         deps[ndeps++] = p[i];
1644                 }
1645         }
1646         s = ""
1647         for (i in deps) {
1648                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1649         }
1650         return substr(s, 1, length(s)-1);
1651 }
1652
1653 function use_tabs()
1654 {
1655         # reverse vim: ts=4 sw=4 et
1656         gsub(/    /, "\t");
1657 }
1658
1659 function add_br(br)
1660 {
1661         BR[BR_count++] = br
1662 }
1663
1664 function replace_requires()
1665 {
1666
1667         # jpackages
1668         sub(/^java-devel$/, "jdk", $2);
1669         sub(/^log4j$/, "logging-log4j", $2);
1670         sub(/^jakarta-log4j$/, "logging-log4j", $2);
1671         sub(/^oro$/, "jakarta-oro", $2);
1672         sub(/^jakarta-ant$/, "ant", $2);
1673         sub(/^xerces-j2$/, "xerces-j", $2);
1674         sub(/^ldapjdk$/, "ldapsdk", $2);
1675         sub(/^saxon-scripts$/, "saxon", $2);
1676         sub(/^xalan-j2$/, "xalan-j", $2);
1677         sub(/^xerces-j2$/, "xerces-j", $2);
1678         sub(/^gnu-regexp$/, "gnu.regexp", $2);
1679
1680         # redhat virtual
1681         sub(/^tftp-server$/, "tftpdaemon", $2);
1682
1683         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2);
1684
1685         replace_php_virtual_deps()
1686 }
1687
1688 # php virtual deps as discussed in devel-en
1689 function replace_php_virtual_deps()
1690 {
1691         pkg = $2
1692 #       if (pkg == "php-program") {
1693 #               $0 = $1 "\t/usr/bin/php"
1694 #               return
1695 #       }
1696
1697 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1698 #               sub(/^php-/, "php(", pkg);
1699 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1700 #               $2 = pkg
1701 #       }
1702
1703         if (pkg ~/^php$/) {
1704                 $2 = "webserver(php)";
1705                 if ($4 ~ /^[0-9]:/) {
1706                         $4 = substr($4, 3);
1707                 }
1708         }
1709
1710         if (pkg ~/^php4$/) {
1711                 $2 = "webserver(php)";
1712                 if ($4 ~ /^[0-9]:/) {
1713                         $4 = substr($4, 3);
1714                 }
1715         }
1716 }
1717
1718 # vim:ts=4:sw=4