adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # This is adapter v0.30. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2007 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Michał Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Jakub Bogusz <qboosh@pld-linux.org>
  14 #       Elan Ruusamäe <glen@pld-linux.org>
  15 #
  16 # See cvs log adapter{,.awk} for list of contributors
  17 #
  18 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  19
  20 # TODO
  21 # - really long sourceX make preamble sorting totally fcked up (try snake.spec r1.1)
  22 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  23 # - add "-nc" option to skip CVS interaction
  24 # - sort Summary(XX)
  25 # - sort Requires, BuildRequires
  26 # - check if %description (lang=C) contains 8bit
  27 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  28
  29 BEGIN {
  30         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  31         SECTIONS = "^%(" RPM_SECTIONS ")"
  32
  33         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests)"
  34
  35         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  36
  37         preamble = 1    # Is it part of preamble? Default - yes
  38         boc = 4                 # Beginning of %changelog
  39         bod = 0                 # Beginning of %description
  40         tw = 70                 # Descriptions width
  41
  42         b_idx = 0               # index of BR/R arrays
  43         BR_count = 0    # number of additional BuildRequires
  44
  45         # If variable removed, then 1 (for removing it from export)
  46         removed["LDFLAGS"] = 0
  47         removed["CFLAGS"] = 0
  48         removed["CXXFLAGS"] = 0
  49
  50         # get cvsaddress for changelog section
  51         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  52         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  53         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  54
  55         # If 1, we are inside of comment block (started with /^#%/)
  56         comment_block = 0
  57
  58         # File with rpm groups
  59         "rpm --eval %_sourcedir" | getline groups_file
  60         groups_file = groups_file "/rpm.groups"
  61         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  62         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  63
  64         # Temporary file for changelog section
  65         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  66
  67         # Load rpm macros
  68         "rpm --eval %_prefix"   | getline prefix
  69         "rpm --eval %_bindir"   | getline bindir
  70         "rpm --eval %_sbindir"  | getline sbindir
  71         "rpm --eval %_libdir"   | getline libdir
  72         "rpm --eval %_sysconfdir" | getline sysconfdir
  73         "rpm --eval %_datadir"  | getline datadir
  74         "rpm --eval %_includedir" | getline includedir
  75         "rpm --eval %_mandir"   | getline mandir
  76         "rpm --eval %_infodir"  | getline infodir
  77         "rpm --eval %_examplesdir"      | getline examplesdir
  78         "rpm --eval %_defaultdocdir"    | getline docdir
  79         "rpm --eval %_kdedocdir"        | getline kdedocdir
  80         "rpm --eval %_desktopdir" | getline desktopdir
  81         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  82         "rpm --eval %_javadir" | getline javadir
  83
  84         "rpm --eval %perl_sitearch" | getline perl_sitearch
  85         "rpm --eval %perl_archlib" | getline perl_archlib
  86         "rpm --eval %perl_privlib" | getline perl_privlib
  87         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  88         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  89         "rpm --eval %perl_sitelib" | getline perl_sitelib
  90
  91         "rpm --eval %py_sitescriptdir 2>/dev/null" | getline py_sitescriptdir
  92         "rpm --eval %py_sitedir 2>/dev/null" | getline py_sitedir
  93         "rpm --eval %py_scriptdir 2>/dev/null" | getline py_scriptdir
  94
  95         "rpm --eval %ruby_archdir" | getline ruby_archdir
  96         "rpm --eval %ruby_ridir" | getline ruby_ridir
  97         "rpm --eval %ruby_rubylibdir" | getline ruby_rubylibdir
  98         "rpm --eval %ruby_sitearchdir" | getline ruby_sitearchdir
  99         "rpm --eval %ruby_sitelibdir" | getline ruby_sitelibdir
 100
 101         "rpm --eval %php_pear_dir" | getline php_pear_dir
 102         "rpm --eval %tmpdir" | getline tmpdir
 103 }
 104
 105 # There should be a comment with CVS keywords on the first line of file.
 106 FNR == 1 {
 107         if (!/# \$Revision:/)   # If this line is already OK?
 108                 print "# $" "Revision:$, " "$" "Date:$" # No
 109         else {
 110                 print $0                                # Yes
 111                 next            # It is enough for first line
 112         }
 113 }
 114
 115 # If the latest line matched /%files/
 116 defattr == 1 {
 117         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 118                 if ($0 !~ /defattr/) {  # If no %defattr
 119                         print "%defattr(644,root,root,755)"     # Add it
 120                 } else {
 121                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 122                 }
 123         }
 124         defattr = 0
 125 }
 126
 127 function b_makekey(a, b,        s) {
 128         s = a "" b;
 129         # kill bcond
 130         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 131
 132         # kill commented out items
 133         gsub(/^#[ \t]*/, "", s);
 134
 135         # force order
 136         gsub(/^Summary\(/, "11Summary(", s);
 137         gsub(/^Summary/, "10Summary", s);
 138         gsub(/^Name/, "2Name", s);
 139         gsub(/^Version/, "3Version", s);
 140         gsub(/^Release/, "4Release", s);
 141         gsub(/^Epoch/, "5Epoch", s);
 142         gsub(/^License/, "5License", s);
 143         gsub(/^Group/, "6Group", s);
 144         gsub(/^URL/, "7URL", s);
 145
 146         gsub(/^BuildRequires/, "B1BuildRequires", s);
 147         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 148
 149         gsub(/^Suggests/, "X1Suggests", s);
 150         gsub(/^Provides/, "X2Provides", s);
 151         gsub(/^Obsoletes/, "X3Obsoletes", s);
 152         gsub(/^Conflicts/, "X4Conflicts", s);
 153         gsub(/^BuildArch/, "X5BuildArch", s);
 154         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 155         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 156         gsub(/^BuildRoot/, "X9BuildRoot", s);
 157
 158 #       printf("%s -> %s\n", a""b, s);
 159         return s;
 160 }
 161
 162 # Comments
 163 /^#/ && (description == 0) {
 164         if (/This file does not like to be adapterized!/) {
 165                 print                   # print this message
 166                 while (getline)         # print the rest of spec as it is
 167                         print
 168                 do_not_touch_anything = 1 # do not touch anything in END()
 169                 exit 0
 170         }
 171
 172         # Generally, comments are printed without touching
 173         sub(/[ \t]+$/, "")
 174
 175         if (/#[ \t]*Source.*md5/) {
 176                 if (usedigest == 1) {
 177                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 178                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 179                 }
 180                 print $0
 181                 next
 182         }
 183 }
 184
 185 /^%define/ {
 186         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 187         if ($2 == "_applnkdir") {
 188                 next
 189         }
 190         if ($2 == "date") {
 191                 date = 1
 192                 if (did_files == 0) {
 193                         print "%files"
 194                         print ""
 195                         did_files = 1
 196                 }
 197         }
 198
 199         # Do not add %define of _prefix if it already is.
 200         if ($2 ~ /^_prefix/) {
 201                 sub("^"prefix, $3, bindir)
 202                 sub("^"prefix, $3, sbindir)
 203                 sub("^"prefix, $3, libdir)
 204                 sub("^"prefix, $3, datadir)
 205                 sub("^"prefix, $3, includedir)
 206                 prefix = $3
 207         }
 208
 209         if ($2 ~ /_bindir/ && !/_sbindir/)
 210                 bindir = $3
 211         if ($2 ~ /_sbindir/)
 212                 sbindir = $3
 213         if ($2 ~ /_libdir/) {
 214                 if ($3 ~ /^%\(/) {
 215                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 216                         libdir = "%%%%%%%%%%%%%%"
 217                 } else {
 218                         libdir = $3
 219                 }
 220         }
 221         if ($2 ~ /_sysconfdir/) {
 222                 if ($3 ~ /^%\(/) {
 223                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 224                         sysconfdir = "%%%%%%%%%%%%%%"
 225                 } else {
 226                         sysconfdir = $3
 227                 }
 228         }
 229         if ($2 ~ /_datadir/) {
 230                 if ($3 ~ /^%\(/) {
 231                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 232                         datadir = "%%%%%%%%%%%%%%"
 233                 } else {
 234                         datadir = $3
 235                 }
 236         }
 237         if ($2 ~ /_includedir/)
 238                 includedir = $3
 239         if ($2 ~ /_mandir/)
 240                 mandir = $3
 241         if ($2 ~ /_infodir/)
 242                 infodir = $3
 243         if ($2 ~ /_docdir/)
 244                 docdir = $3
 245
 246         # version related macros
 247         if ($2 ~ /^_beta$/)
 248                 _beta = $3
 249         if ($2 ~ /^_rc$/)
 250                 _rc = $3
 251         if ($2 ~ /^_pre$/)
 252                 _pre = $3
 253         if ($2 ~ /^_snap$/)
 254                 _snap = $3
 255         if ($2 ~ /^subver$/)
 256                 subver = $3
 257
 258         # these are used usually when adapterizing external spec
 259         if ($2 ~ /^name$/)
 260                 name = $3
 261         if ($2 ~ /^version$/)
 262                 version = $3
 263         if ($2 ~ /^release$/)
 264                 release = $3
 265
 266         if ($2 ~ /^mod_name$/)
 267                 mod_name = $3
 268
 269         sub(/[ \t]+$/, "");
 270         # do nothing further, otherwise adapter thinks we're at preamble
 271         print
 272         next
 273 }
 274
 275 # Obsolete
 276 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 277         next
 278 }
 279
 280 ################
 281 # %description #
 282 ################
 283 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 284         preamble = 0
 285
 286         if (/^%description/) {
 287                 bod++
 288                 format_line = ""
 289                 format_indent = -1
 290         }
 291
 292         # Format description
 293         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 294                 if (/^[ \t]*$/) {
 295                         format_flush(format_line, format_indent)
 296                         print ""
 297                         format_line = ""
 298                         format_indent = -1
 299                 } else if (/^[ \t]*[-\*][ \t]*/) {
 300                         format_flush(format_line, format_indent)
 301                         match($0, /^[ \t]*/)
 302                         format_indent = RLENGTH
 303                         match($0, /^[ \t]*[-\*][ \t]/)
 304                         format_line = substr($0, RLENGTH)
 305                 } else
 306                         format_line = format_line " " $0
 307                 next
 308         }
 309
 310         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 311                 if (NF > 3 && $2 == "-l") {
 312                         ll = $1
 313                         for (i = 4; i <= NF; i++)
 314                                 ll = ll " " $i
 315                         $0 = ll " -l " $3
 316                 }
 317                 format_flush(format_line, format_indent)
 318                 if (bod == 2) {
 319                         bod = 1
 320                         description = 1
 321                 } else {
 322                         bod = 0
 323                         description = 0
 324                 }
 325         } else
 326                 description = 1
 327 }
 328
 329 #########
 330 # %prep #
 331 #########
 332 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 333         preamble = 0
 334         did_prep = 1
 335
 336         use_macros()
 337
 338         # Add '-q' to %setup
 339         if (/^%setup/ && !/-q/) {
 340                 sub(/^%setup/, "%setup -q")
 341         }
 342
 343         if (/^%setup/ && name != "setup") {
 344                 $0 = fixedsub(name, "%{name}", $0);
 345                 $0 = fixedsub(version, "%{version}", $0);
 346                 if (_beta) {
 347                         $0 = fixedsub(_beta, "%{_beta}", $0);
 348                 }
 349                 if (_rc) {
 350                         $0 = fixedsub(_rc, "%{_rc}", $0);
 351                 }
 352                 if (_pre) {
 353                         $0 = fixedsub(_pre, "%{_pre}", $0);
 354                 }
 355                 if (_snap) {
 356                         $0 = fixedsub(_snap, "%{_snap}", $0);
 357                 }
 358                 if (subver) {
 359                         $0 = fixedsub(subver, "%{subver}", $0);
 360                 }
 361         }
 362
 363         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 364                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 365         }
 366         sub("^%patch ", "%patch0 ");
 367
 368         # invalid in %prep
 369         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 370 }
 371
 372 ##########
 373 # %build #
 374 ##########
 375 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 376         preamble = 0
 377
 378         if (did_prep == 0) {
 379                 print "%prep"
 380                 print ""
 381                 did_prep = 1
 382         }
 383
 384         use_macros()
 385         use_tabs()
 386
 387         if (/^automake$/)
 388                 sub(/$/, " -a -c")
 389
 390         if (/LDFLAGS/) {
 391                 if (/LDFLAGS="-s"/) {
 392                         removed["LDFLAGS"] = 1
 393                         next
 394                 } else {
 395                         split($0, tmp, "LDFLAGS=")
 396                         count = split(tmp[2], flags, "\"")
 397                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 398                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 399                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 400                                 for (i = 2; i < count; i++)
 401                                         $0 = $0 flags[i] "\""
 402                         }
 403                 }
 404         }
 405
 406         if (/CFLAGS=/)
 407                 if (cflags("CFLAGS") == 0)
 408                         next
 409
 410         if (/CXXFLAGS=/)
 411                 if (cflags("CXXFLAGS") == 0)
 412                         next
 413
 414         if (/^export /) {
 415                 if (removed["LDFLAGS"])
 416                         sub(" LDFLAGS", "")
 417                 if (removed["CFLAGS"])
 418                         sub(" CFLAGS", "")
 419                 if (removed["CXXFLAGS"])
 420                         sub(" CXXFLAGS", "")
 421                 # Is there still something?
 422                 if (/^export[ ]*$/)
 423                         next
 424         }
 425
 426         # quote CC
 427         if (/CC=%{__cc} /) {
 428                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 429         }
 430
 431         # use PLD Linux macros
 432         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 433         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 434         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 435         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 436         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 437         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 438         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 439         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 440
 441         sub(/^aclocal$/, "%{__aclocal}");
 442         sub(/^autoheader$/, "%{__autoheader}");
 443         sub(/^autoconf$/, "%{__autoconf}");
 444         sub(/^automake$/, "%{__automake}");
 445         sub(/^libtoolize$/, "%{__libtoolize}");
 446
 447         # atrpms
 448         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 449         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 450 }
 451
 452 ##########
 453 # %clean #
 454 ##########
 455 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 456         did_clean = 1
 457
 458         use_macros()
 459 }
 460
 461 ############
 462 # %install #
 463 ############
 464 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 465
 466         preamble = 0
 467
 468         # foreign rpms
 469         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 470         sub("%buildroot", "$RPM_BUILD_ROOT");
 471         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 472
 473         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 474                 did_rmroot=1
 475                 print "rm -rf $RPM_BUILD_ROOT"
 476                 next
 477         }
 478
 479         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 480                 print "rm -rf $RPM_BUILD_ROOT"
 481                 did_rmroot=1
 482         }
 483
 484         if (tmpdir) {
 485                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 486                 gsub(buildroot, "$RPM_BUILD_ROOT")
 487         }
 488
 489         if (!/%{_lib}/) {
 490                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 491         }
 492
 493         use_macros()
 494
 495         # 'install -d' instead 'mkdir -p'
 496         if (/mkdir -p/)
 497                 sub(/mkdir -p/, "install -d")
 498
 499         # cp -a already implies cp -r
 500         sub(/^cp -ar/, "cp -a")
 501
 502         # No '-u root' or '-g root' for 'install'
 503         if (/^install/ && /-[ug][ \t]*root/)
 504                 gsub(/-[ug][ \t]*root /, "")
 505
 506         if (/^install/ && /-m[ \t]*[0-9]+/)
 507                 gsub(/-m[ \t]*[0-9]+ /, "")
 508
 509         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 510         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 511                 next
 512
 513         # No lines contain 'chmod' if it sets the modes to '644'
 514         if ($1 ~ /chmod/ && $2 ~ /644/)
 515                 next
 516
 517         # atrpms
 518         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 519 }
 520
 521 ##########
 522 # %files #
 523 ##########
 524 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 525         preamble = 0
 526         did_files = 1
 527
 528         if ($0 ~ /^%files/)
 529                 defattr = 1
 530
 531         use_files_macros()
 532 }
 533
 534 ##############
 535 # %changelog #
 536 ##############
 537 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 538         preamble = 0
 539         has_changelog = 1
 540         skip = 0
 541         # There should be some CVS keywords on the first line of %changelog.
 542         if (boc == 3) {
 543                 if ($0 !~ _cvsmailfeedback) {
 544                         print "* %{date} " _cvsmailfeedback > changelog_file
 545                 } else {
 546                         skip = 1
 547                 }
 548                 boc = 2
 549         }
 550         if (boc == 2 && !skip) {
 551                 if (!/All persons listed below/) {
 552                         printf "All persons listed below can be reached at " > changelog_file
 553                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 554                 } else {
 555                         skip = 1
 556                 }
 557                 boc = 1
 558         }
 559         if (boc == 1 && !skip) {
 560                 if (!/^$/) {
 561                         if (!/\$.*Log:.*\$/) {
 562                                 print "$" "Log:$" > changelog_file
 563                         }
 564                         boc = 0
 565                 }
 566         }
 567         # Define date macro.
 568         if (boc == 4) {
 569                 if (date == 0) {
 570                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 571                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 572                         date = 1
 573                 }
 574                 boc = 3
 575         }
 576
 577         sub(/[ \t]+$/, "");
 578         if (!/^%[a-z]+$/ || /changelog/) {
 579                 # stop changelog if "real" changelog starts
 580                 if (boc == 0 && /^\* /) {
 581                         boc = -1
 582                 }
 583                 if (boc == -1) {
 584                         next;
 585                 }
 586                 print > changelog_file
 587         } else {
 588                 print
 589         }
 590         next
 591 }
 592
 593 ###########
 594 # SCRIPTS #
 595 ###########
 596 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 597         preamble = 0
 598
 599         if (gsub("/usr/sbin/useradd", "%useradd")) {
 600                 sub(" 2> /dev/null \|\| :", "");
 601                 sub(" >/dev/null 2>&1 \|\|:", "");
 602         }
 603
 604         # %useradd and %groupadd may not be wrapped
 605         if (/%(useradd|groupadd).*\\$/) {
 606                 a = $0; getline;
 607                 sub(/^[\s\t]*/, "");
 608                 $0 = substr(a, 1, length(a) - 1) $0;
 609         }
 610         use_script_macros()
 611 }
 612
 613 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 614         preamble = 0
 615         use_macros()
 616 }
 617 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 618         preamble = 0
 619         use_macros()
 620 }
 621 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 622         preamble = 0
 623         use_script_macros()
 624 }
 625 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 626         preamble = 0
 627         use_script_macros()
 628 }
 629 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 630         preamble = 0
 631         use_script_macros()
 632 }
 633 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 634         preamble = 0
 635         use_script_macros()
 636 }
 637 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 638         preamble = 0
 639         use_script_macros()
 640 }
 641 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 642         preamble = 0
 643         use_script_macros()
 644 }
 645 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 646         preamble = 0
 647         use_script_macros()
 648 }
 649 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 650         preamble = 0
 651         use_script_macros()
 652 }
 653
 654 #############
 655 # PREAMBLES #
 656 #############
 657 preamble == 1 {
 658         # There should not be a space after the name of field
 659         # and before the colon.
 660         sub(/[ \t]*:/, ":")
 661
 662         if (/^%perl_module_wo_prefix/) {
 663                 name = $2
 664                 version = $3
 665                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 666         }
 667
 668         field = tolower($1)
 669         fieldnlower = $1
 670         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 671                 sub(/\.$/, "", $0);
 672         }
 673         if (field ~ /group(\([^)]+\)):/)
 674                 next
 675         if (field ~ /group:/) {
 676                 format_preamble()
 677                 group = $0;
 678                 sub(/^[^ \t]*[ \t]*/, "", group);
 679
 680                 sub(/^Amusements\/Games\/Strategy\/Real Time/, "X11/Applications/Games/Strategy", group)
 681                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 682                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 683                 sub(/^Applications\/Daemons$/, "Daemons", group)
 684                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 685                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 686                 sub(/^Applications\/Productivity$/, "X11/Applications", group)
 687                 sub(/^Database$/, "Applications/Databases", group)
 688                 sub(/^Development\/Code Generators$/, "Development", group)
 689                 sub(/^Development\/Docs$/, "Documentation", group)
 690                 sub(/^Development\/Documentation$/, "Documentation", group)
 691                 sub(/^Development\/Java/, "Development/Languages/Java", group)
 692                 sub(/^Development\/Libraries\/C and C\+\+$/, "Development/Libraries", group)
 693                 sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
 694                 sub(/^Development\/Other/,"Development", group)
 695                 sub(/^Development\/Testing$/, "Development", group)
 696                 sub(/^Emulators$/, "Applications/Emulators", group)
 697                 sub(/^Games/,"Applications/Games", group)
 698                 sub(/^Library\/Development$/, "Development/Libraries", group)
 699                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 700                 sub(/^Shells/,"Applications/Shells", group)
 701                 sub(/^System Environment\/Base$/, "Base", group)
 702                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 703                 sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
 704                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 705                 sub(/^System$/, "Base", group)
 706                 sub(/^System\/Base$/, "Base", group)
 707                 sub(/^System\/Libraries$/, "Libraries", group)
 708                 sub(/^System\/Servers$/, "Daemons", group)
 709                 sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
 710                 sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
 711                 sub(/^Utilities\//,"Applications/", group)
 712                 sub(/^Web\/Database$/, "Applications/WWW", group)
 713                 sub(/^X11\/GNOME/,"X11/Applications", group)
 714                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 715                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 716                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 717                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 718                 sub(/^X11\/Library/,"X11/Libraries", group)
 719                 sub(/^X11\/Utilities/,"X11/Applications", group)
 720                 sub(/^X11\/XFree86/, "X11", group)
 721                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 722                 sub(/^Development\/C$/, "Development/Libraries", group)
 723                 sub(/^Development\/Python$/, "Development/Languages/Python", group)
 724                 sub(/^System\/Kernel and hardware$/, "Base/Kernel", group)
 725                 sub(/^Application\/System$/, "Applications/System", group)
 726
 727                 $0 = "Group:\t\t" group
 728
 729                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 730                         x11 = 1
 731
 732                 byl_plik_z_groupmi = 0
 733                 byl_opis_grupy = 0
 734                 while ((getline linia_grup < groups_file) > 0) {
 735                         byl_plik_z_groupmi = 1
 736                         if (linia_grup == group) {
 737                                 byl_opis_grupy = 1
 738                                 break
 739                         }
 740                 }
 741
 742                 if (!byl_plik_z_groupmi)
 743                         print "######\t\t" groups_file ": no such file"
 744                 else if (!byl_opis_grupy)
 745                         print "######\t\t" "Unknown group!"
 746
 747                 close(groups_file)
 748                 did_groups = 1
 749         }
 750
 751         if (field ~ /prereq:/) {
 752                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 753         }
 754
 755         # split (build)requires, obsoletes on commas
 756         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 757                 value = substr($0, index($0, $2));
 758                 $0 = format_requires($1, value);
 759         }
 760
 761         # BR: tar (and others) is to common (rpm-build requires it)
 762         if (field ~ /^buildrequires:/) {
 763                 l = substr($0, index($0, $2));
 764                 if (l == "awk" ||
 765                         l == "binutils" ||
 766                         l == "bzip2" ||
 767                         l == "cpio" ||
 768                         l == "diffutils" ||
 769                         l == "elfutils" ||
 770                         l == "fileutils" ||
 771                         l == "findutils" ||
 772                         l == "glibc-devel" ||
 773                         l == "grep" ||
 774                         l == "gzip" ||
 775                         l == "make" ||
 776                         l == "patch" ||
 777                         l == "sed" ||
 778                         l == "sh-utils" ||
 779                         l == "tar" ||
 780                         l == "textutils") {
 781                         next
 782                 }
 783
 784                 replace_requires();
 785         }
 786
 787         if (field ~ /^requires:/) {
 788                 replace_requires();
 789         }
 790
 791
 792         # obsolete/unwanted tags
 793         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 794                 next
 795         }
 796
 797         if (field ~ /buildroot:/) {
 798                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 799                 did_build_root = 1
 800         }
 801
 802         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 803         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 804                 $1 = "License:"
 805         }
 806
 807         if (field ~ /license:/) {
 808                 l = substr($0, index($0, $2));
 809                 if (l == "Python Software Foundation License") {
 810                         l = "PSF"
 811                 }
 812                 if (l == "Apache License 2.0" || l == "Apache 2.0" || l == "Apache License Version 2.0" || l == "Apache License, Version 2.0" || l == "Apache Software License v2") {
 813                         l = "Apache v2.0"
 814                 }
 815                 if (l == "Apache Group License" || l == "Apache Software License" || l == "Apache License") {
 816                         l = "Apache"
 817                 }
 818                 if (l == "Apache-style License" || l == "Apache-style Software License") {
 819                         l = "Apache-like"
 820                 }
 821                 if (l == "Apache Software License 1.1" || l == "Apache 1.1") {
 822                         l = "Apache v1.1"
 823                 }
 824                 if (l == "GPLv2") {
 825                         l = "GPL v2"
 826                 }
 827                 if (l == "GPLv2+") {
 828                         l = "GPL v2+"
 829                 }
 830                 $0 = "License:\t" l;
 831         }
 832
 833
 834         if (field ~ /name:/) {
 835                 if ($2 == "%{name}" && name) {
 836                         $2 = name
 837                 }
 838                 name = $2
 839                 name_seen = 1;
 840         }
 841
 842         if (field ~ /version:/) {
 843                 if ($2 == "%{version}" && version) {
 844                         $2 = version
 845                 }
 846                 version = $2
 847                 version_seen = 1;
 848         }
 849
 850         if (field ~ /release:/) {
 851                 if ($2 == "%{release}" && release) {
 852                         $2 = release
 853                 }
 854                 sub(/%atrelease /, "0.", $0)
 855                 release = $2
 856                 release_seen = 1;
 857         }
 858
 859
 860         if (field ~ /serial:/)
 861                 $1 = "Epoch:"
 862
 863         if (field ~ /home-page:/)
 864                 $1 = "URL:"
 865
 866         # proper caps
 867         if (field ~ /^url:$/)
 868                 $1 = "URL:"
 869
 870         if (field ~ /^description:$/)
 871                 $1 = "\n%description\n"
 872
 873         # Use %{name} and %{version} in the filenames in "Source:"
 874         if (field ~ /^source/ || field ~ /patch/) {
 875                 n = split($2, url, /\//)
 876                 if (url[n] ~ /\.gz$/) {
 877                         url[n+1] = ".gz" url[n+1]
 878                         sub(/\.gz$/,"",url[n])
 879                 }
 880                 if (url[n] ~ /\.zip$/) {
 881                         url[n+1] = ".zip" url[n+1]
 882                         sub(/\.zip$/,"",url[n])
 883                 }
 884                 if (url[n] ~ /\.tar$/) {
 885                         url[n+1] = ".tar" url[n+1]
 886                         sub(/\.tar$/,"",url[n])
 887                 }
 888                 if (url[n] ~ /\.patch$/) {
 889                         url[n+1] = ".patch" url[n+1]
 890                         sub(/\.patch$/,"",url[n])
 891                 }
 892                 if (url[n] ~ /\.bz2$/) {
 893                         url[n+1] = ".bz2" url[n+1]
 894                         sub(/\.bz2$/,"",url[n])
 895                 }
 896                 if (url[n] ~ /\.logrotate$/) {
 897                         url[n+1] = ".logrotate" url[n+1]
 898                         sub(/\.logrotate$/,"",url[n])
 899                 }
 900                 if (url[n] ~ /\.pamd$/) {
 901                         url[n+1] = ".pamd" url[n+1]
 902                         sub(/\.pamd$/,"",url[n])
 903                 }
 904
 905                 # allow %{name} only in last url component
 906                 s = ""
 907                 for (i = 1; i <= n; i++) {
 908                         url[i] = fixedsub("%{name}", name, url[i])
 909                         if (s) {
 910                                 s = s "/" url[i]
 911                         } else {
 912                                 s = url[i]
 913                         }
 914                 }
 915                 $2 = s url[n+1]
 916
 917                 filename = url[n]
 918                 if (name) {
 919                         url[n] = fixedsub(name, "%{name}", url[n])
 920                 }
 921                 if (field ~ /source/) {
 922                         if (version) {
 923                                 url[n] = fixedsub(version, "%{version}", url[n])
 924                         }
 925                         if (_beta) {
 926                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 927                         }
 928                         if (_rc) {
 929                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 930                         }
 931                         if (_pre) {
 932                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 933                         }
 934                         if (_snap) {
 935                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 936                         }
 937                         if (subver) {
 938                                 url[n] = fixedsub(subver, "%{subver}", url[n])
 939                         }
 940                 }
 941                 # assigning to $2 kills preamble formatting
 942                 $2 = fixedsub(filename, url[n], $2)
 943
 944                 $2 = unify_url($2)
 945         }
 946
 947
 948         if (field ~ /^source:/)
 949                 $1 = "Source0:"
 950
 951         if (field ~ /^patch:/)
 952                 $1 = "Patch0:"
 953
 954         kill_preamble_macros();
 955         format_preamble()
 956
 957         if (field ~ /requires/) {
 958                 # atrpms
 959                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 960         }
 961 }
 962
 963 /^%bcond_/ {
 964         # do nothing
 965         print
 966         next
 967 }
 968
 969 # sort BR/R!
 970 #
 971 # NOTES:
 972 # - mixing BR/R and anything else confuses this (all will be sorted together)
 973 #       so don't do that.
 974 # - comments leading the BR/R can not be associated,
 975 #       so don't adapterize when the BR/R are mixed with comments
 976 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 977         if ($1 ~ /Pre[Rr]eq:/) {
 978                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 979         }
 980         if ($1 == "BR:" ) {
 981                 $1 = "BuildRequires:"
 982         }
 983         if ($1 == "R:" ) {
 984                 $1 = "Requires:"
 985         }
 986         format_preamble()
 987 #       kill_preamble_macros(); # breaks tabbing
 988
 989         b_idx++;
 990         l = substr($0, index($0, $2));
 991         b_ktmp = b_makekey($1, l);
 992         b_key[b_idx] = b_ktmp;
 993         b_val[b_ktmp] = $0;
 994
 995         next;
 996 }
 997
 998 preamble == 1 {
 999         if (b_idx > 0) {
1000                 isort(b_key, b_idx);
1001                 for (i = 1; i <= b_idx; i++) {
1002                         v = b_val[b_key[i]];
1003                         sub(/[ \t]+$/, "", v);
1004                         print "" v;
1005                 }
1006                 b_idx = 0
1007         }
1008 }
1009
1010 # main() ;-)
1011 {
1012         preamble = 1
1013
1014         sub(/[ \t]+$/, "")
1015         print
1016
1017         if (name_seen == 0 && name) {
1018                 print "Name:\t\t" name
1019                 name_seen = 1
1020         }
1021
1022         if (version_seen == 0 && version) {
1023                 print "Version:\t" version
1024                 version_seen = 1
1025         }
1026
1027         if (release_seen == 0 && release) {
1028                 print "Release:\t" release
1029                 release_seen = 1
1030         }
1031
1032         if (did_build_root == 0) {
1033 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
1034                 did_build_root = 1
1035         }
1036         if (did_groups == 0) {
1037 #               print "Group:\t\tunknown"
1038                 did_groups = 1
1039         }
1040 }
1041
1042
1043 END {
1044         if (do_not_touch_anything)
1045                 exit 0
1046
1047         # TODO: need to output these in proper place
1048         if (BR_count > 0) {
1049                 for (i = 0; i <= BR_count; i++) {
1050                         print BR[i];
1051                 }
1052         }
1053
1054         close(changelog_file)
1055         while ((getline < changelog_file) > 0)
1056                 print
1057         system("rm -f " changelog_file)
1058
1059         if (did_clean == 0) {
1060                 print ""
1061                 print "%clean"
1062                 print "rm -rf $RPM_BUILD_ROOT"
1063         }
1064
1065         if (date == 0) {
1066                 print ""
1067                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1068         }
1069
1070         if (has_changelog == 0) {
1071                 print "%changelog"
1072         }
1073
1074         if (boc > 2) {
1075                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1076         }
1077         if (boc > 1) {
1078                 printf "All persons listed below can be reached at "
1079                 print "<cvs_login>@pld-linux.org\n"
1080         }
1081         if (boc > 0) {
1082                 print "$" "Log:$"
1083         }
1084 }
1085
1086 function fixedsub(s1,s2,t, ind) {
1087 # substitutes fixed strings (not regexps)
1088         if (ind = index(t,s1))
1089                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1090         return t
1091 }
1092
1093 # There should be one or two tabs after the colon.
1094 function format_preamble()
1095 {
1096         if (/^#/ || /^%bcond_with/) {
1097                 return;
1098         }
1099         sub(/:[ \t]*/, ":")
1100         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1101                 if (RLENGTH < 8) {
1102                         sub(/:/, ":\t\t")
1103                 } else {
1104                         sub(/:/, ":\t")
1105                 }
1106         }
1107 }
1108
1109 # Replace directly specified directories with macros
1110 function use_macros()
1111 {
1112         # -m, --skip-macros, --no-macros -- skip macros subst
1113         if (ENVIRON["SKIP_MACROS"]) {
1114                 return
1115         }
1116
1117         # leave inline sed lines alone
1118         if (/(%{__sed}|sed) -i -e/) {
1119                 return;
1120         }
1121
1122         sub("%{_defaultdocdir}", "%{_docdir}");
1123         sub("%{_bindir}/perl", "%{__perl}");
1124         sub("%{_bindir}/python", "%{__python}");
1125
1126         gsub(infodir, "%{_infodir}")
1127
1128         gsub(perl_sitearch, "%{perl_sitearch}")
1129         gsub(perl_archlib, "%{perl_archlib}")
1130         gsub(perl_privlib, "%{perl_privlib}")
1131         gsub(perl_vendorlib, "%{perl_vendorlib}")
1132         gsub(perl_vendorarch, "%{perl_vendorarch}")
1133         gsub(perl_sitelib, "%{perl_sitelib}")
1134
1135         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1136         gsub(py_sitedir, "%{py_sitedir}")
1137         gsub(py_scriptdir, "%{py_scriptdir}")
1138         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1139         gsub("%{python_sitelib}", "%{py_sitedir}")
1140
1141         gsub(ruby_archdir, "%{ruby_archdir}")
1142         gsub(ruby_ridir, "%{ruby_ridir}")
1143         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1144         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1145         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1146
1147         gsub("%{_datadir}/applications", "%{_desktopdir}")
1148         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1149         gsub("%{_datadir}/java", "%{_javadir}")
1150
1151         gsub(libdir, "%{_libdir}")
1152         gsub(javadir, "%{_javadir}")
1153
1154         gsub(bindir, "%{_bindir}")
1155         gsub("%{prefix}/bin", "%{_bindir}")
1156         if (prefix"/bin" == bindir)
1157                 gsub("%{_prefix}/bin", "%{_bindir}")
1158
1159         for (c = 1; c <= NF; c++) {
1160                 if ($c ~ sbindir "/fix-info-dir")
1161                         continue;
1162                 if ($c ~ sbindir "/webapp")
1163                         continue;
1164                 if ($c ~ sbindir "/ldconfig")
1165                         continue;
1166                 if ($c ~ sbindir "/chsh")
1167                         continue;
1168                 if ($c ~ sbindir "/usermod")
1169                         continue;
1170                 if ($c ~ sbindir "/chkconfig")
1171                         continue;
1172                 if ($c ~ sbindir "/installzope(product|3package)")
1173                         continue;
1174                 gsub(sbindir, "%{_sbindir}", $c)
1175         }
1176
1177         gsub("%{prefix}/sbin", "%{_sbindir}")
1178         if (prefix"/sbin" == sbindir) {
1179                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1180         }
1181
1182         for (c = 1; c <= NF; c++) {
1183                 if ($c ~ sysconfdir "/{?cron.")
1184                         continue;
1185                 if ($c ~ sysconfdir "/{?crontab.d")
1186                         continue;
1187                 if ($c ~ sysconfdir "/{?env.d")
1188                         continue;
1189                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1190                         continue;
1191                 if ($c ~ sysconfdir "/{?udev")
1192                         continue;
1193                 if ($c ~ sysconfdir "/{?hotplug")
1194                         continue;
1195                 if ($c ~ sysconfdir "/{?logrotate.d")
1196                         continue;
1197                 if ($c ~ sysconfdir "/{?pam.d")
1198                         continue;
1199                 if ($c ~ sysconfdir "/{?profile.d")
1200                         continue;
1201                 if ($c ~ sysconfdir "/{?rc.d")
1202                         continue;
1203                 if ($c ~ sysconfdir "/{?security")
1204                         continue;
1205                 if ($c ~ sysconfdir "/{?skel")
1206                         continue;
1207                 if ($c ~ sysconfdir "/{?sysconfig")
1208                         continue;
1209                 if ($c ~ sysconfdir "/{?shrc.d")
1210                         continue;
1211                 if ($c ~ sysconfdir "/{?certs")
1212                         continue;
1213                 if ($c ~ sysconfdir "/{?X11")
1214                         continue;
1215                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1216                         continue;
1217                 if ($c ~ sysconfdir "/{?rpm")
1218                         continue;
1219                 if ($c ~ sysconfdir "/{?bash_completion.d")
1220                         continue;
1221                 if ($c ~ sysconfdir "/{?samba")
1222                         continue;
1223                 if ($c ~ sysconfdir "/shells")
1224                         continue;
1225                 if ($c ~ sysconfdir "/ppp")
1226                         continue;
1227                 if ($c ~ sysconfdir "/dbus-1")
1228                         continue;
1229                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1230         }
1231
1232         gsub(kdedocdir, "%{_kdedocdir}")
1233         gsub(docdir, "%{_docdir}")
1234         gsub(php_pear_dir, "%{php_pear_dir}")
1235
1236         for (c = 1; c <= NF; c++) {
1237                 if ($c ~ datadir "/automake")
1238                         continue;
1239                 if ($c ~ datadir "/unsermake")
1240                         continue;
1241                 if ($c ~ datadir "/file/magic.mime")
1242                         continue;
1243                 gsub(datadir, "%{_datadir}", $c)
1244         }
1245
1246         gsub("%{prefix}/share", "%{_datadir}")
1247         if (prefix"/share" == datadir)
1248                 gsub("%{_prefix}/share", "%{_datadir}")
1249
1250         # CFLAGS="-I/usr/include/ncurses is usually correct.
1251         if (!/-I\/usr\/include/) {
1252                 gsub(includedir, "%{_includedir}")
1253         }
1254
1255         gsub("%{prefix}/include", "%{_includedir}")
1256         if (prefix"/include" == includedir) {
1257                 gsub("%{_prefix}/include", "%{_includedir}")
1258         }
1259
1260         gsub(mandir, "%{_mandir}")
1261         if ($0 !~ "%{_datadir}/manual") {
1262                 gsub("%{_datadir}/man", "%{_mandir}")
1263         }
1264         gsub("%{_prefix}/share/man", "%{_mandir}")
1265         gsub("%{prefix}/share/man", "%{_mandir}")
1266         gsub("%{prefix}/man", "%{_mandir}")
1267         gsub("%{_prefix}/man", "%{_mandir}")
1268
1269         gsub(infodir, "%{_infodir}")
1270         gsub("%{prefix}/info", "%{_infodir}")
1271         gsub("%{_prefix}/info", "%{_infodir}")
1272
1273         if (prefix !~ "/X11R6") {
1274                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1275         }
1276
1277         gsub(examplesdir, "%{_examplesdir}")
1278
1279         if (prefix != "/") {
1280                 # leave --with-foo=/usr alone
1281                 if ($0 !~ "--with.*=.*" prefix) {
1282                         for (c = 1; c <= NF; c++) {
1283                                 if ($c ~ prefix "/sbin/fix-info-dir")
1284                                         continue;
1285                                 if ($c ~ prefix "/sbin/webapp")
1286                                         continue;
1287                                 if ($c ~ prefix "/sbin/chsh")
1288                                         continue;
1289                                 if ($c ~ prefix "/sbin/usermod")
1290                                         continue;
1291                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1292                                         continue;
1293                                 if ($c ~ prefix "/share/automake")
1294                                         continue;
1295                                 if ($c ~ prefix "/share/unsermake")
1296                                         continue;
1297                                 if ($c ~ prefix "/lib/sendmail")
1298                                         continue;
1299                                 if ($c ~ prefix "/lib/pkgconfig")
1300                                         continue;
1301
1302                                 # CFLAGS="-I/usr..." is usually correct.
1303                                 if (/-I\/usr/)
1304                                         continue;
1305                                 # same for LDFLAGS="-L/usr..."
1306                                 if (/-L\/usr/)
1307                                         continue;
1308
1309                                 gsub(prefix, "%{_prefix}", $c)
1310                         }
1311                 }
1312                 gsub("%{prefix}", "%{_prefix}")
1313         }
1314
1315         # replace back
1316         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1317         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1318
1319         gsub("%{PACKAGE_VERSION}", "%{version}")
1320         gsub("%{PACKAGE_NAME}", "%{name}")
1321
1322         gsub("^make$", "%{__make}")
1323         gsub("^make ", "%{__make} ")
1324         gsub("^gcc ", "%{__cc} ")
1325         gsub("^rm --interactive=never ", "%{__rm} ")
1326
1327         # mandrake specs
1328         gsub("^%make$", "%{__make}")
1329         gsub("^%make ", "%{__make} ")
1330         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1331         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1332         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1333         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1334         gsub("^%{__install}", "install")
1335         gsub("%optflags", "%{rpmcflags}")
1336         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1337
1338         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1339         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1340         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1341         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1342         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1343         $0 = fixedsub("%__install", "install", $0);
1344
1345         # split configure line to multiple lines
1346         if (/%configure / && !/\\$/) {
1347                 $0 = format_configure($0);
1348         }
1349
1350         gsub("%_bindir", "%{_bindir}")
1351         gsub("%_datadir", "%{_datadir}")
1352         gsub("%_iconsdir", "%{_iconsdir}")
1353         gsub("%_sbindir", "%{_sbindir}")
1354         gsub("%_mandir", "%{_mandir}")
1355         gsub("%name", "%{name}")
1356         gsub(/%__rm/, "rm");
1357         gsub(/%__mkdir_p/, "install -d");
1358         gsub(/%__cp/, "cp");
1359         gsub(/%__ln_s/, "ln -s");
1360         gsub(/%__sed/, "%{__sed}");
1361         gsub(/%__cat/, "cat");
1362         gsub(/%__chmod/, "chmod");
1363
1364         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1365         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1366
1367         if (/^ant /) {
1368                 sub(/^ant/, "%ant")
1369                 add_br("BuildRequires:  jpackage-utils");
1370                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1371         }
1372
1373 }
1374
1375 function format_configure(line,         n, a, s) {
1376         n = split(line, a, / /);
1377         s = a[1] " \\\n";
1378         for (i = 2; i <= n; i++) {
1379                 s = s "\t" a[i] " \\\n"
1380         }
1381         return s
1382 }
1383
1384
1385 # insertion sort of A[1..n]
1386 # copied from mawk manual
1387 function isort(A,n,             i,j,hold) {
1388         for (i = 2; i <= n; i++) {
1389                 hold = A[j = i]
1390                 while (A[j-1] > hold) {
1391                         j-- ; A[j+1] = A[j]
1392                 }
1393                 A[j] = hold
1394         }
1395         # sentinel A[0] = "" will be created if needed
1396 }
1397
1398
1399 function use_files_macros(      i, n, t, a)
1400 {
1401         use_macros()
1402
1403         # skip comments
1404         if (/^#/) {
1405                 return;
1406         }
1407
1408         sub("^%doc %{_mandir}", "%{_mandir}")
1409
1410         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1411         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1412
1413         # uid/gid nobody is not valid in %files
1414         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1415                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1416         }
1417
1418         # s[gu]id programs with globs are evil
1419         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1420                 $0 = $0 " # FIXME no globs for suid/sgid files"
1421         }
1422
1423         # replace back
1424         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1425         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1426         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1427         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1428         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1429         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1430         gsub("%{_sysconfdir}/security", "/etc/security")
1431         gsub("%{_sysconfdir}/skel", "/etc/skel")
1432         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1433         gsub("%{_sysconfdir}/certs", "/etc/certs")
1434         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1435         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1436
1437         # /etc/init.d -> /etc/rc.d/init.d
1438         if (!/^\/etc\/init\.d$/) {
1439                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1440         }
1441
1442         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1443                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1444                         $0 = "%attr(754,root,root) " $0
1445                 }
1446                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1447                         gsub("^%attr\\(... *,", "%attr(754,");
1448                 }
1449         }
1450
1451         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1452                 $0 = "%attr(755,root,root) " $0
1453         }
1454
1455         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1456                 $0 = "%attr(755,root,root) " $0
1457         }
1458
1459         # /etc/sysconfig files
1460         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1461         # attr not required, allow default 644 attr
1462         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1463                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1464                         gsub("%config", "%config(noreplace)")
1465                 }
1466
1467                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1468                         $NF = "%config(noreplace) " $NF
1469                 }
1470
1471                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1472                         gsub("^%attr\\(... *,", "%attr(640,");
1473                 }
1474
1475                 if (/\/etc\/sysconfig\// && !/%verify/) {
1476                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1477                 }
1478         }
1479
1480         # kill leading zeros
1481         if (/%attr\(0[1-9]/) {
1482                 gsub("%attr\\(0", "%attr(")
1483         }
1484
1485         # kill leading whitespace
1486         gsub(/^ +/, "");
1487
1488         # kill default attrs
1489         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1490         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1491         if (!/%dir/) {
1492                 gsub(/%attr\(644,root,root\) /, "");
1493         }
1494
1495         # sort %verify attrs
1496         if (match($0, /%verify\(not([^)]+)\)/)) {
1497                 t = substr($0, RSTART, RLENGTH)
1498                 # kill commas: %verify(not,md5,size,mtime)
1499                 gsub(/,/, " ", t);
1500
1501                 gsub(/^%verify\(not |\)$/, "", t)
1502                 n = split(t, a, / /)
1503                 isort(a, n)
1504
1505                 s = "%verify(not"
1506                 for (i = 1 ; i <= n; i++) {
1507                         s = s " " a[i]
1508                 }
1509                 s = s ")"
1510
1511                 gsub(/%verify\(not[^)]+\)/, s)
1512         }
1513
1514         if (/%{_mandir}/) {
1515                 gsub("\.gz$", "*")
1516         }
1517
1518         # locale dir and no %lang -> bad
1519         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1520                 $(NF + 1) = "# FIXME consider using %find_lang"
1521         }
1522
1523         # atrpms
1524         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1525         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1526         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1527
1528         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1529         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1530         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1531
1532         gsub("%{_datadir}/applications", "%{_desktopdir}");
1533         gsub("%{_datadir}/icons", "%{_iconsdir}");
1534         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1535 }
1536
1537 function use_script_macros()
1538 {
1539         if (gsub("/sbin/service", "%service")) {
1540                 sub(" >/dev/null 2>&1 \|\|:", "");
1541                 sub(" 2> /dev/null \|\| :", "");
1542         }
1543 }
1544
1545 function fill(ch, n, i) {
1546         for (i = 0; i < n; i++)
1547                 printf("%c", ch)
1548 }
1549
1550 function format_flush(line, indent, newline, word, first_word) {
1551         first_word = 1
1552         if (format_indent == -1)
1553                 newline = ""
1554         else
1555                 newline = fill(" ", format_indent) "- "
1556
1557         while (match(line, /[^\t ]+/)) {
1558                 word = substr(line, RSTART, RLENGTH)
1559                 if (length(newline) + length(word) + 1 > tw) {
1560                         print newline
1561
1562                         if (format_indent == -1)
1563                                 newline = ""
1564                         else
1565                                 newline = fill(" ", format_indent + 2)
1566                         first_word = 1
1567                 }
1568
1569                 if (first_word) {
1570                         newline = newline word
1571                         first_word = 0
1572                 } else
1573                         newline = newline " " word
1574
1575                 line = substr(line, RSTART + RLENGTH)
1576         }
1577         if (newline ~ /[^\t ]/) {
1578                 print newline
1579         }
1580 }
1581
1582 function cflags(var)
1583 {
1584         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1585                 removed[var] = 1
1586                 return 0
1587         }
1588
1589         if (!/!\?debug/)
1590                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1591         return 1
1592 }
1593
1594 function unify_url(url)
1595 {
1596
1597         # sourceforge urls
1598         sub("[?&]big_mirror=.*$", "", url);
1599         sub("[?&]modtime=.*$", "", url);
1600         sub("[?]use_mirror=.*$", "", url);
1601         sub("[?]download$", "", url);
1602
1603         sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1604         sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", url)
1605         sub("^http://download\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1606         sub("^http://downloads\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1607
1608         sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", url)
1609         sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", url)
1610         sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", url)
1611
1612         sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", url)
1613         sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", url)
1614
1615         # apache urls
1616         sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", url)
1617
1618         # gnu.org
1619         sub("^ftp://ftp.gnu.org/", "http://ftp.gnu.org/", url)
1620         sub("^http://ftp.gnu.org/pub/gnu/", "http://ftp.gnu.org/gnu/", url)
1621
1622         return url
1623 }
1624
1625 function demacroize(str)
1626 {
1627         if (mod_name) {
1628                 sub("%{mod_name}", mod_name, str);
1629         }
1630         if (name) {
1631                 sub("%{name}", name, str);
1632         }
1633         if (version) {
1634                 sub("%{version}", version, str);
1635         }
1636         if (_beta) {
1637                 sub("%{_beta}", _beta, str);
1638         }
1639         if (_rc) {
1640                 sub("%{_rc}", _rc, str);
1641         }
1642         if (_pre) {
1643                 sub("%{_pre}", _pre, str);
1644         }
1645         if (_snap) {
1646                 sub("%{_snap}", _snap, str);
1647         }
1648         if (subver) {
1649                 sub("%{subver}", subver, str);
1650         }
1651         return str;
1652 }
1653
1654 function kill_preamble_macros()
1655 {
1656         if ($1 ~ /^Obsoletes:/) {
1657                 # NB! assigning $2 a value breaks tabbing
1658                 $2 = demacroize($2);
1659         }
1660         if ($1 ~ /^URL:/) {
1661                 # NB! assigning $2 a value breaks tabbing
1662                 $2 = demacroize($2);
1663                 $2 = unify_url($2)
1664         }
1665 }
1666
1667 function get_epoch(pkg, ver,    epoch)
1668 {
1669         return
1670 # should parse the BR lines more adequately:
1671 #       freetype = 2.0.0 -> correct
1672 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1673
1674         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1675         shell | getline epoch;
1676         return epoch;
1677 }
1678
1679 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1680         # skip any formatting for commented out items or some weird macros
1681         if (/^#/ || /%\(/) {
1682                 return tag "\t" value
1683         }
1684         n = split(value, p, / *,? */);
1685         for (i = 1; i <= n; i++) {
1686                 if (p[i+1] ~ /[<=>]/) {
1687                         # add epoch if the version doesn't have it but BuildRequires.txt has
1688                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1689                                 epoch = get_epoch(p[i], p[i+2])
1690                                 if (epoch) {
1691                                         p[i+2] = epoch ":" p[i+2];
1692                                 }
1693                         }
1694                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1695                         i += 2;
1696                 } else {
1697                         deps[ndeps++] = p[i];
1698                 }
1699         }
1700         s = ""
1701         for (i in deps) {
1702                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1703         }
1704         return substr(s, 1, length(s)-1);
1705 }
1706
1707 function use_tabs()
1708 {
1709         # reverse vim: ts=4 sw=4 et
1710         gsub(/    /, "\t");
1711 }
1712
1713 function add_br(br)
1714 {
1715         BR[BR_count++] = br
1716 }
1717
1718 function replace_requires()
1719 {
1720
1721         # jpackages
1722         sub(/^java-devel$/, "jdk", $2);
1723         sub(/^log4j$/, "logging-log4j", $2);
1724         sub(/^jakarta-log4j$/, "logging-log4j", $2);
1725         sub(/^oro$/, "jakarta-oro", $2);
1726         sub(/^jakarta-ant$/, "ant", $2);
1727         sub(/^xerces-j2$/, "xerces-j", $2);
1728         sub(/^ldapjdk$/, "ldapsdk", $2);
1729         sub(/^saxon-scripts$/, "saxon", $2);
1730         sub(/^xalan-j2$/, "xalan-j", $2);
1731         sub(/^xerces-j2$/, "xerces-j", $2);
1732         sub(/^gnu-regexp$/, "gnu.regexp", $2);
1733
1734         # redhat virtual
1735         sub(/^tftp-server$/, "tftpdaemon", $2);
1736
1737         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2);
1738         sub(/^chkconfig$/, "/sbin/chkconfig", $2);
1739
1740         replace_php_virtual_deps()
1741 }
1742
1743 # php virtual deps as discussed in devel-en
1744 function replace_php_virtual_deps()
1745 {
1746         pkg = $2
1747 #       if (pkg == "php-program") {
1748 #               $0 = $1 "\t/usr/bin/php"
1749 #               return
1750 #       }
1751
1752 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1753 #               sub(/^php-/, "php(", pkg);
1754 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1755 #               $2 = pkg
1756 #       }
1757
1758         if (pkg ~/^php$/) {
1759                 $2 = "webserver(php)";
1760                 if ($4 ~ /^[0-9]:/) {
1761                         $4 = substr($4, 3);
1762                 }
1763         }
1764
1765         if (pkg ~/^php4$/) {
1766                 $2 = "webserver(php)";
1767                 if ($4 ~ /^[0-9]:/) {
1768                         $4 = substr($4, 3);
1769                 }
1770         }
1771 }
1772
1773 # vim:ts=4:sw=4