adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2003 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Elan Ruusamäe <glen@pld-linux.org>
  13 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  14
  15 # TODO
  16 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  17 # - add "-nc" option to skip CVS interaction
  18 # - sort Summary(XX)
  19 # - sort Requires, BuildRequires
  20
  21 BEGIN {
  22         preamble = 1            # Is it part of preamble? Default - yes
  23         boc = 4                 # Beggining of %changelog
  24         bod = 0                 # Beggining of %description
  25         tw = 70                 # Descriptions width
  26
  27         b_idx = 0               # index of BR/R arrays
  28
  29         # If variable removed, then 1 (for removing it from export)
  30         removed["LDFLAGS"] = 0
  31         removed["CFLAGS"] = 0
  32         removed["CXXFLAGS"] = 0
  33
  34         # get cvsaddress for changelog section
  35         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  36         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  37         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  38
  39         # If 1, we are inside of comment block (started with /^#%/)
  40         comment_block = 0
  41
  42         # File with rpm groups
  43         "rpm --eval %_sourcedir" | getline groups_file
  44         groups_file = groups_file "/rpm.groups"
  45         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups >/dev/null")
  46
  47         # Temporary file for changelog section
  48         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  49
  50         # Load rpm macros
  51         "rpm --eval %_prefix"   | getline prefix
  52         "rpm --eval %_bindir"   | getline bindir
  53         "rpm --eval %_sbindir"  | getline sbindir
  54         "rpm --eval %_libdir"   | getline libdir
  55         "rpm --eval %_sysconfdir" | getline sysconfdir
  56         "rpm --eval %_datadir"  | getline datadir
  57         "rpm --eval %_includedir" | getline includedir
  58         "rpm --eval %_mandir"   | getline mandir
  59         "rpm --eval %_infodir"  | getline infodir
  60         "rpm --eval %_examplesdir"      | getline examplesdir
  61
  62         "rpm --eval %perl_sitearch" | getline perl_sitearch
  63         "rpm --eval %perl_archlib" | getline perl_archlib
  64         "rpm --eval %perl_privlib" | getline perl_privlib
  65         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  66         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  67         "rpm --eval %perl_sitelib" | getline perl_sitelib
  68
  69         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  70 }
  71
  72 # There should be a comment with CVS keywords on the first line of file.
  73 FNR == 1 {
  74         if (!/# \$Revision:/)   # If this line is already OK?
  75                 print "# $" "Revision:$, " "$" "Date:$" # No
  76         else {
  77                 print $0                                # Yes
  78                 next            # It is enough for first line
  79         }
  80 }
  81
  82 # If the latest line matched /%files/
  83 defattr == 1 {
  84         if ($0 !~ /defattr/)    # If no %defattr
  85                 print "%defattr(644,root,root,755)"     # Add it
  86         else
  87                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  88         defattr = 0
  89 }
  90
  91 function b_makekey(a, b,        s) {
  92         s = a "" b;
  93         # kill bcond
  94         gsub("%{\\?[_a-zA-Z0-9]+:", "", s);
  95         return s;
  96 }
  97
  98 # sort BR/R!
  99 #
 100 # NOTES:
 101 # - mixing BR/R and anything else confuses this (all will be sorted together)
 102 #   so don't do that.
 103 # - comments leading the BR/R can not be associated,
 104 #   so don't adapterize when the BR/R are mixed with comments
 105 ENVIRON["SORTBR"] == 1 && preamble == 1 && /(Build)?Requires/, /(Build)?Requires/ { # && !/^%/) {
 106         b_idx++;
 107         l = substr($0, index($0, $2));
 108         b_ktmp = b_makekey($1, l);
 109         b_key[b_idx] = b_ktmp;
 110         b_val[b_ktmp] = $0;
 111
 112         next;
 113 }
 114
 115 /^%bcond_/ {
 116         # do nothing
 117         print
 118         next
 119 }
 120
 121 preamble == 1 {
 122         if (b_idx > 0) {
 123                 isort(b_key, b_idx);
 124                 for (i = 1; i <= b_idx; i++) {
 125                         print "" b_val[b_key[i]];
 126                 }
 127                 b_idx = 0
 128         }
 129 }
 130
 131 # Comments
 132 /^#/ && (description == 0) {
 133         if (/This file does not like to be adapterized!/) {
 134                 print                   # print this message
 135                 while (getline)         # print the rest of spec as it is
 136                         print
 137                 do_not_touch_anything = 1 # do not touch anything in END()
 138                 exit 0
 139         }
 140
 141         # Generally, comments are printed without touching
 142         sub(/[ \t]+$/, "")
 143         print $0
 144         next
 145 }
 146
 147 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 148 /^%define/ {
 149         if ($2 == "_applnkdir")
 150                 next
 151         if ($2 == "date")
 152                 date = 1
 153 }
 154
 155 # Obsolete
 156 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 157         next
 158 }
 159
 160 ################
 161 # %description #
 162 ################
 163 /^%description/, (/^%[a-z]+/ && !/^%description/ && !/^%((end)?if|else)/) {
 164         preamble = 0
 165
 166         if (/^%description/) {
 167                 bod++
 168                 format_line = ""
 169                 format_indent = -1
 170         }
 171
 172         # Format description
 173         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 174                 if (/^[ \t]*$/) {
 175                         format_flush(format_line, format_indent)
 176                         print ""
 177                         format_line = ""
 178                         format_indent = -1
 179                 } else if (/^[ \t]*[-\*][ \t]*/) {
 180                         format_flush(format_line, format_indent)
 181                         match($0, /^[ \t]*/)
 182                         format_indent = RLENGTH
 183                         match($0, /^[ \t]*[-\*][ \t]/)
 184                         format_line = substr($0, RLENGTH)
 185                 } else
 186                         format_line = format_line " " $0
 187                 next
 188         }
 189
 190         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 191                 if (NF > 3 && $2 == "-l") {
 192                         ll = $1
 193                         for (i = 4; i <= NF; i++)
 194                                 ll = ll " " $i
 195                         $0 = ll " -l " $3
 196                 }
 197                 format_flush(format_line, format_indent)
 198                 if (bod == 2) {
 199                         bod = 1
 200                         description = 1
 201                 } else {
 202                         bod = 0
 203                         description = 0
 204                 }
 205         } else
 206                 description = 1
 207 }
 208
 209 #########
 210 # %prep #
 211 #########
 212 /^%prep/, (/^%[a-z]+$/ && !/^%prep/ && !/^%((end)?if|else)/) {
 213         preamble = 0
 214
 215         use_macros()
 216
 217         # Add '-q' to %setup
 218         if (/^%setup/ && !/-q/) {
 219                 sub(/^%setup/, "%setup -q")
 220         }
 221
 222         if (/^%setup/) {
 223                 gsub(name, "%{name}");
 224                 gsub(version, "%{version}");
 225                 if (_beta) {
 226                         gsub(_beta, "%{_beta}");
 227                 }
 228                 if (_rc) {
 229                         gsub(_rc, "%{_rc}");
 230                 }
 231                 if (_snap) {
 232                         gsub(_snap, "%{_snap}");
 233                 }
 234         }
 235
 236         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 237                 sub(/ -n %{name}-%{version}/, "")
 238         }
 239
 240         # invalid in %prep
 241         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 242 }
 243
 244 ##########
 245 # %build #
 246 ##########
 247 /^%build/, (/^%[a-z]+$/ && !/^%build/ && !/^%((end)?if|else)/) {
 248         preamble = 0
 249
 250         use_macros()
 251
 252         if (/^automake$/)
 253                 sub(/$/, " -a -c")
 254
 255         if (/LDFLAGS/) {
 256                 if (/LDFLAGS="-s"/) {
 257                         removed["LDFLAGS"] = 1
 258                         next
 259                 } else {
 260                         split($0, tmp, "LDFLAGS=")
 261                         count = split(tmp[2], flags, "\"")
 262                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 263                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 264                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 265                                 for (i = 2; i < count; i++)
 266                                         $0 = $0 flags[i] "\""
 267                         }
 268                 }
 269         }
 270
 271         if (/CFLAGS=/)
 272                 if (cflags("CFLAGS") == 0)
 273                         next
 274
 275         if (/CXXFLAGS=/)
 276                 if (cflags("CXXFLAGS") == 0)
 277                         next
 278
 279         if (/^export /) {
 280                 if (removed["LDFLAGS"])
 281                         sub(" LDFLAGS", "")
 282                 if (removed["CFLAGS"])
 283                         sub(" CFLAGS", "")
 284                 if (removed["CXXFLAGS"])
 285                         sub(" CXXFLAGS", "")
 286                 # Is there still something?
 287                 if (/^export[ ]*$/)
 288                         next
 289         }
 290
 291         # use macros
 292         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 293         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 294
 295         # atrpms
 296         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 297         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 298 }
 299
 300 ##########
 301 # %clean #
 302 ##########
 303 /^%clean/, (/^%[a-z]+$/ && !/^%clean/ && !/^%((end)?if|else)/) {
 304         did_clean = 1
 305         use_macros()
 306 }
 307
 308 ############
 309 # %install #
 310 ############
 311 /^%install/, (/^%[a-z]+$/ && !/^%install/ && !/^%((end)?if|else)/) {
 312
 313         preamble = 0
 314
 315         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 316                 did_rmroot=1
 317                 print "rm -rf $RPM_BUILD_ROOT"
 318                 next
 319         }
 320
 321         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 322                 print "rm -rf $RPM_BUILD_ROOT"
 323                 did_rmroot=1
 324         }
 325
 326         use_macros()
 327
 328         # 'install -d' instead 'mkdir -p'
 329         if (/mkdir -p/)
 330                 sub(/mkdir -p/, "install -d")
 331
 332         # 'install' instead 'cp -p'
 333         if (/cp -p\b/)
 334                 sub(/cp -p/, "install")
 335
 336         # No '-u root' or '-g root' for 'install'
 337         if (/^install/ && /-[ug][ \t]*root/)
 338                 gsub(/-[ug][ \t]*root /, "")
 339
 340         if (/^install/ && /-m[ \t]*[0-9]+/)
 341                 gsub(/-m[ \t]*[0-9]+ /, "")
 342
 343         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 344         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 345                 next
 346
 347         # No lines contain 'chmod' if it sets the modes to '644'
 348         if ($1 ~ /chmod/ && $2 ~ /644/)
 349                 next
 350
 351         # foreign rpms
 352         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 353         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 354
 355         # atrpms
 356         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 357 }
 358
 359 ##########
 360 # %files #
 361 ##########
 362 /^%files/, (/^%[a-z \-]+$/ && !/^%files/ && !/^%((end)?if|else)/) {
 363         preamble = 0
 364
 365         if ($0 ~ /^%files/)
 366                 defattr = 1
 367
 368         use_macros()
 369         use_files_macros()
 370 }
 371
 372 ##############
 373 # %changelog #
 374 ##############
 375 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 376         preamble = 0
 377         has_changelog = 1
 378         skip = 0
 379         # There should be some CVS keywords on the first line of %changelog.
 380         if (boc == 3) {
 381                 if ($0 !~ _cvsmailfeedback)
 382                         print "* %{date} " _cvsmailfeedback > changelog_file
 383                 else
 384                         skip = 1
 385                 boc = 2
 386         }
 387         if (boc == 2 && !skip) {
 388                 if (!/All persons listed below/) {
 389                         printf "All persons listed below can be reached at " > changelog_file
 390                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 391                 } else
 392                         skip = 1
 393                 boc = 1
 394         }
 395         if (boc == 1 && !skip) {
 396                 if (!/^$/) {
 397                         if (!/\$.*Log:.*\$/)
 398                                 print "$" "Log:$" > changelog_file
 399                         boc = 0
 400                 }
 401         }
 402         # Define date macro.
 403         if (boc == 4) {
 404                 if (date == 0) {
 405                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 406                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 407                         date = 1
 408                 }
 409                 boc = 3
 410         }
 411
 412         sub(/[ \t]+$/, "")
 413         if (!/^%[a-z]+$/ || /changelog/)
 414                 print > changelog_file
 415         else
 416                 print
 417         next
 418 }
 419
 420 ###########
 421 # SCRIPTS #
 422 ###########
 423 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 424         preamble = 0
 425
 426         # %useradd and %groupadd may not be wrapped
 427         if (/%(useradd|groupadd).*\\$/) {
 428                 a = $0; getline;
 429                 sub(/^[\s\t]*/, "");
 430                 $0 = substr(a, 1, length(a) - 1) $0;
 431         }
 432 }
 433
 434 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 435         preamble = 0
 436 }
 437 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 438         preamble = 0
 439 }
 440 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 441         preamble = 0
 442 }
 443 /^%triggerin/, (/^%[a-z]+$/ && !/^%triggerin/) {
 444         preamble = 0
 445 }
 446 /^%triggerun/, (/^%[a-z]+$/ && !/^%triggerun/) {
 447         preamble = 0
 448 }
 449 /^%triggerpostun/, (/^%[a-z]+$/ && !/^%triggerpostun/) {
 450         preamble = 0
 451 }
 452 /^%pretrans/, (/^%[a-z]+$/ && !/^%pretrans/) {
 453         preamble = 0
 454 }
 455 /^%posttrans/, (/^%[a-z]+$/ && !/^%posttrans/) {
 456         preamble = 0
 457 }
 458
 459 #############
 460 # PREAMBLES #
 461 #############
 462 preamble == 1 {
 463         # There should not be a space after the name of field
 464         # and before the colon.
 465         sub(/[ \t]*:/, ":")
 466
 467         if (/^%perl_module_wo_prefix/) {
 468                 name = $2
 469                 version = $3
 470                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 471         }
 472
 473         field = tolower($1)
 474         fieldnlower = $1
 475         if (field ~ /summary:/) {
 476                 sub(/\.$/, "", $0);
 477         }
 478         if (field ~ /group(\([^)]+\)):/)
 479                 next
 480         if (field ~ /group:/) {
 481                 format_preamble()
 482                 sub(/^Utilities\//,"Applications/",$2)
 483                 sub(/^Games/,"Applications/Games",$2)
 484                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 485                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 486                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 487                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 488                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 489                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 490                 sub(/^Shells/,"Applications/Shells",$2)
 491
 492                 sub(/^[^ \t]*[ \t]*/,"")
 493                 Grupa = $0
 494
 495                 sub(/^System Environment\/Libraries/, "Libraries", Grupa)
 496
 497                 print "Group:\t\t" Grupa
 498                 if (Grupa ~ /^X11/ && x11 == 0) # Is it X11 application?
 499                         x11 = 1
 500
 501                 byl_plik_z_grupami = 0
 502                 byl_opis_grupy = 0
 503                 while ((getline linia_grup < groups_file) > 0) {
 504                         byl_plik_z_grupami = 1
 505                         if (linia_grup == Grupa) {
 506                                 byl_opis_grupy = 1
 507                                 break
 508                         }
 509                 }
 510
 511                 if (!byl_plik_z_grupami)
 512                         print "######\t\t" groups_file ": no such file"
 513                 else if (!byl_opis_grupy)
 514                         print "######\t\t" "Unknown group!"
 515
 516                 close(groups_file)
 517                 next
 518         }
 519
 520         if (field ~ /prereq:/) {
 521                 $1 = "Requires:"
 522                 $(NF + 1) = " # FIXME add Requires(scriptlet) -adapter.awk"
 523         }
 524
 525         # split (build)requires on commas
 526         if (field ~ /requires:/ && $0 ~ /,/) {
 527                 l = substr($0, index($0, $2));
 528                 n = split(l, p, / *, */);
 529                 for (i in p) {
 530                         printf("%s\t%s\n", $1, p[i]);
 531                 }
 532                 next;
 533         }
 534
 535         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 536                 next
 537
 538         if (field ~ /buildroot:/)
 539                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 540
 541         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 542         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 543                 $1 = "License:"
 544
 545         if (field ~ /name:/) {
 546                 if ($2 == "%{name}" && name) {
 547                         $2 = name
 548                 }
 549                 name = $2
 550                 name_seen = 1;
 551         }
 552
 553         if (field ~ /version:/) {
 554                 if ($2 == "%{version}" && version) {
 555                         $2 = version
 556                 }
 557                 version = $2
 558                 version_seen = 1;
 559         }
 560
 561         if (field ~ /release:/) {
 562                 if ($2 == "%{release}" && release) {
 563                         $2 = release
 564                 }
 565                 release = $2
 566                 release_seen = 1;
 567         }
 568
 569         if (field ~ /serial:/)
 570                 $1 = "Epoch:"
 571
 572         # proper caps
 573         if (field ~ /url:/)
 574                 $1 = "URL:"
 575
 576         # Use %{name} and %{version} in the filenames in "Source:"
 577         if (field ~ /^source/ || field ~ /patch/) {
 578                 n = split($2, url, /\//)
 579                 if (url[n] ~ /\.gz$/) {
 580                         url[n+1] = ".gz" url[n+1]
 581                         sub(/\.gz$/,"",url[n])
 582                 }
 583                 if (url[n] ~ /\.zip$/) {
 584                         url[n+1] = ".zip" url[n+1]
 585                         sub(/\.zip$/,"",url[n])
 586                 }
 587                 if (url[n] ~ /\.tar$/) {
 588                         url[n+1] = ".tar" url[n+1]
 589                         sub(/\.tar$/,"",url[n])
 590                 }
 591                 if (url[n] ~ /\.patch$/) {
 592                         url[n+1] = ".patch" url[n+1]
 593                         sub(/\.patch$/,"",url[n])
 594                 }
 595                 if (url[n] ~ /\.bz2$/) {
 596                         url[n+1] = ".bz2" url[n+1]
 597                         sub(/\.bz2$/,"",url[n])
 598                 }
 599                 if (url[n] ~ /\.logrotate$/) {
 600                         url[n+1] = ".logrotate" url[n+1]
 601                         sub(/\.logrotate$/,"",url[n])
 602                 }
 603                 if (url[n] ~ /\.pamd$/) {
 604                         url[n+1] = ".pamd" url[n+1]
 605                         sub(/\.pamd$/,"",url[n])
 606                 }
 607
 608                 # allow %{name} just in last url component
 609                 s = ""
 610                 for (i = 1; i <= n; i++) {
 611                         url[i] = fixedsub("%{name}", name, url[i])
 612                         if (s) {
 613                                 s = s "/" url[i]
 614                         } else {
 615                                 s = url[i]
 616                         }
 617                 }
 618                 $2 = s url[n+1]
 619
 620                 filename = url[n]
 621                 if (name) {
 622                         url[n] = fixedsub(name, "%{name}", url[n])
 623                 }
 624                 if (field ~ /source/) {
 625                         if (version) {
 626                                 url[n] = fixedsub(version, "%{version}", url[n])
 627                         }
 628                         if (_beta) {
 629                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 630                         }
 631                         if (_rc) {
 632                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 633                         }
 634                         if (_snap) {
 635                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 636                         }
 637                 }
 638                 $2 = fixedsub(filename, url[n], $2)
 639
 640                 # sourceforge urls
 641                 sub("[?]use_mirror=.*$", "", $2);
 642                 sub("[?]download$", "", $2);
 643                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 644
 645                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 646                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 647                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 648         }
 649
 650
 651         if (field ~ /^source:/)
 652                 $1 = "Source0:"
 653
 654         if (field ~ /patch:/)
 655                 $1 = "Patch0:"
 656
 657         format_preamble()
 658
 659         if ($1 ~ /%define/) {
 660                 # Do not add %define of _prefix if it already is.
 661                 if ($2 ~ /^_prefix/) {
 662                         sub("^"prefix, $3, bindir)
 663                         sub("^"prefix, $3, sbindir)
 664                         sub("^"prefix, $3, libdir)
 665                         sub("^"prefix, $3, datadir)
 666                         sub("^"prefix, $3, includedir)
 667                         prefix = $3
 668                 }
 669
 670                 if ($2 ~ /_bindir/ && !/_sbindir/)
 671                         bindir = $3
 672                 if ($2 ~ /_sbindir/)
 673                         sbindir = $3
 674                 if ($2 ~ /_libdir/)
 675                         libdir = $3
 676                 if ($2 ~ /_sysconfdir/ && $3 !~ /^%\(/)
 677                         sysconfdir = $3
 678                 if ($2 ~ /_datadir/)
 679                         datadir = $3
 680                 if ($2 ~ /_includedir/)
 681                         includedir = $3
 682                 if ($2 ~ /_mandir/)
 683                         mandir = $3
 684                 if ($2 ~ /_infodir/)
 685                         infodir = $3
 686
 687                 if ($2 ~ /^_beta$/)
 688                         _beta = $3
 689                 if ($2 ~ /^_rc$/)
 690                         _rc = $3
 691                 if ($2 ~ /^_snap$/)
 692                         _snap = $3
 693
 694                 if ($2 ~ /^name$/)
 695                         name = $3
 696                 if ($2 ~ /^version$/)
 697                         version = $3
 698                 if ($2 ~ /^release$/)
 699                         release = $3
 700         }
 701
 702         if (field ~ /requires/) {
 703                 # atrpms
 704                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 705         }
 706 }
 707
 708 # main() ;-)
 709 {
 710         preamble = 1
 711
 712         sub(/[ \t]+$/, "")
 713         print
 714
 715         if (name_seen == 0 && name) {
 716                 print "Name:\t" name
 717                 name_seen = 1
 718         }
 719
 720         if (version_seen == 0 && version) {
 721                 print "Version:\t" version
 722                 version_seen = 1
 723         }
 724
 725         if (release_seen == 0 && release) {
 726                 print "Release:\t" release
 727                 release_seen = 1
 728         }
 729 }
 730
 731
 732 END {
 733         if (do_not_touch_anything)
 734                 exit 0
 735
 736         close(changelog_file)
 737         while ((getline < changelog_file) > 0)
 738                 print
 739         system("rm -f " changelog_file)
 740
 741
 742
 743         if (did_clean == 0) {
 744                 print ""
 745                 print "%clean"
 746                 print "rm -rf $RPM_BUILD_ROOT"
 747         }
 748
 749         if (date == 0) {
 750                 print ""
 751                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 752         }
 753
 754         if (has_changelog == 0)
 755                 print "%changelog"
 756
 757         if (boc > 2)
 758                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 759         if (boc > 1) {
 760                 printf "All persons listed below can be reached at "
 761                 print "<cvs_login>@pld-linux.org\n"
 762         }
 763         if (boc > 0)
 764                 print "$" "Log:$"
 765 }
 766
 767 function fixedsub(s1,s2,t, ind) {
 768 # substitutes fixed strings (not regexps)
 769         if (ind = index(t,s1))
 770                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 771         return t
 772 }
 773
 774 # There should be one or two tabs after the colon.
 775 function format_preamble()
 776 {
 777         sub(/:[ \t]*/, ":")
 778         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 779                 if (RLENGTH < 8)
 780                         sub(/:/, ":\t\t")
 781                 else
 782                         sub(/:/, ":\t")
 783         }
 784 }
 785
 786 # Replace directly specified directories with macros
 787 function use_macros()
 788 {
 789         gsub(perl_sitearch, "%{perl_sitearch}")
 790         gsub(perl_archlib, "%{perl_archlib}")
 791         gsub(perl_privlib, "%{perl_privlib}")
 792         gsub(perl_vendorlib, "%{perl_vendorlib}")
 793         gsub(perl_vendorarch, "%{perl_vendorarch}")
 794         gsub(perl_sitelib, "%{perl_sitelib}")
 795
 796         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
 797
 798         gsub(bindir, "%{_bindir}")
 799         gsub("%{prefix}/bin", "%{_bindir}")
 800         if(prefix"/bin" == bindir)
 801                 gsub("%{_prefix}/bin", "%{_bindir}")
 802
 803         for (c = 1; c <= NF; c++) {
 804                 if ($c ~ sbindir "/fix-info-dir")
 805                         continue;
 806                 gsub(sbindir, "%{_sbindir}", $c)
 807         }
 808
 809         gsub("%{prefix}/sbin", "%{_sbindir}")
 810         if (prefix"/sbin" == sbindir)
 811                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 812
 813         for (c = 1; c <= NF; c++) {
 814                 if ($c ~ sysconfdir "/{?cron.")
 815                         continue;
 816                 if ($c ~ sysconfdir "/{?crontab.d")
 817                         continue;
 818                 if ($c ~ sysconfdir "/{?logrotate.d")
 819                         continue;
 820                 if ($c ~ sysconfdir "/{?pam.d")
 821                         continue;
 822                 if ($c ~ sysconfdir "/{?profile.d")
 823                         continue;
 824                 if ($c ~ sysconfdir "/{?rc.d")
 825                         continue;
 826                 if ($c ~ sysconfdir "/{?security")
 827                         continue;
 828                 if ($c ~ sysconfdir "/{?skel")
 829                         continue;
 830                 if ($c ~ sysconfdir "/{?sysconfig")
 831                         continue;
 832                 if ($c ~ sysconfdir "/{?certs")
 833                         continue;
 834                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 835         }
 836
 837         for (c = 1; c <= NF; c++) {
 838                 if ($c ~ datadir "/automake")
 839                         continue;
 840                 if ($c ~ datadir "/unsermake")
 841                         continue;
 842                 if ($c ~ datadir "/file/magic.mime")
 843                         continue;
 844                 gsub(datadir, "%{_datadir}", $c)
 845         }
 846
 847         gsub("%_sbindir", "%{_sbindir}")
 848         gsub("%_mandir", "%{_mandir}")
 849         gsub("%name", "%{name}")
 850
 851         gsub("%{prefix}/share", "%{_datadir}")
 852         if (prefix"/share" == datadir)
 853                 gsub("%{_prefix}/share", "%{_datadir}")
 854
 855         gsub(includedir, "%{_includedir}")
 856         gsub("%{prefix}/include", "%{_includedir}")
 857         if (prefix"/include" == includedir)
 858                 gsub("%{_prefix}/include", "%{_includedir}")
 859
 860         gsub(mandir, "%{_mandir}")
 861         if ($0 !~ "%{_datadir}/manual")
 862                 gsub("%{_datadir}/man", "%{_mandir}")
 863         gsub("%{_prefix}/share/man", "%{_mandir}")
 864         gsub("%{prefix}/share/man", "%{_mandir}")
 865         gsub("%{prefix}/man", "%{_mandir}")
 866         gsub("%{_prefix}/man", "%{_mandir}")
 867
 868         gsub(infodir, "%{_infodir}")
 869         gsub("%{prefix}/info", "%{_infodir}")
 870         gsub("%{_prefix}/info", "%{_infodir}")
 871
 872         if (prefix !~ "/X11R6") {
 873                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 874         }
 875
 876         gsub(examplesdir, "%{_examplesdir}")
 877
 878         if (prefix != "/") {
 879                 # leave --with-foo=/usr alone
 880                 if ($0 !~ "--with.*=.*" prefix) {
 881                         for (c = 1; c <= NF; c++) {
 882                                 if ($c ~ prefix "/sbin/fix-info-dir")
 883                                         continue;
 884                                 if ($c ~ prefix "/share/automake")
 885                                         continue;
 886                                 if ($c ~ prefix "/share/unsermake")
 887                                         continue;
 888                                 if ($c ~ prefix "/lib/sendmail")
 889                                         continue;
 890                                 if ($c ~ prefix "/lib/pkgconfig")
 891                                         continue;
 892                                 gsub(prefix, "%{_prefix}", $c)
 893                         }
 894                 }
 895                 gsub("%{prefix}", "%{_prefix}")
 896         }
 897
 898         gsub("%{PACKAGE_VERSION}", "%{version}")
 899         gsub("%{PACKAGE_NAME}", "%{name}")
 900
 901         gsub("^make$", "%{__make}")
 902         gsub("^make ", "%{__make} ")
 903         gsub("^gcc ", "%{__cc} ")
 904
 905         # mandrake specs
 906         gsub("^%make$", "%{__make}")
 907         gsub("^%make ", "%{__make} ")
 908         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 909         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 910         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 911         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 912         gsub("^%{__install}", "install")
 913         gsub("^%{__rm}", "rm")
 914         gsub("%optflags", "%{rpmcflags}")
 915         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
 916
 917         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
 918         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
 919         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 920         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 921         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
 922
 923         gsub("%_bindir", "%{_bindir}")
 924         gsub("%_datadir", "%{_datadir}")
 925         gsub("%_iconsdir", "%{_iconsdir}")
 926
 927         gsub("/usr/src/linux", "%{_kernelsrcdir}")
 928         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
 929 }
 930
 931
 932 # insertion sort of A[1..n]
 933 # copied from mawk manual
 934 function isort(A,n,             i,j,hold) {
 935         for (i = 2; i <= n; i++) {
 936                 hold = A[j = i]
 937                 while (A[j-1] > hold) {
 938                         j-- ; A[j+1] = A[j]
 939                 }
 940                 A[j] = hold
 941         }
 942         # sentinel A[0] = "" will be created if needed
 943 }
 944
 945
 946 function use_files_macros(      i, n, t, a)
 947 {
 948         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 949         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 950
 951         # uid/gid nobody is not valid in %files
 952         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
 953                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
 954         }
 955
 956         # replace back
 957         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
 958         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
 959         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
 960         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
 961         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
 962         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
 963         gsub("%{_sysconfdir}/security", "/etc/security")
 964         gsub("%{_sysconfdir}/skel", "/etc/skel")
 965         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
 966         gsub("%{_sysconfdir}/certs", "/etc/certs")
 967         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
 968
 969         # /etc/init.d -> /etc/rc.d/init.d
 970         if (!/^\/etc\/init\.d$/) {
 971                  gsub("/etc/init.d", "/etc/rc.d/init.d")
 972         }
 973
 974         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
 975                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
 976                         $0 = "%attr(754,root,root) " $0
 977                 }
 978                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
 979                         gsub("^%attr\\(... *,", "%attr(754,");
 980                 }
 981         }
 982
 983         if (/lib.+\.so/ && !/^%attr.*/) {
 984                 $0 = "%attr(755,root,root) " $0
 985         }
 986
 987         # /etc/sysconfig files
 988         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
 989         # attr not required, allow default 644 attr
 990         if (!/network-scripts/) {
 991                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace\)/) {
 992                         gsub("%config", "%config(noreplace)")
 993                 }
 994
 995                 if (/\/etc\/sysconfig\// && !/%config\(noreplace\)/) {
 996                         $NF = "%config(noreplace) " $NF
 997                 }
 998
 999                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1000                         gsub("^%attr\\(... *,", "%attr(640,");
1001                 }
1002
1003                 if (/\/etc\/sysconfig\// && !/%verify/) {
1004                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1005                 }
1006         }
1007
1008         # kill leading zeros
1009         if (/%attr\(0[1-9]/) {
1010                 gsub("%attr\\(0", "%attr(")
1011         }
1012
1013         # sort %verify attrs
1014         if (match($0, /%verify\(not([^)]+)\)/)) {
1015                 t = substr($0, RSTART, RLENGTH)
1016                 gsub(/^%verify\(not |\)$/, "", t)
1017                 n = split(t, a, / /)
1018                 isort(a, n)
1019
1020                 s = "%verify(not"
1021                 for (i = 1 ; i <= n; i++) {
1022                         s = s " " a[i]
1023                 }
1024                 s = s ")"
1025
1026                 gsub(/%verify\(not[^)]+\)/, s)
1027         }
1028
1029         if (/%{_mandir}/) {
1030                 gsub("\.gz$", "*")
1031         }
1032
1033         # atrpms
1034         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1035         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1036         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1037
1038         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1039         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1040         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1041 }
1042
1043 function fill(ch, n, i) {
1044         for (i = 0; i < n; i++)
1045                 printf("%c", ch)
1046 }
1047
1048 function format_flush(line, indent, newline, word, first_word) {
1049         first_word = 1
1050         if (format_indent == -1)
1051                 newline = ""
1052         else
1053                 newline = fill(" ", format_indent) "- "
1054
1055         while (match(line, /[^\t ]+/)) {
1056                 word = substr(line, RSTART, RLENGTH)
1057                 if (length(newline) + length(word) + 1 > tw) {
1058                         print newline
1059
1060                         if (format_indent == -1)
1061                                 newline = ""
1062                         else
1063                                 newline = fill(" ", format_indent + 2)
1064                         first_word = 1
1065                 }
1066
1067                 if (first_word) {
1068                         newline = newline word
1069                         first_word = 0
1070                 } else
1071                         newline = newline " " word
1072
1073                 line = substr(line, RSTART + RLENGTH)
1074         }
1075         if (newline ~ /[^\t ]/) {
1076                 print newline
1077         }
1078 }
1079
1080 function cflags(var)
1081 {
1082         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1083                 removed[var] = 1
1084                 return 0
1085         }
1086
1087         if (!/!\?debug/)
1088                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1089         return 1
1090 }