adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2006 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Micha³ Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Elan Ruusamä¤e <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  21 # - add "-nc" option to skip CVS interaction
  22 # - sort Summary(XX)
  23 # - sort Requires, BuildRequires
  24 # - check if %description (lang=C) contains 8bit
  25 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  26
  27 BEGIN {
  28         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  29         SECTIONS = "^%(" RPM_SECTIONS ")"
  30
  31         PREAMBLE_TAGS = "(Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires)"
  32
  33         preamble = 1    # Is it part of preamble? Default - yes
  34         boc = 4                 # Beginning of %changelog
  35         bod = 0                 # Beginning of %description
  36         tw = 70                 # Descriptions width
  37
  38         b_idx = 0               # index of BR/R arrays
  39     BR_count = 0   # number of additional BuildRequires
  40
  41         # If variable removed, then 1 (for removing it from export)
  42         removed["LDFLAGS"] = 0
  43         removed["CFLAGS"] = 0
  44         removed["CXXFLAGS"] = 0
  45
  46         # get cvsaddress for changelog section
  47         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  48         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  49         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  50
  51         # If 1, we are inside of comment block (started with /^#%/)
  52         comment_block = 0
  53
  54         # File with rpm groups
  55         "rpm --eval %_sourcedir" | getline groups_file
  56         groups_file = groups_file "/rpm.groups"
  57         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  58         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  59
  60         # Temporary file for changelog section
  61         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  62
  63         # Load rpm macros
  64         "rpm --eval %_prefix"   | getline prefix
  65         "rpm --eval %_bindir"   | getline bindir
  66         "rpm --eval %_sbindir"  | getline sbindir
  67         "rpm --eval %_libdir"   | getline libdir
  68         "rpm --eval %_sysconfdir" | getline sysconfdir
  69         "rpm --eval %_datadir"  | getline datadir
  70         "rpm --eval %_includedir" | getline includedir
  71         "rpm --eval %_mandir"   | getline mandir
  72         "rpm --eval %_infodir"  | getline infodir
  73         "rpm --eval %_examplesdir"      | getline examplesdir
  74         "rpm --eval %_defaultdocdir"    | getline docdir
  75         "rpm --eval %_desktopdir" | getline desktopdir
  76         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  77
  78         "rpm --eval %perl_sitearch" | getline perl_sitearch
  79         "rpm --eval %perl_archlib" | getline perl_archlib
  80         "rpm --eval %perl_privlib" | getline perl_privlib
  81         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  82         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  83         "rpm --eval %perl_sitelib" | getline perl_sitelib
  84
  85         "rpm --eval %py_sitescriptdir 2>/dev/null" | getline py_sitescriptdir
  86         "rpm --eval %py_sitedir 2>/dev/null" | getline py_sitedir
  87         "rpm --eval %py_scriptdir 2>/dev/null" | getline py_scriptdir
  88
  89         "rpm --eval %ruby_archdir" | getline ruby_archdir
  90         "rpm --eval %ruby_ridir" | getline ruby_ridir
  91         "rpm --eval %ruby_rubylibdir" | getline ruby_rubylibdir
  92         "rpm --eval %ruby_sitearchdir" | getline ruby_sitearchdir
  93         "rpm --eval %ruby_sitelibdir" | getline ruby_sitelibdir
  94
  95         "rpm --eval %php_pear_dir" | getline php_pear_dir
  96         "rpm --eval %tmpdir" | getline tmpdir
  97 }
  98
  99 # There should be a comment with CVS keywords on the first line of file.
 100 FNR == 1 {
 101         if (!/# \$Revision:/)   # If this line is already OK?
 102                 print "# $" "Revision:$, " "$" "Date:$" # No
 103         else {
 104                 print $0                                # Yes
 105                 next            # It is enough for first line
 106         }
 107 }
 108
 109 # If the latest line matched /%files/
 110 defattr == 1 {
 111         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 112                 if ($0 !~ /defattr/) {  # If no %defattr
 113                         print "%defattr(644,root,root,755)"     # Add it
 114                 } else {
 115                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 116                 }
 117         }
 118         defattr = 0
 119 }
 120
 121 function b_makekey(a, b,        s) {
 122         s = a "" b;
 123         # kill bcond
 124     gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 125
 126         # kill commented out items
 127     gsub(/^#[ \t]*/, "", s);
 128
 129         # force order
 130     gsub(/^Summary\(/, "11Summary(", s);
 131     gsub(/^Summary/, "10Summary", s);
 132     gsub(/^Name/, "2Name", s);
 133     gsub(/^Version/, "3Version", s);
 134     gsub(/^Release/, "4Release", s);
 135     gsub(/^Epoch/, "5Epoch", s);
 136     gsub(/^License/, "5License", s);
 137     gsub(/^Group/, "6Group", s);
 138     gsub(/^URL/, "7URL", s);
 139
 140     gsub(/^BuildRequires/, "B1BuildRequires", s);
 141     gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 142     gsub(/^Provides/, "X1Provides", s);
 143     gsub(/^Obsoletes/, "X2Obsoletes", s);
 144     gsub(/^Conflicts/, "X3Conflicts", s);
 145     gsub(/^BuildArch/, "X4BuildArch", s);
 146     gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 147     gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 148     gsub(/^BuildRoot/, "X9BuildRoot", s);
 149
 150 #       printf("%s -> %s\n", a""b, s);
 151         return s;
 152 }
 153
 154 # Comments
 155 /^#/ && (description == 0) {
 156         if (/This file does not like to be adapterized!/) {
 157                 print                   # print this message
 158                 while (getline)         # print the rest of spec as it is
 159                         print
 160                 do_not_touch_anything = 1 # do not touch anything in END()
 161                 exit 0
 162         }
 163
 164         # Generally, comments are printed without touching
 165         sub(/[ \t]+$/, "")
 166
 167         if (/Source.*md5/) {
 168                 print $0
 169                 next
 170         }
 171 }
 172
 173 /^%define/ {
 174         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 175         if ($2 == "_applnkdir") {
 176                 next
 177         }
 178         if ($2 == "date") {
 179                 date = 1
 180                 if (did_files == 0) {
 181                         print "%files"
 182                         print ""
 183                         did_files = 1
 184                 }
 185         }
 186
 187         # Do not add %define of _prefix if it already is.
 188         if ($2 ~ /^_prefix/) {
 189                 sub("^"prefix, $3, bindir)
 190                 sub("^"prefix, $3, sbindir)
 191                 sub("^"prefix, $3, libdir)
 192                 sub("^"prefix, $3, datadir)
 193                 sub("^"prefix, $3, includedir)
 194                 prefix = $3
 195         }
 196
 197         if ($2 ~ /_bindir/ && !/_sbindir/)
 198                 bindir = $3
 199         if ($2 ~ /_sbindir/)
 200                 sbindir = $3
 201         if ($2 ~ /_libdir/) {
 202                 if ($3 ~ /^%\(/) {
 203                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 204                         libdir = "%%%%%%%%%%%%%%"
 205                 } else {
 206                         libdir = $3
 207                 }
 208         }
 209         if ($2 ~ /_sysconfdir/) {
 210                 if ($3 ~ /^%\(/) {
 211                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 212                         sysconfdir = "%%%%%%%%%%%%%%"
 213                 } else {
 214                         sysconfdir = $3
 215                 }
 216         }
 217         if ($2 ~ /_datadir/) {
 218                 if ($3 ~ /^%\(/) {
 219                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 220                         datadir = "%%%%%%%%%%%%%%"
 221                 } else {
 222                         datadir = $3
 223                 }
 224         }
 225         if ($2 ~ /_includedir/)
 226                 includedir = $3
 227         if ($2 ~ /_mandir/)
 228                 mandir = $3
 229         if ($2 ~ /_infodir/)
 230                 infodir = $3
 231         if ($2 ~ /_docdir/)
 232                 docdir = $3
 233
 234         # version related macros
 235         if ($2 ~ /^_beta$/)
 236                 _beta = $3
 237         if ($2 ~ /^_rc$/)
 238                 _rc = $3
 239         if ($2 ~ /^_pre$/)
 240                 _pre = $3
 241         if ($2 ~ /^_snap$/)
 242                 _snap = $3
 243
 244         # these are used usually when adapterizing external spec
 245         if ($2 ~ /^name$/)
 246                 name = $3
 247         if ($2 ~ /^version$/)
 248                 version = $3
 249         if ($2 ~ /^release$/)
 250                 release = $3
 251
 252         if ($2 ~ /^mod_name$/)
 253                 mod_name = $3
 254
 255         sub(/[ \t]+$/, "");
 256         # do nothing further, otherwise adapter thinks we're at preamble
 257         print
 258         next
 259 }
 260
 261 # Obsolete
 262 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 263         next
 264 }
 265
 266 ################
 267 # %description #
 268 ################
 269 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 270         preamble = 0
 271
 272         if (/^%description/) {
 273                 bod++
 274                 format_line = ""
 275                 format_indent = -1
 276         }
 277
 278         # Format description
 279         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 280                 if (/^[ \t]*$/) {
 281                         format_flush(format_line, format_indent)
 282                         print ""
 283                         format_line = ""
 284                         format_indent = -1
 285                 } else if (/^[ \t]*[-\*][ \t]*/) {
 286                         format_flush(format_line, format_indent)
 287                         match($0, /^[ \t]*/)
 288                         format_indent = RLENGTH
 289                         match($0, /^[ \t]*[-\*][ \t]/)
 290                         format_line = substr($0, RLENGTH)
 291                 } else
 292                         format_line = format_line " " $0
 293                 next
 294         }
 295
 296         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 297                 if (NF > 3 && $2 == "-l") {
 298                         ll = $1
 299                         for (i = 4; i <= NF; i++)
 300                                 ll = ll " " $i
 301                         $0 = ll " -l " $3
 302                 }
 303                 format_flush(format_line, format_indent)
 304                 if (bod == 2) {
 305                         bod = 1
 306                         description = 1
 307                 } else {
 308                         bod = 0
 309                         description = 0
 310                 }
 311         } else
 312                 description = 1
 313 }
 314
 315 #########
 316 # %prep #
 317 #########
 318 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 319         preamble = 0
 320         did_prep = 1
 321
 322         use_macros()
 323
 324         # Add '-q' to %setup
 325         if (/^%setup/ && !/-q/) {
 326                 sub(/^%setup/, "%setup -q")
 327         }
 328
 329         if (/^%setup/ && name != "setup") {
 330                 $0 = fixedsub(name, "%{name}", $0);
 331                 $0 = fixedsub(version, "%{version}", $0);
 332                 if (_beta) {
 333                         $0 = fixedsub(_beta, "%{_beta}", $0);
 334                 }
 335                 if (_rc) {
 336                         $0 = fixedsub(_rc, "%{_rc}", $0);
 337                 }
 338                 if (_pre) {
 339                         $0 = fixedsub(_pre, "%{_pre}", $0);
 340                 }
 341                 if (_snap) {
 342                         $0 = fixedsub(_snap, "%{_snap}", $0);
 343                 }
 344         }
 345
 346         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 347                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 348         }
 349     sub("^%patch ", "%patch0 ");
 350
 351         # invalid in %prep
 352         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 353 }
 354
 355 ##########
 356 # %build #
 357 ##########
 358 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 359         preamble = 0
 360
 361         if (did_prep == 0) {
 362                 print "%prep"
 363                 print ""
 364                 did_prep = 1
 365         }
 366
 367         use_macros()
 368         use_tabs()
 369
 370         if (/^automake$/)
 371                 sub(/$/, " -a -c")
 372
 373         if (/LDFLAGS/) {
 374                 if (/LDFLAGS="-s"/) {
 375                         removed["LDFLAGS"] = 1
 376                         next
 377                 } else {
 378                         split($0, tmp, "LDFLAGS=")
 379                         count = split(tmp[2], flags, "\"")
 380                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 381                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 382                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 383                                 for (i = 2; i < count; i++)
 384                                         $0 = $0 flags[i] "\""
 385                         }
 386                 }
 387         }
 388
 389         if (/CFLAGS=/)
 390                 if (cflags("CFLAGS") == 0)
 391                         next
 392
 393         if (/CXXFLAGS=/)
 394                 if (cflags("CXXFLAGS") == 0)
 395                         next
 396
 397         if (/^export /) {
 398                 if (removed["LDFLAGS"])
 399                         sub(" LDFLAGS", "")
 400                 if (removed["CFLAGS"])
 401                         sub(" CFLAGS", "")
 402                 if (removed["CXXFLAGS"])
 403                         sub(" CXXFLAGS", "")
 404                 # Is there still something?
 405                 if (/^export[ ]*$/)
 406                         next
 407         }
 408
 409         # quote CC
 410         if (/CC=%{__cc} /) {
 411                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 412         }
 413
 414         # use PLD Linux macros
 415         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 416         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 417         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 418         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 419         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 420         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 421         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 422
 423         sub(/^aclocal$/, "%{__aclocal}");
 424         sub(/^autoheader$/, "%{__autoheader}");
 425         sub(/^autoconf$/, "%{__autoconf}");
 426         sub(/^automake$/, "%{__automake}");
 427
 428         # atrpms
 429         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 430         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 431 }
 432
 433 ##########
 434 # %clean #
 435 ##########
 436 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 437         did_clean = 1
 438
 439     use_macros()
 440 }
 441
 442 ############
 443 # %install #
 444 ############
 445 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 446
 447         preamble = 0
 448
 449         # foreign rpms
 450         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 451     sub("%buildroot", "$RPM_BUILD_ROOT");
 452     sub("%{buildroot}", "$RPM_BUILD_ROOT");
 453
 454         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 455                 did_rmroot=1
 456                 print "rm -rf $RPM_BUILD_ROOT"
 457                 next
 458         }
 459
 460         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 461                 print "rm -rf $RPM_BUILD_ROOT"
 462                 did_rmroot=1
 463         }
 464
 465     if (tmpdir) {
 466         buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 467                 gsub(buildroot, "$RPM_BUILD_ROOT")
 468     }
 469
 470     if (!/%{_lib}/) {
 471         sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 472     }
 473
 474         use_macros()
 475
 476         # 'install -d' instead 'mkdir -p'
 477         if (/mkdir -p/)
 478                 sub(/mkdir -p/, "install -d")
 479
 480         # cp -a already implies cp -r
 481     sub(/^cp -ar/, "cp -a")
 482
 483         # No '-u root' or '-g root' for 'install'
 484         if (/^install/ && /-[ug][ \t]*root/)
 485                 gsub(/-[ug][ \t]*root /, "")
 486
 487         if (/^install/ && /-m[ \t]*[0-9]+/)
 488                 gsub(/-m[ \t]*[0-9]+ /, "")
 489
 490         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 491         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 492                 next
 493
 494         # No lines contain 'chmod' if it sets the modes to '644'
 495         if ($1 ~ /chmod/ && $2 ~ /644/)
 496                 next
 497
 498         # atrpms
 499         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 500 }
 501
 502 ##########
 503 # %files #
 504 ##########
 505 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 506         preamble = 0
 507         did_files = 1
 508
 509         if ($0 ~ /^%files/)
 510                 defattr = 1
 511
 512         use_files_macros()
 513 }
 514
 515 ##############
 516 # %changelog #
 517 ##############
 518 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 519         preamble = 0
 520         has_changelog = 1
 521         skip = 0
 522         # There should be some CVS keywords on the first line of %changelog.
 523         if (boc == 3) {
 524                 if ($0 !~ _cvsmailfeedback)
 525                         print "* %{date} " _cvsmailfeedback > changelog_file
 526                 else
 527                         skip = 1
 528                 boc = 2
 529         }
 530         if (boc == 2 && !skip) {
 531                 if (!/All persons listed below/) {
 532                         printf "All persons listed below can be reached at " > changelog_file
 533                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 534                 } else
 535                         skip = 1
 536                 boc = 1
 537         }
 538         if (boc == 1 && !skip) {
 539                 if (!/^$/) {
 540                         if (!/\$.*Log:.*\$/)
 541                                 print "$" "Log:$" > changelog_file
 542                         boc = 0
 543                 }
 544         }
 545         # Define date macro.
 546         if (boc == 4) {
 547                 if (date == 0) {
 548                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 549                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 550                         date = 1
 551                 }
 552                 boc = 3
 553         }
 554
 555         sub(/[ \t]+$/, "")
 556         if (!/^%[a-z]+$/ || /changelog/)
 557                 print > changelog_file
 558         else
 559                 print
 560         next
 561 }
 562
 563 ###########
 564 # SCRIPTS #
 565 ###########
 566 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 567         preamble = 0
 568
 569         if (gsub("/usr/sbin/useradd", "%useradd")) {
 570                 sub(" 2> /dev/null \|\| :", "");
 571                 sub(" >/dev/null 2>&1 \|\|:", "");
 572         }
 573
 574         # %useradd and %groupadd may not be wrapped
 575         if (/%(useradd|groupadd).*\\$/) {
 576                 a = $0; getline;
 577                 sub(/^[\s\t]*/, "");
 578                 $0 = substr(a, 1, length(a) - 1) $0;
 579         }
 580         use_script_macros()
 581 }
 582
 583 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 584         preamble = 0
 585         use_macros()
 586 }
 587 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 588         preamble = 0
 589         use_script_macros()
 590 }
 591 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 592         preamble = 0
 593         use_script_macros()
 594 }
 595 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 596         preamble = 0
 597         use_script_macros()
 598 }
 599 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 600         preamble = 0
 601         use_script_macros()
 602 }
 603 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 604         preamble = 0
 605         use_script_macros()
 606 }
 607 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 608         preamble = 0
 609         use_script_macros()
 610 }
 611 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 612         preamble = 0
 613         use_script_macros()
 614 }
 615 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 616         preamble = 0
 617         use_script_macros()
 618 }
 619 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 620         preamble = 0
 621         use_script_macros()
 622 }
 623
 624 #############
 625 # PREAMBLES #
 626 #############
 627 preamble == 1 {
 628         # There should not be a space after the name of field
 629         # and before the colon.
 630         sub(/[ \t]*:/, ":")
 631
 632         if (/^%perl_module_wo_prefix/) {
 633                 name = $2
 634                 version = $3
 635                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 636         }
 637
 638         field = tolower($1)
 639         fieldnlower = $1
 640         if (field ~ /summary:/ && !/etc\.$/) {
 641                 sub(/\.$/, "", $0);
 642         }
 643         if (field ~ /group(\([^)]+\)):/)
 644                 next
 645         if (field ~ /group:/) {
 646                 format_preamble()
 647                 group = $0;
 648                 sub(/^[^ \t]*[ \t]*/, "", group);
 649
 650                 sub(/^Utilities\//,"Applications/", group)
 651                 sub(/^Games/,"Applications/Games", group)
 652                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 653                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 654                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 655                 sub(/^X11\/GNOME/,"X11/Applications", group)
 656                 sub(/^X11\/Utilities/,"X11/Applications", group)
 657                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 658                 sub(/^X11\/Library/,"X11/Libraries", group)
 659                 sub(/^Shells/,"Applications/Shells", group)
 660                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 661                 sub(/^Library\/Development$/, "Development/Libraries", group)
 662                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 663                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 664                 sub(/^Applications\/Daemons$/, "Daemons", group)
 665                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 666                 sub(/^System\/Servers$/, "Daemons", group)
 667                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 668                 sub(/^X11\/XFree86/, "X11", group)
 669                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 670                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 671                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 672                 sub(/^Development\/Docs$/, "Documentation", group)
 673                 sub(/^Development\/Documentation$/, "Documentation", group)
 674                 sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
 675                 sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
 676                 sub(/^Development\/Java/, "Development/Languages/Java", group)
 677                 sub(/^Development\/Testing$/, "Development", group)
 678                 sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
 679                 sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
 680                 sub(/^Web\/Database$/, "Applications/WWW", group)
 681                 sub(/^System Environment\/Base$/, "Base", group)
 682
 683                 $0 = "Group:\t\t" group
 684
 685                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 686                         x11 = 1
 687
 688                 byl_plik_z_groupmi = 0
 689                 byl_opis_grupy = 0
 690                 while ((getline linia_grup < groups_file) > 0) {
 691                         byl_plik_z_groupmi = 1
 692                         if (linia_grup == group) {
 693                                 byl_opis_grupy = 1
 694                                 break
 695                         }
 696                 }
 697
 698                 if (!byl_plik_z_groupmi)
 699                         print "######\t\t" groups_file ": no such file"
 700                 else if (!byl_opis_grupy)
 701                         print "######\t\t" "Unknown group!"
 702
 703                 close(groups_file)
 704                 did_groups = 1
 705         }
 706
 707         if (field ~ /prereq:/) {
 708                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 709         }
 710
 711         # split (build)requires, obsoletes on commas
 712         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 713                 value = substr($0, index($0, $2));
 714                 $0 = format_requires($1, value);
 715         }
 716
 717         # BR: tar (and others) is to common (rpm-build requires it)
 718         if (field ~ /^buildrequires:/) {
 719                 l = substr($0, index($0, $2));
 720                 if (l == "awk" ||
 721                         l == "binutils" ||
 722                         l == "bzip2" ||
 723                         l == "cpio" ||
 724                         l == "diffutils" ||
 725                         l == "elfutils" ||
 726                         l == "fileutils" ||
 727                         l == "findutils" ||
 728                         l == "glibc-devel" ||
 729                         l == "grep" ||
 730                         l == "gzip" ||
 731                         l == "make" ||
 732                         l == "patch" ||
 733                         l == "sed" ||
 734                         l == "sh-utils" ||
 735                         l == "tar" ||
 736                         l == "textutils") {
 737                         next
 738                 }
 739
 740         # perhaps we have common known name?
 741
 742         # jpackages
 743                 sub(/^java-devel$/, "jdk", $2);
 744                 sub(/^log4j$/, "jakarta-log4j", $2);
 745                 sub(/^oro$/, "jakarta-oro", $2);
 746                 sub(/^xerces-j2$/, "xerces-j", $2);
 747                 sub(/^ant-junit$/, "jakarta-ant", $2);
 748                 sub(/^ldapjdk$/, "ldapsdk", $2);
 749                 sub(/^saxon-scripts$/, "saxon", $2);
 750
 751         replace_php_virtual_deps();
 752         }
 753
 754         if (field ~ /^requires:/) {
 755         replace_php_virtual_deps();
 756     }
 757
 758
 759         # obsolete/unwanted tags
 760         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 761                 next
 762         }
 763
 764         if (field ~ /buildroot:/) {
 765                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 766                 did_build_root = 1
 767         }
 768
 769         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 770         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 771                 $1 = "License:"
 772         }
 773
 774         if (field ~ /license:/) {
 775                 l = substr($0, index($0, $2));
 776                 if (l == "Python Software Foundation License") {
 777                         l = "PSF"
 778                 }
 779                 $0 = "License:\t" l;
 780         }
 781
 782
 783         if (field ~ /name:/) {
 784                 if ($2 == "%{name}" && name) {
 785                         $2 = name
 786                 }
 787                 name = $2
 788                 name_seen = 1;
 789         }
 790
 791         if (field ~ /version:/) {
 792                 if ($2 == "%{version}" && version) {
 793                         $2 = version
 794                 }
 795                 version = $2
 796                 version_seen = 1;
 797         }
 798
 799         if (field ~ /release:/) {
 800                 if ($2 == "%{release}" && release) {
 801                         $2 = release
 802                 }
 803                 sub(/%atrelease /, "0.", $0)
 804                 release = $2
 805                 release_seen = 1;
 806         }
 807
 808
 809         if (field ~ /serial:/)
 810                 $1 = "Epoch:"
 811
 812         if (field ~ /home-page:/)
 813                 $1 = "URL:"
 814
 815         # proper caps
 816         if (field ~ /^url:$/)
 817                 $1 = "URL:"
 818
 819         if (field ~ /^description:$/)
 820                 $1 = "\n%description\n"
 821
 822         # Use %{name} and %{version} in the filenames in "Source:"
 823         if (field ~ /^source/ || field ~ /patch/) {
 824                 n = split($2, url, /\//)
 825                 if (url[n] ~ /\.gz$/) {
 826                         url[n+1] = ".gz" url[n+1]
 827                         sub(/\.gz$/,"",url[n])
 828                 }
 829                 if (url[n] ~ /\.zip$/) {
 830                         url[n+1] = ".zip" url[n+1]
 831                         sub(/\.zip$/,"",url[n])
 832                 }
 833                 if (url[n] ~ /\.tar$/) {
 834                         url[n+1] = ".tar" url[n+1]
 835                         sub(/\.tar$/,"",url[n])
 836                 }
 837                 if (url[n] ~ /\.patch$/) {
 838                         url[n+1] = ".patch" url[n+1]
 839                         sub(/\.patch$/,"",url[n])
 840                 }
 841                 if (url[n] ~ /\.bz2$/) {
 842                         url[n+1] = ".bz2" url[n+1]
 843                         sub(/\.bz2$/,"",url[n])
 844                 }
 845                 if (url[n] ~ /\.logrotate$/) {
 846                         url[n+1] = ".logrotate" url[n+1]
 847                         sub(/\.logrotate$/,"",url[n])
 848                 }
 849                 if (url[n] ~ /\.pamd$/) {
 850                         url[n+1] = ".pamd" url[n+1]
 851                         sub(/\.pamd$/,"",url[n])
 852                 }
 853
 854                 # allow %{name} only in last url component
 855                 s = ""
 856                 for (i = 1; i <= n; i++) {
 857                         url[i] = fixedsub("%{name}", name, url[i])
 858                         if (s) {
 859                                 s = s "/" url[i]
 860                         } else {
 861                                 s = url[i]
 862                         }
 863                 }
 864                 $2 = s url[n+1]
 865
 866                 filename = url[n]
 867                 if (name) {
 868                         url[n] = fixedsub(name, "%{name}", url[n])
 869                 }
 870                 if (field ~ /source/) {
 871                         if (version) {
 872                                 url[n] = fixedsub(version, "%{version}", url[n])
 873                         }
 874                         if (_beta) {
 875                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 876                         }
 877                         if (_rc) {
 878                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 879                         }
 880                         if (_pre) {
 881                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 882                         }
 883                         if (_snap) {
 884                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 885                         }
 886                 }
 887                 # assigning to $2 kills preamble formatting
 888                 $2 = fixedsub(filename, url[n], $2)
 889
 890                 # sourceforge urls
 891                 sub("[?]use_mirror=.*$", "", $2);
 892                 sub("[?]download$", "", $2);
 893                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 894                 sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", $2)
 895
 896                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 897                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 898                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 899         }
 900
 901
 902         if (field ~ /^source:/)
 903                 $1 = "Source0:"
 904
 905         if (field ~ /^patch:/)
 906                 $1 = "Patch0:"
 907
 908         kill_preamble_macros();
 909         format_preamble()
 910
 911         if (field ~ /requires/) {
 912                 # atrpms
 913                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 914         }
 915 }
 916
 917 /^%bcond_/ {
 918         # do nothing
 919         print
 920         next
 921 }
 922
 923 # sort BR/R!
 924 #
 925 # NOTES:
 926 # - mixing BR/R and anything else confuses this (all will be sorted together)
 927 #   so don't do that.
 928 # - comments leading the BR/R can not be associated,
 929 #   so don't adapterize when the BR/R are mixed with comments
 930 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 931         if ($1 ~ /Pre[Rr]eq:/) {
 932                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 933         }
 934         format_preamble()
 935 #       kill_preamble_macros(); # breaks tabbing
 936
 937         b_idx++;
 938         l = substr($0, index($0, $2));
 939         b_ktmp = b_makekey($1, l);
 940         b_key[b_idx] = b_ktmp;
 941         b_val[b_ktmp] = $0;
 942
 943         next;
 944 }
 945
 946 preamble == 1 {
 947         if (b_idx > 0) {
 948                 isort(b_key, b_idx);
 949                 for (i = 1; i <= b_idx; i++) {
 950                         v = b_val[b_key[i]];
 951                         sub(/[ \t]+$/, "", v);
 952                         print "" v;
 953                 }
 954                 b_idx = 0
 955         }
 956 }
 957
 958 # main() ;-)
 959 {
 960         preamble = 1
 961
 962         sub(/[ \t]+$/, "")
 963         print
 964
 965         if (name_seen == 0 && name) {
 966                 print "Name:\t\t" name
 967                 name_seen = 1
 968         }
 969
 970         if (version_seen == 0 && version) {
 971                 print "Version:\t" version
 972                 version_seen = 1
 973         }
 974
 975         if (release_seen == 0 && release) {
 976                 print "Release:\t" release
 977                 release_seen = 1
 978         }
 979
 980         if (did_build_root == 0) {
 981 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 982                 did_build_root = 1
 983         }
 984         if (did_groups == 0) {
 985 #               print "Group:\t\tunknown"
 986                 did_groups = 1
 987         }
 988 }
 989
 990
 991 END {
 992         if (do_not_touch_anything)
 993                 exit 0
 994
 995     # TODO: need to output these in proper place
 996     if (BR_count > 0) {
 997         for (i = 0; i <= BR_count; i++) {
 998             print BR[i];
 999         }
1000     }
1001
1002         close(changelog_file)
1003         while ((getline < changelog_file) > 0)
1004                 print
1005         system("rm -f " changelog_file)
1006
1007         if (did_clean == 0) {
1008                 print ""
1009                 print "%clean"
1010                 print "rm -rf $RPM_BUILD_ROOT"
1011         }
1012
1013         if (date == 0) {
1014                 print ""
1015                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1016         }
1017
1018         if (has_changelog == 0) {
1019                 print "%changelog"
1020     }
1021
1022         if (boc > 2) {
1023                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1024     }
1025         if (boc > 1) {
1026                 printf "All persons listed below can be reached at "
1027                 print "<cvs_login>@pld-linux.org\n"
1028         }
1029         if (boc > 0) {
1030                 print "$" "Log:$"
1031     }
1032 }
1033
1034 function fixedsub(s1,s2,t, ind) {
1035 # substitutes fixed strings (not regexps)
1036         if (ind = index(t,s1))
1037                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1038         return t
1039 }
1040
1041 # There should be one or two tabs after the colon.
1042 function format_preamble()
1043 {
1044         if (/^#/ || /^%bcond_with/) {
1045                 return;
1046         }
1047         sub(/:[ \t]*/, ":")
1048         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
1049                 if (RLENGTH < 8)
1050                         sub(/:/, ":\t\t")
1051                 else
1052                         sub(/:/, ":\t")
1053         }
1054 }
1055
1056 # Replace directly specified directories with macros
1057 function use_macros()
1058 {
1059         # -m, --skip-macros, --no-macros -- skip macros subst
1060         if (ENVIRON["SKIP_MACROS"]) {
1061                 return
1062         }
1063
1064         # leave inline sed lines alone
1065         if (/(%{__sed}|sed) -i -e/) {
1066                 return;
1067         }
1068
1069     sub("%{_defaultdocdir}", "%{_docdir}");
1070     sub("%{_bindir}/perl", "%{__perl}");
1071     sub("%{_bindir}/python", "%{__python}");
1072
1073         gsub(infodir, "%{_infodir}")
1074
1075         gsub(perl_sitearch, "%{perl_sitearch}")
1076         gsub(perl_archlib, "%{perl_archlib}")
1077         gsub(perl_privlib, "%{perl_privlib}")
1078         gsub(perl_vendorlib, "%{perl_vendorlib}")
1079         gsub(perl_vendorarch, "%{perl_vendorarch}")
1080         gsub(perl_sitelib, "%{perl_sitelib}")
1081
1082         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1083         gsub(py_sitedir, "%{py_sitedir}")
1084         gsub(py_scriptdir, "%{py_scriptdir}")
1085         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1086         gsub("%{python_sitelib}", "%{py_sitedir}")
1087
1088         gsub(ruby_archdir, "%{ruby_archdir}")
1089         gsub(ruby_ridir, "%{ruby_ridir}")
1090         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1091         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1092         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1093
1094         gsub("%{_datadir}/applications", "%{_desktopdir}")
1095         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1096
1097         gsub(bindir, "%{_bindir}")
1098         gsub("%{prefix}/bin", "%{_bindir}")
1099         if (prefix"/bin" == bindir)
1100                 gsub("%{_prefix}/bin", "%{_bindir}")
1101
1102         for (c = 1; c <= NF; c++) {
1103                 if ($c ~ sbindir "/fix-info-dir")
1104                         continue;
1105                 if ($c ~ sbindir "/webapp")
1106                         continue;
1107                 if ($c ~ sbindir "/ldconfig")
1108                         continue;
1109                 if ($c ~ sbindir "/chsh")
1110                         continue;
1111                 if ($c ~ sbindir "/usermod")
1112                         continue;
1113                 if ($c ~ sbindir "/chkconfig")
1114                         continue;
1115                 if ($c ~ sbindir "/installzope(product|3package)")
1116                         continue;
1117                 gsub(sbindir, "%{_sbindir}", $c)
1118         }
1119
1120         gsub("%{prefix}/sbin", "%{_sbindir}")
1121         if (prefix"/sbin" == sbindir) {
1122                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1123         }
1124
1125         for (c = 1; c <= NF; c++) {
1126                 if ($c ~ sysconfdir "/{?cron.")
1127                         continue;
1128                 if ($c ~ sysconfdir "/{?crontab.d")
1129                         continue;
1130                 if ($c ~ sysconfdir "/{?env.d")
1131                         continue;
1132                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1133                         continue;
1134                 if ($c ~ sysconfdir "/{?udev/rules.d")
1135                         continue;
1136                 if ($c ~ sysconfdir "/{?logrotate.d")
1137                         continue;
1138                 if ($c ~ sysconfdir "/{?pam.d")
1139                         continue;
1140                 if ($c ~ sysconfdir "/{?profile.d")
1141                         continue;
1142                 if ($c ~ sysconfdir "/{?rc.d")
1143                         continue;
1144                 if ($c ~ sysconfdir "/{?security")
1145                         continue;
1146                 if ($c ~ sysconfdir "/{?skel")
1147                         continue;
1148                 if ($c ~ sysconfdir "/{?sysconfig")
1149                         continue;
1150                 if ($c ~ sysconfdir "/{?shrc.d")
1151                         continue;
1152                 if ($c ~ sysconfdir "/{?certs")
1153                         continue;
1154                 if ($c ~ sysconfdir "/{?X11")
1155                         continue;
1156                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1157                         continue;
1158                 if ($c ~ sysconfdir "/{?rpm")
1159                         continue;
1160                 if ($c ~ sysconfdir "/{?bash_completion.d")
1161                         continue;
1162                 if ($c ~ sysconfdir "/{?samba")
1163                         continue;
1164                 if ($c ~ sysconfdir "/shells")
1165                         continue;
1166                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1167         }
1168
1169         gsub(docdir, "%{_docdir}")
1170         gsub(php_pear_dir, "%{php_pear_dir}")
1171
1172         for (c = 1; c <= NF; c++) {
1173                 if ($c ~ datadir "/automake")
1174                         continue;
1175                 if ($c ~ datadir "/unsermake")
1176                         continue;
1177                 if ($c ~ datadir "/file/magic.mime")
1178                         continue;
1179                 gsub(datadir, "%{_datadir}", $c)
1180         }
1181
1182         gsub("%{prefix}/share", "%{_datadir}")
1183         if (prefix"/share" == datadir)
1184                 gsub("%{_prefix}/share", "%{_datadir}")
1185
1186         # CFLAGS="-I/usr/include/ncurses is usually correct.
1187         if (!/-I\/usr\/include/) {
1188                 gsub(includedir, "%{_includedir}")
1189         }
1190
1191         gsub("%{prefix}/include", "%{_includedir}")
1192         if (prefix"/include" == includedir) {
1193                 gsub("%{_prefix}/include", "%{_includedir}")
1194         }
1195
1196         gsub(mandir, "%{_mandir}")
1197         if ($0 !~ "%{_datadir}/manual") {
1198                 gsub("%{_datadir}/man", "%{_mandir}")
1199         }
1200         gsub("%{_prefix}/share/man", "%{_mandir}")
1201         gsub("%{prefix}/share/man", "%{_mandir}")
1202         gsub("%{prefix}/man", "%{_mandir}")
1203         gsub("%{_prefix}/man", "%{_mandir}")
1204
1205         gsub(infodir, "%{_infodir}")
1206         gsub("%{prefix}/info", "%{_infodir}")
1207         gsub("%{_prefix}/info", "%{_infodir}")
1208
1209         if (prefix !~ "/X11R6") {
1210                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1211         }
1212
1213         gsub(examplesdir, "%{_examplesdir}")
1214
1215         if (prefix != "/") {
1216                 # leave --with-foo=/usr alone
1217                 if ($0 !~ "--with.*=.*" prefix) {
1218                         for (c = 1; c <= NF; c++) {
1219                                 if ($c ~ prefix "/sbin/fix-info-dir")
1220                                         continue;
1221                                 if ($c ~ prefix "/sbin/webapp")
1222                                         continue;
1223                                 if ($c ~ prefix "/sbin/chsh")
1224                                         continue;
1225                                 if ($c ~ prefix "/sbin/usermod")
1226                                         continue;
1227                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1228                                         continue;
1229                                 if ($c ~ prefix "/share/automake")
1230                                         continue;
1231                                 if ($c ~ prefix "/share/unsermake")
1232                                         continue;
1233                                 if ($c ~ prefix "/lib/sendmail")
1234                                         continue;
1235                                 if ($c ~ prefix "/lib/pkgconfig")
1236                                         continue;
1237
1238                                 # CFLAGS="-I/usr..." is usually correct.
1239                                 if (/-I\/usr/)
1240                                         continue;
1241                                 # same for LDFLAGS="-L/usr..."
1242                                 if (/-L\/usr/)
1243                                         continue;
1244
1245                                 gsub(prefix, "%{_prefix}", $c)
1246                         }
1247                 }
1248                 gsub("%{prefix}", "%{_prefix}")
1249         }
1250
1251         # replace back
1252         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1253         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1254
1255         gsub("%{PACKAGE_VERSION}", "%{version}")
1256         gsub("%{PACKAGE_NAME}", "%{name}")
1257
1258         gsub("^make$", "%{__make}")
1259         gsub("^make ", "%{__make} ")
1260         gsub("^gcc ", "%{__cc} ")
1261
1262         # mandrake specs
1263         gsub("^%make$", "%{__make}")
1264         gsub("^%make ", "%{__make} ")
1265         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1266         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1267         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1268         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1269         gsub("^%{__install}", "install")
1270         gsub("^%{__rm}", "rm")
1271         gsub("%optflags", "%{rpmcflags}")
1272         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1273
1274         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1275         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
1276         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1277         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1278         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1279
1280         # split configure line to multiple lines
1281         if (/%configure / && !/\\$/) {
1282                 $0 = format_configure($0);
1283         }
1284
1285         gsub("%_bindir", "%{_bindir}")
1286         gsub("%_datadir", "%{_datadir}")
1287         gsub("%_iconsdir", "%{_iconsdir}")
1288         gsub("%_sbindir", "%{_sbindir}")
1289         gsub("%_mandir", "%{_mandir}")
1290         gsub("%name", "%{name}")
1291     gsub(/%__rm/, "rm");
1292     gsub(/%__mkdir_p/, "install -d");
1293     gsub(/%__cp/, "cp");
1294     gsub(/%__ln_s/, "ln -s");
1295     gsub(/%__sed/, "%{__sed}");
1296     gsub(/%__cat/, "cat");
1297     gsub(/%__chmod/, "chmod");
1298
1299         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1300         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1301
1302         if (/^ant /) {
1303                 sub(/^ant/, "%ant")
1304         add_br("BuildRequires:  jpackage-utils");
1305         add_br("BuildRequires:  rpmbuild(macros) >= 1.294");
1306     }
1307
1308 }
1309
1310 function format_configure(line,         n, a, s) {
1311         n = split(line, a, / /);
1312         s = a[1] " \\\n";
1313         for (i = 2; i <= n; i++) {
1314                 s = s "\t" a[i] " \\\n"
1315         }
1316         return s
1317 }
1318
1319
1320 # insertion sort of A[1..n]
1321 # copied from mawk manual
1322 function isort(A,n,             i,j,hold) {
1323         for (i = 2; i <= n; i++) {
1324                 hold = A[j = i]
1325                 while (A[j-1] > hold) {
1326                         j-- ; A[j+1] = A[j]
1327                 }
1328                 A[j] = hold
1329         }
1330         # sentinel A[0] = "" will be created if needed
1331 }
1332
1333
1334 function use_files_macros(      i, n, t, a)
1335 {
1336         use_macros()
1337
1338         # skip comments
1339         if (/^#/) {
1340                 return;
1341         }
1342
1343         sub("^%doc %{_mandir}", "%{_mandir}")
1344
1345         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1346         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1347
1348         # uid/gid nobody is not valid in %files
1349         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1350                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1351         }
1352
1353         # s[gu]id programs with globs are evil
1354         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1355                 $0 = $0 " # FIXME no globs for suid/sgid files"
1356         }
1357
1358         # replace back
1359         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1360         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1361         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1362         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1363         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1364         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1365         gsub("%{_sysconfdir}/security", "/etc/security")
1366         gsub("%{_sysconfdir}/skel", "/etc/skel")
1367         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1368         gsub("%{_sysconfdir}/certs", "/etc/certs")
1369         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1370
1371         # /etc/init.d -> /etc/rc.d/init.d
1372         if (!/^\/etc\/init\.d$/) {
1373                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1374         }
1375
1376         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1377                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1378                         $0 = "%attr(754,root,root) " $0
1379                 }
1380                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1381                         gsub("^%attr\\(... *,", "%attr(754,");
1382                 }
1383         }
1384
1385         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1386                 $0 = "%attr(755,root,root) " $0
1387         }
1388
1389         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1390                 $0 = "%attr(755,root,root) " $0
1391         }
1392
1393         # /etc/sysconfig files
1394         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1395         # attr not required, allow default 644 attr
1396         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1397                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1398                         gsub("%config", "%config(noreplace)")
1399                 }
1400
1401                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1402                         $NF = "%config(noreplace) " $NF
1403                 }
1404
1405                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1406                         gsub("^%attr\\(... *,", "%attr(640,");
1407                 }
1408
1409                 if (/\/etc\/sysconfig\// && !/%verify/) {
1410                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1411                 }
1412         }
1413
1414         # kill leading zeros
1415         if (/%attr\(0[1-9]/) {
1416                 gsub("%attr\\(0", "%attr(")
1417         }
1418
1419     # kill default attrs
1420     gsub(/%dir %attr\(755,root,root\)/, "%dir");
1421     if (!/%dir/) {
1422         gsub(/%attr\(644,root,root\) /, "");
1423     }
1424
1425         # sort %verify attrs
1426         if (match($0, /%verify\(not([^)]+)\)/)) {
1427                 t = substr($0, RSTART, RLENGTH)
1428                 # kill commas: %verify(not,md5,size,mtime)
1429                 gsub(/,/, " ", t);
1430
1431                 gsub(/^%verify\(not |\)$/, "", t)
1432                 n = split(t, a, / /)
1433                 isort(a, n)
1434
1435                 s = "%verify(not"
1436                 for (i = 1 ; i <= n; i++) {
1437                         s = s " " a[i]
1438                 }
1439                 s = s ")"
1440
1441                 gsub(/%verify\(not[^)]+\)/, s)
1442         }
1443
1444         if (/%{_mandir}/) {
1445                 gsub("\.gz$", "*")
1446         }
1447
1448         # locale dir and no %lang -> bad
1449         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1450                 $(NF + 1) = "# FIXME consider using %find_lang"
1451         }
1452
1453         # atrpms
1454         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1455         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1456         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1457
1458         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1459         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1460         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1461
1462         gsub("%{_datadir}/applications", "%{_desktopdir}");
1463         gsub("%{_datadir}/icons", "%{_iconsdir}");
1464         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1465 }
1466
1467 function use_script_macros()
1468 {
1469         if (gsub("/sbin/service", "%service")) {
1470                 sub(" >/dev/null 2>&1 \|\|:", "");
1471                 sub(" 2> /dev/null \|\| :", "");
1472         }
1473 }
1474
1475 function fill(ch, n, i) {
1476         for (i = 0; i < n; i++)
1477                 printf("%c", ch)
1478 }
1479
1480 function format_flush(line, indent, newline, word, first_word) {
1481         first_word = 1
1482         if (format_indent == -1)
1483                 newline = ""
1484         else
1485                 newline = fill(" ", format_indent) "- "
1486
1487         while (match(line, /[^\t ]+/)) {
1488                 word = substr(line, RSTART, RLENGTH)
1489                 if (length(newline) + length(word) + 1 > tw) {
1490                         print newline
1491
1492                         if (format_indent == -1)
1493                                 newline = ""
1494                         else
1495                                 newline = fill(" ", format_indent + 2)
1496                         first_word = 1
1497                 }
1498
1499                 if (first_word) {
1500                         newline = newline word
1501                         first_word = 0
1502                 } else
1503                         newline = newline " " word
1504
1505                 line = substr(line, RSTART + RLENGTH)
1506         }
1507         if (newline ~ /[^\t ]/) {
1508                 print newline
1509         }
1510 }
1511
1512 function cflags(var)
1513 {
1514         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1515                 removed[var] = 1
1516                 return 0
1517         }
1518
1519         if (!/!\?debug/)
1520                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1521         return 1
1522 }
1523
1524 function demacroize(str)
1525 {
1526         if (mod_name) {
1527                 sub("%{mod_name}", mod_name, str);
1528         }
1529         if (name) {
1530                 sub("%{name}", name, str);
1531         }
1532         if (version) {
1533                 sub("%{version}", version, str);
1534         }
1535         if (_beta) {
1536                 sub("%{_beta}", _beta, str);
1537         }
1538         if (_rc) {
1539                 sub("%{_rc}", _rc, str);
1540         }
1541         if (_pre) {
1542                 sub("%{_pre}", _pre, str);
1543         }
1544         if (_snap) {
1545                 sub("%{_snap}", _snap, str);
1546         }
1547         return str;
1548 }
1549
1550 function kill_preamble_macros()
1551 {
1552         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1553                 # NB! assigning $2 a value breaks tabbing
1554                 $2 = demacroize($2);
1555                 # unify sourceforge url
1556                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1557         }
1558 }
1559
1560 function get_epoch(pkg, ver,    epoch)
1561 {
1562         return
1563 # should parse the BR lines more adequately:
1564 #       freetype = 2.0.0 -> correct
1565 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1566
1567         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1568         shell | getline epoch;
1569         return epoch;
1570 }
1571
1572 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1573         # skip any formatting for commented out items or some weird macros
1574         if (/^#/ || /%\(/) {
1575                 return tag "\t" value
1576         }
1577         n = split(value, p, / *,? */);
1578         for (i = 1; i <= n; i++) {
1579                 if (p[i+1] ~ /[<=>]/) {
1580                         # add epoch if the version doesn't have it but BuildRequires.txt has
1581                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1582                                 epoch = get_epoch(p[i], p[i+2])
1583                                 if (epoch) {
1584                                         p[i+2] = epoch ":" p[i+2];
1585                                 }
1586                         }
1587                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1588                         i += 2;
1589                 } else {
1590                         deps[ndeps++] = p[i];
1591                 }
1592         }
1593         s = ""
1594         for (i in deps) {
1595                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1596         }
1597         return substr(s, 1, length(s)-1);
1598 }
1599
1600 function use_tabs()
1601 {
1602         # reverse vim: ts=4 sw=4 et
1603         gsub(/    /, "\t");
1604 }
1605
1606 function add_br(br)
1607 {
1608     BR[BR_count++] = br
1609 }
1610
1611 # php virtual deps as discussed in devel-en
1612 function replace_php_virtual_deps()
1613 {
1614     pkg = $2
1615 #    if (pkg == "php-program") {
1616 #        $0 = $1 "\t/usr/bin/php"
1617 #        return
1618 #    }
1619
1620     if (pkg ~ /^php-/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|ZendOptimizer|pecl-)/) {
1621         sub(/^php-/, "php(", pkg);
1622         sub(/$/, ")", pkg);
1623         $2 = pkg
1624     }
1625
1626     if (pkg ~/^php$/) {
1627         $2 = "webserver(php)";
1628         if ($4 ~ /^[0-9]:/) {
1629             $4 = substr($4, 3);
1630         }
1631     }
1632 }
1633
1634 # vim:ts=4:sw=4:et